Ipinapakita ng tutorial kung paano ihambing ang mga string ng text sa Excel para sa case-insensitive at eksaktong tugma. Matututuhan mo ang ilang mga formula upang ihambing ang dalawang cell sa pamamagitan ng kanilang mga halaga, haba ng string, o bilang ng mga paglitaw ng isang partikular na character, pati na rin kung paano maghambing ng maraming mga cell.

Kapag gumagamit ng Excel para sa pagsusuri ng data, ang katumpakan ay ang pinakamahalagang alalahanin. Ang maling impormasyon ay humahantong sa mga napalampas na mga deadline, maling paghusga sa mga uso, mga maling desisyon, at mga nawalang kita.

Bagama't ang mga formula ng Excel ay laging ganap na totoo, ang mga resulta ng mga ito ay maaaring mali dahil may ilang maling data na pumasok sa system. Sa kasong ito, ang tanging lunas ay suriin ang data para sa katumpakan. Hindi malaking bagay na manu-manong paghambingin ang dalawang cell, ngunit imposibleng makita ang mga pagkakaiba sa pagitan ng daan-daan at libu-libong mga string ng teksto.

Itinuturo sa iyo ng tutorial na ito kung paano i-automate ang nakakapagod at madaling pagkakamali ng gawain ng cell paghahambing at kung anong mga formula ang pinakamahusay na gamitin sa bawat partikular na kaso.

Paano ihambing ang dalawang cell sa Excel

May dalawang magkaibang paraan upang ihambing ang mga string sa Excel depende sa kung naghahanap ka man ng case-sensitive o case-insensitive na paghahambing.

Case-insensitive na formula para ihambing ang 2 cell

Upang paghambingin ang dalawang cell sa Excel na binabalewala ang case, gumamit ng simpleng formula na tulad nito:

=A1=B1

Kung saan A1 at B1 ang mga cell na iyong inihahambing. Ang resulta ng formula ay mga Boolean value na TRUEat MALI.

Kung gusto mong i-output ang iyong sariling mga teksto para sa mga tugma at pagkakaiba, i-embed ang pahayag sa itaas sa lohikal na pagsubok ng IF function. Halimbawa:

=IF(A1=B1, "Equal", "Not equal")

Tulad ng nakikita mo sa screenshot sa ibaba, parehong mahusay na pinaghahambing ng mga formula ang mga string ng text, petsa at numero:

Case-sensitive na formula upang ihambing ang mga string sa Excel

Sa ilang sitwasyon, maaaring mahalagang hindi lamang paghambingin ang mga value ng text ng dalawang cell, kundi pati na rin ang paghambingin ang case ng character. Maaaring gawin ang case-sensitive na paghahambing ng text gamit ang Excel EXACT function:

Kung saan ang text1 at text2 ay ang dalawang cell na iyong inihahambing.

Ipagpalagay na ang iyong mga string ay nasa mga cell A2 at B2, ang formula ay sumusunod:

=EXACT(A2, B2)

Bilang resulta, makakakuha ka ng TRUE para sa mga string ng teksto na eksaktong tumutugma kasama ang kaso ng bawat character, FALSE kung hindi.

Kung gusto mo ang EXACT function na maghatid ng ilang iba pang mga resulta, i-embed ito sa isang IF formula at i-type ang sarili mong text para sa value_if_true at value_if_false mga argumento:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Ang sumusunod na screenshot ay nagpapakita ng mga resulta ng case-sensitive na paghahambing ng string sa Excel:

Paano ihambing ang maramihang mga cell sa Excel

Upang paghambingin ang higit sa 2 mga cell sa isang hilera, gamitin ang mga formula na tinalakay sa mga halimbawa sa itaas kasama ang AND operator. Ang buong detalye ay sumusunod sa ibaba.

Case-insensitive na formula na ihahambinghigit sa 2 cell

Depende sa kung paano mo gustong ipakita ang mga resulta, gamitin ang isa sa mga sumusunod na formula:

=AND(A2=B2, A2=C2)

o

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

Ang formula na AND ay nagbabalik ng TRUE kung ang lahat ng mga cell ay naglalaman ng parehong halaga, FALSE kung ang anumang halaga ay naiiba. Ang IF formula ay naglalabas ng mga label na tina-type mo dito, " Pantay " at " Hindi pantay " sa halimbawang ito.

Tulad ng ipinakita sa screenshot sa ibaba, ang Perpektong gumagana ang formula sa anumang uri ng data - teksto, mga petsa at mga numerong halaga:

Case-sensitive na formula upang ihambing ang teksto sa ilang mga cell

Upang maghambing ng maraming string sa isa't isa upang makita kung eksaktong tumutugma ang mga ito, gamitin ang mga sumusunod na formula:

=AND(EXACT(A2,B2), EXACT(A2, C2))

O

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Tulad ng sa nakaraang halimbawa, ang una Ang formula ay naghahatid ng TRUE at FALSE value, samantalang ang pangalawa ay nagpapakita ng sarili mong mga text para sa mga tugma at pagkakaiba:

Ihambing ang isang hanay ng mga cell sa isang sample na cell

Ipinapakita ng mga sumusunod na halimbawa kung paano mo mabe-verify na ang lahat ng mga cell sa isang naibigay na hanay ay naglalaman ng parehong teksto tulad ng sa isang sample na cell.

Case-insensitive na formula upang ihambing ang mga cell sa isang sample na text

Kung ang hindi mahalaga ang case ng character, maaari mong gamitin ang sumusunod na formula upang ihambing ang mga cell sa isang sample:

Sa logical test ng function na IF, naghahambing ka ng dalawang numero:

• Ang kabuuang bilang ng mga cellsa isang tinukoy na hanay (ang bilang ng mga row na na-multiply sa bilang ng mga column), at
• Ang bilang ng mga cell na naglalaman ng parehong halaga tulad ng sa sample na cell (ibinalik ng COUNTIF function).

Ipagpalagay na ang sample na text ay nasa C2 at ang mga string na ihahambing ay nasa hanay na A2:B6, ang formula ay sumusunod:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Upang gawing mas user ang mga resulta- friendly, ibig sabihin, mag-output ng isang bagay tulad ng "Lahat ng tugma" at "Hindi lahat ng tugma" sa halip na TRUE at FALSE, gamitin ang IF function tulad ng ginawa namin sa mga nakaraang halimbawa:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Tulad ng ipinakita sa screenshot sa itaas, ang formula ay ganap na nakayanan ang isang hanay ng mga string ng teksto, ngunit maaari rin itong gamitin upang ihambing ang mga numero at petsa.

Case-sensitive na formula upang ihambing ang mga string sa isang sample na text

Kung may pagkakaiba ang case ng character, maaari mong ihambing ang mga string sa sample na text gamit ang mga sumusunod na array formula.

Gamit ang source range na nasa A2:B6 at ang sample na text sa C2, ang formula ay may sumusunod na hugis:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Hindi tulad ng mga regular na Excel formula , ang mga array formula ay nakumpleto sa pamamagitan ng pagpindot sa Ctrl + Shift + Enter . Kung nailagay nang tama, isinasama ng Excel ang array formula sa {curly braces}, tulad ng ipinapakita sa screenshot:

Paano ihambing ang dalawang cell sa pamamagitan ng stringhaba

Minsan maaaring gusto mong tingnan kung ang mga string ng teksto sa bawat hilera ay naglalaman ng pantay na bilang ng mga character. Ang formula para sa gawaing ito ay napaka-simple. Una, makukuha mo ang haba ng string ng dalawang cell gamit ang LEN function, at pagkatapos ay ikumpara ang mga numero.

Ipagpalagay na ang mga string na ihahambing ay nasa mga cell A2 at B2, gamitin ang alinman sa mga sumusunod na formula:

=LEN(A2)=LEN(B2)

O

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Tulad ng alam mo na, ang unang formula ay nagbabalik ng mga Boolean na halaga na TRUE o FALSE, samantalang ang pangalawang formula ay naglalabas ng sarili mong mga resulta:

Tulad ng ipinakita sa screenshot sa itaas, gumagana ang mga formula para sa mga string ng text pati na rin sa mga numero.

Tip. Kung ang dalawang tila magkaparehong string ay nagbabalik ng magkaibang haba, malamang na ang problema ay nasa nangunguna o trailing mga puwang sa isa o parehong mga cell. Sa kasong ito, alisin ang mga karagdagang espasyo gamit ang TRIM function. Ang detalyadong paliwanag at mga halimbawa ng formula ay matatagpuan dito: Paano mag-trim ng mga puwang sa Excel.

Ihambing ang dalawang cell ayon sa mga paglitaw ng isang partikular na character

Ito ang huling halimbawa sa aming Excel Compare Strings tutorial, at nagpapakita ito ng solusyon para sa isang medyo partikular na gawain. Kumbaga, mayroon kang 2 column ng mga text string na naglalaman ng character na mahalaga sa iyo. Ang iyong layunin ay suriin kung ang dalawang cell sa bawat row ay naglalaman ng parehong bilang ng mga paglitaw ng isang partikular na character.

Upang gawing mas malinaw ang mga bagay, isaalang-alang ang sumusunodhalimbawa. Sabihin nating, mayroon kang dalawang listahan ng mga order na ipinadala (column B) at natanggap (column C). Ang bawat row ay naglalaman ng mga order para sa isang partikular na item, na ang natatanging identifier ay kasama sa lahat ng order ID at nakalista sa parehong row sa column A (pakitingnan ang screenshot sa ibaba). Gusto mong tiyakin na ang bawat row ay naglalaman ng pantay na bilang ng mga naipadala at natanggap na mga item na may partikular na ID na iyon.

Upang malutas ang problemang ito, sumulat ng formula na may sumusunod na lohika.

• Una, palitan ang natatanging identifier ng wala gamit ang SUBSTITUTE function:

  SUBSTITUTE(A1, character_to_count,"")

• Pagkatapos, kalkulahin kung gaano karaming beses lumalabas ang natatanging identifier sa bawat cell. Para dito, kunin ang haba ng string nang walang natatanging identifier at ibawas ito sa kabuuang haba ng string. Ang bahaging ito ay isusulat para sa cell 1 at cell 2 nang paisa-isa, halimbawa:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  at

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Panghuli, ikumpara mo ang 2 numerong ito sa pamamagitan ng paglalagay ng equality sign (=) sa pagitan ng mga bahagi sa itaas.

LEN( cell 2 ) - LEN(SUBSTITUTE( cell 2 , character_to_count , ""))

Sa aming halimbawa, ang natatanging identifier ay nasa A2 , at ang mga string na ihahambing ay nasa mga cell B2 at C2. Kaya, ang kumpletong formula ay ang sumusunod:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Ang formula ay nagbabalik ng TRUE kung ang mga cell B2 at C2 ay naglalaman ng pantay na bilang ng mga paglitaw ng character sa A2,FALSE kung hindi. Upang gawing mas makabuluhan ang mga resulta para sa iyong mga user, maaari mong i-embed ang formula sa function na IF:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Gaya ng nakikita mo sa screenshot sa itaas , perpektong gumagana ang formula sa kabila ng ilang karagdagang komplikasyon:

• Ang character na bibilangin (natatanging identifier) ​​ay maaaring lumabas kahit saan sa isang text string.
• Ang mga string ay naglalaman ng variable na numero ng mga character at iba't ibang separator tulad ng semicolon, kuwit o espasyo.

Ganito ka naghahambing ng mga string sa Excel. Upang mas masusing tingnan ang mga formula na tinalakay sa tutorial na ito, malugod kang mag-download ng Excel Compare Strings Worksheet. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo.