Təlimatda Excel-də mətn sətirlərinin böyük hərflərə həssas olmayan və dəqiq uyğunluq üçün necə müqayisə olunacağı göstərilir. Siz iki xananı dəyərlərinə, sətir uzunluğuna və ya xüsusi simvolun təkrarlanmalarının sayına görə müqayisə etmək üçün bir sıra düsturları öyrənəcəksiniz, həmçinin birdən çox xananı necə müqayisə etmək olar.

Excel-dən istifadə edərkən. məlumatların təhlili, dəqiqlik ən həyati narahatlıqdır. Yanlış məlumat buraxılmış son tarixlərə, yanlış hesablanmış tendensiyalara, yanlış qərarlara və itirilmiş gəlirlərə gətirib çıxarır.

Excel düsturları həmişə mükəmməl doğru olsa da, bəzi qüsurlu məlumatlar sistemə daxil olduğu üçün onların nəticələri yanlış ola bilər. Bu vəziyyətdə yeganə çıxış yolu məlumatların düzgünlüyünü yoxlamaqdır. İki xananı əl ilə müqayisə etmək o qədər də böyük məsələ deyil, lakin yüzlərlə və minlərlə mətn sətirləri arasındakı fərqləri tapmaq qeyri-mümkündür.

Bu dərslik sizə xananın yorucu və xətaya meyilli tapşırığının avtomatlaşdırılmasını öyrədəcək. müqayisə və hər bir konkret halda hansı düsturlardan istifadə etmək daha yaxşıdır.

Excel-də iki xananı necə müqayisə etmək olar

Excel-də sətirləri müqayisə etməyin iki fərqli yolu var. istər hərf-həssas, istərsə də hərf-həssas müqayisə axtarın.

2 xananı müqayisə etmək üçün hərflərə həssas olmayan düstur

Excel-də hərfi nəzərə almadan iki xananı müqayisə etmək üçün bu kimi sadə düsturdan istifadə edin:

=A1=B1

A1 və B1 müqayisə etdiyiniz xanalardır. Düsturun nəticəsi məntiqi dəyərlərdir TRUEvə FALSE.

Uyğunluqlar və fərqlər üçün öz mətnlərinizi çıxarmaq istəyirsinizsə, yuxarıdakı ifadəni IF funksiyasının məntiqi testinə daxil edin. Məsələn:

=IF(A1=B1, "Equal", "Not equal")

Aşağıdakı ekran görüntüsündə gördüyünüz kimi, hər iki düstur mətn sətirlərini, tarixləri və rəqəmləri eyni dərəcədə yaxşı müqayisə edir:

Excel-də sətirləri müqayisə etmək üçün hərf-həssas düstur

Bəzi hallarda təkcə iki xananın mətn qiymətlərini müqayisə etmək deyil, həm də simvol registrini müqayisə etmək vacib ola bilər. Böyük hərflərə həssas mətn müqayisəsi Excel EXACT funksiyasından istifadə etməklə həyata keçirilə bilər:

Burada mətn1 və mətn2 müqayisə etdiyiniz iki xanadır.

Setirlərinizin A2 və B2 xanalarında olduğunu fərz etsək, düstur aşağıdakı kimi olur:

=EXACT(A2, B2)

Nəticədə, mətn sətirlərinin hərf daxil olmaqla tam uyğunluğu üçün TRUE alırsınız hər simvol üçün YANLIŞ, əks halda.

Əgər DƏMƏN funksiyasının bəzi digər nəticələr verməsini istəyirsinizsə, onu ƏGƏR düsturuna daxil edin və əgər_əgər_əgər_dəyər və əgər_yalan_dəyər<üçün öz mətninizi yazın. 2> arqumentlər:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Aşağıdakı skrinşot Excel-də hərflərə həssas sətir müqayisəsinin nəticələrini göstərir:

Necə etmək olar Excel-də birdən çox xananı müqayisə edin

Ardıcıl 2-dən çox xananı müqayisə etmək üçün yuxarıdakı nümunələrdə müzakirə olunan düsturları AND operatoru ilə birlikdə istifadə edin. Tam təfərrüatlar aşağıda verilmişdir.

Müqayisə etmək üçün hərflərə həssas olmayan düstur2-dən çox xana

Nəticələri necə göstərmək istədiyinizdən asılı olaraq, aşağıdakı düsturlardan birini istifadə edin:

=AND(A2=B2, A2=C2)

və ya

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

Əgər bütün xanalar eyni dəyərə malikdirsə VƏ düsturu TRUE, hər hansı dəyər fərqlidirsə FALSE qaytarır. ƏGƏR düsturu bu misalda daxil etdiyiniz " Bərabər " və " Bərabər deyil " etiketlərini çıxarır.

Aşağıdakı ekran görüntüsündə göstərildiyi kimi, düstur istənilən məlumat növləri ilə mükəmməl işləyir - mətn, tarix və rəqəmli dəyərlər:

Bir neçə xanadakı mətni müqayisə etmək üçün hərflərə həssas düstur

Birdən çox sətirləri müqayisə etmək bir-birlərinə tam uyğun olub-olmadığını görmək üçün aşağıdakı düsturlardan istifadə edin:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Vəya

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Əvvəlki misalda olduğu kimi, birinci düstur DOĞRU və YANLIŞ dəyərləri təqdim edir, ikincisi isə uyğunluqlar və fərqlər üçün öz mətnlərinizi göstərir:

Bir sıra xanaları nümunə xana ilə müqayisə edin

Aşağıdakı nümunələr verilmiş diapazondakı bütün xanaların nümunə xanadakı kimi eyni mətni ehtiva etdiyini necə yoxlaya biləcəyinizi göstərir.

Hanları nümunə mətnlə müqayisə etmək üçün hərflərə həssas olmayan düstur

Əgər simvol böyüklüyünün əhəmiyyəti yoxdur, siz xanaları nümunə ilə müqayisə etmək üçün aşağıdakı düsturdan istifadə edə bilərsiniz:

IF funksiyasının məntiqi testində siz iki ədədi müqayisə edirsiniz:

• Hüceyrələrin ümumi sayımüəyyən diapazonda (sütunların sayına vurulan sətirlərin sayı) və
• Nümunə xanasındakı ilə eyni dəyəri ehtiva edən xanaların sayı (COUNTIF funksiyası ilə qaytarılır).

Nümunə mətnin C2-də olduğunu və müqayisə ediləcək sətirlərin A2:B6 diapazonunda olduğunu fərz etsək, düstur aşağıdakı kimi olur:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Nəticələri daha çox istifadəçi etmək üçün- dostluq, yəni TRUE və FALSE əvəzinə "Bütün uyğunluq" və "Hamısı uyğun deyil" kimi bir şey çıxarın, əvvəlki nümunələrdə etdiyimiz kimi ƏGƏR funksiyasından istifadə edin:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Yuxarıdakı ekran görüntüsündə göstərildiyi kimi, düstur bir sıra mətn sətirlərinin öhdəsindən mükəmməl gəlir, lakin o, həm də nömrələri və tarixləri müqayisə etmək üçün istifadə edilə bilər.

Sətrləri hərflərlə müqayisə etmək üçün hərf-həssas düstur nümunə mətn

Əgər simvol rejisiyası fərq yaradırsa, siz aşağıdakı massiv düsturlarından istifadə edərək sətirləri nümunə mətnlə müqayisə edə bilərsiniz.

Mənbə diapazonu A2:B6-da və nümunə mətni C2-də olan halda düstur aşağıdakı formanı alır:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Adi Excel düsturlarından fərqli olaraq , massiv düsturları Ctrl + Shift + Enter düymələrini basmaqla tamamlanır. Düzgün daxil edilərsə, Excel ekran görüntüsündə göstərildiyi kimi massiv düsturunu {qıvrımlı mötərizələr} içərisinə daxil edir:

İki xananı sətirlə necə müqayisə etmək olaruzunluq

Bəzən siz hər sətirdəki mətn sətirlərinin bərabər sayda simvoldan ibarət olub-olmadığını yoxlamaq istəyə bilərsiniz. Bu tapşırığın düsturu çox sadədir. Əvvəlcə LEN funksiyasından istifadə edərək iki xananın sətir uzunluğunu əldə edirsiniz, sonra isə ədədləri müqayisə edirsiniz.

Müqayisə ediləcək sətirlərin A2 və B2 xanalarında olduğunu düşünsək, aşağıdakı düsturlardan birini istifadə edin:

=LEN(A2)=LEN(B2)

Vəya

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Bildiyiniz kimi, birinci düstur DOĞRU və ya YANLIŞ Boolean dəyərlərini qaytarır, ikinci düstur isə öz nəticələrinizi verir:

Yuxarıdakı ekran görüntüsündə göstərildiyi kimi, düsturlar mətn sətirləri və rəqəmlər üçün işləyir.

İpucu. Əgər eyni görünən iki sətir fərqli uzunluqları qaytarırsa, çox güman ki, problem bir və ya hər iki xanada aparıcı və ya arxada gedən boşluqlar ilə bağlıdır. Bu halda, TRIM funksiyasından istifadə edərək əlavə boşluqları çıxarın. Ətraflı izahat və düstur nümunələrini burada tapa bilərsiniz: Excel-də boşluqları necə kəsmək olar.

İki xananı konkret simvolun təkrarlanmasına görə müqayisə edin

Bu, Excel Strings Müqayisə dərsliyimizdəki sonuncu nümunədir və kifayət qədər konkret tapşırıq üçün həlli göstərir. Tutaq ki, sizin üçün vacib olan simvolu ehtiva edən mətn sətirlərinin 2 sütunu var. Məqsədiniz hər cərgədəki iki xananın verilmiş simvolun eyni sayda təkrarını ehtiva edib-etmədiyini yoxlamaqdır.

Hər şeyi aydınlaşdırmaq üçün aşağıdakıları nəzərdən keçirin.misal. Tutaq ki, göndərilmiş (B sütunu) və qəbul edilmiş (C sütunu) sifarişlərin iki siyahısı var. Hər bir sıra unikal identifikatoru bütün sifariş identifikatorlarına daxil edilmiş və A sütununda eyni cərgədə verilmiş xüsusi element üçün sifarişləri ehtiva edir (zəhmət olmasa, aşağıdakı ekran görüntüsünə baxın). Siz əmin olmaq istəyirsiniz ki, hər bir cərgədə həmin xüsusi ID ilə bərabər sayda göndərilmiş və qəbul edilmiş elementlər var.

Bu problemi həll etmək üçün aşağıdakı məntiqlə düstur yazın.

• Birincisi, Əvəz etmə funksiyasından istifadə edərək unikal identifikatoru heç nə ilə əvəz edin:

  SUBSTITUTE(A1, character_to_count,"")

• Sonra, unikal identifikatorun hər xanada neçə dəfə göründüyünü hesablayın. Bunun üçün unikal identifikator olmadan sətir uzunluğunu alın və onu sətirin ümumi uzunluğundan çıxarın. Bu hissə 1-ci xana və 2-ci xana üçün ayrı-ayrılıqda yazılmalıdır, məsələn:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  və

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Nəhayət, siz bu 2 rəqəmi müqayisə edirsiniz yuxarıdakı hissələr arasında bərabərlik işarəsini (=) qoymaqla.

LEN( xana 2 ) - LEN(Əvəz( xana 2 , saymaq üçün_xarakter , ""))

Bizim nümunəmizdə unikal identifikator A2-dədir , və müqayisə ediləcək sətirlər B2 və C2 xanalarındadır. Beləliklə, tam düstur aşağıdakı kimidir:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

B2 və C2 xanalarında A2-də simvolun bərabər sayda təkrarlanması varsa, düstur DOĞRU qaytarır,əks halda FALSE. Nəticələri istifadəçiləriniz üçün daha mənalı etmək üçün düsturu IF funksiyasına yerləşdirə bilərsiniz:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Yuxarıdakı ekran görüntüsündə gördüyünüz kimi , düstur bir neçə əlavə çətinliyə baxmayaraq mükəmməl işləyir:

• Hesablanacaq simvol (unikal identifikator) mətn sətirinin istənilən yerində görünə bilər.
• Sətrlər dəyişən nömrə ehtiva edir. simvollar və nöqtəli vergül, vergül və ya boşluq kimi müxtəlif ayırıcılar.

Excel-də sətirləri belə müqayisə edirsiniz. Bu dərslikdə müzakirə olunan düsturlara daha yaxından baxmaq üçün Excel Strings Müqayisə İş Cədvəlini yükləyə bilərsiniz. Oxuduğunuz üçün sizə təşəkkür edirəm və sizi gələn həftə bloqumuzda görməyə ümid edirəm.