Tutorial nunjukkeun cara ngabandingkeun senar téks dina Excel pikeun pacocokan anu teu sensitip sareng pasti. Anjeun bakal diajar sababaraha rumus pikeun ngabandingkeun dua sél ku nilai, panjang string, atawa jumlah kajadian tina karakter husus, kitu ogé kumaha carana ngabandingkeun sababaraha sél.

Nalika ngagunakeun Excel pikeun analisis data, akurasi mangrupa perhatian paling vital. Inpormasi anu salah nyababkeun wates waktu anu lasut, tren anu salah, kaputusan anu salah sareng panghasilan anu leungit.

Sanaos rumus Excel salawasna leres leres, hasilna tiasa salah sabab sababaraha data cacad tembus kana sistem. Dina hal ieu, hiji-hijina ubar nyaéta mariksa katepatan data. Henteu masalah gedé pikeun ngabandingkeun dua sél sacara manual, tapi ampir teu mungkin pikeun ningali bédana antara ratusan sareng rébuan string téks.

Tutorial ieu bakal ngajarkeun anjeun kumaha ngajadikeun otomatis tugas sél anu pikasieuneun sareng rawan kasalahan. babandingan jeung rumus naon nu pangalusna dipaké dina unggal kasus nu tangtu.

Kumaha ngabandingkeun dua sél dina Excel

Aya dua cara béda pikeun ngabandingkeun string dina Excel gumantung kana naha anjeun milarian babandingan sénsitip-sénsitip atanapi kasus-sénsitip.

Rumus sénsitip hurup pikeun ngabandingkeun 2 sél

Pikeun ngabandingkeun dua sél dina Excel anu teu malire kasus, paké rumus saderhana sapertos kieu:

=A1=B1

Dimana A1 sareng B1 mangrupikeun sél anu anjeun bandingkeun. Hasil tina rumus nyaéta nilai Boolean BENERsareng PALSU.

Upami anjeun hoyong kaluaran téks anjeun nyalira pikeun patandingan sareng bédana, lebetkeun pernyataan di luhur dina uji logis tina fungsi IF. Contona:

=IF(A1=B1, "Equal", "Not equal")

Sakumaha nu katingali dina screenshot di handap, duanana rumus ngabandingkeun string téks, kaping jeung angka sarua ogé:

Rumus sénsitip hurup pikeun ngabandingkeun string dina Excel

Dina sababaraha kaayaan, meureun penting henteu ngan ukur ngabandingkeun nilai téks dua sél, tapi ogé pikeun ngabandingkeun kasus karakter. Perbandingan téks sénsitip leutik tiasa dilakukeun nganggo fungsi Excel EXACT:

Dimana text1 sareng text2 mangrupikeun dua sél anu anjeun bandingkeun.

Anggap string anjeun aya dina sél A2 jeung B2, rumusna kieu:

=EXACT(A2, B2)

Hasilna, anjeun meunang TRUE pikeun string téks cocog persis kaasup kasus. unggal karakter, FALSE sabalikna.

Upami anjeun hoyong pungsi EXACT pikeun nganteurkeun sababaraha hasil anu sanés, lebetkeun kana rumus IF teras ketik téks anjeun nyalira pikeun value_if_true sareng value_if_false argumen:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Potret layar di handap ieu nembongkeun hasil babandingan string sensitip leutik dina Excel:

Kumaha carana ngabandingkeun sababaraha sél dina Excel

Pikeun ngabandingkeun leuwih ti 2 sél dina urutan, make rumus dibahas dina conto di luhur dina kombinasi jeung operator AND. Rincian lengkepna di handap ieu.

Rumus sensitip-huruf pikeun ngabandingkeunleuwih ti 2 sél

Gumantung kumaha rék mintonkeun hasilna, gunakeun salah sahiji rumus ieu:

=AND(A2=B2, A2=C2)

atawa

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

Rumus AND ngabalikeun BENER upami sadaya sél ngandung nilai anu sami, PALSU upami aya nilai anu béda. Rumus IF ngaluarkeun labél anu anjeun ketik di jerona, " Sarua " sareng " Teu sarua " dina conto ieu.

Sapertos anu dipidangkeun dina screenshot di handap, rumus dianggo sampurna sareng jinis data naon waé - téks, kaping sareng nilai numerik:

Rumus sénsitip hurup pikeun ngabandingkeun téks dina sababaraha sél

Pikeun ngabandingkeun sababaraha senar pikeun ningali naha éta cocog persis, paké rumus ieu:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Atawa

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Sapertos dina conto sateuacana, anu kahiji rumus ngirimkeun nilai BENER jeung PALSU, sedengkeun nu kadua mintonkeun téks anjeun sorangan pikeun patandingan jeung bédana:

Bandingkeun rentang sél jeung sél sampel

Conto di handap ieu nunjukkeun kumaha anjeun tiasa pariksa yén sadaya sél dina rentang anu ditangtukeun ngandung téks anu sami sareng dina sél sampel.

Rumus sensitip-huruf pikeun ngabandingkeun sél kana téks sampel

Lamun kasus karakter henteu masalah, anjeun tiasa nganggo rumus ieu pikeun ngabandingkeun sél kana sampel:

Dina uji logis fungsi IF, anjeun ngabandingkeun dua angka:

• Jumlah séldina rentang nu tangtu (jumlah baris dikalikeun ku jumlah kolom), jeung
• Jumlah sél nu ngandung nilai sarua jeung dina sél sampel (dipulangkeun ku fungsi COUNTIF).

Anggap téks sampel aya dina C2 jeung string pikeun ngabandingkeun aya dina rentang A2:B6, rumusna kieu:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Pikeun nyieun hasilna leuwih pamaké- ramah, nyaéta kaluaran sapertos "Sadaya cocok" sareng "Teu sadayana cocog" tinimbang BENER sareng PALSU, nganggo fungsi IF sapertos anu urang lakukeun dina conto sateuacana:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Saperti anu dipidangkeun dina screenshot di luhur, rumusna sampurna nyumponan sauntuyan string téks, tapi ogé bisa dipaké pikeun ngabandingkeun angka jeung kaping.

Rumus sénsitip hurup pikeun ngabandingkeun string ka a conto téks

Lamun kasus karakter ngajadikeun bédana, anjeun bisa ngabandingkeun string jeung téks sampel ngagunakeun rumus array handap.

Kalayan rentang sumber nu aya dina A2:B6 jeung sampel téks dina C2, rumusna jadi kieu:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Teu kawas rumus Excel biasa , Rumus Asép Sunandar Sunarya réngsé ku mencét Ctrl + Shift + Lebetkeun. Lamun diasupkeun bener, Excel ngawengku rumus array dina {curly braces}, sakumaha ditémbongkeun dina screenshot:

Kumaha carana ngabandingkeun dua sél ku stringpanjang

Sakapeung anjeun hoyong pariksa naha string téks dina unggal baris ngandung jumlah karakter anu sarua. Rumus pikeun tugas ieu basajan pisan. Kahiji, anjeun meunang panjang string dua sél ngagunakeun fungsi LEN, lajeng ngabandingkeun angka.

Anggap string nu bakal dibandingkeun dina sél A2 jeung B2, make salah sahiji rumus ieu:

=LEN(A2)=LEN(B2)

Atawa

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Sapertos anjeun terang, rumus kahiji ngabalikeun nilai Boolean BENER atanapi SALAH, sedengkeun rumus kadua ngahasilkeun hasil anjeun sorangan:

Sakumaha anu dipidangkeun dina screenshot di luhur, rumus dianggo pikeun string téks ogé angka.

Tip. Lamun dua senar sigana sarua balik panjangna béda, paling kamungkinan masalahna aya dina ngarah atawa labuh spasi dina hiji atawa duanana sél. Dina hal ieu, piceun spasi tambahan ngagunakeun fungsi TRIM. Katerangan lengkep sareng conto rumus tiasa dipendakan di dieu: Kumaha motong rohangan dina Excel.

Bandingkeun dua sél dumasar kana kajadian karakter husus

Ieu conto panungtungan dina Excel urang Bandingkeun Strings tutorial, sarta nembongkeun solusi pikeun tugas rada husus. Upami anjeun gaduh 2 kolom senar téks anu ngandung karakter anu penting pikeun anjeun. Tujuan anjeun nyaéta pikeun mariksa naha dua sél dina unggal baris ngandung jumlah kajadian anu sami dina karakter anu ditangtukeun.

Pikeun langkung jelas, pertimbangkeun ieu di handap.conto. Sebutkeun, anjeun gaduh dua daptar pesenan anu dikirimkeun (kolom B) sareng nampi (kolom C). Unggal baris ngandung pesenan pikeun item husus, nu identifier unik kaasup dina sakabéh ID urutan na didaptarkeun dina baris sarua dina kolom A (mangga tingali screenshot handap). Anjeun hoyong mastikeun yén unggal baris ngandung jumlah anu sami sareng barang anu dikirim sareng katampi kalayan ID khusus éta.

Pikeun ngajawab masalah ieu, tulis rumus kalayan logika ieu.

• Mimiti, ganti identifier unik nganggo fungsi SUBSTITUTE:

  SUBSTITUTE(A1, character_to_count,"")

  Tempo_ogé: Selapkeun gambar tina SharePoint dina pesen Outlook nganggo Témplat Email Dibagi
• Teras, itung sabaraha kali identifier unik muncul dina unggal sél. Jang ngalampahkeun ieu, meunang panjang string tanpa identifier unik tur subtract tina total panjang string. Bagian ieu bakal ditulis pikeun sél 1 jeung sél 2 individual, contona:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  jeung

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Pamungkas, anjeun ngabandingkeun 2 angka ieu ku cara nempatkeun tanda sarua (=) di antara bagian di luhur.

LEN( sél 2 ) - LEN(SUBSTITUTE( sél 2 , karakter_to_count , ""))

Dina conto urang, identifier unik aya dina A2 , sarta string pikeun ngabandingkeun aya dina sél B2 jeung C2. Jadi, rumus lengkepna kieu:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Rumusna ngabalikeun BENER lamun sél B2 jeung C2 ngandung jumlah kajadian anu sarua dina karakter dina A2,PALSU disebutkeun. Pikeun ngajantenkeun hasil langkung bermakna pikeun pangguna anjeun, anjeun tiasa nyelapkeun rumus dina pungsi IF:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Sapertos anu anjeun tingali dina layar di luhur. , rumusna jalan sampurna sanajan aya sababaraha komplikasi tambahan:

• Karakter nu bakal diitung (identifier unik) bisa muncul di mana waé dina string téks.
• Senar ngandung angka variabel tina karakter sareng separator anu béda sapertos titik koma, koma atanapi spasi.

Kieu kumaha anjeun ngabandingkeun string dina Excel. Pikeun ningali langkung caket kana rumus anu dibahas dina tutorial ieu, anjeun tiasa ngaunduh Lembar Kerja Excel Compare Strings. Abdi ngahaturkeun nuhun pikeun maca sareng ngarepkeun anjeun tiasa ningali dina blog urang minggu payun.