ٽيوٽوريل ڏيکاري ٿو ته ڪيئن ايڪسل ۾ ٽيڪسٽ اسٽرنگ جو مقابلو ڪرڻ لاءِ ڪيس-غير حساس ۽ درست ميچ. توهان ٻه سيلز کي انهن جي قيمتن، اسٽرنگ جي ڊيگهه، يا هڪ مخصوص ڪردار جي واقعن جي تعداد جي لحاظ سان مقابلو ڪرڻ لاء ڪيترن ئي فارمولين کي سکندا، ۽ انهي سان گڏ ڪيترن ئي سيلز جو مقابلو ڪيئن ڪجي.

جڏهن Excel استعمال ڪندي ڊيٽا جو تجزيو، درستگي سڀ کان اهم تشويش آهي. غلط معلومات گم ٿيل آخري تاريخن، غلط فيصلا ڪيل رجحانن، غلط فيصلن ۽ گم ٿيل آمدني جي ڪري ٿي.

جڏهن ته Excel فارمولا هميشه صحيح هوندا آهن، انهن جا نتيجا غلط هوندا ڇو ته ڪجهه غلط ڊيٽا سسٽم ۾ داخل ٿي ويا آهن. انهي حالت ۾، واحد علاج آهي ڊيٽا جي درستگي لاء چيڪ ڪرڻ. ٻن سيلن جو دستي طور تي مقابلو ڪرڻ ڪا وڏي ڳالهه ناهي، پر سوين ۽ هزارين ٽيڪسٽ اسٽرنگ جي وچ ۾ فرق کي سمجهڻ ناممڪن آهي.

هي ٽيوٽوريل توهان کي سيکاريندو ته سيل جي مشڪل ۽ نقص واري ڪم کي ڪيئن خودڪار ڪجي. مقابلي ۽ ڪھڙا فارمولا استعمال ڪرڻ لاءِ بھترين آھن ھر خاص ڪيس ۾.

Excel ۾ ٻن سيلن جو مقابلو ڪيئن ڪجي

Excel ۾ تارن جي ڀيٽ ڪرڻ جا ٻه مختلف طريقا آھن. ڇا توھان ڳولھيو ٿا ڪيس-حساس يا ڪيس-غير حساس موازن.

2 سيلز جي مقابلي لاءِ ڪيس-حساس فارمولا

Exel ۾ ٻن سيلز کي نظر انداز ڪرڻ واري صورت ۾ مقابلو ڪرڻ لاءِ، ھڪڙو سادو فارمولا استعمال ڪريو ھن جھڙو:

=A1=B1

جتي A1 ۽ B1 سيل آهن جن جو توهان مقابلو ڪري رهيا آهيو. فارمولا جا نتيجا آهن Boolean قدر TRUE۽ غلط.

جيڪڏهن توهان چاهيو ٿا ته توهان جا پنهنجا متن ملن ۽ فرقن لاءِ، مٿي ڏنل بيان کي IF فنڪشن جي منطقي ٽيسٽ ۾ شامل ڪريو. مثال طور:

=IF(A1=B1, "Equal", "Not equal")

جيئن توهان هيٺ ڏنل اسڪرين شاٽ ۾ ڏسو ٿا، ٻنهي فارمولين ۾ متن جي تارن، تاريخن ۽ انگن جو هڪجهڙائي سان مقابلو ڪيو وڃي ٿو:

ڪجهه حالتن ۾، اهو اهم ٿي سگهي ٿو نه رڳو ٻن سيلن جي متن جي قدرن جو مقابلو ڪرڻ، پر ڪردار جي صورت جو مقابلو ڪرڻ پڻ. ڪيس-حساس متن جو مقابلو Excel EXACT فنڪشن استعمال ڪندي ڪري سگهجي ٿو:

جتي text1 ۽ text2 اهي ٻه سيل آهن جيڪي توهان موازنہ ڪري رهيا آهيو.

فرض ڪريو ته توهان جا اسٽرنگ سيل A2 ۽ B2 ۾ آهن، فارمولا هن ريت آهي:

=EXACT(A2, B2)

نتيجي جي طور تي، توهان کي حاصل ٿئي ٿو TRUE ٽيڪسٽ اسٽرنگ لاءِ بلڪل صحيح طور تي ميچ سميت ڪيس هر ڪردار جو، غلط ٻي صورت ۾.

جيڪڏهن توهان چاهيو ٿا ته EXACT فنڪشن ڪجهه ٻيا نتيجا ڏئي، ان کي IF فارمولا ۾ شامل ڪريو ۽ value_if_true ۽ value_if_false<لاءِ پنهنجو متن ٽائيپ ڪريو. 2> دليل:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

هيٺ ڏنل اسڪرين شاٽ ڏيکاري ٿو ڪيس-حساس اسٽرنگ جي مقابلي جا نتيجا Excel ۾:

ڪيئن ڪجي Excel ۾ گھڻن سيلن جو موازنہ ڪريو

لاڳاپيل 2 سيلن کان وڌيڪ مقابلو ڪرڻ لاءِ، مٿي ڏنل مثالن ۾ بيان ڪيل فارمولن کي AND آپريٽر سان گڏ استعمال ڪريو. مڪمل تفصيل ھيٺ ڏنل آھي.

مقابلي ڪرڻ لاءِ ڪيس غير حساس فارمولا2 سيلز کان وڌيڪ

ان تي منحصر ڪري ٿو ته توهان نتيجن کي ڪيئن ڏيکارڻ چاهيو ٿا، هيٺ ڏنل فارمولن مان هڪ استعمال ڪريو:

=AND(A2=B2, A2=C2)

يا

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

۽ فارمولا واپس ڏئي ٿو TRUE جيڪڏھن سڀني سيلن ۾ ساڳي قدر آھي، FALSE جيڪڏھن ڪا قدر مختلف آھي. IF فارمولا انھن ليبلن کي ٻاھر ڪڍندو آھي جيڪي توھان ٽائيپ ڪندا آھيو، " برابر " ۽ " Not equal " ھن مثال ۾.

جيئن ھيٺ ڏنل اسڪرين شاٽ ۾ ڏيکاريو ويو آھي، فارمولا ڪنهن به ڊيٽا جي قسمن سان مڪمل طور تي ڪم ڪري ٿو - متن، تاريخون ۽ عددي قدر:

ڪيس-حساس فارمولا ڪيترن ئي سيلن ۾ متن جي ڀيٽ ڪرڻ لاءِ

گھڻن تارن جو مقابلو ڪرڻ لاءِ هڪ ٻئي کي ڏسڻ لاءِ ته ڇا اهي بلڪل ملن ٿا، هيٺ ڏنل فارمولو استعمال ڪريو:

=AND(EXACT(A2,B2), EXACT(A2, C2))

يا

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

اڳئين مثال وانگر، پهريون فارمولا صحيح ۽ غلط قيمتون فراهم ڪري ٿو، جڏهن ته ٻيو نمبر توهان جي پنهنجي نصوص ڏيکاري ٿو ميچن ۽ فرقن لاءِ:

سيلز جي هڪ حد کي نموني سيل سان موازنہ ڪريو

هيٺ ڏنل مثال ڏيکارين ٿا ته توهان ڪيئن تصديق ڪري سگهو ٿا ته هڪ ڏنل رينج ۾ سڀني سيلن ۾ ساڳيو متن آهي جيئن نموني سيل ۾.

سيلز کي نموني جي متن سان ڀيٽڻ لاءِ ڪيس غير حساس فارمولا

جيڪڏهن ڪردار جي صورت ۾ واقعي ڪا به اهميت نه آهي، توهان هيٺ ڏنل فارمولا استعمال ڪري سگهو ٿا سيلز کي نموني سان ڀيٽڻ لاءِ:

IF فنڪشن جي منطقي ٽيسٽ ۾، توهان ٻن انگن جو مقابلو ڪريو ٿا:

• سيلن جو ڪل تعدادمخصوص رينج ۾ (قطار جو تعداد ڪالمن جي تعداد سان ضرب ڪيو ويو)، ۽
• سيلن جو تعداد جيڪو ساڳئي قدر تي مشتمل آهي جيئن نموني سيل ۾ (COUNTIF فنڪشن طرفان واپسي).

فرض ڪري نموني جو متن C2 ۾ آهي ۽ تارن جو مقابلو ڪرڻ جي حد A2:B6 ۾ آهي، فارمولا هن ريت آهي:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

نتيجن کي وڌيڪ استعمال ڪرڻ لاءِ- دوستانه، يعني آئوٽ ڪڍو ڪجهه "سڀ ميچ" ۽ "سڀ ميچ نه" جي بدران TRUE ۽ FALSE، IF فنڪشن استعمال ڪريو جيئن اسان اڳئين مثالن ۾ ڪيو آهي:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

جيئن مٿي ڏنل اسڪرين شاٽ ڏيکاريو ويو آهي، فارمولا مڪمل طور تي متن جي تارن جي هڪ حد سان نقل ڪري ٿو، پر اهو پڻ استعمال ڪري سگهجي ٿو انگن ۽ تاريخن جو مقابلو ڪرڻ لاءِ.

ڪيس-حساس فارمولا تارن جي ڀيٽ ڪرڻ لاءِ نموني متن

جيڪڏهن ڪردار جي صورت ۾ فرق اچي ٿو، ته توهان هيٺ ڏنل صفن جي فارمولين کي استعمال ڪندي نموني متن سان تارن جو مقابلو ڪري سگهو ٿا.

A2:B6 ۾ رهندڙ ماخذ جي حد ۽ C2 ۾ نموني متن سان، فارمولا هيٺ ڏنل شڪل وٺي ٿو:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

برعڪس ايڪسل فارمولن جي باقاعده , array فارمولا مڪمل ڪيا ويندا Ctrl + Shift + Enter کي دٻائڻ سان. جيڪڏهن صحيح طور تي داخل ڪيو ويو آهي، ايڪسل ترتيب واري فارمولا کي {curly braces} ۾ شامل ڪري ٿو، جيئن اسڪرين شاٽ ۾ ڏيکاريل آهي:

ڪڏهن توهان اهو چيڪ ڪرڻ چاهيو ٿا ته ڇا هر قطار ۾ متن جي تارن ۾ اکرن جي برابر تعداد شامل آهي. هن ڪم لاء فارمولا تمام سادو آهي. پهرين، توهان LEN فنڪشن کي استعمال ڪندي ٻن سيلن جي اسٽرنگ جي ڊيگهه حاصل ڪريو، ۽ پوء انگن جو مقابلو ڪريو.

فرض ڪيو ته تارن جو مقابلو ڪيو وڃي سيلز A2 ۽ B2 ۾، هيٺ ڏنل فارمولن مان ڪنهن کي استعمال ڪريو:

=LEN(A2)=LEN(B2)

يا

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

جيئن ته توهان اڳ ۾ ئي ڄاڻو ٿا، پهريون فارمولا بولين ويلز TRUE يا FALSE ڏئي ٿو، جڏهن ته ٻيو فارمولا توهان جا پنهنجا نتيجا ڪڍي ٿو:

جيئن مٿي ڏنل اسڪرين شاٽ ۾ ڏيکاريو ويو آهي، فارمولا ٽيڪسٽ اسٽرنگ ۽ انگن لاءِ ڪم ڪن ٿا.

ٽپ. جيڪڏهن ٻه بظاهر هڪجهڙا اسٽرنگ مختلف لمبائيون موٽن ٿا، گهڻو ڪري اهو مسئلو آهي اڳوڻي يا پيريان > اسپيس هڪ يا ٻنهي سيلن ۾. انهي حالت ۾، TRIM فنڪشن استعمال ڪندي اضافي خالن کي هٽايو. تفصيلي وضاحت ۽ فارمولا جا مثال هتي ملي سگهن ٿا: ايڪسل ۾ اسپيس کي ڪيئن ٽرم ڪجي.

هڪ مخصوص ڪردار جي واقعن سان ٻن سيلن جو مقابلو ڪريو

هي اسان جي Excel Compare Strings ٽيوٽوريل ۾ آخري مثال آهي، ۽ اهو هڪ خاص ڪم لاءِ حل ڏيکاري ٿو. فرض ڪريو، توهان وٽ ٽيڪسٽ اسٽرنگ جا 2 ڪالمن آهن جيڪي توهان لاءِ اهم ڪردار تي مشتمل آهن. توھان جو مقصد اھو چيڪ ڪرڻ آھي ته ڇا ھر قطار ۾ ٻن سيلن ۾ ھڪڙي ڏنل ڪردار جي واقعن جو ساڳيو تعداد آھي.

شين کي صاف ڪرڻ لاءِ، ھيٺين تي غور ڪريومثال. اچو ته چئو، توهان وٽ موڪليل آرڊر جون ٻه لسٽون آهن (ڪالمن بي) ۽ وصول ڪيل (ڪالمن سي). هر قطار ۾ هڪ مخصوص شئي لاءِ آرڊر شامل آهن، جن جي منفرد سڃاڻپ ڪندڙ سڀني آرڊر IDs ۾ شامل آهي ۽ ساڳئي قطار ۾ ڪالمن A ۾ درج ٿيل آهي (مهرباني ڪري هيٺ ڏنل اسڪرين شاٽ ڏسو). توھان پڪ ڪرڻ چاھيو ٿا ته ھر قطار ۾ انھيءَ مخصوص ID سان موڪليل ۽ وصول ڪيل شيون شامل آھن.

ھن مسئلي کي حل ڪرڻ لاءِ ھيٺ ڏنل منطق سان ھڪڙو فارمولا لکو.

• سڀ کان پهريان، SUBSTITUTE فنڪشن استعمال ڪندي منفرد سڃاڻپ ڪندڙ کي ڪجھ به نه مٽايو:

  SUBSTITUTE(A1, character_to_count,"")

• پوءِ، حساب ڪريو ته هر سيل ۾ ڪيترا ڀيرا منفرد سڃاڻپ ڪندڙ ظاهر ٿئي ٿو. ان لاءِ، ڌار ڌار سڃاڻپ ڪندڙ کان سواءِ اسٽرنگ جي ڊگھائي حاصل ڪريو ۽ ان کي اسٽرنگ جي ڪل ڊگھائي مان گھٽايو. هي حصو سيل 1 ۽ سيل 2 لاءِ انفرادي طور لکيو ويندو، مثال طور:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  ۽

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• آخر ۾، توهان انهن 2 نمبرن جو مقابلو ڪريو. مٿي ڏنل حصن جي وچ ۾ برابري جي نشاني (=) کي رکڻ سان.

LEN( cell 2 ) - LEN(SUBSTITUTE( cell 2 , character_to_count , ""))

اسان جي مثال ۾، منفرد سڃاڻپ ڪندڙ A2 ۾ آهي ، ۽ مقابلي ڪرڻ لاءِ تارون سيل B2 ۽ C2 ۾ آهن. تنهن ڪري، مڪمل فارمولا هن ريت آهي:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

فارمولا واپس اچي ٿو TRUE جيڪڏهن سيلز B2 ۽ C2 ۾ A2 ۾ ڪردار جي واقعن جي برابر تعداد تي مشتمل آهي،ٻي صورت ۾ FALSE. نتيجن کي توهان جي استعمال ڪندڙن لاءِ وڌيڪ بامعني بڻائڻ لاءِ، توهان فارمولا کي IF فنڪشن ۾ شامل ڪري سگهو ٿا:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

جيئن توهان مٿي اسڪرين شاٽ ۾ ڏسي سگهو ٿا , فارمولا ڪجھ اضافي پيچيدگين جي باوجود مڪمل طور تي ڪم ڪري ٿو:

• جيڪو اکر ڳڻيو وڃي ٿو (منفرد سڃاڻپ ڪندڙ) ٽيڪسٽ اسٽرنگ ۾ ڪٿي به ظاهر ٿي سگھي ٿو.
• اسٽرنگ ۾ هڪ متغير نمبر شامل آهي اکرن جا ۽ مختلف جدا ڪندڙ جهڙوڪ سيميڪولن، ڪاما يا اسپيس.

اهڙيءَ طرح توهان ايڪسل ۾ تارن جو مقابلو ڪندا آهيو. ھن سبق ۾ بحث ڪيل فارمولين تي ويجھي نظر رکڻ لاءِ، توھان کي ڀليڪار آھي ڊائون لوڊ ڪريو Excel Compare Strings Worksheet. مان توهان جي پڙهڻ جي مهرباني ۽ اميد آهي ته توهان کي ايندڙ هفتي اسان جي بلاگ تي ڏسڻ لاء.