টিউটোরিয়ালটি দেখায় কিভাবে কেস-অসংবেদনশীল এবং সঠিক মিলের জন্য এক্সেলে টেক্সট স্ট্রিং তুলনা করা যায়। আপনি দুটি কক্ষের মান, স্ট্রিং দৈর্ঘ্য বা একটি নির্দিষ্ট অক্ষরের সংঘটনের সংখ্যা, সেইসাথে একাধিক কক্ষের তুলনা করার জন্য অনেকগুলি সূত্র শিখবেন।

এর জন্য এক্সেল ব্যবহার করার সময় তথ্য বিশ্লেষণ, নির্ভুলতা সবচেয়ে গুরুত্বপূর্ণ উদ্বেগ. ভুল তথ্যের ফলে সময়সীমা মিস হয়ে যায়, ভুল বিচার প্রবণতা, ভুল সিদ্ধান্ত এবং হারানো রাজস্ব।

যদিও এক্সেলের সূত্রগুলি সর্বদা সম্পূর্ণ সত্য হয়, তবে তাদের ফলাফলগুলি ভুল হতে পারে কারণ কিছু ত্রুটিপূর্ণ ডেটা সিস্টেমে প্রবেশ করেছে। এই ক্ষেত্রে, একমাত্র প্রতিকার হল সঠিকতার জন্য ডেটা পরীক্ষা করা। ম্যানুয়ালি দুটি কক্ষের তুলনা করা কোন বড় ব্যাপার নয়, তবে শত শত এবং হাজার হাজার পাঠ্য স্ট্রিংগুলির মধ্যে পার্থক্য চিহ্নিত করা অসম্ভব।

এই টিউটোরিয়ালটি আপনাকে শেখাবে কিভাবে ঘরের ক্লান্তিকর এবং ত্রুটি-প্রবণ কাজটি স্বয়ংক্রিয়ভাবে করা যায়। তুলনা করুন এবং প্রতিটি নির্দিষ্ট ক্ষেত্রে কোন সূত্রগুলি ব্যবহার করা ভাল।

এক্সেলের দুটি ঘরের তুলনা কিভাবে করা যায়

এক্সেলে স্ট্রিং তুলনা করার দুটি ভিন্ন উপায় রয়েছে আপনি কেস-সংবেদনশীল বা কেস-সংবেদনশীল তুলনা খুঁজছেন।

2টি কোষের তুলনা করার জন্য কেস-সংবেদনশীল সূত্র

এক্সেলের ক্ষেত্রে দুটি কোষের তুলনা করতে, এই ধরনের একটি সহজ সূত্র ব্যবহার করুন:<3

=A1=B1

যেখানে A1 এবং B1 হল সেই ঘরগুলি যেখানে আপনি তুলনা করছেন৷ সূত্রের ফলাফল হল বুলিয়ান মান TRUEএবং মিথ্যা।

আপনি যদি মিল এবং পার্থক্যের জন্য আপনার নিজস্ব পাঠ্য আউটপুট করতে চান তবে IF ফাংশনের যৌক্তিক পরীক্ষায় উপরের বিবৃতিটি এম্বেড করুন। উদাহরণস্বরূপ:

=IF(A1=B1, "Equal", "Not equal")

যেমন আপনি নীচের স্ক্রিনশটে দেখতে পাচ্ছেন, উভয় সূত্রই টেক্সট স্ট্রিং, তারিখ এবং সংখ্যা সমানভাবে তুলনা করে:

কিছু ​​পরিস্থিতিতে, শুধুমাত্র দুটি কক্ষের পাঠ্যের মান তুলনা করা নয়, ক্যারেক্টার কেস তুলনা করাও গুরুত্বপূর্ণ হতে পারে। কেস-সংবেদনশীল টেক্সট তুলনা এক্সেল EXACT ফাংশন ব্যবহার করে করা যেতে পারে:

যেখানে টেক্সট1 এবং টেক্সট2 আপনি যে দুটি সেল তুলনা করছেন।

আপনার স্ট্রিংগুলি A2 এবং B2 কক্ষে রয়েছে বলে ধরে নিলে, সূত্রটি নিম্নরূপ:

=EXACT(A2, B2)

ফলস্বরূপ, আপনি টেক্সট স্ট্রিংগুলি কেস সহ হুবহু মিলে যাওয়ার জন্য TRUE পাবেন প্রতিটি অক্ষরের, অন্যথায় মিথ্যা।

আপনি যদি সঠিক ফাংশনটি অন্য কিছু ফলাফল দিতে চান তবে এটিকে একটি IF সূত্রে এম্বেড করুন এবং value_if_true এবং value_if_false<এর জন্য আপনার নিজস্ব পাঠ্য টাইপ করুন 2> আর্গুমেন্ট:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

নিম্নলিখিত স্ক্রিনশটটি এক্সেল-এ কেস-সংবেদনশীল স্ট্রিং তুলনার ফলাফলগুলি দেখায়:

কীভাবে এক্সেলের একাধিক কোষ তুলনা করুন

এক সারিতে 2টির বেশি ঘর তুলনা করতে, AND অপারেটরের সংমিশ্রণে উপরের উদাহরণগুলিতে আলোচিত সূত্রগুলি ব্যবহার করুন। সম্পূর্ণ বিবরণ নীচে অনুসরণ করুন৷

তুলনা করার জন্য কেস-সংবেদনশীল সূত্র৷2টির বেশি কক্ষ

আপনি কীভাবে ফলাফলগুলি প্রদর্শন করতে চান তার উপর নির্ভর করে, নিম্নলিখিত সূত্রগুলির মধ্যে একটি ব্যবহার করুন:

=AND(A2=B2, A2=C2)

বা

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal") <3

এবং সূত্রটি TRUE প্রদান করে যদি সমস্ত কক্ষে একই মান থাকে, যদি কোনো মান ভিন্ন হয় তাহলে FALSE। IF সূত্রটি এই উদাহরণে " সমান " এবং " সমান নয় " টাইপ করা লেবেলগুলিকে আউটপুট করে৷

নিচের স্ক্রিনশটে যেমন দেখানো হয়েছে, সূত্রটি যেকোন ডেটা প্রকারের সাথে পুরোপুরি কাজ করে - টেক্সট, তারিখ এবং সাংখ্যিক মান:

কেস-সংবেদনশীল সূত্র বিভিন্ন কক্ষে পাঠ তুলনা করার জন্য

একাধিক স্ট্রিং তুলনা করতে তারা ঠিক মেলে কিনা তা দেখতে একে অপরের সাথে, নিম্নলিখিত সূত্রগুলি ব্যবহার করুন:

=AND(EXACT(A2,B2), EXACT(A2, C2))

বা

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

আগের উদাহরণের মতো, প্রথমটি সূত্রটি সত্য এবং মিথ্যা মান প্রদান করে, যেখানে দ্বিতীয়টি মিল এবং পার্থক্যের জন্য আপনার নিজস্ব পাঠ্য প্রদর্শন করে:

একটি নমুনা কক্ষের সাথে সেলের একটি পরিসর তুলনা করুন

নিম্নলিখিত উদাহরণগুলি দেখায় যে আপনি কীভাবে যাচাই করতে পারেন যে একটি প্রদত্ত পরিসরের সমস্ত কক্ষে একটি নমুনা কক্ষের মতো একই পাঠ্য রয়েছে৷

কেস-সংবেদনশীল সূত্র একটি নমুনা পাঠ্যের সাথে কোষের তুলনা করার জন্য

যদি ক্যারেক্টার কেস আসলে কোন ব্যাপার না, আপনি একটি নমুনার সাথে সেল তুলনা করতে নিম্নলিখিত সূত্র ব্যবহার করতে পারেন:

IF ফাংশনের লজিক্যাল পরীক্ষায়, আপনি দুটি সংখ্যার তুলনা করেন:

• মোট কক্ষের সংখ্যাএকটি নির্দিষ্ট পরিসরে (কলামের সংখ্যা দ্বারা গুণিত সারির সংখ্যা), এবং
• নমুনা ঘরের মতো একই মান ধারণকারী কক্ষের সংখ্যা (COUNTIF ফাংশন দ্বারা প্রত্যাবর্তন করা হয়েছে)।
<5

নমুনা পাঠ্যটি C2-তে রয়েছে এবং তুলনা করার জন্য স্ট্রিংগুলি A2:B6 পরিসরে রয়েছে, সূত্রটি নিম্নরূপ:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

ফলাফলগুলিকে আরও ব্যবহারকারী করতে- বন্ধুত্বপূর্ণ, যেমন সত্য এবং মিথ্যার পরিবর্তে "সমস্ত ম্যাচ" এবং "সমস্ত ম্যাচ নয়" এর মতো কিছু আউটপুট করুন, IF ফাংশনটি ব্যবহার করুন যেমন আমরা পূর্ববর্তী উদাহরণগুলিতে করেছি:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")



উপরের স্ক্রিনশটটি যেমন দেখানো হয়েছে, সূত্রটি সম্পূর্ণরূপে পাঠ্য স্ট্রিংগুলির একটি পরিসরের সাথে মানিয়ে নেয়, তবে এটি সংখ্যা এবং তারিখের তুলনা করতেও ব্যবহার করা যেতে পারে।

কেস-সংবেদনশীল সূত্র একটি স্ট্রিংগুলির সাথে তুলনা করতে নমুনা টেক্সট

যদি অক্ষরের ক্ষেত্রে পার্থক্য হয়, আপনি নিম্নলিখিত অ্যারে সূত্র ব্যবহার করে নমুনা পাঠ্যের সাথে স্ট্রিং তুলনা করতে পারেন।

IF(ROWS( range )*COLUMNS( পরিসীমা )=SUM(--EXACT( sample_cell , range )), " text_if_match ", " text_if_ মিলছে না ")

A2:B6-এ থাকা উৎস পরিসর এবং C2-তে নমুনা পাঠ্যের সাথে, সূত্রটি নিম্নলিখিত আকার ধারণ করে:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

নিয়মিত এক্সেল সূত্রের বিপরীতে , Ctrl + Shift + Enter টিপে অ্যারে সূত্রগুলি সম্পন্ন হয়। সঠিকভাবে প্রবেশ করা হলে, এক্সেল অ্যারে সূত্রটিকে {কোঁকড়া ধনুর্বন্ধনীতে ঘেরাও করে, যেমনটি স্ক্রিনশটে দেখানো হয়েছে:



স্ট্রিং দ্বারা দুটি ঘরের তুলনা কিভাবে করা যায়দৈর্ঘ্য

কখনও কখনও আপনি প্রতিটি সারির পাঠ্য স্ট্রিংগুলিতে সমান সংখ্যক অক্ষর রয়েছে কিনা তা পরীক্ষা করতে চাইতে পারেন। এই কাজের সূত্র খুবই সহজ। প্রথমে, আপনি LEN ফাংশন ব্যবহার করে দুটি কক্ষের স্ট্রিং দৈর্ঘ্য পাবেন এবং তারপর সংখ্যার তুলনা করুন।

মনে করা স্ট্রিংগুলি A2 এবং B2 কক্ষে রয়েছে, নিচের যে কোনো একটি সূত্র ব্যবহার করুন:

=LEN(A2)=LEN(B2)

বা

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

যেমন আপনি ইতিমধ্যেই জানেন, প্রথম সূত্রটি বুলিয়ান মান সত্য বা মিথ্যা প্রদান করে, যেখানে দ্বিতীয় সূত্রটি আপনার নিজস্ব ফলাফলগুলিকে আউটপুট করে:

আরো দেখুন: সূত্র উদাহরণ সহ Google পত্রকগুলিতে COUNT এবং COUNTA ফাংশন৷



উপরের স্ক্রিনশটে যেমন দেখানো হয়েছে, সূত্রগুলি পাঠ্য স্ট্রিংগুলির পাশাপাশি সংখ্যাগুলির জন্যও কাজ করে৷

টিপ৷ যদি দুটি আপাতদৃষ্টিতে সমান স্ট্রিংগুলি ভিন্ন দৈর্ঘ্য প্রদান করে, সম্ভবত সমস্যাটি একটি বা উভয় কক্ষে প্রধান বা পরবর্তী স্পেস -এ। এই ক্ষেত্রে, TRIM ফাংশন ব্যবহার করে অতিরিক্ত স্পেস মুছে ফেলুন। বিস্তারিত ব্যাখ্যা এবং সূত্র উদাহরণ এখানে পাওয়া যাবে: কিভাবে Excel এ স্পেস ট্রিম করতে হয়।

একটি নির্দিষ্ট অক্ষরের উপস্থিতির দ্বারা দুটি ঘরের তুলনা করুন

এটি আমাদের এক্সেল তুলনা স্ট্রিংস টিউটোরিয়ালের শেষ উদাহরণ, এবং এটি একটি বরং নির্দিষ্ট কাজের জন্য একটি সমাধান দেখায়। ধরুন, আপনার কাছে টেক্সট স্ট্রিং-এর 2টি কলাম রয়েছে যাতে আপনার জন্য গুরুত্বপূর্ণ একটি অক্ষর রয়েছে। আপনার লক্ষ্য হল প্রতিটি সারির দুটি কক্ষে প্রদত্ত অক্ষরের একই সংখ্যক উপস্থিতি রয়েছে কিনা তা পরীক্ষা করা৷

বিষয়গুলি আরও পরিষ্কার করতে, নিম্নলিখিতগুলি বিবেচনা করুনউদাহরণ ধরা যাক, আপনার কাছে পাঠানো অর্ডারের দুটি তালিকা রয়েছে (কলাম বি) এবং প্রাপ্ত (কলাম সি)। প্রতিটি সারিতে একটি নির্দিষ্ট আইটেমের অর্ডার থাকে, যার অনন্য শনাক্তকারী সমস্ত অর্ডার আইডিতে অন্তর্ভুক্ত থাকে এবং কলাম A-তে একই সারিতে তালিকাভুক্ত হয় (দয়া করে নীচের স্ক্রিনশটটি দেখুন)। আপনি নিশ্চিত করতে চান যে প্রতিটি সারিতে সেই নির্দিষ্ট আইডির সাথে সমান সংখ্যক শিপড এবং প্রাপ্ত আইটেম রয়েছে৷

এই সমস্যাটি সমাধান করতে, নিম্নলিখিত যুক্তি সহ একটি সূত্র লিখুন৷

• প্রথমত, SUBSTITUTE ফাংশন ব্যবহার করে অনন্য শনাক্তকারীকে কিছু না দিয়ে প্রতিস্থাপন করুন:

  SUBSTITUTE(A1, character_to_count,"")

• তারপর, প্রতিটি কক্ষে কতবার অনন্য শনাক্তকারী প্রদর্শিত হবে তা গণনা করুন। এর জন্য, অনন্য শনাক্তকারী ছাড়া স্ট্রিং দৈর্ঘ্য পান এবং স্ট্রিংয়ের মোট দৈর্ঘ্য থেকে এটি বিয়োগ করুন। এই অংশটি সেল 1 এবং সেল 2 এর জন্য পৃথকভাবে লেখা হবে, উদাহরণস্বরূপ:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  এবং

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• শেষে, আপনি এই 2টি সংখ্যার তুলনা করুন উপরের অংশগুলির মধ্যে সমতা চিহ্ন (=) স্থাপন করে।
LEN( সেল 1 ) - LEN(SUBSTITUTE( cell 1 , character_to_count , ""))=

LEN( cell 2 ) - LEN(SUBSTITUTE( cell 2 , character_to_count , ""))

আমাদের উদাহরণে, অনন্য শনাক্তকারী A2 এ , এবং তুলনা করার জন্য স্ট্রিংগুলি B2 এবং C2 কোষে রয়েছে৷ সুতরাং, সম্পূর্ণ সূত্রটি নিম্নরূপ:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

যদি B2 এবং C2 কক্ষে A2-তে অক্ষরের সংখ্যা সমান সংখ্যক থাকে, তাহলে সূত্রটি TRUE প্রদান করে।অন্যথায় মিথ্যা। ফলাফলগুলিকে আপনার ব্যবহারকারীদের জন্য আরও অর্থবহ করতে, আপনি IF ফাংশনে সূত্রটি এম্বেড করতে পারেন:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")



যেমন আপনি উপরের স্ক্রিনশটে দেখতে পাচ্ছেন , কয়েকটি অতিরিক্ত জটিলতা থাকা সত্ত্বেও সূত্রটি পুরোপুরি কাজ করে:

• যে অক্ষরটি গণনা করা হবে (অনন্য শনাক্তকারী) একটি পাঠ্য স্ট্রিং-এর যেকোনো জায়গায় উপস্থিত হতে পারে।
• স্ট্রিংগুলিতে একটি পরিবর্তনশীল সংখ্যা রয়েছে অক্ষর এবং বিভিন্ন বিভাজক যেমন সেমিকোলন, কমা বা স্থান।

এভাবে আপনি Excel এ স্ট্রিং তুলনা করেন। এই টিউটোরিয়ালে আলোচিত সূত্রগুলো ঘনিষ্ঠভাবে দেখার জন্য, আপনাকে Excel Compare Strings Worksheet ডাউনলোড করতে স্বাগতম। আমি পড়ার জন্য আপনাকে ধন্যবাদ এবং আশা করি আগামী সপ্তাহে আমাদের ব্লগে আপনাকে দেখতে পাব৷

৷