يوضح البرنامج التعليمي كيفية مقارنة السلاسل النصية في Excel للمطابقة التامة وغير الحساسة لحالة الأحرف. ستتعلم عددًا من الصيغ لمقارنة خليتين حسب قيمهما ، أو طول السلسلة ، أو عدد تكرارات حرف معين ، وكذلك كيفية مقارنة خلايا متعددة.

عند استخدام Excel لـ تحليل البيانات ، الدقة هي الشاغل الأكثر أهمية. تؤدي المعلومات غير الصحيحة إلى عدم الالتزام بالمواعيد النهائية ، والتوجهات الخاطئة ، والقرارات الخاطئة ، وخسارة الإيرادات.

بينما تكون صيغ Excel صحيحة تمامًا دائمًا ، فقد تكون نتائجها خاطئة لأن بعض البيانات المعيبة قد اخترقت النظام. في هذه الحالة ، يكون العلاج الوحيد هو التحقق من دقة البيانات. ليس من المهم مقارنة خليتين يدويًا ، ولكن من المستحيل تحديد الاختلافات بين مئات وآلاف السلاسل النصية.

سيعلمك هذا البرنامج التعليمي كيفية أتمتة مهمة الخلية المملة والمعرضة للخطأ المقارنة والصيغ الأفضل للاستخدام في كل حالة معينة.

كيفية مقارنة خليتين في Excel

هناك طريقتان مختلفتان لمقارنة السلاسل في Excel اعتمادًا على سواء كنت تبحث عن مقارنة حساسة لحالة الأحرف أو غير حساسة لحالة الأحرف.

صيغة غير حساسة لحالة الأحرف لمقارنة خليتين

لمقارنة خليتين في Excel مع تجاهل حالة الأحرف ، استخدم صيغة بسيطة مثل:

=A1=B1

حيث A1 و B1 هي الخلايا التي تقوم بمقارنتها. نتيجة الصيغة هي القيم المنطقية TRUEو FALSE.

إذا كنت تريد إخراج النصوص الخاصة بك للمطابقات والاختلافات ، فقم بتضمين العبارة أعلاه في الاختبار المنطقي لوظيفة IF. على سبيل المثال:

=IF(A1=B1, "Equal", "Not equal")

كما ترى في لقطة الشاشة أدناه ، تقارن الصيغتان السلاسل النصية والتواريخ والأرقام بشكل متساوٍ:

صيغة حساسة لحالة الأحرف لمقارنة السلاسل في Excel

في بعض الحالات ، قد يكون من المهم ليس فقط مقارنة القيم النصية لخليتين ، ولكن أيضًا مقارنة حالة الأحرف. يمكن إجراء مقارنة نص حساس لحالة الأحرف باستخدام وظيفة Excel EXACT:

حيث نص 1 و نص 2 هما الخليتان اللتان تقارنهما.

بافتراض أن السلاسل الخاصة بك موجودة في الخليتين A2 و B2 ، فإن الصيغة تسير على النحو التالي:

=EXACT(A2, B2)

ونتيجة لذلك ، تحصل على TRUE لأن السلاسل النصية تتطابق تمامًا مع الحالة لكل حرف ، FALSE بخلاف ذلك.

إذا كنت تريد أن تقدم الدالة EXACT بعض النتائج الأخرى ، فقم بتضمينها في صيغة IF واكتب النص الخاص بك لـ value_if_true و value_if_false الوسيطات:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

توضح لقطة الشاشة التالية نتائج مقارنة السلسلة الحساسة لحالة الأحرف في Excel:

How to مقارنة عدة خلايا في Excel

لمقارنة أكثر من خليتين على التوالي ، استخدم الصيغ التي تمت مناقشتها في الأمثلة أعلاه مع عامل التشغيل AND. التفاصيل الكاملة تتبع أدناه.

صيغة غير حساسة لحالة الأحرف للمقارنةأكثر من خليتين

اعتمادًا على الطريقة التي تريد بها عرض النتائج ، استخدم إحدى الصيغ التالية:

=AND(A2=B2, A2=C2)

أو

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

ترجع الصيغة AND TRUE إذا كانت جميع الخلايا تحتوي على نفس القيمة ، FALSE إذا كانت أي قيمة مختلفة. تُخرج صيغة IF الملصقات التي تكتبها فيها ، " يساوي " و " لا يساوي " في هذا المثال.

كما هو موضح في لقطة الشاشة أدناه ، تعمل الصيغة بشكل مثالي مع أي أنواع بيانات - نص وتواريخ وقيم رقمية:

صيغة حساسة لحالة الأحرف لمقارنة النص في عدة خلايا

لمقارنة سلاسل متعددة مع بعضها البعض لمعرفة ما إذا كانت متطابقة تمامًا ، استخدم الصيغ التالية:

=AND(EXACT(A2,B2), EXACT(A2, C2))

أو

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

كما في المثال السابق ، تقدم الصيغة قيم TRUE و FALSE ، بينما تعرض الثانية النصوص الخاصة بك للمطابقات والاختلافات:

قارن نطاق من الخلايا بخلية عينة

توضح الأمثلة التالية كيف يمكنك التحقق من أن جميع الخلايا في نطاق معين تحتوي على نفس النص الموجود في عينة خلية.

صيغة غير حساسة لحالة الأحرف لمقارنة الخلايا بنموذج نصي

إذا كان حالة الأحرف لا تهم حقًا ، يمكنك استخدام الصيغة التالية لمقارنة الخلايا بعينة:

في الاختبار المنطقي لوظيفة IF ، تقارن رقمين:

• العدد الإجمالي للخلايافي نطاق محدد (عدد الصفوف مضروبًا في عدد الأعمدة) ، و
• عدد الخلايا التي تحتوي على نفس القيمة الموجودة في خلية العينة (التي تُرجعها الدالة COUNTIF).

بافتراض أن نص العينة موجود في C2 وأن السلاسل المطلوب مقارنتها موجودة في النطاق A2: B6 ، فإن الصيغة تسير على النحو التالي:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

لجعل النتائج أكثر للمستخدم ودية ، أي إخراج شيء مثل "كل التطابق" و "ليس كل التطابق" بدلاً من TRUE و FALSE ، استخدم الدالة IF كما فعلنا في الأمثلة السابقة:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

كما هو موضح في لقطة الشاشة أعلاه ، تتوافق الصيغة تمامًا مع مجموعة من السلاسل النصية ، ولكن يمكن أيضًا استخدامها لمقارنة الأرقام والتواريخ.

صيغة حساسة لحالة الأحرف لمقارنة السلاسل مع نموذج نص

إذا كانت حالة الأحرف تحدث فرقًا ، فيمكنك مقارنة السلاسل بنموذج النص باستخدام صيغ الصفيف التالية.

مع وجود نطاق المصدر في A2: B6 ونموذج النص في C2 ، تأخذ الصيغة الشكل التالي:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

بخلاف صيغ Excel العادية ، يتم إكمال صيغ الصفيف بالضغط على Ctrl + Shift + Enter. إذا تم إدخاله بشكل صحيح ، يقوم Excel بتضمين صيغة الصفيف {curly braces} ، كما هو موضح في لقطة الشاشة:

كيفية مقارنة خليتين حسب السلسلةlength

قد ترغب أحيانًا في التحقق مما إذا كانت السلاسل النصية في كل صف تحتوي على عدد متساوٍ من الأحرف. صيغة هذه المهمة بسيطة للغاية. أولاً ، تحصل على طول سلسلة خليتين باستخدام وظيفة LEN ، ثم قارن الأرقام.

بافتراض أن السلاسل المراد مقارنتها موجودة في الخليتين A2 و B2 ، استخدم أيًا من الصيغتين التاليتين:

=LEN(A2)=LEN(B2)

أو

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

كما تعلم ، ترجع الصيغة الأولى القيم المنطقية TRUE أو FALSE ، بينما تنتج الصيغة الثانية النتائج الخاصة بك:

كما هو موضح في لقطة الشاشة أعلاه ، تعمل الصيغ مع السلاسل النصية وكذلك الأرقام.

نصيحة. إذا كانت هناك سلسلتان متماثلتان ظاهريا ترجعان أطوال مختلفة ، فمن المرجح أن تكون المشكلة في بادئة أو لاحقة مسافات في خلية واحدة أو كلتيهما. في هذه الحالة ، قم بإزالة المسافات الزائدة باستخدام وظيفة TRIM. يمكن العثور على الشرح التفصيلي وأمثلة الصيغة هنا: كيفية قص المسافات في Excel.

قارن بين خليتين حسب تكرارات حرف معين

هذا هو المثال الأخير في برنامج Excel Compare Strings التعليمي الخاص بنا ، ويعرض حلاً لمهمة محددة نوعًا ما. لنفترض أن لديك عمودين من السلاسل النصية التي تحتوي على حرف مهم بالنسبة لك. هدفك هو التحقق مما إذا كانت خليتان في كل صف تحتويان على نفس عدد التكرارات لحرف معين.

لتوضيح الأمور ، ضع في اعتبارك ما يليمثال. لنفترض أن لديك قائمتين من الطلبات المشحونة (العمود B) والمستلمة (العمود C). يحتوي كل صف على طلبات لعنصر معين ، يتم تضمين معرفه الفريد في جميع معرفات الطلبات ويتم إدراجه في نفس الصف في العمود A (يرجى الاطلاع على لقطة الشاشة أدناه). تريد التأكد من أن كل صف يحتوي على عدد متساوٍ من العناصر المشحونة والمستلمة بهذا المعرف المحدد.

لحل هذه المشكلة ، اكتب صيغة بالمنطق التالي.

• أولاً ، استبدل المعرف الفريد بلا شيء باستخدام الدالة SUBSTITUTE:

  SUBSTITUTE(A1, character_to_count,"")

• ثم احسب عدد المرات التي يظهر فيها المعرف الفريد في كل خلية. لهذا ، احصل على طول السلسلة بدون المعرف الفريد واطرحها من الطول الإجمالي للسلسلة. يجب كتابة هذا الجزء للخلية 1 والخلية 2 بشكل فردي ، على سبيل المثال:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  و

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• أخيرًا ، تقارن هذين الرقمين بوضع علامة المساواة (=) بين الأجزاء أعلاه.

LEN ( الخلية 2 ) - LEN (SUBSTITUTE ( الخلية 2 ، character_to_count ، ""))

في مثالنا ، المعرف الفريد موجود في A2 ، والسلاسل المطلوب مقارنتها موجودة في الخلايا B2 و C2. إذن ، الصيغة الكاملة هي كما يلي:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

ترجع الصيغة TRUE إذا كانت الخلايا B2 و C2 تحتويان على عدد متساوٍ من تكرارات الحرف في A2 ،خطأ خلاف ذلك. لجعل النتائج أكثر وضوحًا للمستخدمين ، يمكنك تضمين الصيغة في وظيفة IF:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

كما ترى في لقطة الشاشة أعلاه ، تعمل الصيغة بشكل مثالي على الرغم من بعض التعقيدات الإضافية:

• يمكن أن يظهر الحرف المراد حسابه (المعرف الفريد) في أي مكان في سلسلة نصية.
• تحتوي السلاسل على رقم متغير من الأحرف والفواصل المختلفة مثل الفاصلة المنقوطة أو الفاصلة أو المسافة.

هذه هي الطريقة التي تقارن بها السلاسل في Excel. لإلقاء نظرة فاحصة على الصيغ التي تمت مناقشتها في هذا البرنامج التعليمي ، فنحن نرحب بك لتنزيل ورقة عمل Excel Compare Strings Worksheet. أشكرك على القراءة وآمل أن أراك على مدونتنا الأسبوع المقبل.