El tutorial mostra com comparar cadenes de text a Excel per a la concordança exacta i que no distingeix entre majúscules i minúscules. Aprendràs una sèrie de fórmules per comparar dues cel·les segons els seus valors, la longitud de la cadena o el nombre d'ocurrències d'un caràcter específic, així com com comparar diverses cel·les.

Quan utilitza Excel per a anàlisi de dades, la precisió és la preocupació més important. La informació incorrecta fa que s'incompleixin els terminis, les tendències no es jutgin, les decisions errònies i la pèrdua d'ingressos.

Tot i que les fórmules d'Excel sempre són perfectament certes, els seus resultats poden ser equivocats perquè algunes dades defectuoses han penetrat al sistema. En aquest cas, l'únic remei és comprovar la precisió de les dades. No és gran cosa comparar dues cel·les manualment, però és gairebé impossible detectar les diferències entre centenars i milers de cadenes de text.

Aquest tutorial us ensenyarà com automatitzar la tasca tediosa i propensa a errors de la cel·la. comparació i quines fórmules són les millors per utilitzar en cada cas particular.

Com comparar dues cel·les a Excel

Hi ha dues maneres diferents de comparar cadenes a Excel en funció de tant si cerqueu una comparació que distingeix entre majúscules i minúscules.

Fórmula que no distingeix entre majúscules i minúscules per comparar 2 cel·les

Per comparar dues cel·les a Excel ignorant majúscules i minúscules, utilitzeu una fórmula senzilla com aquesta:

=A1=B1

On A1 i B1 són les cel·les que esteu comparant. El resultat de la fórmula són valors booleans TRUEi FALSE.

Si voleu mostrar els vostres propis textos per a coincidències i diferències, incrusteu la declaració anterior a la prova lògica de la funció SI. Per exemple:

=IF(A1=B1, "Equal", "Not equal")

Com veieu a la captura de pantalla següent, ambdues fórmules comparen igualment bé les cadenes de text, les dates i els números:

Fórmula sensible a majúscules i minúscules per comparar cadenes a Excel

En algunes situacions, pot ser important no només comparar els valors de text de dues cel·les, sinó també comparar les majúscules i minúscules. La comparació de text que distingeix entre majúscules i minúscules es pot fer mitjançant la funció EXACTE d'Excel:

On text1 i text2 són les dues cel·les que esteu comparant.

Suposant que les vostres cadenes es troben a les cel·les A2 i B2, la fórmula és la següent:

=EXACT(A2, B2)

Com a resultat, obteniu TRUE per a les cadenes de text que coincideixin exactament amb les majúscules i minúscules. de cada caràcter, FAL en cas contrari.

Si voleu que la funció EXACTA proporcioni altres resultats, incrusteu-la en una fórmula SI i escriviu el vostre propi text per a valor_si_verdader i valor_si_fals arguments:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

La captura de pantalla següent mostra els resultats de la comparació de cadenes sensibles a majúscules i minúscules a Excel:

Com comparar diverses cel·les a Excel

Per comparar més de 2 cel·les seguides, utilitzeu les fórmules descrites als exemples anteriors en combinació amb l'operador AND. A continuació trobareu els detalls complets.

Fórmula que no distingeix entre majúscules i minúscules per compararmés de 2 cel·les

Depenent de com vulgueu mostrar els resultats, utilitzeu una de les fórmules següents:

=AND(A2=B2, A2=C2)

o

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

La fórmula AND retorna TRUE si totes les cel·les contenen el mateix valor, FALSE si algun valor és diferent. La fórmula SI mostra les etiquetes que hi escriviu, " Igual " i " No igual " en aquest exemple.

Com es mostra a la captura de pantalla següent, el La fórmula funciona perfectament amb qualsevol tipus de dades: text, dates i valors numèrics:

Fórmula que distingeix entre majúscules i minúscules per comparar text en diverses cel·les

Per comparar diverses cadenes entre si per veure si coincideixen exactament, utilitzeu les fórmules següents:

=AND(EXACT(A2,B2), EXACT(A2, C2))

O

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Com a l'exemple anterior, el primer La fórmula ofereix valors VERDADERS i FALS, mentre que la segona mostra els vostres propis textos per a coincidències i diferències:

Compara un interval de cel·les amb una cel·la de mostra

Els exemples següents mostren com podeu verificar que totes les cel·les d'un interval determinat contenen el mateix text que en una cel·la de mostra.

Fórmula que no distingeix entre majúscules i minúscules per comparar cel·les amb un text de mostra

Si el No importa realment la majúscula i minúscula, podeu utilitzar la fórmula següent per comparar cel·les amb una mostra:

A la prova lògica de la funció SI, compareu dos nombres:

• El nombre total de cel·lesen un interval especificat (el nombre de files multiplicat pel nombre de columnes) i
• El nombre de cel·les que contenen el mateix valor que a la cel·la de mostra (retornada per la funció COUNTIF).

Suposant que el text de mostra es troba a C2 i que les cadenes a comparar es troben en l'interval A2:B6, la fórmula és la següent:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Per fer que els resultats siguin més usuari- amigable, és a dir, emet alguna cosa com "Tots coincideixen" i "No tots coincideixen" en lloc de TRUE i FALSE, utilitzeu la funció SI com vam fer als exemples anteriors:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Com es mostra a la captura de pantalla anterior, la fórmula s'adapta perfectament a una sèrie de cadenes de text, però també es pot utilitzar per comparar números i dates.

Fórmula que distingeix entre majúscules i minúscules per comparar cadenes amb una text de mostra

Si les majúscules i minúscules marcan la diferència, podeu comparar les cadenes amb el text de mostra utilitzant les fórmules de matriu següents.

Amb l'interval d'origen que resideix a A2:B6 i el text de mostra a C2, la fórmula pren la forma següent:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

A diferència de les fórmules normals d'Excel , les fórmules de matriu es completen prement Ctrl + Maj + Retorn . Si s'introdueix correctament, Excel tanca la fórmula matricial entre {llances}, tal com es mostra a la captura de pantalla:

Com comparar dues cel·les per cadenalength

De vegades és possible que vulgueu comprovar si les cadenes de text de cada fila contenen el mateix nombre de caràcters. La fórmula per a aquesta tasca és molt senzilla. Primer, obteniu la longitud de la cadena de dues cel·les mitjançant la funció LEN i, a continuació, compareu els nombres.

Suposant que les cadenes que s'han de comparar es troben a les cel·les A2 i B2, utilitzeu qualsevol de les fórmules següents:

=LEN(A2)=LEN(B2)

O

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Com ja sabeu, la primera fórmula retorna valors booleans VERDADERS o FALS, mentre que la segona fórmula produeix els vostres propis resultats:

Com es demostra a la captura de pantalla anterior, les fórmules funcionen per a cadenes de text i números.

Consell. Si dues cadenes aparentment iguals retornen longituds diferents, el més probable és que el problema estigui als inicials o finals espais en una o ambdues cel·les. En aquest cas, elimineu els espais addicionals mitjançant la funció TRIM. L'explicació detallada i els exemples de fórmules es poden trobar aquí: Com retallar espais a Excel.

Compareu dues cel·les per aparicions d'un caràcter específic

Aquest és l'últim exemple del nostre tutorial de comparació de cadenes d'Excel i mostra una solució per a una tasca força específica. Suposant que teniu 2 columnes de cadenes de text que contenen un caràcter important per a vosaltres. El vostre objectiu és comprovar si dues cel·les de cada fila contenen el mateix nombre d'ocurrències d'un caràcter determinat.

Per aclarir les coses, tingueu en compte el següentexemple. Suposem que teniu dues llistes de comandes enviades (columna B) i rebudes (columna C). Cada fila conté comandes per a un article específic, l'identificador únic del qual s'inclou a tots els identificadors de comanda i es mostra a la mateixa fila de la columna A (vegeu la captura de pantalla següent). Voleu assegurar-vos que cada fila contingui el mateix nombre d'articles enviats i rebuts amb aquest identificador específic.

Per resoldre aquest problema, escriviu una fórmula amb la lògica següent.

• En primer lloc, substituïu l'identificador únic per res utilitzant la funció SUBSTITUTE:

  SUBSTITUTE(A1, character_to_count,"")

• A continuació, calculeu quantes vegades apareix l'identificador únic a cada cel·la. Per a això, obteniu la longitud de la cadena sense l'identificador únic i resteu-la de la longitud total de la cadena. Aquesta part s'escriurà per a la cel·la 1 i la cel·la 2 individualment, per exemple:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  i

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Per últim, compareu aquests 2 nombres col·locant el signe d'igualtat (=) entre les parts anteriors.

LEN( cel·la 2 ) - LEN(SUBSTITUTE( cel·la 2 , caràcter_a_comptar , ""))

En el nostre exemple, l'identificador únic és a A2 , i les cadenes a comparar es troben a les cel·les B2 i C2. Per tant, la fórmula completa és la següent:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

La fórmula retorna TRUE si les cel·les B2 i C2 contenen el mateix nombre d'ocurrències del caràcter a A2,FALS en cas contrari. Per fer que els resultats siguin més significatius per als usuaris, podeu incrustar la fórmula a la funció SI:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Com podeu veure a la captura de pantalla anterior , la fórmula funciona perfectament malgrat un parell de complicacions addicionals:

• El caràcter que s'ha de comptar (identificador únic) pot aparèixer en qualsevol lloc d'una cadena de text.
• Les cadenes contenen un número variable. de caràcters i diferents separadors com el punt i coma, la coma o l'espai.

Així es comparen les cadenes a Excel. Per veure amb més detall les fórmules que es tracten en aquest tutorial, us convidem a descarregar el full de treball de comparació de cadenes d'Excel. Us agraeixo la lectura i espero veure-us al nostre blog la setmana vinent.