අන්තර්ගත වගුව
Case-sensitive සහ හරියටම ගැළපීම සඳහා Excel හි පෙළ තන්තු සංසන්දනය කරන ආකාරය නිබන්ධනය පෙන්වයි. සෛල දෙකක් ඒවායේ අගයන්, තන්තු දිග, හෝ නිශ්චිත අක්ෂරයක සිදුවීම් ගණන, මෙන්ම බහු සෛල සංසන්දනය කරන ආකාරය අනුව ඔබ සූත්‍ර ගණනාවක් ඉගෙන ගනු ඇත.
එක්සෙල් භාවිතා කරන විට දත්ත විශ්ලේෂණය, නිරවද්‍යතාවය වඩාත් වැදගත් සැලකිල්ලකි. වැරදි තොරතුරු මග හැරුණු කාලසීමාවන්, වැරදි ලෙස විනිශ්චය කරන ලද ප්‍රවණතා, වැරදි තීරණ සහ නැතිවූ ආදායම් වලට මග පාදයි.
Excel සූත්‍ර සෑම විටම සම්පුර්ණයෙන්ම සත්‍ය වන අතර, සමහර දෝෂ සහිත දත්ත පද්ධතියට විනිවිද යාම නිසා ඒවායේ ප්‍රතිඵල වැරදි විය හැක. මෙම අවස්ථාවේදී, එකම පිළියම වන්නේ නිරවද්යතාව සඳහා දත්ත පරීක්ෂා කිරීමයි. සෛල දෙකක් අතින් සංසන්දනය කිරීම ලොකු දෙයක් නොවේ, නමුත් පෙළ තන්තු සිය ගණනක් සහ දහස් ගණනක් අතර ඇති වෙනස්කම් හඳුනා ගැනීමට නොහැකි තරම්ය.
මෙම නිබන්ධනය සෛලයේ වෙහෙසකර සහ දෝෂ සහිත කාර්යය ස්වයංක්‍රීය කරන්නේ කෙසේදැයි ඔබට කියා දෙනු ඇත. සංසන්දනය කිරීම සහ එක් එක් විශේෂිත අවස්ථාවෙහි භාවිතා කිරීමට හොඳම සූත්‍ර මොනවාද.
Excel හි සෛල දෙකක් සංසන්දනය කරන්නේ කෙසේද
එක්සෙල් මත පදනම්ව තන්තු සංසන්දනය කිරීමට විවිධ ක්‍රම දෙකක් තිබේ ඔබ කේස්-සංවේදී හෝ සිද්ධි-සංවේදි සංසන්දනය සොයන්නේද යන්න.
කොටු 2ක් සංසන්දනය කිරීමට සිද්ධි-අසංවේදී සූත්රය
Excel නොසලකා හැර ඇති අවස්ථාවක සෛල දෙකක් සංසන්දනය කිරීමට, මෙවැනි සරල සූත්‍රයක් භාවිතා කරන්න:
=A1=B1
A1 සහ B1 ඔබ සංසන්දනය කරන සෛල වේ. සූත්‍රයේ ප්‍රතිඵලය බූලියන් අගයන් සත්‍ය වේසහ FALSE.
ඔබට ගැලපෙන සහ වෙනස්කම් සඳහා ඔබේම පෙළ ප්‍රතිදානය කිරීමට අවශ්‍ය නම්, ඉහත ප්‍රකාශය IF ශ්‍රිතයේ තාර්කික පරීක්ෂණයට ඇතුළත් කරන්න. උදාහරණයක් ලෙස:
=IF(A1=B1, "Equal", "Not equal")
ඔබට පහත තිර රුවෙහි පෙනෙන පරිදි, සූත්‍ර දෙකම පෙළ තන්තු, දින සහ අංක එක සමානව සංසන්දනය කරයි:
Excel හි තන්තු සංසන්දනය කිරීමට සිද්ධි සංවේදී සූත්රය
සමහර අවස්ථා වලදී, කොටු දෙකක පාඨ අගයන් සංසන්දනය කිරීම පමණක් නොව, අක්ෂර නඩුව සංසන්දනය කිරීමද වැදගත් විය හැක. Excel EXACT ශ්රිතය භාවිතයෙන් සිද්ධි සංවේදී පෙළ සංසන්දනය කළ හැක:
EXACT (text1, text2)text1 සහ text2 ඔබ සංසන්දනය කරන කොටු දෙක වේ.
ඔබේ තන්තු A2 සහ B2 කොටුවල ඇතැයි උපකල්පනය කළහොත්, සූත්රය පහත පරිදි වේ:
=EXACT(A2, B2)
ප්‍රතිඵලයක් ලෙස, ඔබට නඩුව ඇතුළුව පෙළ නූල් ගැලපීම සඳහා සත්‍ය ලැබේ. එක් එක් අක්ෂරවල, වෙනත් ආකාරයකින් අසත්‍යය.
ඔබට EXACT ශ්රිතය වෙනත් ප්‍රතිඵල ලබා දීමට අවශ්‍ය නම්, එය IF සූත්‍රයක තැන්පත් කර value_if_true සහ value_if_false<සඳහා ඔබේම පෙළ ටයිප් කරන්න. 2> තර්ක:
=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")
පහත තිර රුවක් Excel හි සිද්ධි සංවේදී තන්තු සංසන්දනයේ ප්‍රතිඵල පෙන්වයි:
කෙසේද Excel හි බහු සෛල සංසන්දනය කරන්න
පේළියක සෛල 2 කට වඩා සංසන්දනය කිරීම සඳහා, ඉහත උදාහරණවල සාකච්ඡා කර ඇති සූත්‍ර AND ක්‍රියාකරු සමඟ ඒකාබද්ධව භාවිතා කරන්න. සම්පූර්ණ විස්තර පහතින්.
සංසන්දනය කිරීමට සිද්ධි සංවේදී නොවන සූත්‍රයකොටු 2කට වඩා
ඔබට ප්‍රතිඵල පෙන්වීමට අවශ්‍ය ආකාරය අනුව, පහත සූත්‍රවලින් එකක් භාවිතා කරන්න:
=AND(A2=B2, A2=C2)
හෝ
=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")
සහ සූත්රය සියලුම සෛලවල එකම අගය අඩංගු නම් TRUE ලෙසත්, කිසියම් අගයක් වෙනස් නම් FALSE ලෙසත් ලබා දෙයි. IF සූත්රය ඔබ එහි ටයිප් කරන ලේබල ප්‍රතිදානය කරයි, මෙම උදාහරණයේ " සමාන " සහ " සමාන නොවේ ".
පහත තිර රුවෙහි පෙන්වා ඇති පරිදි, සූත්රය ඕනෑම දත්ත වර්ගයක් සමඟ හොඳින් ක්‍රියා කරයි - පෙළ, දිනයන් සහ සංඛ්‍යාත්මක අගයන්:
කොටු කිහිපයක පෙළ සංසන්දනය කිරීමට සිද්ධි සංවේදී සූත්රය
විවිධ නූල් සංසන්දනය කිරීමට ඒවා හරියටම ගැළපේ දැයි බැලීමට, පහත සූත්‍ර භාවිතා කරන්න:
=AND(EXACT(A2,B2), EXACT(A2, C2))
හෝ
=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")
පෙර උදාහරණයේ මෙන්, පළමු සූත්රය සත්‍ය සහ අසත්‍ය අගයන් ලබා දෙන අතර, දෙවැන්න ගැලපීම් සහ වෙනස්කම් සඳහා ඔබේම පෙළ පෙන්වයි:
සෛල පරාසයක් නියැදි සෛලයකට සසඳන්න
පහත උදාහරණ මඟින් ලබා දී ඇති පරාසයක ඇති සියලුම සෛල නියැදි කොටුවක ඇති එකම පෙළ අඩංගු බව ඔබට සත්‍යාපනය කළ හැකි ආකාරය පෙන්වයි.
සෛල නියැදි පෙළකට සංසන්දනය කිරීමට සිද්ධි සංවේදී නොවන සූත්රය
නම් අක්ෂර නඩුව ඇත්ත වශයෙන්ම වැදගත් නොවේ, ඔබට සෛල නියැදියකට සංසන්දනය කිරීමට පහත සූත්රය භාවිතා කළ හැක:
ROWS( පරාසය)*COLUMNS( rang e)=COUNTIF( පරාසය, නියැදි කොටුව)IF ශ්‍රිතයේ තාර්කික පරීක්ෂණයේදී, ඔබ සංඛ්‍යා දෙකක් සංසන්දනය කරයි:
- මුළු සෛල ගණනනිශ්චිත පරාසයක (තීරු ගණනින් ගුණ කළ පේළි ගණන), සහ
- නියැදි කොටුවේ ඇති අගයම අඩංගු කොටු ගණන (COUNTIF ශ්රිතය මඟින් ආපසු ලබා දී ඇත).
නියැදි පෙළ C2 හි ඇති අතර සංසන්දනය කළ යුතු නූල් A2:B6 පරාසයේ ඇතැයි උපකල්පනය කළහොත්, සූත්රය පහත පරිදි වේ:
=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)
ප්‍රතිඵල වඩාත් පරිශීලක කිරීමට- මිත්‍රශීලී, එනම් සත්‍ය සහ අසත්‍ය වෙනුවට "සියල්ල ගැලපීම" සහ "සියල්ල නොගැලපේ" වැනි දෙයක් ප්‍රතිදානය කරන්න, අපි පෙර උදාහරණවල කළාක් මෙන් IF ශ්රිතය භාවිතා කරන්න:
=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")
ඉහත තිර රුව පෙන්වා ඇති පරිදි, සූත්රය පෙළ තන්තු පරාසයක් සමඟ හොඳින් මුහුණ දෙයි, නමුත් එය සංඛ්‍යා සහ දින සංසන්දනය කිරීමට ද භාවිතා කළ හැක.
අවශ්‍ය සංවේදී සූත්රය තන්තු සංසන්දනය කිරීමට නියැදි පෙළ
අනුලකුණු නඩුව වෙනසක් ඇති කරන්නේ නම්, ඔබට පහත අරා සූත්‍ර භාවිතා කර නියැදි පෙළ සමඟ නූල් සංසන්දනය කළ හැක.
IF(ROWS( range)*COLUMNS( range)=SUM(--EXACT( sample_cell, range)), " text_if_match", " text_if_ නොගැලපේ")A2:B6 හි පවතින මූලාශ්‍ර පරාසය සහ C2 හි නියැදි පෙළ සමඟ, සූත්රය පහත හැඩය ගනී:
=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")
සාමාන්‍ය Excel සූත්‍ර මෙන් නොව , Ctrl + Shift + Enter එබීමෙන් අරා සූත්‍ර සම්පූර්ණ වේ. නිවැරදිව ඇතුළත් කළහොත්, තිර රුවෙහි පෙන්වා ඇති පරිදි Excel විසින් අරා සූත්රය {curly braces} වලින් වටකරයිදිග
සමහර විට ඔබට එක් එක් පේළියේ ඇති පෙළ තන්තු වල සමාන අක්ෂර සංඛ්‍යාවක් තිබේදැයි පරීක්ෂා කිරීමට අවශ්‍ය විය හැක. මෙම කාර්යය සඳහා සූත්රය ඉතා සරල ය. පළමුව, ඔබ LEN ශ්රිතය භාවිතයෙන් කොටු දෙකක තන්තු දිග ලබාගෙන, පසුව සංඛ්‍යා සංසන්දනය කරන්න.
සැසඳිය යුතු නූල් A2 සහ B2 සෛලවල ඇතැයි සිතමින්, පහත සූත්‍රවලින් එකක් භාවිතා කරන්න:
=LEN(A2)=LEN(B2)
නැතහොත්
=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")
ඔබ දැනටමත් දන්නා පරිදි, පළමු සූත්රය බූලියන් අගයන් සත්‍ය හෝ අසත්‍ය ලබා දෙයි, දෙවන සූත්රය ඔබේම ප්‍රතිඵල ප්‍රතිදානය කරයි:
ඉහත තිර රුවෙහි පෙන්වා ඇති පරිදි, සූත්‍ර පෙළ තන්තු සඳහා මෙන්ම අංක සඳහාද ක්‍රියා කරයි.
ඉඟිය. පෙනෙන ආකාරයට සමාන නූල් දෙකක් වෙනස් දිගක් ලබා දෙන්නේ නම්, බොහෝ විට ගැටලුව ඇත්තේ සෛල එකක හෝ දෙකෙහිම ප්‍රමුඛ හෝ පෙර ඉඩ වේ. මෙම අවස්ථාවේදී, TRIM ශ්රිතය භාවිතයෙන් අමතර හිස්තැන් ඉවත් කරන්න. සවිස්තරාත්මක පැහැදිලි කිරීම් සහ සූත්‍ර උදාහරණ මෙතැනින් සොයාගත හැකිය: Excel හි හිස්තැන් කපා ගන්නේ කෙසේද.
නිශ්චිත අක්ෂරයක සිදුවීම් මගින් සෛල දෙකක් සසඳන්න
මෙය අපගේ Excel Compare Strings නිබන්ධනයේ අවසාන උදාහරණය වන අතර, එය තරමක් නිශ්චිත කාර්යයක් සඳහා විසඳුමක් පෙන්වයි. සිතන්න, ඔබට වැදගත් අක්ෂරයක් අඩංගු පෙළ නූල් තීරු 2ක් ඔබ සතුව ඇත. ඔබේ ඉලක්කය වන්නේ එක් එක් පේළියේ ඇති කොටු දෙකක දී ඇති අක්ෂරයක සමාන සිදුවීම් සංඛ්‍යාවක් අඩංගු දැයි පරීක්ෂා කිරීමයි.
දේ පැහැදිලි කිරීමට, පහත කරුණු සලකා බලන්නඋදාහරණයක්. අපි කියමු, ඔබට නැව්ගත කළ (බී තීරුව) සහ ලැබුණු (සී තීරුව) ඇණවුම් ලැයිස්තුවක් දෙකක් තිබේ. සෑම පේළියකම නිශ්චිත අයිතමයක් සඳහා ඇණවුම් අඩංගු වන අතර, එහි අනන්‍ය හඳුනාගැනීම සියලු ඇණවුම් හැඳුනුම්පත්වල ඇතුළත් කර ඇති අතර A තීරුවේ එකම පේළියේ ලැයිස්තුගත කර ඇත (කරුණාකර පහත තිර රුව බලන්න). ඔබට එක් එක් පේළිය තුළ එම නිශ්චිත ID සමඟ නැව්ගත කළ සහ ලැබුණු අයිතම සමාන සංඛ්‍යාවක් අඩංගු බව සහතික කර ගැනීමට අවශ්‍ය වේ.
මෙම ගැටලුව විසඳීමට, පහත තර්කනය සමඟ සූත්‍රයක් ලියන්න.
- පළමුව, SUBSTITUTE ශ්රිතය භාවිතයෙන් කිසිවක් නොමැතිව අනන්‍ය හඳුනාගැනීම ප්‍රතිස්ථාපනය කරන්න:
SUBSTITUTE(A1, character_to_count,"") - ඉන්පසු, එක් එක් කොටුව තුළ අනන්‍ය හැඳුනුම්කාරකය කොපමණ වාර ගණනක් දිස් වේද යන්න ගණනය කරන්න. මේ සඳහා, අනන්‍ය හඳුනාගැනීමක් නොමැතිව නූල් දිග ලබාගෙන එය නූලෙහි සම්පූර්ණ දිගෙන් අඩු කරන්න. මෙම කොටස කොටුව 1 සහ කොටු 2 සඳහා තනි තනිව ලියා ඇත, උදාහරණයක් ලෙස:
LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))සහ
LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, "")) - අවසාන වශයෙන්, ඔබ මෙම අංක 2 සංසන්දනය කරන්න ඉහත කොටස් අතර සමානතා ලකුණ (=) තැබීමෙන්.
LEN( සෛල 2 ) - LEN(ආදේශකය( සෛල 2 , අනුලකුණු_කිරීමට_ගණනය , ""))
අපගේ උදාහරණයේ, අනන්‍ය හඳුනාගැනීම A2 හි ඇත , සහ සංසන්දනය කිරීමට නූල් B2 සහ C2 සෛල තුළ ඇත. එබැවින්, සම්පූර්ණ සූත්රය පහත පරිදි වේ:
=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))
B2 සහ C2 සෛල A2 හි අක්ෂරයේ සමාන සිදුවීම් සංඛ්‍යාවක් අඩංගු නම්, සූත්රය සත්‍ය වේ.එසේ නොමැතිනම් FALSE. ඔබගේ පරිශීලකයින් සඳහා ප්‍රතිඵල වඩාත් අර්ථවත් කිරීමට, ඔබට IF ශ්රිතය තුළ සූත්රය කාවැද්දීමට හැකිය:
=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")
ඔබට ඉහත තිර රුවෙහි පෙනෙන පරිදි , අතිරේක සංකූලතා කිහිපයක් තිබියදීත් සූත්රය පරිපූර්ණව ක්‍රියා කරයි:
- ගණනය කළ යුතු අක්ෂරය (අද්විතීය හඳුනාගැනීම්) පෙළ තන්තුවක ඕනෑම තැනක දිස්විය හැක.
- තන්තුවල විචල්‍ය අංකයක් අඩංගු වේ අක්ෂරවල සහ අර්ධ කෝමාව, කොමාව හෝ අවකාශය වැනි විවිධ බෙදුම්කරුවන්.
ඔබ Excel හි තන්තු සංසන්දනය කරන්නේ මෙලෙසයි. මෙම නිබන්ධනයේ සාකච්ඡා කර ඇති සූත්‍ර දෙස සමීපව බැලීමට, Excel සංසන්දනය කිරීමේ වැඩ පත්‍රිකාව බාගත කිරීමට ඔබව සාදරයෙන් පිළිගනිමු. කියවීම ගැන මම ඔබට ස්තූතිවන්ත වන අතර ලබන සතියේ අපගේ බ්ලොග් අඩවියෙන් ඔබව දැකීමට බලාපොරොත්තු වෙමි.
