Tutorial ini menunjukkan cara membandingkan string teks di Excel untuk case-insensitive dan pencocokan tepat. Anda akan mempelajari sejumlah rumus untuk membandingkan dua sel dengan nilainya, panjang string, atau jumlah kemunculan karakter tertentu, serta cara membandingkan beberapa sel.

Ketika menggunakan Excel untuk analisis data, keakuratan adalah hal yang paling penting. Informasi yang salah menyebabkan tenggat waktu yang terlewat, tren yang salah penilaian, keputusan yang salah, dan pendapatan yang hilang.

Meskipun rumus Excel selalu benar secara sempurna, hasilnya mungkin salah karena beberapa data yang cacat masuk ke dalam sistem. Dalam hal ini, satu-satunya solusi adalah memeriksa keakuratan data. Bukan masalah besar untuk membandingkan dua sel secara manual, tetapi hampir tidak mungkin untuk melihat perbedaan antara ratusan dan ribuan string teks.

Tutorial ini akan mengajarkan Anda cara mengotomatiskan tugas perbandingan sel yang membosankan dan rawan kesalahan dan rumus apa yang terbaik untuk digunakan dalam setiap kasus tertentu.

Bagaimana membandingkan dua sel di Excel

Ada dua cara berbeda untuk membandingkan string di Excel tergantung pada apakah Anda mencari perbandingan case-sensitive atau case-insensitive.

Rumus case-insensitive untuk membandingkan 2 sel

Untuk membandingkan dua sel dalam kasus pengabaian Excel, gunakan rumus sederhana seperti ini:

=A1=B1

Di mana A1 dan B1 adalah sel yang Anda bandingkan. Hasil rumusnya adalah nilai Boolean TRUE dan FALSE.

Jika Anda ingin mengeluarkan teks Anda sendiri untuk kecocokan dan perbedaan, sematkan pernyataan di atas dalam uji logika fungsi IF. Sebagai contoh:

=IF(A1=B1, "Sama", "Tidak sama")

Seperti yang Anda lihat pada tangkapan layar di bawah ini, kedua rumus tersebut membandingkan string teks, tanggal, dan angka dengan sama baiknya:

Rumus peka huruf besar-kecil untuk membandingkan string di Excel

Dalam beberapa situasi, mungkin penting tidak hanya untuk membandingkan nilai teks dari dua sel, tetapi juga untuk membandingkan kasus karakter. Perbandingan teks peka huruf besar-kecil dapat dilakukan dengan menggunakan fungsi EXACT Excel:

Di mana teks1 dan teks2 adalah dua sel yang Anda bandingkan.

Dengan asumsi string Anda berada di sel A2 dan B2, rumusnya adalah sebagai berikut:

=EXACT(A2, B2)

Sebagai hasilnya, Anda mendapatkan TRUE untuk string teks yang cocok persis termasuk kasus setiap karakter, FALSE jika tidak.

Jika Anda ingin fungsi EXACT memberikan beberapa hasil lain, sematkan dalam rumus IF dan ketik teks Anda sendiri untuk value_if_true dan value_if_false argumen:

=IF(EXACT(A2 ,B2), "Persis sama", "Tidak sama")

Tangkapan layar berikut menunjukkan hasil perbandingan string case-sensitive di Excel:

Bagaimana membandingkan beberapa sel di Excel

Untuk membandingkan lebih dari 2 sel dalam satu baris, gunakan rumus yang dibahas dalam contoh di atas dalam kombinasi dengan operator AND. Rincian lengkapnya ikuti di bawah ini.

Rumus case-insensitive untuk membandingkan lebih dari 2 sel

Tergantung pada bagaimana Anda ingin menampilkan hasilnya, gunakan salah satu rumus berikut ini:

=DAN(A2=B2, A2=C2)

atau

=IF(AND(A2=B2, A2=C2), "Sama", "Tidak sama")

Rumus AND mengembalikan TRUE jika semua sel berisi nilai yang sama, FALSE jika ada nilai yang berbeda. Rumus IF menghasilkan label yang Anda ketikkan di dalamnya, " Sama " dan " Tidak sama " dalam contoh ini.

Seperti yang ditunjukkan dalam tangkapan layar di bawah ini, rumus ini bekerja dengan sempurna dengan tipe data apa pun - teks, tanggal, dan nilai numerik:

Rumus peka huruf besar-kecil untuk membandingkan teks dalam beberapa sel

Untuk membandingkan beberapa string satu sama lain untuk melihat apakah mereka cocok persis, gunakan rumus berikut:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Atau

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)), "Sama persis", "Tidak sama")

Seperti pada contoh sebelumnya, rumus pertama memberikan nilai TRUE dan FALSE, sedangkan rumus kedua menampilkan teks Anda sendiri untuk kecocokan dan perbedaan:

Membandingkan rentang sel dengan sel sampel

Contoh-contoh berikut menunjukkan bagaimana Anda dapat memverifikasi bahwa semua sel dalam rentang tertentu berisi teks yang sama seperti dalam sel sampel.

Rumus case-insensitive untuk membandingkan sel dengan teks sampel

Jika kasus karakter tidak terlalu penting, Anda dapat menggunakan rumus berikut untuk membandingkan sel dengan sampel:

Dalam uji logika fungsi IF, Anda membandingkan dua angka:

• Jumlah total sel dalam rentang tertentu (jumlah baris dikalikan dengan jumlah kolom), dan
• Jumlah sel yang mengandung nilai yang sama seperti pada sel sampel (dikembalikan oleh fungsi COUNTIF).

Dengan asumsi teks sampel berada di C2 dan string yang akan dibandingkan berada dalam rentang A2: B6, rumusnya adalah sebagai berikut:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Untuk membuat hasilnya lebih ramah pengguna, yaitu output sesuatu seperti "Semua cocok" dan "Tidak semua cocok" alih-alih TRUE dan FALSE, gunakan fungsi IF seperti yang kita lakukan pada contoh sebelumnya:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2), "Semua cocok", "Tidak semua cocok")

Seperti yang ditunjukkan tangkapan layar di atas, rumus ini dengan sempurna mengatasi berbagai string teks, tetapi juga dapat digunakan untuk membandingkan angka dan tanggal.

Rumus peka huruf besar-kecil untuk membandingkan string dengan teks sampel

Jika kasus karakter membuat perbedaan, Anda dapat membandingkan string dengan teks sampel menggunakan rumus array berikut.

Dengan rentang sumber berada di A2:B6 dan teks sampel di C2, rumusnya mengambil bentuk berikut:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "Semua cocok", "Tidak semua cocok")

Tidak seperti rumus Excel biasa, rumus array diselesaikan dengan menekan Ctrl + Shift + Enter . Jika dimasukkan dengan benar, Excel melampirkan rumus array dalam {kurung kurung keriting}, seperti yang ditunjukkan pada tangkapan layar:

Cara membandingkan dua sel dengan panjang string

Terkadang Anda mungkin ingin memeriksa apakah string teks di setiap baris berisi jumlah karakter yang sama. Rumus untuk tugas ini sangat sederhana. Pertama, Anda mendapatkan panjang string dari dua sel menggunakan fungsi LEN, lalu membandingkan angkanya.

Misalkan string yang akan dibandingkan berada di sel A2 dan B2, gunakan salah satu rumus berikut:

=LEN(A2)=LEN(B2)

Atau

=IF(LEN(A2)=LEN(B2), "Sama", "Tidak sama")

Seperti yang sudah Anda ketahui, rumus pertama mengembalikan nilai Boolean TRUE atau FALSE, sedangkan rumus kedua mengeluarkan hasil Anda sendiri:

Seperti yang ditunjukkan dalam tangkapan layar di atas, formula bekerja untuk string teks serta angka.

Tip. Jika dua string yang tampaknya sama panjangnya menghasilkan panjang yang berbeda, kemungkinan besar masalahnya ada pada memimpin atau trailing ruang Dalam kasus ini, hapus spasi ekstra menggunakan fungsi TRIM. Penjelasan rinci dan contoh rumus dapat ditemukan di sini: Cara memangkas spasi di Excel.

Membandingkan dua sel berdasarkan kemunculan karakter tertentu

Ini adalah contoh terakhir dalam tutorial Excel Compare Strings, dan ini menunjukkan solusi untuk tugas yang agak spesifik. Misalkan, Anda memiliki 2 kolom string teks yang berisi karakter yang penting bagi Anda. Tujuan Anda adalah untuk memeriksa apakah dua sel di setiap baris berisi jumlah kemunculan yang sama dari karakter tertentu.

Untuk memperjelas, pertimbangkan contoh berikut ini. Katakanlah, Anda memiliki dua daftar pesanan yang dikirim (kolom B) dan diterima (kolom C). Setiap baris berisi pesanan untuk item tertentu, yang pengidentifikasi uniknya termasuk dalam semua ID pesanan dan terdaftar di baris yang sama di kolom A (lihat tangkapan layar di bawah ini). Anda ingin memastikan bahwa setiap baris berisi jumlah yang sama antara pesanan yang dikirim dan yang diterima.item dengan ID spesifik itu.

Untuk menyelesaikan masalah ini, tulis rumus dengan logika berikut.

• Pertama, ganti pengidentifikasi unik dengan tidak menggunakan fungsi SUBSTITUTE:

  SUBSTITUTE(A1, character_to_count,"")

• Kemudian, hitung berapa kali pengenal unik muncul di setiap sel. Untuk ini, dapatkan panjang string tanpa pengenal unik dan kurangi dari total panjang string. Bagian ini harus ditulis untuk sel 1 dan sel 2 secara individual, misalnya:

  LEN(sel 1) - LEN(SUBSTITUTE(sel 1, character_to_count, ""))

  dan

  LEN(sel 2) - LEN(SUBSTITUTE(sel 2, character_to_count, ""))

• Terakhir, Anda membandingkan 2 angka ini dengan menempatkan tanda persamaan (=) di antara bagian-bagian di atas.

LEN( sel 2 ) - LEN(SUBSTITUTE( sel 2 , character_to_count , ""))

Dalam contoh kita, pengenal unik ada di A2, dan string yang akan dibandingkan ada di sel B2 dan C2. Jadi, rumus lengkapnya adalah sebagai berikut:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Rumus mengembalikan TRUE jika sel B2 dan C2 berisi jumlah kemunculan karakter yang sama di A2, jika tidak, FALSE. Untuk membuat hasilnya lebih bermakna bagi pengguna Anda, Anda bisa menyematkan rumus dalam fungsi IF:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,"""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Sama", "Tidak sama")

Seperti yang bisa Anda lihat pada tangkapan layar di atas, formula ini bekerja dengan sempurna meskipun ada beberapa komplikasi tambahan:

• Karakter yang akan dihitung (pengidentifikasi unik) dapat muncul di mana saja dalam string teks.
• String mengandung sejumlah karakter variabel dan pemisah yang berbeda seperti titik koma, koma atau spasi.

Untuk melihat lebih dekat rumus-rumus yang dibahas dalam tutorial ini, Anda dipersilakan untuk mengunduh Excel Compare Strings Worksheet. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan.