Tutorialak Excel-en testu-kateak nola alderatu erakusten du maiuskulak eta minuskulak bereizteko eta bat-etortze zehatza lortzeko. Hainbat formula ikasiko dituzu bi gelaxka haien balioen, katearen luzeraren edo karaktere zehatz baten agerraldi kopuruaren arabera alderatzeko, baita gelaxka bat baino gehiago nola alderatu ere.

Excel erabiltzeko orduan. datuen azterketa, zehaztasuna da kezkarik garrantzitsuena. Informazio okerrak epeak galdu, okerreko joerak, erabaki okerrak eta diru-sarrerak galtzen ditu.

Excel formulak beti egiazkoak diren arren, baliteke haien emaitzak oker egotea, datu akats batzuk sisteman sartu direlako. Kasu honetan, erremedio bakarra datuak zehaztasuna egiaztatzea da. Ez da gauza handirik bi gelaxka eskuz alderatzea, baina ia ezinezkoa da ehunka eta milaka testu-kateren arteko desberdintasunak antzematea.

Tutorial honek zelulen zeregin neketsu eta akatsetarako joera nola automatizatzen irakatsiko dizu. konparazioa eta zein formulak erabili egokienak kasu zehatz bakoitzean.

Nola alderatu bi gelaxka Excel-en

Excel-en kateak alderatzeko bi modu ezberdin daude. maiuskulak eta minuskulak bereizten dituen konparazioa bilatzen baduzu.

Mauskulak eta minuskulak bereizten ez dituen formula 2 gelaxka alderatzeko

Excel-en bi gelaxka alderatzeko, maiuskulak eta minuskulak alde batera utzita, erabili honelako formula sinple bat:

=A1=B1

Non A1 eta B1 diren konparatzen ari zaren gelaxkak. Formularen emaitza balio boolearrak EGIA diraeta GEZURRA.

Zure testuak atera nahi badituzu parekatze eta desberdintasunetarako, txertatu goiko adierazpena IF funtzioaren proba logikoan. Adibidez:

=IF(A1=B1, "Equal", "Not equal")

Beheko pantaila-argazkian ikusten duzun bezala, bi formulek testu-kateak, datak eta zenbakiak berdin alderatzen dituzte:

Mauskulak eta minuskulak bereizten dituen formula Excel-en kateak alderatzeko

Egoera batzuetan, garrantzitsua izan daiteke bi gelaxken testu-balioak konparatzeaz gain, karaktereen maiuskulak eta minuskulak konparatzea ere. Maiuskulak eta minuskulak bereizten dituen Excel-en ZEHAZ funtzioa erabiliz egin daiteke:

Non testua1 eta testua2 alderatzen ari zaren bi gelaxkak diren.

Zure kateak A2 eta B2 gelaxketan daudela suposatuz, formula honela doa:

=EXACT(A2, B2)

Ondorioz, EGIA lortzen duzu testu-kateak maiuskulak eta minuskulak barne. karaktere bakoitzaren, FALSE bestela.

ZEHAZ funtzioak beste emaitza batzuk ematea nahi baduzu, txertatu IF formula batean eta idatzi zure testua value_if_true eta value_if_false argumentuak:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Ondoko pantaila-argazkiak Excel-en maiuskulak eta minuskulak bereizten dituen kateen konparaketaren emaitzak erakusten ditu:

Nola konparatu gelaxka anitz Excel-en

Bi gelaxka baino gehiago jarraian alderatzeko, erabili goiko adibideetan eztabaidatutako formulak AND eragilearekin konbinatuta. Xehetasun osoak jarraian.

Mauskulak eta minuskulak bereizten ez dituen formula konparatzeko2 gelaxka baino gehiago

Emaitzak bistaratu nahi dituzunaren arabera, erabili formula hauetako bat:

=AND(A2=B2, A2=C2)

edo

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

AND formulak EGIA ematen du gelaxka guztiek balio bera badute, GEZURRA balioren bat desberdina bada. IF formulak bertan idazten dituzun etiketak ateratzen ditu, " Berdin " eta " Ez berdina " adibide honetan.

Beheko pantaila-argazkian erakusten den moduan, Formula ezin hobeto funtzionatzen du edozein datu motekin: testua, datak eta zenbakizko balioak:

Mauskulak eta minuskulak bereizten ditu hainbat gelaxketako testua alderatzeko

Kate anitz alderatzeko elkarren artean zehazki bat datozen ikusteko, erabili formula hauek:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Edo

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Aurreko adibidean bezala, lehenengoa. formulak EGIA eta GEZURRA balioak ematen ditu, bigarrenak, berriz, zure testuak bistaratzen ditu bat etortzeen eta desberdintasunen arabera:

Konparatu gelaxka sorta bat lagin-gelaxka batekin

Ondorengo adibideek erakusten dute nola egiazta dezakezun barruti jakin bateko gelaxka guztiek lagin-gelaxka bateko testu bera dutela.

Mauskulak eta minuskulak bereizten ez dituzten formula gelaxkak lagin-testu batekin alderatzeko

Bada. karakterearen maiuskulak ez du axola, formula hau erabil dezakezu gelaxkak lagin batekin alderatzeko:

IF funtzioaren proba logikoan, bi zenbaki konparatzen dituzu:

• Zelula kopuru osoazehaztutako barruti batean (errenkada kopurua biderkatuta zutabe kopuruarekin), eta
• Lagin-gelaxkaren balio bera duten gelaxken kopurua (ZENBATU BEN funtzioak itzultzen du).

Lagin-testua C2-n dagoela eta alderatu beharreko kateak A2:B6 barrutian daudela suposatuz, formula hauxe da:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Emaitzak erabiltzaile gehiago izateko- adiskidetsua, hau da, "Denak bat datoz" eta "Ez bat datoz guztiak" bezalako zerbait atera TRUE eta FALSEren ordez, erabili IF funtzioa aurreko adibideetan egin genuen bezala:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Goiko pantaila-argazkian erakusten den bezala, formulak testu-kate sorta batekin ezin hobeto moldatzen da, baina zenbakiak eta datak alderatzeko ere erabil daiteke.

Maiuskulak eta minuskulak bereizten dituen formula kateak batekin alderatzeko. lagin-testua

Kaktere-maiuskulak eta minuskulak aldea eragiten badute, kateak lagin-testuarekin aldera ditzakezu ondoko matrize-formula hauek erabiliz.

Iturburu-barrutia A2:B6-n dagoenez eta lagin-testua C2-n dagoenez, formulak forma hau hartzen du:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Excel formula arruntek ez bezala. , array formulak Ctrl + Shift + Sartu sakatuz osatzen dira. Ondo sartzen bada, Excel-ek matrizearen formula {giltza kizkurren artean} sartzen du, pantaila-argazkian erakusten den moduan:

Nola konparatu bi gelaxka katearen araberaluzera

Batzuetan, errenkada bakoitzeko testu-kateek karaktere kopuru berdina duten egiaztatu nahi izan dezakezu. Zeregin honen formula oso erraza da. Lehenik eta behin, bi gelaxken katearen luzera lortzen duzu LEN funtzioa erabiliz, eta gero zenbakiak alderatu.

Konparatu beharreko kateak A2 eta B2 gelaxketan daudela suposatuz, erabili formula hauetako bat:

=LEN(A2)=LEN(B2)

Edo

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Dagoeneko dakizunez, lehenengo formulak EGIA edo GEZURRA balio boolearrak itzultzen ditu, eta bigarren formulak zure emaitzak ematen ditu:

Goiko pantaila-argazkian frogatzen den moduan, formulek testu-kateetarako nahiz zenbakietarako funtzionatzen dute.

Aholkua. Itxuraz berdinak diren bi kate luzera desberdinak itzultzen badituzte, ziurrenik arazoa lehenengo edo aurreko espazio gelaxka batean edo bietan egotea. Kasu honetan, kendu espazio gehigarriak TRIM funtzioa erabiliz. Azalpen zehatza eta formula adibideak hemen aurki daitezke: Nola moztu espazioak Excel-en.

Konparatu bi gelaxka karaktere zehatz baten agerraldien arabera

Hau da gure Excel Konparatu kateak tutorialaren azken adibidea, eta nahiko zeregin zehatz baterako irtenbidea erakusten du. Demagun, zuretzat garrantzitsua den karaktere bat duten testu-kateen 2 zutabe dituzula. Zure helburua errenkada bakoitzeko bi gelaxk karaktere jakin baten agerraldi kopuru bera duten egiaztatzea da.

Gauzak argiago izateko, kontuan hartu honako hau.adibidea. Demagun, bidalitako (B zutabea) eta jasotako eskaerak (C zutabea) bi zerrenda dituzu. Errenkada bakoitzak elementu zehatz baterako eskaerak ditu, zeinaren identifikatzaile bakarra eskaera ID guztietan sartuta dago eta A zutabean errenkada berean agertzen da (ikus beheko pantaila-argazkia). Ziurtatu nahi duzu errenkada bakoitzak ID zehatz horrekin bidalitako eta jasotako elementu kopuru berdina duela.

Arazo hau konpontzeko, idatzi formula bat honako logika honekin.

• Lehenik eta behin, ordezkatu identifikatzaile esklusiboa ezer ezarekin ORDEZKO funtzioa erabiliz:

  SUBSTITUTE(A1, character_to_count,"")

• Ondoren, kalkulatu zenbat aldiz agertzen den identifikatzaile bakarra gelaxka bakoitzean. Horretarako, lortu katearen luzera identifikatzaile esklusiborik gabe eta kendu katearen luzera osotik. Zati hau banan-banan idatziko da 1. gelaxkarako eta 2. gelaxkarako, adibidez:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  eta

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Azkenik, alderatu 2 zenbaki hauek. goiko zatien artean berdintasun zeinua (=) jarriz.

LEN( 2. gelaxka ) - LEN (ORDEZKOAK ( 2. gelaxka , karaktere_zenbatzeko_zenbatzeko , ""))

Gure adibidean, identifikatzaile bakarra A2-n dago , eta alderatu beharreko kateak B2 eta C2 gelaxketan daude. Beraz, formula osoa honako hau da:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Formulak EGIA ematen du B2 eta C2 gelaxkek A2ko karakterearen agerraldi kopuru berdina badute,GEZURRA bestela. Emaitzak zure erabiltzaileentzat esanguratsuagoak izan daitezen, formula IF funtzioan txerta dezakezu:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Goiko pantaila-argazkian ikus dezakezun bezala. , formulak ezin hobeto funtzionatzen du konplikazio gehigarri batzuk izan arren:

• Kontatu beharreko karakterea (identifikatzaile bakarra) edozein lekutan ager daiteke testu-kate batean.
• Kateek zenbaki aldakorra dute. karaktereen eta bereizle desberdinak, hala nola puntu eta koma, koma edo zuriunea.

Horrela konparatzen dituzu kateak Excel-en. Tutorial honetan eztabaidatutako formulak gertutik ikusteko, ongi etorria deskargatu Excel Compare Strings Worksheet. Eskerrik asko irakurtzeagatik eta datorren astean gure blogean ikustea espero dut.