Die tutoriaal wys hoe om teksstringe in Excel te vergelyk vir hoofletter-onsensitiewe en presiese passing. Jy sal 'n aantal formules leer om twee selle te vergelyk volgens hul waardes, stringlengte of die aantal voorkoms van 'n spesifieke karakter, asook hoe om veelvuldige selle te vergelyk.

Wanneer jy Excel gebruik vir data-analise, akkuraatheid is die belangrikste bekommernis. Verkeerde inligting lei tot misgeloopte spertye, verkeerde neigings, verkeerde besluite en verlore inkomste.

Terwyl Excel-formules altyd heeltemal waar is, kan die resultate daarvan verkeerd wees omdat sommige gebrekkige data die stelsel binnegedring het. In hierdie geval is die enigste oplossing om data vir akkuraatheid na te gaan. Dit is nie 'n groot probleem om twee selle met die hand te vergelyk nie, maar dit is byna onmoontlik om die verskille tussen honderde en duisende teksstringe raak te sien.

Hierdie handleiding sal jou leer hoe om die vervelige en foutgevoelige taak van sel te outomatiseer vergelyking en watter formules die beste is om in elke spesifieke geval te gebruik.

Hoe om twee selle in Excel te vergelyk

Daar is twee verskillende maniere om stringe in Excel te vergelyk, afhangende van of jy hooflettersensitiewe of hoofletteronsensitiewe vergelyking soek.

Hoofletteronsensitiewe formule om 2 selle te vergelyk

Om twee selle in Excel te vergelyk, ignoreer hoofletters, gebruik 'n eenvoudige formule soos hierdie:

=A1=B1

Waar A1 en B1 die selle is wat jy vergelyk. Die resultaat van die formule is Boole-waardes WAARen ONWAAR.

As jy jou eie tekste vir passings en verskille wil uitvoer, sluit die bogenoemde stelling in die logiese toets van die IF-funksie in. Byvoorbeeld:

=IF(A1=B1, "Equal", "Not equal")

Soos jy in die skermkiekie hieronder sien, vergelyk beide formules teksstringe, datums en nommers ewe goed:

Kase-sensitiewe formule om stringe in Excel te vergelyk

In sommige situasies kan dit belangrik wees om nie net tekswaardes van twee selle te vergelyk nie, maar ook om die karakterkas te vergelyk. Hooflettersensitiewe teksvergelyking kan gedoen word deur die Excel EXACT-funksie te gebruik:

Waar teks1 en teks2 die twee selle is wat jy vergelyk.

As aangeneem word dat jou stringe in selle A2 en B2 is, gaan die formule soos volg:

=EXACT(A2, B2)

As gevolg hiervan kry jy WAAR vir teksstringe wat presies pas, insluitend die hoofletters van elke karakter, anders ONWAAR.

As jy wil hê dat die EXACT-funksie 'n paar ander resultate moet lewer, sluit dit in 'n IF-formule in en tik jou eie teks vir waarde_as_waar en waarde_as_onwaar argumente:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Die volgende skermkiekie wys die resultate van die hooflettersensitiewe stringvergelyking in Excel:

Hoe om vergelyk veelvuldige selle in Excel

Om meer as 2 selle in 'n ry te vergelyk, gebruik die formules wat in die bogenoemde voorbeelde bespreek is in kombinasie met die EN-operateur. Die volledige besonderhede volg hieronder.

Kase-onsensitiewe formule om te vergelykmeer as 2 selle

Afhangende van hoe jy die resultate wil vertoon, gebruik een van die volgende formules:

=AND(A2=B2, A2=C2)

of

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

Die EN-formule gee WAAR as al die selle dieselfde waarde bevat, ONWAAR as enige waarde anders is. Die IF-formule voer die etikette uit wat jy daarin tik, " Gelyk " en " Nie gelyk " in hierdie voorbeeld.

Soos gedemonstreer in die skermkiekie hieronder, die formule werk perfek met enige datatipes - teks, datums en numeriese waardes:

Kase-sensitiewe formule om teks in verskeie selle te vergelyk

Om veelvuldige stringe te vergelyk met mekaar om te sien of hulle presies ooreenstem, gebruik die volgende formules:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Of

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Soos in die vorige voorbeeld, die eerste formule lewer WAAR en ONWAAR waardes, terwyl die tweede een jou eie tekste vir passings en verskille vertoon:

Vergelyk 'n reeks selle met 'n voorbeeldsel

Die volgende voorbeelde wys hoe jy kan verifieer dat alle selle in 'n gegewe reeks dieselfde teks bevat as in 'n voorbeeldsel.

Kase-onsensitiewe formule om selle met 'n voorbeeldteks te vergelyk

As die karakterkas maak nie regtig saak nie, jy kan die volgende formule gebruik om selle met 'n monster te vergelyk:

In die logiese toets van die IF-funksie vergelyk jy twee getalle:

• Die totale aantal sellein 'n gespesifiseerde reeks (die aantal rye vermenigvuldig met die aantal kolomme), en
• Die aantal selle wat dieselfde waarde as in die monstersel bevat (teruggestuur deur die COUNTIF-funksie).

As die voorbeeldteks in C2 is en die stringe om te vergelyk is in die reeks A2:B6, gaan die formule soos volg:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Om die resultate meer gebruiker- vriendelik, d.w.s. voer iets uit soos "Alle pas" en "Nie almal pas nie" in plaas van WAAR en ONWAAR, gebruik die IF-funksie soos ons in die vorige voorbeelde gedoen het:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Soos die skermkiekie hierbo getoon, hanteer die formule 'n reeks teksstringe perfek, maar dit kan ook gebruik word om getalle en datums te vergelyk.

Kleinlettergevoelige formule om stringe te vergelyk met 'n voorbeeldteks

As die hoofletters 'n verskil maak, kan jy stringe met die voorbeeldteks vergelyk deur die volgende skikkingsformules te gebruik.

Met die bronreeks in A2:B6 en die voorbeeldteks in C2, neem die formule die volgende vorm aan:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Anders as gewone Excel-formules , word skikkingsformules voltooi deur Ctrl + Shift + Enter te druk. As dit korrek ingevoer is, sluit Excel die skikkingsformule in {krulhakies} in, soos in die skermkiekie getoon:

Hoe om twee selle per string te vergelyklengte

Soms wil jy dalk kyk of die teksstringe in elke ry 'n gelyke aantal karakters bevat. Die formule vir hierdie taak is baie eenvoudig. Eerstens kry jy die stringlengte van twee selle deur die LEN-funksie te gebruik, en vergelyk dan die getalle.

Gestel die stringe wat vergelyk moet word, is in selle A2 en B2, gebruik enige van die volgende formules:

=LEN(A2)=LEN(B2)

Of

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Soos jy reeds weet, gee die eerste formule Boolese waardes WAAR of ONWAAR terug, terwyl die tweede formule jou eie resultate lewer:

Soos gedemonstreer in die skermkiekie hierbo, werk die formules vir teksstringe sowel as syfers.

Wenk. As twee oënskynlik gelyke stringe verskillende lengtes gee, is die probleem heel waarskynlik in voorste of volgende spasies in een of albei selle. In hierdie geval, verwyder ekstra spasies met die TRIM-funksie. Die gedetailleerde verduideliking en formulevoorbeelde kan hier gevind word: Hoe om spasies in Excel te snoei.

Vergelyk twee selle volgens voorkoms van 'n spesifieke karakter

Dit is die laaste voorbeeld in ons Excel Vergelyk Strings-tutoriaal, en dit wys 'n oplossing vir 'n taamlik spesifieke taak. Gestel, jy het 2 kolomme teksstringe wat 'n karakter bevat wat vir jou belangrik is. Jou doel is om te kyk of twee selle in elke ry dieselfde aantal voorkomste van 'n gegewe karakter bevat.

Om dinge duideliker te maak, oorweeg die volgendevoorbeeld. Kom ons sê, jy het twee lyste van bestellings wat gestuur is (kolom B) en ontvang (kolom C). Elke ry bevat bestellings vir 'n spesifieke item, waarvan die unieke identifiseerder by alle bestelling-ID's ingesluit is en in dieselfde ry in kolom A gelys word (sien asseblief die skermkiekie hieronder). Jy wil seker maak dat elke ry 'n gelyke aantal gestuurde en ontvangde items met daardie spesifieke ID bevat.

Om hierdie probleem op te los, skryf 'n formule met die volgende logika.

• Eerstens, vervang die unieke identifiseerder met niks deur die PLAASVERVANG-funksie te gebruik:

  SUBSTITUTE(A1, character_to_count,"")

• Bereken dan hoeveel keer die unieke identifiseerder in elke sel voorkom. Hiervoor, kry die stringlengte sonder die unieke identifiseerder en trek dit af van die totale lengte van die string. Hierdie deel sal vir sel 1 en sel 2 individueel geskryf word, byvoorbeeld:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  en

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Laastens vergelyk jy hierdie 2 getalle deur die gelykheidsteken (=) tussen bogenoemde dele te plaas.

LEN( sel 2 ) - LEN(SUBSTITUTE( sel 2 , karakter_tot_telling , ""))

In ons voorbeeld is die unieke identifiseerder in A2 , en die stringe om te vergelyk is in selle B2 en C2. Dus, die volledige formule is soos volg:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Die formule gee WAAR as selle B2 en C2 'n gelyke aantal voorkoms van die karakter in A2 bevat,ONWAAR andersins. Om die resultate meer betekenisvol vir jou gebruikers te maak, kan jy die formule in die IF-funksie insluit:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Soos jy in die skermkiekie hierbo kan sien , werk die formule perfek ten spyte van 'n paar bykomende komplikasies:

• Die karakter wat getel moet word (unieke identifiseerder) kan enige plek in 'n teksstring verskyn.
• Die stringe bevat 'n veranderlike getal van karakters en verskillende skeiers soos kommapunte, komma of spasie.

Dit is hoe jy stringe in Excel vergelyk. Om die formules wat in hierdie tutoriaal bespreek word van nader te bekyk, is jy welkom om Excel Vergelyk Strings Werkblad af te laai. Ek bedank jou vir die lees en hoop om jou volgende week op ons blog te sien.