Упатството покажува како да се споредат текстуалните низи во Excel за нечувствителни на големи букви и точно совпаѓање. Ќе научите голем број формули за споредување на две ќелии според нивните вредности, должината на низата или бројот на појавувања на одреден знак, како и како да споредите повеќе ќелии.

Кога користите Excel за анализа на податоци, точноста е највиталната грижа. Неточните информации доведуваат до пропуштени рокови, погрешни трендови, погрешни одлуки и изгубени приходи.

Иако формулите на Excel се секогаш совршено вистинити, нивните резултати може да бидат погрешни бидејќи некои неисправни податоци навлегле во системот. Во овој случај, единствениот лек е да ги проверите податоците за точност. Не е голема работа рачно да се споредуваат две ќелии, но речиси е невозможно да се забележат разликите помеѓу стотици и илјадници текстуални низи.

Овој туторијал ќе ве научи како да ја автоматизирате мачната и склона кон грешки задача на ќелијата споредба и кои формули се најдобро да се користат во секој конкретен случај.

Како да се споредат две ќелии во Excel

Постојат два различни начини за споредување низи во Excel во зависност од без разлика дали барате споредба чувствителна на големи или големи букви.

Формула за споредба на 2 ќелии не се чувствителни на големи букви

За да споредите две ќелии во Excel игнорирајќи букви, користете едноставна формула како оваа:

=A1=B1

Каде A1 и B1 се ќелиите што ги споредувате. Резултатот од формулата се Булови вредности ТОЧНОи FALSE.

Ако сакате да излезете од вашите сопствени текстови за совпаѓање и разлики, вметнете ја горната изјава во логичкиот тест на функцијата IF. На пример:

=IF(A1=B1, "Equal", "Not equal")

Како што гледате на екранот подолу, двете формули подеднакво добро ги споредуваат текстуалните низи, датумите и броевите:

Формула чувствителна на букви за споредување низи во Excel

Во некои ситуации, можеби е важно не само да се споредат текстуалните вредности на две ќелии, туку и да се споредат буквите на знаците. Споредбата на текст чувствителна на букви може да се направи со помош на функцијата Excel EXACT:

Каде што текст1 и текст2 се двете ќелии што ги споредувате.

Претпоставувајќи дека вашите низи се во ќелиите A2 и B2, формулата оди на следниов начин:

=EXACT(A2, B2)

Како резултат на тоа, добивате TRUE за текстуалните низи точно да се совпаѓаат вклучувајќи го и случајот од секој знак, во спротивно FALSE.

Ако сакате функцијата EXACT да дава некои други резултати, вметнете ја во формулата IF и напишете свој текст за value_if_true и value_if_false аргументи:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Следната слика од екранот ги прикажува резултатите од споредбата на низи чувствителни на големи букви во Excel:

Како да споредете повеќе ќелии во Excel

За да споредите повеќе од 2 ќелии по ред, користете ги формулите дискутирани во горните примери во комбинација со операторот AND. Целосните детали следуваат подолу.

Формула за споредување нечувствителна на големи буквиповеќе од 2 ќелии

Во зависност од тоа како сакате да ги прикажете резултатите, користете една од следниве формули:

=AND(A2=B2, A2=C2)

или

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

Формулата И враќа TRUE ако сите ќелии ја содржат истата вредност, FALSE ако некоја вредност е различна. Формулата IF ги прикажува етикетите што ги внесувате во неа, „ Еднакво “ и „ Не еднакво “ во овој пример.

Како што е прикажано на сликата од екранот подолу, формулата работи совршено со сите типови податоци - текст, датуми и нумерички вредности:

Формула чувствителна на букви за споредување текст во неколку ќелии

За споредба на повеќе низи еден на друг за да видите дали точно се совпаѓаат, користете ги следните формули:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Или

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Како во претходниот пример, првиот формулата испорачува TRUE и FALSE вредности, додека втората ги прикажува вашите сопствени текстови за совпаѓање и разлики:

Споредете опсег на ќелии со клетка примерок

Следниве примери покажуваат како можете да потврдите дека сите ќелии во даден опсег го содржат истиот текст како во ќелијата примерок.

Формула која не е чувствителна на букви за споредување ќелии со примерок текст

Ако буквите на знаците навистина не се важни, можете да ја користите следнава формула за да ги споредите ќелиите со примерок:

Во логичкиот тест на функцијата IF, споредувате два броја:

• Вкупниот број на ќелииво одреден опсег (бројот на редови помножен со бројот на колони) и
• Бројот на ќелии што ја содржат истата вредност како во ќелијата примерок (вратен со функцијата COUNTIF).

Претпоставувајќи дека примерокот текст е во C2 и низите што треба да се споредат се во опсегот A2:B6, формулата оди на следниов начин:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

За да ги направиме резултатите повеќе кориснички- пријателски, т.е. излези нешто како „Сите се совпаѓаат“ и „Не сите се совпаѓаат“ наместо TRUE и FALSE, користете ја функцијата IF како што направивме во претходните примери:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Како што е прикажано на горната слика од екранот, формулата совршено се справува со низа текстуални низи, но може да се користи и за споредување броеви и датуми.

Формула чувствителна на букви за споредување низи со примерок текст

Ако големината на знакот прави разлика, можете да ги споредите низите со примерокот на текстот користејќи ги следните формули на низа.

Со изворниот опсег што се наоѓа во A2:B6 и примерокот на текст во C2, формулата ја добива следната форма:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

За разлика од обичните формули на Excel , формулите на низата се комплетираат со притискање на Ctrl + Shift + Enter . Ако е правилно внесено, Excel ја става формулата на низата во {кадрави загради}, како што е прикажано на сликата од екранот:

Како да споредите две ќелии со низадолжина

Понекогаш можеби ќе сакате да проверите дали текстуалните низи во секој ред содржат еднаков број знаци. Формулата за оваа задача е многу едноставна. Прво, ја добивате должината на стрингот на две ќелии користејќи ја функцијата LEN, а потоа ги споредувате броевите.

Да претпоставиме дека низите што треба да се споредат се во ќелиите A2 и B2, користете една од следниве формули:

=LEN(A2)=LEN(B2)

Или

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Како што веќе знаете, првата формула враќа Булова вредност TRUE или FALSE, додека втората формула ги дава вашите сопствени резултати:

Како што е прикажано на горната слика од екранот, формулите работат и за текстуални низи, како и за броеви.

Совет. Ако две навидум еднакви жици враќаат различни должини, најверојатно проблемот е во водните или заостанати простори во едната или двете ќелии. Во овој случај, отстранете ги дополнителните празни места користејќи ја функцијата TRIM. Деталното објаснување и примерите на формулата може да се најдат овде: Како да ги намалите празнините во Excel.

Споредете две ќелии по појава на специфичен знак

Ова е последниот пример во нашиот туторијал за споредување низи на Excel и покажува решение за прилично специфична задача. Да претпоставиме дека имате 2 колони текстуални низи кои содржат знак важен за вас. Вашата цел е да проверите дали две ќелии во секој ред содржат ист број на појави на даден знак.

За да ги направите работите појасни, разгледајте го следновопример. Да речеме, имате две списоци на нарачки испратени (колона Б) и примени (колона В). Секој ред содржи нарачки за одредена ставка, чиј уникатен идентификатор е вклучен во сите ID на нарачки и е наведен во истиот ред во колоната А (ве молиме погледнете ја сликата од екранот подолу). Сакате да бидете сигурни дека секој ред содржи еднаков број на испорачани и примени ставки со тој специфичен ID.

За да го решите овој проблем, напишете формула со следнава логика.

• Прво, заменете го единствениот идентификатор со ништо користејќи ја функцијата SUBSTITUTE:

  SUBSTITUTE(A1, character_to_count,"")

• Потоа, пресметајте колку пати единствениот идентификатор се појавува во секоја ќелија. За ова, земете ја должината на низата без единствениот идентификатор и одземете ја од вкупната должина на низата. Овој дел ќе биде напишан за ќелијата 1 и ќелијата 2 поединечно, на пример:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  и

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• На крај, споредете ги овие 2 броја со поставување на знакот за еднаквост (=) помеѓу горенаведените делови.

LEN( ќелија 2 ) - LEN(SUBSTITUTE( ќелија 2 , знак_да_брои , ""))

Во нашиот пример, единствениот идентификатор е во A2 , а низите за споредба се во ќелиите B2 и C2. Значи, комплетната формула е следна:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Формулата враќа ТОЧНО ако ќелиите B2 и C2 содржат еднаков број на појавувања на знакот во A2,НЕТОЧНО инаку. За да ги направите резултатите позначајни за вашите корисници, можете да ја вметнете формулата во функцијата IF:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Како што можете да видите на сликата од екранот погоре , формулата функционира совршено и покрај неколку дополнителни компликации:

• Кликот што треба да се брои (единствен идентификатор) може да се појави каде било во текстуалната низа.
• Ниците содржат променлив број на знаци и различни разделувачи како точка-запирка, запирка или празно место.

Вака ги споредувате низите во Excel. За поблиску да ги погледнете формулите дискутирани во ова упатство, добредојдени сте да го преземете Excel Compare String Worksheet. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела.