Водич показује како да упоредите текстуалне стрингове у Екцел-у ради потпуног подударања без обзира на велика и мала слова. Научићете бројне формуле за упоређивање две ћелије према њиховим вредностима, дужини низа или броју појављивања одређеног карактера, као и како да упоредите више ћелија.

Када користите Екцел за анализа података, тачност је најважнија брига. Нетачне информације доводе до пропуштених рокова, погрешно процењених трендова, погрешних одлука и изгубљених прихода.

Иако су Екцел формуле увек савршено тачне, њихови резултати могу бити погрешни јер су неки погрешни подаци продрли у систем. У овом случају, једини лек је да проверите тачност података. Није велика ствар ручно упоредити две ћелије, али је скоро немогуће уочити разлике између стотина и хиљада текстуалних низова.

Овај водич ће вас научити како да аутоматизујете заморан задатак ћелије склон грешкама поређење и које формуле је најбоље користити у сваком конкретном случају.

Како упоредити две ћелије у Екцел-у

Постоје два различита начина за упоређивање стрингова у Екцел-у у зависности од без обзира да ли тражите поређење осетљиво на велика или мала и велика слова.

Формула која не разликује велика и мала слова за поређење 2 ћелије

Да бисте упоредили две ћелије у Екцел-у игноришући велика и мала слова, користите једноставну формулу попут ове:

=A1=B1

Где су А1 и Б1 ћелије које упоређујете. Резултат формуле су Булове вредности ТРУЕи ФАЛСЕ.

Ако желите да избаците сопствене текстове за подударања и разлике, уградите горњу изјаву у логички тест функције ИФ. На пример:

=IF(A1=B1, "Equal", "Not equal")

Као што видите на слици испод, обе формуле подједнако добро упоређују текстуалне низове, датуме и бројеве:

Формула осетљива на велика и мала слова за поређење стрингова у Екцел-у

У неким ситуацијама може бити важно не само да упоредите текстуалне вредности две ћелије, већ и да упоредите велика и мала слова. Поређење текста осетљиво на велика и мала слова се може урадити помоћу Екцел функције ЕКСАЦТ:

Где су текст1 и текст2 две ћелије које упоређујете.

Под претпоставком да су ваши стрингови у ћелијама А2 и Б2, формула иде на следећи начин:

=EXACT(A2, B2)

Као резултат, добијате ТРУЕ за текстуалне низове који се тачно подударају укључујући и велика и мала слова сваког знака, иначе ФАЛСЕ.

Ако желите да функција ЕКСАЦТ испоручи неке друге резултате, уградите је у ИФ формулу и унесите свој текст за валуе_иф_труе и валуе_иф_фалсе аргументи:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Следећи снимак екрана приказује резултате поређења стрингова осетљивих на велика и мала слова у Екцел-у:

Како да упореди више ћелија у Екцел-у

Да бисте упоредили више од 2 ћелије у низу, користите формуле о којима се говори у горњим примерима у комбинацији са оператором АНД. Пуни детаљи следе у наставку.

Формула која не разликује велика и мала слова за поређењевише од 2 ћелије

У зависности од тога како желите да прикажете резултате, користите једну од следећих формула:

=AND(A2=B2, A2=C2)

или

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

Формула И враћа ТРУЕ ако све ћелије садрже исту вредност, ФАЛСЕ ако је било која вредност другачија. ИФ формула даје ознаке које унесете у њу, „ Једнако “ и „ Није једнако “ у овом примеру.

Као што је приказано на снимку екрана испод, формула савршено функционише са свим типовима података - текстом, датумима и нумеричким вредностима:

Формула осетљива на велика и мала слова за упоређивање текста у неколико ћелија

За упоређивање више стрингова једни другима да видите да ли се тачно поклапају, користите следеће формуле:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Или

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Као у претходном примеру, први формула испоручује вредности ТРУЕ и ФАЛСЕ, док друга приказује ваше сопствене текстове за подударања и разлике:

Упореди опсег ћелија са ћелијом узорка

Следећи примери показују како можете да проверите да ли све ћелије у датом опсегу садрже исти текст као у ћелији узорка.

Формула која не разликује велика и мала слова за поређење ћелија са примером текста

Ако велика и мала слова нису битна, можете користити следећу формулу да упоредите ћелије са узорком:

У логичком тесту функције ИФ, поредите два броја:

• Укупан број ћелијау одређеном опсегу (број редова помножен бројем колона) и
• Број ћелија које садрже исту вредност као у ћелији узорка (враћа функција ЦОУНТИФ).

Под претпоставком да је текст примера у Ц2 и низови за поређење су у опсегу А2:Б6, формула иде на следећи начин:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Да би резултати били кориснији пријатељски, тј. изнесите нешто попут „Све се подударају“ и „Не подударају се све“ уместо ТРУЕ и ФАЛСЕ, користите функцију ИФ као што смо радили у претходним примерима:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Као што је приказано на горњој слици екрана, формула се савршено носи са низом текстуалних стрингова, али се такође може користити за поређење бројева и датума.

Формула осетљива на велика и мала слова за поређење стрингова са пример текста

Ако велика и мала слова чине разлику, можете да упоредите стрингове са примером текста користећи следеће формуле низа.

Са изворним опсегом који се налази у А2:Б6 и примером текста у Ц2, формула поприма следећи облик:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

За разлику од обичних Екцел формула , формуле низа се завршавају притиском на Цтрл + Схифт + Ентер. Ако је унета исправно, Екцел ставља формулу низа у {вирдзате заграде}, као што је приказано на снимку екрана:

Како упоредити две ћелије по низуленгтх

Понекад ћете можда желети да проверите да ли текстуални низови у сваком реду садрже једнак број знакова. Формула за овај задатак је врло једноставна. Прво добијате дужину низа две ћелије користећи ЛЕН функцију, а затим упоредите бројеве.

Претпоставимо да су стрингови које треба упоредити у ћелијама А2 и Б2, користите неку од следећих формула:

=LEN(A2)=LEN(B2)

Или

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Као што већ знате, прва формула враћа Булове вредности ТРУЕ или ФАЛСЕ, док друга формула даје ваше сопствене резултате:

Као што је приказано на слици изнад, формуле раде за текстуалне низове као и за бројеве.

Савет. Ако два наизглед једнака низа враћају различите дужине, највероватније је проблем у предводним или задњим размацима у једној или обе ћелије. У том случају, уклоните додатне размаке помоћу функције ТРИМ. Детаљно објашњење и примери формуле могу се наћи овде: Како смањити размаке у Екцел-у.

Упореди две ћелије према појављивању одређеног карактера

Ово је последњи пример у нашем водичу за упоређивање стрингова у Екцел-у и показује решење за прилично специфичан задатак. Претпоставимо да имате 2 колоне текстуалних низова који садрже знак који вам је важан. Ваш циљ је да проверите да ли две ћелије у сваком реду садрже исти број појављивања датог знака.

Да би ствари биле јасније, размотрите следећепример. Рецимо, имате две листе испоручених поруџбина (колона Б) и примљених (колона Ц). Сваки ред садржи поруџбине за одређену ставку, чији је јединствени идентификатор укључен у све ИД-ове поруџбине и наведен је у истом реду у колони А (погледајте снимак екрана испод). Желите да се уверите да сваки ред садржи једнак број отпремљених и примљених артикала са тим специфичним ИД-ом.

Да бисте решили овај проблем, напишите формулу са следећом логиком.

• Прво, замените јединствени идентификатор ничим користећи функцију СУБСТИТУТЕ:

  SUBSTITUTE(A1, character_to_count,"")

• Затим израчунајте колико пута се јединствени идентификатор појављује у свакој ћелији. За ово, узмите дужину стринга без јединственог идентификатора и одузмите је од укупне дужине стринга. Овај део ће бити написан за ћелију 1 и ћелију 2 појединачно, на пример:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  и

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• На крају, упоредите ова 2 броја постављањем знака једнакости (=) између горњих делова.

ЛЕН( ћелија 2 ) - ЛЕН(СУБСТИТУТЕ( ћелија 2 , карактер_према_броју , ""))

У нашем примеру, јединствени идентификатор је у А2 , а низови за поређење су у ћелијама Б2 и Ц2. Дакле, комплетна формула је следећа:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Формула враћа ТРУЕ ако ћелије Б2 и Ц2 садрже једнак број појављивања знака у А2,ЛАЖНО иначе. Да би резултати били значајнији за своје кориснике, можете да уградите формулу у функцију ИФ:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Као што можете видети на слици изнад , формула функционише савршено упркос неколико додатних компликација:

• Знак који се рачуна (јединствени идентификатор) може да се појави било где у текстуалном низу.
• Стрингови садрже променљиви број знакова и различитих сепаратора као што су тачка-зарез, зарез или размак.

Овако упоређујете стрингове у Екцел-у. Да бисте ближе погледали формуле о којима се говори у овом водичу, можете преузети радни лист Екцел Цомпаре Стринг Ворксхеет. Захваљујем вам на читању и надам се да ћемо се следеће недеље видети на нашем блогу.