ट्यूटोरियल दिखाता है कि केस-असंवेदनशील और सटीक मिलान के लिए एक्सेल में टेक्स्ट स्ट्रिंग्स की तुलना कैसे करें। आप दो सेलों की तुलना उनके मूल्यों, स्ट्रिंग की लंबाई, या किसी विशिष्ट वर्ण की घटनाओं की संख्या के साथ-साथ कई सेलों की तुलना करने के तरीके के साथ-साथ कई सूत्रों को सीखेंगे।

के लिए एक्सेल का उपयोग करते समय डेटा विश्लेषण, सटीकता सबसे महत्वपूर्ण चिंता है। गलत जानकारी की वजह से डेडलाइन मिस हो जाती है, गलत रुझान, गलत निर्णय और राजस्व का नुकसान होता है।

जबकि एक्सेल फॉर्मूला हमेशा पूरी तरह से सही होते हैं, उनके परिणाम गलत हो सकते हैं क्योंकि कुछ त्रुटिपूर्ण डेटा सिस्टम में प्रवेश कर जाते हैं। इस मामले में, सटीकता के लिए डेटा की जांच करना एकमात्र उपाय है। मैन्युअल रूप से दो सेल की तुलना करना कोई बड़ी बात नहीं है, लेकिन सैकड़ों और हजारों टेक्स्ट स्ट्रिंग्स के बीच के अंतर को खोजना लगभग असंभव है।

यह ट्यूटोरियल आपको सिखाएगा कि सेल के थकाऊ और त्रुटि-प्रवण कार्य को कैसे स्वचालित किया जाए तुलना और प्रत्येक विशेष मामले में उपयोग करने के लिए कौन से सूत्र सबसे अच्छे हैं।

एक्सेल में दो सेल की तुलना कैसे करें

एक्सेल में स्ट्रिंग्स की तुलना करने के दो अलग-अलग तरीके हैं जो इस पर निर्भर करते हैं चाहे आप केस-संवेदी या केस-संवेदी तुलना चाहते हैं।

2 सेल की तुलना करने के लिए केस-असंवेदनशील सूत्र

केस को अनदेखा करते हुए एक्सेल में दो सेल की तुलना करने के लिए, इस तरह के एक सरल सूत्र का उपयोग करें:<3

=A1=B1

जहाँ A1 और B1 वे सेल हैं जिनकी आप तुलना कर रहे हैं। सूत्र के परिणाम बूलियन मान TRUE हैंऔर FALSE।

यदि आप मिलानों और अंतरों के लिए अपने स्वयं के टेक्स्ट आउटपुट करना चाहते हैं, तो उपरोक्त कथन को IF फ़ंक्शन के तार्किक परीक्षण में एम्बेड करें। उदाहरण के लिए:

=IF(A1=B1, "Equal", "Not equal")

जैसा कि आप नीचे स्क्रीनशॉट में देख सकते हैं, दोनों सूत्र टेक्स्ट स्ट्रिंग, दिनांक और संख्याओं की समान रूप से तुलना करते हैं:

एक्सेल में स्ट्रिंग्स की तुलना करने के लिए केस-संवेदी फॉर्मूला

कुछ स्थितियों में, न केवल दो सेल के टेक्स्ट वैल्यू की तुलना करना महत्वपूर्ण हो सकता है, बल्कि कैरेक्टर केस की तुलना करना भी महत्वपूर्ण हो सकता है। केस-संवेदी पाठ की तुलना एक्सेल एक्सक्लूसिव फंक्शन का उपयोग करके की जा सकती है:

जहाँ text1 और text2 वे दो सेल हैं जिनकी आप तुलना कर रहे हैं।

यह मानते हुए कि आपकी स्ट्रिंग्स कक्ष A2 और B2 में हैं, सूत्र इस प्रकार है:

=EXACT(A2, B2)

परिणाम के रूप में, आपको केस सहित टेक्स्ट स्ट्रिंग्स के मिलान के लिए TRUE मिलता है अन्यथा प्रत्येक वर्ण का गलत।

यदि आप चाहते हैं कि EXACT फ़ंक्शन कुछ अन्य परिणाम प्रदान करे, तो इसे एक IF सूत्र में एम्बेड करें और value_if_true और value_if_false<के लिए अपना टेक्स्ट टाइप करें। 2> तर्क:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

निम्नलिखित स्क्रीनशॉट एक्सेल में केस-संवेदी स्ट्रिंग तुलना के परिणाम दिखाता है:

कैसे करें Excel में एकाधिक कक्षों की तुलना करें

एक पंक्ति में 2 से अधिक कक्षों की तुलना करने के लिए, AND ऑपरेटर के संयोजन में उपरोक्त उदाहरणों में चर्चा किए गए सूत्रों का उपयोग करें। पूरा विवरण नीचे दिया गया है।

तुलना करने के लिए केस-इनसेंसिटिव फॉर्मूला2 से अधिक सेल

इस आधार पर कि आप परिणाम कैसे प्रदर्शित करना चाहते हैं, निम्न सूत्रों में से किसी एक का उपयोग करें:

=AND(A2=B2, A2=C2)

या

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal") <3

यदि सभी सेल में समान मान है, तो AND सूत्र TRUE लौटाता है, यदि कोई मान भिन्न है, तो FALSE देता है। IF सूत्र इस उदाहरण में आपके द्वारा टाइप किए गए लेबल, " बराबर " और " बराबर नहीं " को आउटपुट करता है।

जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, फ़ॉर्मूला किसी भी प्रकार के डेटा - टेक्स्ट, दिनांक और संख्यात्मक मानों के साथ पूरी तरह से काम करता है:

कई सेल में टेक्स्ट की तुलना करने के लिए केस-संवेदी फ़ॉर्मूला

कई स्ट्रिंग्स की तुलना करने के लिए एक दूसरे से यह देखने के लिए कि क्या वे सटीक रूप से मेल खाते हैं, निम्नलिखित सूत्रों का उपयोग करें:

=AND(EXACT(A2,B2), EXACT(A2, C2))

या

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

पिछले उदाहरण की तरह, पहला सूत्र TRUE और FALSE मान प्रदान करता है, जबकि दूसरा मिलान और अंतर के लिए आपके स्वयं के टेक्स्ट प्रदर्शित करता है:

सेल की श्रेणी की नमूना सेल से तुलना करें

निम्नलिखित उदाहरण दिखाते हैं कि आप यह कैसे सत्यापित कर सकते हैं कि किसी दी गई श्रेणी के सभी कक्षों में वही पाठ है जो नमूना कक्ष में है। चरित्र का मामला वास्तव में मायने नहीं रखता है, आप नमूने के साथ कोशिकाओं की तुलना करने के लिए निम्न सूत्र का उपयोग कर सकते हैं:

IF फ़ंक्शन के तार्किक परीक्षण में, आप दो संख्याओं की तुलना करते हैं:

• कोशिकाओं की कुल संख्याएक निर्दिष्ट सीमा में (पंक्तियों की संख्या को कॉलम की संख्या से गुणा किया जाता है), और
• नमूना सेल के समान मान वाले सेल की संख्या (COUNTIF फ़ंक्शन द्वारा लौटाया गया)।

यह मानते हुए कि नमूना पाठ C2 में है और तुलना करने के लिए तार A2:B6 श्रेणी में हैं, सूत्र इस प्रकार है:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

परिणामों को अधिक उपयोगकर्ता बनाने के लिए- दोस्ताना, यानी TRUE और FALSE के बजाय "ऑल मैच" और "नॉट ऑल मैच" जैसा कुछ आउटपुट करें, IF फ़ंक्शन का उपयोग करें जैसे हमने पिछले उदाहरणों में किया था:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

जैसा कि ऊपर दिए गए स्क्रीनशॉट में दिखाया गया है, फ़ॉर्मूला पूरी तरह से टेक्स्ट स्ट्रिंग्स की एक श्रृंखला के साथ काम करता है, लेकिन इसका उपयोग संख्याओं और तिथियों की तुलना करने के लिए भी किया जा सकता है। नमूना पाठ

यदि वर्ण केस में कोई फर्क पड़ता है, तो आप निम्नलिखित सरणी सूत्रों का उपयोग करके स्ट्रिंग की नमूना पाठ से तुलना कर सकते हैं।

A2:B6 में स्थित स्रोत श्रेणी और C2 में नमूना पाठ के साथ, सूत्र निम्न आकार लेता है:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

नियमित एक्सेल सूत्रों के विपरीत , सरणी सूत्र Ctrl + Shift + Enter दबाकर पूर्ण किए जाते हैं। यदि सही ढंग से दर्ज किया गया है, तो एक्सेल {घुंघराले ब्रेसिज़} में सरणी सूत्र को संलग्न करता है, जैसा कि स्क्रीनशॉट में दिखाया गया है:

स्ट्रिंग द्वारा दो कोशिकाओं की तुलना कैसे करेंलंबाई

कभी-कभी आप यह जांचना चाहेंगे कि प्रत्येक पंक्ति में टेक्स्ट स्ट्रिंग्स में वर्णों की समान संख्या है या नहीं। इस कार्य का सूत्र अत्यंत सरल है। सबसे पहले, आप LEN फ़ंक्शन का उपयोग करके दो सेलों की स्ट्रिंग लंबाई प्राप्त करते हैं, और फिर संख्याओं की तुलना करते हैं।

मान लें कि तुलना की जाने वाली स्ट्रिंग्स A2 और B2 कक्षों में हैं, तो निम्न सूत्रों में से किसी एक का उपयोग करें:

=LEN(A2)=LEN(B2)

या

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

जैसा कि आप पहले से ही जानते हैं, पहला सूत्र बूलियन मान TRUE या FALSE लौटाता है, जबकि दूसरा सूत्र आपके अपने परिणाम देता है:<3

जैसा कि ऊपर दिए गए स्क्रीनशॉट में दिखाया गया है, सूत्र टेक्स्ट स्ट्रिंग्स के साथ-साथ संख्याओं के लिए भी काम करते हैं।

युक्ति। यदि दो प्रतीत होने वाली समान स्ट्रिंग्स अलग-अलग लंबाई लौटाती हैं, तो सबसे अधिक संभावना है कि समस्या एक या दोनों सेल में लीडिंग या ट्रेलिंग स्पेस में हो। इस स्थिति में, TRIM फ़ंक्शन का उपयोग करके अतिरिक्त स्थान हटा दें। विस्तृत स्पष्टीकरण और सूत्र उदाहरण यहां देखे जा सकते हैं: एक्सेल में रिक्त स्थान कैसे ट्रिम करें।

किसी विशिष्ट वर्ण की घटनाओं के आधार पर दो सेल की तुलना करें

यह हमारे एक्सेल कंपेयर स्ट्रिंग्स ट्यूटोरियल का अंतिम उदाहरण है, और यह एक विशिष्ट कार्य के लिए एक समाधान दिखाता है। मान लीजिए, आपके पास टेक्स्ट स्ट्रिंग्स के 2 कॉलम हैं जिनमें आपके लिए महत्वपूर्ण एक वर्ण है। आपका लक्ष्य यह जांचना है कि क्या प्रत्येक पंक्ति में दो कोशिकाओं में दिए गए वर्ण की समान संख्या है।

चीजों को स्पष्ट करने के लिए, निम्नलिखित पर विचार करेंउदाहरण। मान लीजिए, आपके पास शिप किए गए ऑर्डर (कॉलम बी) और प्राप्त ऑर्डर (कॉलम सी) की दो सूचियां हैं। प्रत्येक पंक्ति में एक विशिष्ट आइटम के लिए ऑर्डर होते हैं, जिसका विशिष्ट पहचानकर्ता सभी ऑर्डर आईडी में शामिल होता है और कॉलम A में उसी पंक्ति में सूचीबद्ध होता है (कृपया नीचे स्क्रीनशॉट देखें)। आप यह सुनिश्चित करना चाहते हैं कि प्रत्येक पंक्ति में उस विशिष्ट आईडी के साथ समान संख्या में शिप किए गए और प्राप्त किए गए आइटम हों।

इस समस्या को हल करने के लिए, निम्न तर्क के साथ एक सूत्र लिखें।

• सबसे पहले, अद्वितीय पहचानकर्ता को सबस्टिट्यूट फ़ंक्शन का उपयोग करके शून्य से बदलें:

  SUBSTITUTE(A1, character_to_count,"")

• फिर, गणना करें कि प्रत्येक सेल में अद्वितीय पहचानकर्ता कितनी बार दिखाई देता है। इसके लिए, विशिष्ट पहचानकर्ता के बिना स्ट्रिंग की लंबाई प्राप्त करें और इसे स्ट्रिंग की कुल लंबाई से घटाएं। यह भाग सेल 1 और सेल 2 के लिए अलग-अलग लिखा जाएगा, उदाहरण के लिए:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  और

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• अंत में, आप इन 2 नंबरों की तुलना करें उपरोक्त भागों के बीच समता चिह्न (=) लगाकर।

LEN( सेल 2 ) - LEN(SUBSTITUTE( सेल 2 , character_to_count , ""))

हमारे उदाहरण में, विशिष्ट पहचानकर्ता A2 में है , और तुलना करने के लिए तार कक्ष B2 और C2 में हैं। इसलिए, पूरा सूत्र इस प्रकार है:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

यदि कक्ष B2 और C2 में A2 में वर्णों की घटनाओं की समान संख्या है, तो सूत्र TRUE लौटाता है,असत्य अन्यथा। अपने उपयोगकर्ताओं के लिए परिणामों को अधिक सार्थक बनाने के लिए, आप IF फ़ंक्शन में सूत्र एम्बेड कर सकते हैं:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

जैसा कि आप ऊपर दिए गए स्क्रीनशॉट में देख सकते हैं , सूत्र कुछ अतिरिक्त जटिलताओं के बावजूद पूरी तरह से काम करता है:

• गिनने के लिए वर्ण (अद्वितीय पहचानकर्ता) टेक्स्ट स्ट्रिंग में कहीं भी दिखाई दे सकता है।
• स्ट्रिंग्स में एक चर संख्या होती है वर्णों और विभिन्न विभाजक जैसे कि अर्धविराम, अल्पविराम या स्थान।

इस तरह आप एक्सेल में स्ट्रिंग्स की तुलना करते हैं। इस ट्यूटोरियल में चर्चा किए गए फ़ार्मुलों पर करीब से नज़र डालने के लिए, एक्सेल स्ट्रिंग्स वर्कशीट की तुलना करें डाउनलोड करने के लिए आपका स्वागत है। पढ़ने के लिए मैं आपको धन्यवाद देता हूं और आशा करता हूं कि अगले सप्ताह हमारे ब्लॉग पर आपसे मुलाकात होगी।