Udžbenik pokazuje kako usporediti tekstualne nizove u Excelu za neosjetljivost na velika i mala slova i točno podudaranje. Naučit ćete brojne formule za usporedbu dviju ćelija prema njihovim vrijednostima, duljini niza ili broju pojavljivanja određenog znaka, kao i kako usporediti više ćelija.

Kada koristite Excel za analiza podataka, točnost je najvažnija briga. Netočne informacije dovode do propuštanja rokova, krivo procijenjenih trendova, pogrešnih odluka i izgubljenih prihoda.

Iako su formule programa Excel uvijek savršeno istinite, njihovi rezultati mogu biti pogrešni jer su neki pogrešni podaci prodrli u sustav. U ovom slučaju, jedini lijek je provjeriti točnost podataka. Nije velika stvar ručno usporediti dvije ćelije, ali gotovo je nemoguće uočiti razlike između stotina i tisuća tekstualnih nizova.

Ovaj vodič će vas naučiti kako automatizirati zamoran i pogreškama sklon zadatak ćelije usporedbu i koje je formule najbolje koristiti u svakom pojedinom slučaju.

Kako usporediti dvije ćelije u Excelu

Postoje dva različita načina za usporedbu nizova u Excelu ovisno o tražite li usporedbu koja razlikuje velika ili mala slova.

Formula koja ne razlikuje velika i mala slova za usporedbu 2 ćelije

Da biste usporedili dvije ćelije u Excelu zanemarujući velika i mala slova, koristite jednostavnu formulu poput ove:

=A1=B1

Gdje su A1 i B1 ćelije koje uspoređujete. Rezultat formule su Booleove vrijednosti TRUEi FALSE.

Ako želite ispisati vlastite tekstove za podudaranja i razlike, ugradite gornju izjavu u logički test funkcije IF. Na primjer:

=IF(A1=B1, "Equal", "Not equal")

Kao što vidite na slici ispod, obje formule jednako dobro uspoređuju tekstualne nizove, datume i brojeve:

Formula koja razlikuje velika i mala slova za usporedbu nizova u Excelu

U nekim situacijama može biti važno ne samo usporediti tekstualne vrijednosti dviju ćelija, već i usporediti velika i mala slova. Usporedbu teksta koja razlikuje velika i mala slova moguće je izvršiti pomoću funkcije Excel EXACT:

Gdje su tekst1 i tekst2 dvije ćelije koje uspoređujete.

Pod pretpostavkom da su vaši nizovi u ćelijama A2 i B2, formula ide kako slijedi:

=EXACT(A2, B2)

Kao rezultat, dobivate TRUE za tekstualne nizove koji se točno podudaraju uključujući velika i mala slova svakog znaka, inače FALSE.

Ako želite da funkcija EXACT isporuči neke druge rezultate, ugradite je u formulu IF i upišite vlastiti tekst za value_if_true i value_if_false argumenti:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Sljedeća snimka zaslona prikazuje rezultate usporedbe nizova koji razlikuju velika i mala slova u programu Excel:

Kako usporedite više ćelija u programu Excel

Za usporedbu više od 2 ćelije u nizu, upotrijebite formule navedene u gornjim primjerima u kombinaciji s operatorom AND. Potpuni detalji slijede u nastavku.

Formula za usporedbu koja ne razlikuje velika i mala slovaviše od 2 ćelije

Ovisno o tome kako želite prikazati rezultate, upotrijebite jednu od sljedećih formula:

=AND(A2=B2, A2=C2)

ili

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

Formula I vraća TRUE ako sve ćelije sadrže istu vrijednost, FALSE ako je bilo koja vrijednost različita. IF formula daje oznake koje upisujete u nju, " Jednako " i " Nije jednako " u ovom primjeru.

Kao što je prikazano na slici ispod, formula radi savršeno sa svim vrstama podataka - tekst, datumi i numeričke vrijednosti:

Formula koja razlikuje velika i mala slova za usporedbu teksta u nekoliko ćelija

Za usporedbu više nizova da biste vidjeli podudaraju li se točno, upotrijebite sljedeće formule:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Ili

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Kao u prethodnom primjeru, prvi formula isporučuje TRUE i FALSE vrijednosti, dok druga prikazuje vaše vlastite tekstove za podudaranja i razlike:

Usporedite raspon ćelija s uzorkom ćelije

Sljedeći primjeri pokazuju kako možete provjeriti sadrže li sve ćelije u određenom rasponu isti tekst kao u uzorku ćelije.

Formula koja ne razlikuje velika i mala slova za usporedbu ćelija s uzorkom teksta

Ako velika i mala slova zapravo nisu bitna, možete koristiti sljedeću formulu za usporedbu ćelija s uzorkom:

U logičkom testu funkcije IF uspoređujete dva broja:

• Ukupan broj ćelijau određenom rasponu (broj redaka pomnožen s brojem stupaca) i
• Broj ćelija koje sadrže istu vrijednost kao u ćeliji uzorka (vraća funkcija COUNTIF).

Uz pretpostavku da je uzorak teksta u C2, a nizovi za usporedbu u rasponu A2:B6, formula je sljedeća:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Da bi rezultati bili korisniji prijateljski, tj. izlaz nešto poput "Sve se podudaraju" i "Ne podudaraju se svi" umjesto TRUE i FALSE, upotrijebite funkciju IF kao što smo učinili u prethodnim primjerima:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Kao što je prikazano na gornjoj snimci zaslona, ​​formula se savršeno nosi s nizom tekstualnih nizova, ali se također može koristiti za usporedbu brojeva i datuma.

Formula koja razlikuje velika i mala slova za usporedbu nizova s uzorak teksta

Ako velika i mala slova čine razliku, možete usporediti nizove s uzorkom teksta pomoću sljedećih formula polja.

S izvornim rasponom koji se nalazi u A2:B6 i oglednim tekstom u C2, formula ima sljedeći oblik:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Za razliku od običnih Excel formula , formule polja dovršavaju se pritiskom na Ctrl + Shift + Enter . Ako je ispravno uneseno, Excel zatvara formulu polja u {vitičaste zagrade}, kao što je prikazano na snimci zaslona:

Kako usporediti dvije ćelije prema nizuduljina

Ponekad biste mogli provjeriti sadrže li tekstualni nizovi u svakom retku jednak broj znakova. Formula za ovaj zadatak je vrlo jednostavna. Prvo dobijete duljinu niza dviju ćelija pomoću funkcije LEN, a zatim usporedite brojeve.

Pretpostavimo da su nizovi za usporedbu u ćelijama A2 i B2, upotrijebite jednu od sljedećih formula:

=LEN(A2)=LEN(B2)

Ili

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Kao što već znate, prva formula vraća Booleove vrijednosti TRUE ili FALSE, dok druga formula daje vaše rezultate:

Kao što je pokazano na gornjoj snimci zaslona, ​​formule rade za tekstualne nizove kao i za brojeve.

Savjet. Ako dva naizgled jednaka niza vraćaju različite duljine, najvjerojatnije je problem u početnim ili zadnjim razmacima u jednoj ili obje ćelije. U tom slučaju uklonite suvišne razmake pomoću funkcije TRIM. Detaljno objašnjenje i primjere formula možete pronaći ovdje: Kako smanjiti razmake u Excelu.

Usporedite dvije ćelije prema pojavljivanju određenog znaka

Ovo je posljednji primjer u našem vodiču za usporedbu nizova u Excelu i pokazuje rješenje za prilično specifičan zadatak. Pretpostavimo da imate 2 stupca tekstualnih nizova koji sadrže vama važan znak. Vaš cilj je provjeriti sadrže li dvije ćelije u svakom retku isti broj pojavljivanja određenog znaka.

Da bi stvari bile jasnije, razmotrite sljedećeprimjer. Recimo, imate dva popisa otpremljenih (stupac B) i primljenih narudžbi (stupac C). Svaki redak sadrži narudžbe za određenu stavku, čiji je jedinstveni identifikator uključen u sve ID-ove narudžbi i naveden je u istom retku u stupcu A (pogledajte snimak zaslona u nastavku). Želite biti sigurni da svaki redak sadrži jednak broj otpremljenih i primljenih artikala s tim određenim ID-om.

Da biste riješili ovaj problem, napišite formulu sa sljedećom logikom.

• Prvo zamijenite jedinstveni identifikator ničim pomoću funkcije SUBSTITUTE:

  SUBSTITUTE(A1, character_to_count,"")

• Zatim izračunajte koliko se puta jedinstveni identifikator pojavljuje u svakoj ćeliji. U tu svrhu uzmite duljinu niza bez jedinstvenog identifikatora i oduzmite je od ukupne duljine niza. Ovaj dio će biti napisan za ćeliju 1 i ćeliju 2 pojedinačno, na primjer:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  i

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Na kraju, usporedite ova 2 broja stavljanjem znaka jednakosti (=) između gornjih dijelova.

LEN( cell 2 ) - LEN(SUBSTITUTE( cell 2 , character_to_count , ""))

U našem primjeru, jedinstveni identifikator je u A2 , a nizovi za usporedbu nalaze se u ćelijama B2 i C2. Dakle, potpuna formula je sljedeća:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Formula vraća TRUE ako ćelije B2 i C2 sadrže jednak broj pojavljivanja znaka u A2,FALSE inače. Kako bi rezultati bili značajniji za vaše korisnike, možete ugraditi formulu u funkciju IF:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Kao što možete vidjeti na gornjoj snimci zaslona , formula radi savršeno unatoč nekoliko dodatnih komplikacija:

• Znak koji se broji (jedinstveni identifikator) može se pojaviti bilo gdje u tekstualnom nizu.
• Nizovi sadrže varijabilni broj znakova i različitih separatora kao što su točka-zarez, zarez ili razmak.

Ovako možete uspoređivati ​​nizove u Excelu. Kako biste pobliže pogledali formule o kojima se govori u ovom vodiču, slobodno preuzmite Excel radni list za usporedbu nizova. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan.