Tutorial menunjukkan cara membandingkan rentetan teks dalam Excel untuk padanan tidak sensitif huruf besar dan tepat. Anda akan mempelajari beberapa formula untuk membandingkan dua sel mengikut nilainya, panjang rentetan atau bilangan kemunculan aksara tertentu, serta cara membandingkan berbilang sel.

Apabila menggunakan Excel untuk analisis data, ketepatan adalah kebimbangan yang paling penting. Maklumat yang salah membawa kepada tarikh akhir yang terlepas, arah aliran yang salah dinilai, keputusan yang salah dan hasil yang hilang.

Walaupun formula Excel sentiasa benar, keputusannya mungkin salah kerana beberapa data yang cacat menembusi ke dalam sistem. Dalam kes ini, satu-satunya ubat ialah menyemak data untuk ketepatan. Bukan masalah besar untuk membandingkan dua sel secara manual, tetapi hampir mustahil untuk mengesan perbezaan antara ratusan dan ribuan rentetan teks.

Tutorial ini akan mengajar anda cara mengautomasikan tugas sel yang membosankan dan mudah ralat. perbandingan dan formula yang terbaik untuk digunakan dalam setiap kes tertentu.

Cara membandingkan dua sel dalam Excel

Terdapat dua cara berbeza untuk membandingkan rentetan dalam Excel bergantung pada sama ada anda mencari perbandingan sensitif huruf atau huruf kecil.

Formula tidak sensitif huruf besar untuk membandingkan 2 sel

Untuk membandingkan dua sel dalam Excel yang mengabaikan huruf besar, gunakan formula mudah seperti ini:

=A1=B1

Di mana A1 dan B1 ialah sel yang anda bandingkan. Hasil formula ialah nilai Boolean TRUEdan SALAH.

Jika anda ingin mengeluarkan teks anda sendiri untuk padanan dan perbezaan, benamkan pernyataan di atas dalam ujian logik fungsi IF. Contohnya:

=IF(A1=B1, "Equal", "Not equal")

Seperti yang anda lihat dalam tangkapan skrin di bawah, kedua-dua formula membandingkan rentetan teks, tarikh dan nombor dengan sama baik:

Formula sensitif huruf besar untuk membandingkan rentetan dalam Excel

Dalam sesetengah situasi, mungkin penting bukan sahaja untuk membandingkan nilai teks dua sel, tetapi juga untuk membandingkan huruf besar. Perbandingan teks sensitif huruf besar boleh dilakukan menggunakan fungsi Excel EXACT:

Di mana teks1 dan teks2 ialah dua sel yang anda bandingkan.

Dengan mengandaikan rentetan anda berada dalam sel A2 dan B2, formulanya adalah seperti berikut:

=EXACT(A2, B2)

Akibatnya, anda mendapat TRUE untuk rentetan teks sepadan dengan tepat termasuk kes bagi setiap aksara, FALSE sebaliknya.

Jika anda mahu fungsi EXACT menyampaikan beberapa hasil lain, benamkannya dalam formula IF dan taip teks anda sendiri untuk value_if_true dan value_if_false argumen:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Tangkapan skrin berikut menunjukkan hasil perbandingan rentetan sensitif huruf besar-besaran dalam Excel:

Cara untuk bandingkan berbilang sel dalam Excel

Untuk membandingkan lebih daripada 2 sel berturut-turut, gunakan formula yang dibincangkan dalam contoh di atas dalam kombinasi dengan operator AND. Butiran penuh mengikuti di bawah.

Formula tidak peka huruf besar-besaran untuk dibandingkanlebih daripada 2 sel

Bergantung pada cara anda mahu memaparkan hasil, gunakan salah satu daripada formula berikut:

=AND(A2=B2, A2=C2)

atau

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

Formula AND mengembalikan BENAR jika semua sel mengandungi nilai yang sama, FALSE jika mana-mana nilai berbeza. Formula IF mengeluarkan label yang anda taip di dalamnya, " Equal " dan " Not equal " dalam contoh ini.

Seperti yang ditunjukkan dalam tangkapan skrin di bawah, formula berfungsi dengan sempurna dengan mana-mana jenis data - teks, tarikh dan nilai angka:

Formula sensitif huruf besar untuk membandingkan teks dalam beberapa sel

Untuk membandingkan berbilang rentetan antara satu sama lain untuk melihat sama ada ia sepadan dengan tepat, gunakan formula berikut:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Atau

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Seperti dalam contoh sebelumnya, yang pertama formula menyampaikan nilai TRUE dan FALSE, manakala yang kedua memaparkan teks anda sendiri untuk padanan dan perbezaan:

Bandingkan julat sel kepada sel sampel

Contoh berikut menunjukkan cara anda boleh mengesahkan bahawa semua sel dalam julat tertentu mengandungi teks yang sama seperti dalam sel sampel.

Formula tidak sensitif huruf besar untuk membandingkan sel dengan teks sampel

Jika huruf besar tidak begitu penting, anda boleh menggunakan formula berikut untuk membandingkan sel dengan sampel:

Dalam ujian logik fungsi IF, anda membandingkan dua nombor:

• Jumlah bilangan seldalam julat yang ditentukan (bilangan baris didarab dengan bilangan lajur) dan
• Bilangan sel yang mengandungi nilai yang sama seperti dalam sel sampel (dipulangkan oleh fungsi COUNTIF).

Dengan mengandaikan teks sampel berada dalam C2 dan rentetan untuk dibandingkan berada dalam julat A2:B6, formulanya adalah seperti berikut:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Untuk menjadikan hasil lebih pengguna- mesra, iaitu mengeluarkan sesuatu seperti "Semua padan" dan "Tidak semua padan" dan bukannya BENAR dan SALAH, gunakan fungsi IF seperti yang kita lakukan dalam contoh sebelumnya:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Seperti yang ditunjukkan pada tangkapan skrin di atas, formula mengatasi dengan sempurna julat rentetan teks, tetapi ia juga boleh digunakan untuk membandingkan nombor dan tarikh.

Formula sensitif huruf besar-besaran untuk membandingkan rentetan dengan teks sampel

Jika huruf besar membuat perbezaan, anda boleh membandingkan rentetan dengan teks sampel menggunakan formula tatasusunan berikut.

Dengan julat sumber yang berada dalam A2:B6 dan teks sampel dalam C2, formula mengambil bentuk berikut:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Tidak seperti formula Excel biasa , formula tatasusunan dilengkapkan dengan menekan Ctrl + Shift + Enter . Jika dimasukkan dengan betul, Excel menyertakan formula tatasusunan dalam {curly braces}, seperti yang ditunjukkan dalam tangkapan skrin:

Cara membandingkan dua sel dengan rentetanpanjang

Kadangkala anda mungkin ingin menyemak sama ada rentetan teks dalam setiap baris mengandungi bilangan aksara yang sama. Formula untuk tugasan ini sangat mudah. Mula-mula, anda mendapat panjang rentetan dua sel menggunakan fungsi LEN, dan kemudian bandingkan nombornya.

Andaikata rentetan yang hendak dibandingkan berada dalam sel A2 dan B2, gunakan salah satu daripada formula berikut:

=LEN(A2)=LEN(B2)

Atau

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Seperti yang anda sedia maklum, formula pertama mengembalikan nilai Boolean TRUE atau FALSE, manakala formula kedua mengeluarkan hasil anda sendiri:

Seperti yang ditunjukkan dalam tangkapan skrin di atas, formula berfungsi untuk rentetan teks serta nombor.

Petua. Jika dua rentetan yang kelihatan sama mengembalikan panjang yang berbeza, kemungkinan besar masalahnya adalah dalam menuju atau mengikut ruang dalam satu atau kedua-dua sel. Dalam kes ini, alih keluar ruang tambahan menggunakan fungsi TRIM. Penjelasan terperinci dan contoh formula boleh didapati di sini: Cara memangkas ruang dalam Excel.

Bandingkan dua sel mengikut kejadian aksara tertentu

Ini ialah contoh terakhir dalam tutorial Excel Compare Strings kami dan ia menunjukkan penyelesaian untuk tugas yang agak khusus. Andainya, anda mempunyai 2 lajur rentetan teks yang mengandungi aksara yang penting kepada anda. Matlamat anda ialah untuk menyemak sama ada dua sel dalam setiap baris mengandungi bilangan kejadian yang sama bagi aksara tertentu.

Untuk membuat perkara lebih jelas, pertimbangkan perkara berikutcontoh. Katakan, anda mempunyai dua senarai pesanan yang dihantar (lajur B) dan diterima (lajur C). Setiap baris mengandungi pesanan untuk item tertentu, yang pengecam uniknya disertakan dalam semua ID pesanan dan disenaraikan dalam baris yang sama dalam lajur A (sila lihat tangkapan skrin di bawah). Anda ingin memastikan bahawa setiap baris mengandungi bilangan item yang dihantar dan diterima yang sama dengan ID khusus tersebut.

Untuk menyelesaikan masalah ini, tulis formula dengan logik berikut.

• Mula-mula, gantikan pengecam unik tanpa apa-apa menggunakan fungsi SUBSTITUTE:

  SUBSTITUTE(A1, character_to_count,"")

• Kemudian, hitung berapa kali pengecam unik muncul dalam setiap sel. Untuk ini, dapatkan panjang rentetan tanpa pengecam unik dan tolaknya daripada jumlah panjang rentetan. Bahagian ini hendaklah ditulis untuk sel 1 dan sel 2 secara berasingan, contohnya:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  dan

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Akhir sekali, anda bandingkan 2 nombor ini dengan meletakkan tanda kesamaan (=) di antara bahagian di atas.

LEN( sel 2 ) - LEN(SUBSTITUTE( sel 2 , character_to_count , ""))

Dalam contoh kami, pengecam unik adalah dalam A2 , dan rentetan untuk dibandingkan adalah dalam sel B2 dan C2. Jadi, formula lengkap adalah seperti berikut:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Formula mengembalikan BENAR jika sel B2 dan C2 mengandungi bilangan kejadian yang sama bagi aksara dalam A2,PALSU sebaliknya. Untuk menjadikan hasil lebih bermakna bagi pengguna anda, anda boleh membenamkan formula dalam fungsi IF:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Seperti yang anda boleh lihat dalam tangkapan skrin di atas , formula berfungsi dengan sempurna walaupun terdapat beberapa komplikasi tambahan:

• Watak yang akan dikira (pengecam unik) boleh muncul di mana-mana dalam rentetan teks.
• Rentetan mengandungi nombor pembolehubah aksara dan pemisah berbeza seperti koma bertitik, koma atau ruang.

Beginilah cara anda membandingkan rentetan dalam Excel. Untuk melihat dengan lebih dekat formula yang dibincangkan dalam tutorial ini, anda dialu-alukan untuk memuat turun Lembaran Kerja Excel Compare Strings. Saya berterima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan.