Bu eğitimde, Excel'de metin dizelerinin büyük/küçük harfe duyarlı olmayan ve tam eşleşme için nasıl karşılaştırılacağı gösterilmektedir. İki hücreyi değerlerine, dize uzunluğuna veya belirli bir karakterin oluşum sayısına göre karşılaştırmak için bir dizi formülün yanı sıra birden çok hücreyi nasıl karşılaştıracağınızı öğreneceksiniz.

Veri analizi için Excel kullanırken, doğruluk en hayati konudur. Yanlış bilgi, kaçırılan son teslim tarihlerine, yanlış değerlendirilen eğilimlere, yanlış kararlara ve gelir kaybına yol açar.

Excel formülleri her zaman mükemmel bir şekilde doğru olsa da, bazı hatalı veriler sisteme girdiği için sonuçları yanlış olabilir. Bu durumda, tek çare verilerin doğruluğunu kontrol etmektir. İki hücreyi manuel olarak karşılaştırmak çok önemli değildir, ancak yüzlerce ve binlerce metin dizesi arasındaki farkları tespit etmek neredeyse imkansızdır.

Bu eğitim size hücre karşılaştırma gibi sıkıcı ve hataya açık bir görevi nasıl otomatikleştireceğinizi ve her bir özel durumda hangi formülleri kullanmanız gerektiğini öğretecektir.

Excel'de iki hücre nasıl karşılaştırılır

Excel'de dizeleri karşılaştırmanın, büyük/küçük harfe duyarlı veya büyük/küçük harfe duyarsız karşılaştırma istemenize bağlı olarak iki farklı yolu vardır.

İki hücreyi karşılaştırmak için büyük/küçük harfe duyarlı olmayan formül

Excel'de yok sayma durumunda iki hücreyi karşılaştırmak için aşağıdaki gibi basit bir formül kullanın:

=A1=B1

Burada A1 ve B1 karşılaştırdığınız hücrelerdir. Formülün sonucu DOĞRU ve YANLIŞ Boole değerleridir.

Eşleşmeler ve farklılıklar için kendi metinlerinizin çıktısını almak istiyorsanız, yukarıdaki ifadeyi IF fonksiyonunun mantıksal testine yerleştirin. Örneğin:

=IF(A1=B1, "Eşit", "Eşit değil")

Aşağıdaki ekran görüntüsünde gördüğünüz gibi, her iki formül de metin dizelerini, tarihleri ve sayıları eşit derecede iyi karşılaştırır:

Excel'de dizeleri karşılaştırmak için büyük/küçük harfe duyarlı formül

Bazı durumlarda, yalnızca iki hücrenin metin değerlerini karşılaştırmak değil, aynı zamanda karakter büyük/küçük harflerini karşılaştırmak da önemli olabilir. Büyük/küçük harfe duyarlı metin karşılaştırması Excel EXACT işlevi kullanılarak yapılabilir:

Nerede metin1 ve metin2 karşılaştırdığınız iki hücredir.

Dizelerinizin A2 ve B2 hücrelerinde olduğunu varsayarsak, formül aşağıdaki gibi olur:

=EXACT(A2, B2)

Sonuç olarak, metin dizeleri her karakterin büyük/küçük harf durumu da dahil olmak üzere tam olarak eşleşiyorsa DOĞRU, aksi takdirde YANLIŞ alırsınız.

EXACT işlevinin başka sonuçlar vermesini istiyorsanız, bunu bir EĞER formülüne yerleştirin ve işlev için kendi metninizi yazın value_if_true ve value_if_false Argümanlar:

=IF(EXACT(A2 ,B2), "Tam olarak eşit", "Eşit değil")

Aşağıdaki ekran görüntüsü Excel'de büyük/küçük harfe duyarlı dize karşılaştırmasının sonuçlarını göstermektedir:

Excel'de birden çok hücre nasıl karşılaştırılır

Bir satırda 2'den fazla hücreyi karşılaştırmak için, AND operatörü ile birlikte yukarıdaki örneklerde tartışılan formülleri kullanın. Tüm ayrıntılar aşağıda yer almaktadır.

2'den fazla hücreyi karşılaştırmak için büyük/küçük harfe duyarsız formül

Sonuçları nasıl görüntülemek istediğinize bağlı olarak, aşağıdaki formüllerden birini kullanın:

=VE(A2=B2, A2=C2)

veya

=IF(AND(A2=B2, A2=C2), "Eşit", "Eşit değil")

VE formülü, tüm hücreler aynı değeri içeriyorsa DOĞRU, herhangi bir değer farklıysa YANLIŞ döndürür. EĞER formülü, içine yazdığınız etiketlerin çıktısını verir, " Eşit " ve " Eşit değil " bu örnekte.

Aşağıdaki ekran görüntüsünde gösterildiği gibi, formül metin, tarih ve sayısal değerler gibi tüm veri türleriyle mükemmel bir şekilde çalışır:

Birkaç hücredeki metni karşılaştırmak için büyük/küçük harfe duyarlı formül

Birden fazla dizeyi birbirleriyle karşılaştırarak tam olarak eşleşip eşleşmediklerini görmek için aşağıdaki formülleri kullanın:

=VE(EXACT(A2,B2), EXACT(A2, C2))

Ya da

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)), "Tam olarak eşit", "Eşit değil")

Önceki örnekte olduğu gibi, ilk formül DOĞRU ve YANLIŞ değerleri verirken, ikincisi eşleşmeler ve farklılıklar için kendi metinlerinizi görüntüler:

Bir hücre aralığını bir örnek hücreyle karşılaştırın

Aşağıdaki örnekler, belirli bir aralıktaki tüm hücrelerin örnek bir hücredekiyle aynı metni içerdiğini nasıl doğrulayabileceğinizi göstermektedir.

Hücreleri örnek bir metinle karşılaştırmak için büyük/küçük harfe duyarlı olmayan formül

Karakter durumu gerçekten önemli değilse, hücreleri bir örnekle karşılaştırmak için aşağıdaki formülü kullanabilirsiniz:

IF fonksiyonunun mantıksal testinde iki sayıyı karşılaştırırsınız:

• Belirli bir aralıktaki toplam hücre sayısı (satır sayısı ile sütun sayısının çarpımı) ve
• Örnek hücredekiyle aynı değeri içeren hücrelerin sayısı (COUNTIF işlevi tarafından döndürülür).

Örnek metnin C2'de ve karşılaştırılacak dizelerin A2:B6 aralığında olduğunu varsayarsak, formül aşağıdaki gibi olur:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Sonuçları daha kullanıcı dostu hale getirmek için, yani TRUE ve FALSE yerine "All match" ve "Not all match" gibi bir çıktı elde etmek için, önceki örneklerde yaptığımız gibi IF fonksiyonunu kullanın:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2), "Hepsi eşleşiyor", "Hepsi eşleşmiyor")

Yukarıdaki ekran görüntüsünde gösterildiği gibi, formül bir dizi metin dizesiyle mükemmel bir şekilde başa çıkmaktadır, ancak sayıları ve tarihleri karşılaştırmak için de kullanılabilir.

Dizeleri örnek bir metinle karşılaştırmak için büyük/küçük harfe duyarlı formül

Karakterlerin büyük/küçük olması fark yaratıyorsa, aşağıdaki dizi formüllerini kullanarak dizeleri örnek metinle karşılaştırabilirsiniz.

A2:B6'da bulunan kaynak aralığı ve C2'de bulunan örnek metin ile formül aşağıdaki şekli alır:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "Hepsi eşleşiyor", "Hepsi eşleşmiyor")

Normal Excel formüllerinden farklı olarak, dizi formülleri Ctrl + Shift + Enter tuşlarına basılarak tamamlanır. Doğru girilirse, Excel dizi formülünü ekran görüntüsünde gösterildiği gibi {kıvırcık parantez} içine alır:

İki hücreyi dize uzunluğuna göre karşılaştırma

Bazen her satırdaki metin dizelerinin eşit sayıda karakter içerip içermediğini kontrol etmek isteyebilirsiniz. Bu görev için formül çok basittir. İlk olarak, LEN işlevini kullanarak iki hücrenin dize uzunluğunu alırsınız ve ardından sayıları karşılaştırırsınız.

Karşılaştırılacak dizelerin A2 ve B2 hücrelerinde olduğunu varsayarsak, aşağıdaki formüllerden birini kullanın:

=LEN(A2)=LEN(B2)

Ya da

=IF(LEN(A2)=LEN(B2), "Eşit", "Eşit değil")

Bildiğiniz gibi, ilk formül DOĞRU veya YANLIŞ Boolean değerlerini döndürürken, ikinci formül kendi sonuçlarınızı verir:

Yukarıdaki ekran görüntüsünde gösterildiği gibi, formüller sayıların yanı sıra metin dizeleri için de çalışır.

İpucu: Görünüşte eşit olan iki dizge farklı uzunluklarda dönüyorsa, büyük olasılıkla sorun lider veya takip eden boşluklar Bu durumda, KIRP işlevini kullanarak fazladan boşlukları kaldırın. Ayrıntılı açıklama ve formül örneklerini burada bulabilirsiniz: Excel'de boşluklar nasıl kırpılır.

İki hücreyi belirli bir karakterin oluşumuna göre karşılaştırma

Bu, Excel Dizeleri Karşılaştırma eğitimimizdeki son örnektir ve oldukça özel bir görev için bir çözüm gösterir. Diyelim ki, sizin için önemli bir karakter içeren 2 sütun metin dizeniz var. Amacınız, her satırdaki iki hücrenin belirli bir karakterin aynı sayıda oluşumunu içerip içermediğini kontrol etmektir.

İşleri daha açık hale getirmek için aşağıdaki örneği ele alalım. Diyelim ki, gönderilen (sütun B) ve alınan (sütun C) iki sipariş listeniz var. Her satır, benzersiz tanımlayıcısı tüm sipariş kimliklerine dahil edilen ve A sütununda aynı satırda listelenen belirli bir ürün için siparişleri içerir (lütfen aşağıdaki ekran görüntüsüne bakın). Her satırın eşit sayıda gönderilen ve alınan sipariş içerdiğinden emin olmak istiyorsunuzbelirli bir kimliğe sahip öğeler.

Bu problemi çözmek için aşağıdaki mantıkla bir formül yazınız.

• İlk olarak, SUBSTITUTE işlevini kullanarak benzersiz tanımlayıcıyı hiçbir şeyle değiştirmeyin:

  SUBSTITUTE(A1, character_to_count,"")

• Ardından, benzersiz tanımlayıcının her bir hücrede kaç kez göründüğünü hesaplayın. Bunun için, benzersiz tanımlayıcı olmadan dize uzunluğunu alın ve toplam dize uzunluğundan çıkarın. Bu kısım, örneğin hücre 1 ve hücre 2 için ayrı ayrı yazılacaktır:

  LEN(hücre 1) - LEN(SUBSTITUTE(hücre 1, character_to_count, ""))

  ve

  LEN(hücre 2) - LEN(SUBSTITUTE(hücre 2, character_to_count, ""))

• Son olarak, yukarıdaki parçaların arasına eşitlik işareti (=) koyarak bu 2 sayıyı karşılaştırırsınız.

LEN( Hücre 2 ) - LEN(SUBSTITUTE( Hücre 2 , character_to_count , ""))

Örneğimizde, benzersiz tanımlayıcı A2'de ve karşılaştırılacak dizeler B2 ve C2 hücrelerindedir. Dolayısıyla, formülün tamamı aşağıdaki gibidir:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Formül, B2 ve C2 hücreleri A2'deki karakterin eşit sayıda oluşumunu içeriyorsa DOĞRU, aksi takdirde YANLIŞ döndürür. Sonuçları kullanıcılarınız için daha anlamlı hale getirmek için, formülü EĞER işlevine gömebilirsiniz:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Eşit", "Eşit değil")

Yukarıdaki ekran görüntüsünde görebileceğiniz gibi, formül birkaç ek komplikasyona rağmen mükemmel bir şekilde çalışıyor:

• Sayılacak karakter (benzersiz tanımlayıcı) bir metin dizesinin herhangi bir yerinde görünebilir.
• Dizeler değişken sayıda karakter ve noktalı virgül, virgül veya boşluk gibi farklı ayırıcılar içerir.

Excel'de dizeleri bu şekilde karşılaştırırsınız. Bu eğitimde tartışılan formüllere daha yakından bakmak için Excel Dizeleri Karşılaştırma Çalışma Sayfasını indirebilirsiniz. Okuduğunuz için teşekkür eder, gelecek hafta blogumuzda görüşmeyi dilerim.