O titorial mostra como comparar cadeas de texto en Excel para a coincidencia exacta e que non distingue entre maiúsculas e minúsculas. Aprenderá unha serie de fórmulas para comparar dúas celas polos seus valores, a lonxitude da cadea ou o número de aparicións dun carácter específico, así como a comparar varias celas.

Ao usar Excel para análise de datos, a precisión é a preocupación máis vital. A información incorrecta leva a prazos incumplidos, tendencias mal valoradas, decisións incorrectas e ingresos perdidos.

Aínda que as fórmulas de Excel son sempre perfectamente certas, os seus resultados poden ser incorrectos porque algúns datos defectuosos penetraron no sistema. Neste caso, o único remedio é comprobar a precisión dos datos. Non é gran cousa comparar dúas celas manualmente, pero é case imposible detectar as diferenzas entre centos e miles de cadeas de texto.

Este tutorial ensinarache como automatizar a tediosa e propensa a erros da cela. comparación e que fórmulas son mellores para usar en cada caso particular.

Como comparar dúas celas en Excel

Hai dúas formas diferentes de comparar cadeas en Excel dependendo de tanto se busca unha comparación que distingue entre maiúsculas e minúsculas ou non.

Fórmula que non distingue entre maiúsculas e minúsculas para comparar 2 celas

Para comparar dúas celas en Excel ignorando maiúsculas e minúsculas, use unha fórmula sinxela como esta:

=A1=B1

Onde A1 e B1 son as celas que está a comparar. O resultado da fórmula son valores booleanos TRUEe FALSE.

Se queres sacar os teus propios textos para coincidencias e diferenzas, incrusta a declaración anterior na proba lóxica da función SE. Por exemplo:

=IF(A1=B1, "Equal", "Not equal")

Como ves na seguinte captura de pantalla, ambas fórmulas comparan as cadeas de texto, as datas e os números por igual:

Fórmula que distingue entre maiúsculas e minúsculas para comparar cadeas en Excel

Nalgunhas situacións, pode ser importante non só comparar os valores de texto de dúas celas, senón tamén comparar as maiúsculas e minúsculas. A comparación de texto que distingue entre maiúsculas e minúsculas pódese facer mediante a función EXACTO de Excel:

Onde texto1 e texto2 son as dúas celas que está a comparar.

Supoñendo que as túas cadeas estean nas celas A2 e B2, a fórmula é a seguinte:

=EXACT(A2, B2)

Como resultado, obtén TRUE para as cadeas de texto coinciden exactamente incluíndo o caso. de cada carácter, FALSO en caso contrario.

Se queres que a función EXACTA ofreza outros resultados, incorpóraa nunha fórmula SE e escriba o seu propio texto para valor_se_verdadeiro e valor_se_falso argumentos:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

A seguinte captura de pantalla mostra os resultados da comparación entre maiúsculas e minúsculas en Excel:

Como comparar varias celas en Excel

Para comparar máis de 2 celas seguidas, use as fórmulas descritas nos exemplos anteriores en combinación co operador AND. A continuación os detalles completos.

Fórmula que non distingue entre maiúsculas e minúsculas para compararmáis de 2 celas

Según como quere mostrar os resultados, utilice unha das seguintes fórmulas:

=AND(A2=B2, A2=C2)

ou

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

A fórmula AND devolve VERDADEIRO se todas as celas conteñen o mesmo valor, FALSO se algún valor é diferente. A fórmula SE mostra as etiquetas que escribe nela, " Igual " e " Non igual " neste exemplo.

Como se demostra na captura de pantalla a continuación, o fórmula funciona perfectamente con calquera tipo de datos: texto, datas e valores numéricos:

Fórmula que distingue entre maiúsculas e minúsculas para comparar texto en varias celas

Para comparar varias cadeas entre si para ver se coinciden exactamente, use as seguintes fórmulas:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Ou

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Como no exemplo anterior, a primeira fórmula ofrece valores VERDADEIRO e FALSO, mentres que a segunda mostra os seus propios textos para as coincidencias e as diferenzas:

Compara un intervalo de celas cunha cela de mostra

Os seguintes exemplos mostran como pode verificar que todas as celas dun intervalo determinado conteñen o mesmo texto que nunha cela de mostra.

Fórmula que non distingue entre maiúsculas e minúsculas para comparar celas cun texto de mostra

Se o As maiúsculas e minúsculas non importan realmente, pode usar a seguinte fórmula para comparar celas cunha mostra:

Na proba lóxica da función SE, compara dous números:

• O número total de celasnun intervalo especificado (o número de filas multiplicado polo número de columnas) e
• O número de celas que conteñen o mesmo valor que na cela de mostra (devolta pola función COUNTIF).

Asumindo que o texto de mostra está en C2 e que as cadeas para comparar están no rango A2:B6, a fórmula é a seguinte:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Para que os resultados sexan máis usuarios. amigable, é dicir, saia algo como "Todos coinciden" e "Non todos coinciden" en lugar de VERDADEIRO e FALSO, use a función SE como fixemos nos exemplos anteriores:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Como se mostra na captura de pantalla anterior, a fórmula afronta perfectamente unha serie de cadeas de texto, pero tamén se pode usar para comparar números e datas.

Fórmula que distingue entre maiúsculas e minúsculas para comparar cadeas cun texto de mostra

Se as maiúsculas e minúsculas marcan a diferenza, pode comparar cadeas co texto de mostra utilizando as seguintes fórmulas de matriz.

Co intervalo de orixe que reside en A2:B6 e o ​​texto de mostra en C2, a fórmula toma a seguinte forma:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

A diferenza das fórmulas regulares de Excel , as fórmulas de matriz complétanse premendo Ctrl + Maiús + Intro . Se se introduce correctamente, Excel encerra a fórmula matricial entre {llaves}, como se mostra na captura de pantalla:

Como comparar dúas celas por cadealength

Ás veces pode querer comprobar se as cadeas de texto de cada fila conteñen o mesmo número de caracteres. A fórmula para esta tarefa é moi sinxela. Primeiro, obtén a lonxitude das cadeas de dúas celas mediante a función LEN e, a continuación, compara os números.

Supoñendo que as cadeas que se van comparar están nas celas A2 e B2, use calquera das seguintes fórmulas:

=LEN(A2)=LEN(B2)

Ou

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Como xa sabes, a primeira fórmula devolve valores booleanos VERDADEIRO ou FALSO, mentres que a segunda formula os teus propios resultados:

Como se demostra na captura de pantalla anterior, as fórmulas funcionan tanto para cadeas de texto como para números.

Consello. Se dúas cadeas aparentemente iguais devolven lonxitudes diferentes, o máis probable é que o problema estea nos espazos ao final ou espazos finales nunha ou ambas celas. Neste caso, elimine os espazos adicionais mediante a función TRIM. A explicación detallada e os exemplos de fórmulas pódense atopar aquí: Como recortar espazos en Excel.

Compara dúas celas por ocorrencias dun carácter específico

Este é o último exemplo do noso tutorial de comparación de cadeas de Excel e mostra unha solución para unha tarefa bastante específica. Supoñamos que tes 2 columnas de cadeas de texto que conteñen un carácter importante para ti. O teu obxectivo é comprobar se dúas celas de cada fila conteñen o mesmo número de aparicións dun determinado carácter.

Para aclarar as cousas, considera o seguinteexemplo. Digamos que tes dúas listas de pedidos enviados (columna B) e recibidos (columna C). Cada fila contén pedidos para un artigo específico, cuxo identificador único está incluído en todos os ID de pedido e aparece na mesma fila da columna A (consulta a captura de pantalla a continuación). Quere asegurarse de que cada fila conteña un número igual de artigos enviados e recibidos con ese ID específico.

Para resolver este problema, escriba unha fórmula coa seguinte lóxica.

• En primeiro lugar, substitúe o identificador único por nada usando a función SUBSTITUTE:

  SUBSTITUTE(A1, character_to_count,"")

• A continuación, calcula cantas veces aparece o identificador único en cada cela. Para iso, obtén a lonxitude da cadea sen o identificador único e réstao da lonxitude total da cadea. Esta parte escribirase individualmente para a cela 1 e a cela 2, por exemplo:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  e

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Por último, compara estes 2 números colocando o signo de igualdade (=) entre as partes anteriores.

LEN( celda 2 ) - LEN(SUBSTITUTE( celda 2 , caracter_a_contar , ""))

No noso exemplo, o identificador único está en A2 , e as cadeas para comparar están nas celas B2 e C2. Entón, a fórmula completa é a seguinte:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

A fórmula devolve VERDADEIRO se as celas B2 e C2 conteñen o mesmo número de aparicións do carácter en A2,FALSO en caso contrario. Para que os resultados sexan máis significativos para os teus usuarios, podes inserir a fórmula na función SE:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Como podes ver na captura de pantalla anterior , a fórmula funciona perfectamente a pesar dun par de complicacións adicionais:

• O carácter que se vai contar (identificador único) pode aparecer en calquera lugar dunha cadea de texto.
• As cadeas conteñen un número variable. de caracteres e diferentes separadores como punto e coma, coma ou espazo.

Así comparas cadeas en Excel. Para ter unha ollada máis atenta ás fórmulas que se comentan neste tutorial, podes descargar a folla de cálculo de comparación de cadeas de Excel. Agradézoche a lectura e espero verte no noso blog a vindeira semana.