Tha an oideachadh a’ sealltainn mar a nì thu coimeas eadar sreangan teacsa ann an Excel airson cùisean neo-mhothachail agus maids cheart. Ionnsaichidh tu grunn fhoirmlean gus coimeas a dhèanamh eadar dà chealla a rèir an luachan, fad sreang, no an àireamh de thachartasan de charactar sònraichte, a bharrachd air mar a nì thu coimeas eadar ioma cealla.

Nuair a chleachdas tu Excel airson mion-sgrùdadh dàta, is e cruinneas an dragh as cudromaiche. Tha fiosrachadh ceàrr a’ leantainn gu cinn-latha air chall, gluasadan mì-bhreithneachaidh, co-dhùnaidhean ceàrr agus teachd-a-steach caillte.

Ged a tha foirmlean Excel an-còmhnaidh fìor, dh’ fhaodadh gum bi na toraidhean aca ceàrr leis gun deach cuid de dhàta lochtach a-steach don t-siostam. Anns a 'chùis seo, is e an aon leigheas a bhith a' sgrùdadh dàta airson cruinneas. Chan eil e gu diofar mòr coimeas a dhèanamh eadar dà chealla le làimh, ach tha e faisg air a bhith eu-comasach na h-eadar-dhealachaidhean eadar na ceudan is mìltean de shreathan teacsa fhaicinn.

Innsidh an oideachadh seo dhut mar a nì thu fèin-ghluasad air a’ ghnìomh sgìth agus mearachdach aig cill coimeas agus dè na foirmlean as fheàrr a chleachdadh anns gach cùis shònraichte.

Mar a nì thu coimeas eadar dà chealla ann an Excel

Tha dà dhòigh eadar-dhealaichte ann airson coimeas a dhèanamh eadar sreangan ann an Excel a rèir co-dhiù a tha thu a’ sireadh coimeas cùis-mhothachail no cùis-mhothachail.

Foirmle cùis-mhothachail gus coimeas a dhèanamh eadar 2 chealla

Gus coimeas a dhèanamh eadar dà chealla ann an Excel gun chùis, cleachd foirmle sìmplidh mar seo:<3

=A1=B1

Càit a bheil A1 agus B1 na ceallan air a bheil thu a’ dèanamh coimeas. Is e toradh na foirmle luachan Boolean TRUEagus FALSE.

Ma tha thu airson na teacsaichean agad fhèin a chuir a-mach airson maidsean is eadar-dhealachaidhean, cuir a-steach an aithris gu h-àrd ann an deuchainn loidsigeach gnìomh IF. Mar eisimpleir:

=IF(A1=B1, "Equal", "Not equal")

Mar a chì thu san dealbh-sgrìn gu h-ìosal, tha an dà fhoirmle a’ dèanamh coimeas cho math ri sreangan teacsa, cinn-latha agus àireamhan:

Foirmle cùis-mhothachail airson coimeas a dhèanamh eadar sreangan ann an Excel

Ann an cuid de shuidheachaidhean, is dòcha gum bi e cudromach chan ann a-mhàin coimeas a dhèanamh eadar luachan teacsa dà chealla, ach cuideachd coimeas a dhèanamh eadar a’ chùis caractar. Faodar coimeas teacsa a tha mothachail air cùis a dhèanamh a’ cleachdadh an gnìomh Excel EXACT:

Càite a bheil text1 agus text2 an dà chealla a tha thu a’ dèanamh coimeas.

A’ gabhail ris gu bheil na teudan agad ann an ceallan A2 agus B2, tha am foirmle a’ dol mar a leanas:

=EXACT(A2, B2)

Mar thoradh air an sin, gheibh thu TRUE airson sreangan teacsa a’ maidseadh gu dìreach a’ toirt a-steach a’ chùis a thaobh gach caractar, FALSE air dhòigh eile.

Ma tha thu airson 's gun lìbhrig an gnìomh EXACT toraidhean eile, cuir a-steach e ann am foirmle IF agus taidhp an teacsa agad fhèin airson value_if_true agus value_if_false argamaidean:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Tha an dealbh-sgrìn a leanas a’ sealltainn toraidhean a’ choimeas sreang a tha mothachail air cùis ann an Excel:

Mar a nì thu dèan coimeas eadar ioma-cheallan ann an Excel

Gus coimeas a dhèanamh eadar barrachd air 2 chealla ann an sreath, cleachd na foirmlean a chaidh a dheasbad anns na h-eisimpleirean gu h-àrd còmhla ris a’ ghnìomhaiche AND. Tha am mion-fhiosrachadh slàn a' leantainn gu h-ìosal.

Foirmle cùise neo-mhothachail airson coimeas a dhèanamhbarrachd air 2 chealla

A rèir mar a tha thu airson na toraidhean a thaisbeanadh, cleachd aon de na foirmlean a leanas:

=AND(A2=B2, A2=C2)

neo

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal") <3

Bidh am foirmle AND a’ tilleadh TRUE ma tha an aon luach anns a h-uile cealla, FALSE ma tha luach sam bith eadar-dhealaichte. Tha am foirmle IF a' toirt a-mach na leubailean a tha thu a' sgrìobhadh a-steach ann, " Co-ionann " agus " Chan eil co-ionnan " san eisimpleir seo.

Mar a chithear san dealbh gu h-ìosal, tha an bidh foirmle ag obair gu foirfe le seòrsa dàta sam bith - teacsa, cinn-latha agus luachan àireamhach:

Foirmle a tha mothachail air cùis gus coimeas a dhèanamh eadar teacsa ann an grunn cheallan

Gus coimeas a dhèanamh eadar iomadh sreath ri chèile feuch a bheil iad a’ maidseadh gu dìreach, cleachd na foirmlean a leanas:

=AND(EXACT(A2,B2), EXACT(A2, C2))

No

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Mar a bha san eisimpleir roimhe, a’ chiad fhear foirmle a’ lìbhrigeadh luachan TRUE agus FALSE, ach tha an dàrna fear a’ taisbeanadh na teacsaichean agad fhèin airson maidsean is eadar-dhealachaidhean:

Dèan coimeas eadar raon cheallan agus sampall cealla

Tha na h-eisimpleirean a leanas a' sealltainn mar as urrainn dhut dearbhadh gu bheil an aon teacsa anns a h-uile ceal ann an raon sònraichte 's a tha ann an cill sampall.

Foirmle cùis-mhothachail airson coimeas a dhèanamh eadar ceallan agus sampall teacsa

Ma tha an chan eil cùis caractar gu diofar, faodaidh tu am foirmle a leanas a chleachdadh gus coimeas a dhèanamh eadar ceallan agus sampall:

Ann an deuchainn loidsigeach gnìomh IF, bidh thu a’ dèanamh coimeas eadar dà àireamh:

• An àireamh iomlan de cheallanann an raon sònraichte (an àireamh de shreathan air an iomadachadh le àireamh nan colbhan), agus
• An àireamh de cheallan anns a bheil an aon luach agus a tha sa chill sampall (air a thilleadh leis a’ ghnìomh COUNTIF).
<5

A’ gabhail ris gu bheil an teacsa sampall ann an C2 agus gu bheil na sreangan airson coimeas a dhèanamh anns an raon A2:B6, tha am foirmle a’ dol mar a leanas:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Gus na toraidhean a dhèanamh nas cleachdaiche- càirdeil, ie cuir a-mach rudeigin mar "All match" agus "Chan eil a h-uile maids" an àite TRUE agus FALSE, cleachd an gnìomh IF mar a rinn sinn anns na h-eisimpleirean roimhe:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")



Mar a chithear san dealbh-sgrìn gu h-àrd, bidh am foirmle a’ dèiligeadh gu foirfe ri raon de shreathan teacsa, ach faodar a cleachdadh cuideachd airson coimeas a dhèanamh eadar àireamhan is cinn-latha. sampall teacsa

Ma nì a’ chùis caractair eadar-dhealachadh, ’s urrainn dhut teudan a choimeas ris an teacsa sampaill a’ cleachdadh na foirmlean rèite a leanas.

IF(ROWS( raon )*COLUMNS( raon )=SUM(--EXACT( sample_cell , raon )), " text_if_match ", " text_if_ chan eil iad a' maidseadh ")

Leis an raon thùsail ann an A2:B6 agus an teacsa sampall ann an C2, tha an cumadh a leanas air an fhoirmle:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Eu-coltach ri foirmlean àbhaisteach Excel , tha foirmlean rèite air an crìochnachadh le bhith a’ putadh Ctrl + Shift + Enter . Ma thèid a chuir a-steach gu ceart, tha Excel a’ cuairteachadh na foirmle rèite ann an {braces lùbte}, mar a chithear san dealbh-sgrìn:



Mar a nì thu coimeas eadar dà chealla le sreangfaid

Uaireannan 's dòcha gum bi thu airson faighinn a-mach a bheil an aon àireamh de charactaran anns na teudan teacsa anns gach sreath. Tha am foirmle airson na h-obrach seo gu math sìmplidh. An toiseach, gheibh thu fad sreang dà chealla a’ cleachdadh an ghnìomh LEN, agus an uair sin dèan coimeas eadar na h-àireamhan.

Ma tha na teudan ri choimeas ann an ceallan A2 agus B2, cleachd aon dhe na foirmlean a leanas:

=LEN(A2)=LEN(B2)

No

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Mar a tha fios agad mu thràth, tha a’ chiad fhoirmle a’ tilleadh luachan Boolean TRUE no FALSE, ach tha an dàrna foirmle a’ toirt a-mach na toraidhean agad fhèin:<3



Mar a chithear san dealbh gu h-àrd, tha na foirmlean ag obair airson teudan teacsa a bharrachd air àireamhan.

Gliocas. Ma thilleas dà shreath a tha coltach gu co-ionann faid eadar-dhealaichte, is coltaiche gu bheil an duilgheadas ann an stiùireadh no slighe àitean ann an aon no an dà chealla. Anns a 'chùis seo, thoir air falbh àiteachan a bharrachd a' cleachdadh an gnìomh TRIM. Gheibhear am mìneachadh mionaideach agus eisimpleirean foirmle an seo: Mar a ghearras tu àiteachan ann an Excel.

Dèan coimeas eadar dà chealla le tachartasan de charactar sònraichte

Seo an eisimpleir mu dheireadh anns an oideachadh Excel Compare Strings againn, agus tha e a’ sealltainn fuasgladh airson gnìomh caran sònraichte. A dh 'aindeoin, tha 2 cholbh de shreathan teacsa agad anns a bheil caractar a tha cudromach dhut. 'S e an t-amas agad dearbhadh a bheil an aon àireamh de thachartasan de charactar sònraichte ann an dà chealla anns gach sreath.

Gus cùisean a dhèanamh nas soilleire, smaoinich air na leanaseisimpleir. Canaidh sinn, tha dà liosta òrdughan agad air an cur (colbh B) agus air fhaighinn (colbh C). Anns gach sreath tha òrdughan airson rud sònraichte, aig a bheil an aithnichear sònraichte air a ghabhail a-steach anns a h-uile ID òrdugh agus air a liostadh san aon sreath ann an colbh A (faic an dealbh gu h-ìosal). Tha thu airson dèanamh cinnteach gu bheil an aon àireamh de nithean air an cur air falbh 's air fhaighinn leis an ID shònraichte sin anns gach sreath.

Gus an duilgheadas seo fhuasgladh, sgrìobh foirmle leis an reusanachadh a leanas.

• An toiseach, cuir dad an àite an aithnichear sònraichte le bhith a’ cleachdadh an gnìomh SUBSTITUTE:

  SUBSTITUTE(A1, character_to_count,"")

• An uairsin, obraich a-mach cia mheud uair a nochdas an aithnichear sònraichte anns gach cealla. Airson seo, faigh fad an t-sreang às aonais an aithnichear sònraichte agus thoir air falbh e bho fhad iomlan an t-sreang. Thèid am pàirt seo a sgrìobhadh airson ceal 1 agus ceal 2 leotha fhèin, mar eisimpleir:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  agus

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Mu dheireadh, nì thu coimeas eadar an dà àireamh seo le bhith a’ cur an soidhne co-ionannachd (=) eadar na pàirtean gu h-àrd.
LEN( cealla 1 ) - LEN(SUBSTITUTE( ceal 1 , charactar_to_count ," ""))=

LEN( ceal 2 ) - LEN(SUBSTITUTE( cell 2 , character_to_count , ""))

San eisimpleir againn, tha an aithnichear sònraichte ann an A2 , agus tha na teudan airson coimeas a dhèanamh ann an ceallan B2 agus C2. Mar sin, tha am foirmle iomlan mar a leanas:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Tha am foirmle a’ tilleadh TRUE ma tha an aon àireamh de thachartasan ann an ceallan B2 agus C2 ann an A2,FALSE a chaochladh. Gus na toraidhean a dhèanamh nas ciallaiche don luchd-cleachdaidh agad, faodaidh tu am foirmle a chur a-steach don ghnìomh IF:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Faic cuideachd: Cuir a-steach fiosan bho Excel gu Outlook ann an 3 ceumannan sgiobalta



Mar a chì thu san dealbh-sgrìn gu h-àrd , tha am foirmle ag obair gu foirfe a dh’ aindeoin duilgheadas no dhà a bharrachd:

• Faodaidh an caractar a thèid a chunntadh (aithnichear gun samhail) nochdadh an àite sam bith ann an sreang teacsa.
• Tha àireamh caochlaideach anns na teudan de charactaran agus luchd-sgaraidh eadar-dhealaichte leithid leth-choloin, cromag no àite.

Seo mar a nì thu coimeas eadar sreangan ann an Excel. Gus sùil nas mionaidiche a thoirt air na foirmlean air an deach beachdachadh san oideachadh seo, tha fàilte ort duilleag-obrach Excel Compare Strings a luchdachadh sìos. Tha mi a' toirt taing dhut airson an leughadh agus an dòchas ur faicinn air a' bhlog againn an ath-sheachdain.