این آموزش نحوه مقایسه رشته های متنی در اکسل را برای تطابق دقیق به حروف کوچک و بزرگ نشان می دهد. شما تعدادی فرمول برای مقایسه دو سلول با مقادیر، طول رشته یا تعداد تکرار یک کاراکتر خاص و همچنین نحوه مقایسه چند سلول را یاد خواهید گرفت.

هنگام استفاده از Excel برای تجزیه و تحلیل داده ها، دقت حیاتی ترین نگرانی است. اطلاعات نادرست منجر به مهلت های از دست رفته، روندهای اشتباه، تصمیمات اشتباه و درآمدهای از دست رفته می شود.

در حالی که فرمول های اکسل همیشه کاملاً درست هستند، نتایج آنها ممکن است اشتباه باشد زیرا برخی از داده های ناقص به سیستم نفوذ کرده اند. در این مورد، تنها راه حل بررسی صحت داده ها است. مقایسه دو سلول به صورت دستی کار مهمی نیست، اما تشخیص تفاوت بین صدها و هزاران رشته متن تقریباً غیرممکن است.

این آموزش به شما می‌آموزد که چگونه وظایف خسته‌کننده و پرخطا سلول را خودکار کنید. مقایسه و اینکه چه فرمول هایی برای هر مورد خاص بهتر است استفاده شود.

نحوه مقایسه دو سلول در اکسل

دو روش مختلف برای مقایسه رشته ها در اکسل بسته به چه به دنبال مقایسه حساس به حروف بزرگ و چه بزرگ و کوچک باشید.

فرمول حساس به حروف بزرگ برای مقایسه 2 سلول

برای مقایسه دو سلول در Excel با نادیده گرفتن حروف، از فرمول ساده ای مانند این استفاده کنید:

=A1=B1

جایی که A1 و B1 سلول هایی هستند که شما مقایسه می کنید. نتیجه فرمول مقادیر بولی TRUE استو FALSE.

اگر می خواهید متن های خود را برای مطابقت ها و تفاوت ها خروجی بگیرید، عبارت فوق را در تست منطقی تابع IF قرار دهید. به عنوان مثال:

=IF(A1=B1, "Equal", "Not equal")

همانطور که در تصویر زیر می بینید، هر دو فرمول رشته های متن، تاریخ ها و اعداد را به خوبی مقایسه می کنند:

فرمول حساس به حروف بزرگ برای مقایسه رشته ها در اکسل

در برخی شرایط، ممکن است نه تنها مقایسه مقادیر متنی دو سلول، بلکه مقایسه حروف کاراکتر نیز مهم باشد. مقایسه متن حساس به حروف بزرگ را می توان با استفاده از تابع EXACT Excel انجام داد:

که در آن text1 و text2 دو سلولی هستند که شما با هم مقایسه می کنید.

با فرض اینکه رشته‌های شما در سلول‌های A2 و B2 قرار دارند، فرمول به شرح زیر است:

=EXACT(A2, B2)

در نتیجه، برای رشته‌های متنی که دقیقاً شامل حروف بزرگ هم می‌شوند، درست است. از هر کاراکتر، در غیر این صورت FALSE.

اگر می خواهید تابع EXACT نتایج دیگری را ارائه دهد، آن را در فرمول IF قرار دهید و متن خود را برای value_if_true و value_if_false<تایپ کنید. 2> آرگومان ها:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

تصویر صفحه زیر نتایج مقایسه رشته های حساس به حروف کوچک و بزرگ را در اکسل نشان می دهد:

چگونه مقایسه چند سلول در اکسل

برای مقایسه بیش از 2 سلول پشت سر هم، از فرمول های مورد بحث در مثال های بالا در ترکیب با عملگر AND استفاده کنید. جزئیات کامل در زیر آمده است.

فرمول حساس به حروف بزرگ برای مقایسهبیش از 2 سلول

بسته به نحوه نمایش نتایج، از یکی از فرمول های زیر استفاده کنید:

=AND(A2=B2, A2=C2)

یا

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

فرمول AND اگر همه سلول‌ها دارای مقدار یکسانی باشند، TRUE و اگر مقداری متفاوت باشد، FALSE را برمی‌گرداند. فرمول IF برچسب هایی را که در آن تایپ می کنید، " برابر " و " نه برابر " در این مثال به بیرون می دهد.

همانطور که در تصویر زیر نشان داده شده است، فرمول با هر نوع داده ای کاملاً کار می کند - متن، تاریخ و مقادیر عددی:

فرمول حساس به حروف بزرگ برای مقایسه متن در چندین سلول

برای مقایسه چند رشته برای دیدن اینکه آیا دقیقا مطابقت دارند یا خیر، از فرمول های زیر استفاده کنید:

=AND(EXACT(A2,B2), EXACT(A2, C2))

یا

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

مانند مثال قبل، اول فرمول مقادیر TRUE و FALSE را ارائه می دهد، در حالی که فرمول دوم متون خود را برای مطابقت ها و تفاوت ها نشان می دهد:

مقایسه طیفی از سلول ها با یک سلول نمونه

مثال‌های زیر نشان می‌دهند که چگونه می‌توانید تأیید کنید که همه سلول‌ها در یک محدوده مشخص حاوی متنی مشابه در یک سلول نمونه هستند.

فرمول حساس به حروف کوچک و بزرگ برای مقایسه سلول‌ها با یک متن نمونه

اگر حروف نویسه واقعاً مهم نیست، می‌توانید از فرمول زیر برای مقایسه سلول‌ها با نمونه استفاده کنید:

در آزمون منطقی تابع IF، شما دو عدد را با هم مقایسه می کنید:

• تعداد کل سلول هادر یک محدوده مشخص (تعداد ردیف ها در تعداد ستون ها) و
• تعداد سلول هایی که دارای همان مقدار سلول نمونه هستند (با تابع COUNTIF برگردانده می شود).

با فرض اینکه متن نمونه در C2 باشد و رشته های مورد مقایسه در محدوده A2:B6 قرار دارند، فرمول به شرح زیر است:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

برای اینکه نتایج کاربر بیشتر شود- دوستانه، یعنی به جای TRUE و FALSE چیزی مانند "All match" و "Not all match" را خروجی کنید، از تابع IF مانند مثال های قبلی استفاده کنید:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

همانطور که در تصویر بالا نشان داده شده است، فرمول کاملاً با طیف وسیعی از رشته های متن مقابله می کند، اما می توان از آن برای مقایسه اعداد و تاریخ نیز استفاده کرد.

فرمول حساس به حروف بزرگ برای مقایسه رشته ها با یک نمونه متن

اگر حروف نویسه تفاوت ایجاد می کند، می توانید رشته ها را با متن نمونه با استفاده از فرمول های آرایه زیر مقایسه کنید.

با محدوده منبع موجود در A2:B6 و متن نمونه در C2، فرمول شکل زیر را به خود می گیرد:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

بر خلاف فرمول های معمولی Excel ، فرمول های آرایه با فشار دادن Ctrl + Shift + Enter تکمیل می شوند. اگر به درستی وارد شده باشد، اکسل فرمول آرایه را در {پرانتز فرفری} محصور می کند، همانطور که در تصویر نشان داده شده است:

نحوه مقایسه دو سلول با رشتهlength

گاهی اوقات ممکن است بخواهید بررسی کنید که آیا رشته های متنی در هر ردیف دارای تعداد مساوی کاراکتر هستند یا خیر. فرمول این کار بسیار ساده است. ابتدا طول رشته دو سلول را با استفاده از تابع LEN بدست می آورید و سپس اعداد را با هم مقایسه می کنید.

با فرض اینکه رشته های مورد مقایسه در سلول های A2 و B2 هستند، از یکی از فرمول های زیر استفاده کنید:

=LEN(A2)=LEN(B2)

یا

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

همانطور که می دانید، فرمول اول مقادیر بولی TRUE یا FALSE را برمی گرداند، در حالی که فرمول دوم نتایج خود را به دست می دهد:

همانطور که در تصویر بالا نشان داده شد، فرمول ها برای رشته های متنی و همچنین اعداد کار می کنند.

نکته. اگر دو رشته به ظاهر مساوی طول های متفاوتی را برگردانند، به احتمال زیاد مشکل در پیشرو یا فضاهای انتهایی 20> در یک یا هر دو سلول است. در این حالت، فضاهای اضافی را با استفاده از عملکرد TRIM حذف کنید. توضیح دقیق و مثال‌های فرمول را می‌توانید در اینجا بیابید: نحوه برش فضاها در اکسل.

مقایسه دو سلول بر اساس وقوع یک کاراکتر خاص

این آخرین مثال در آموزش مقایسه رشته های اکسل ما است و راه حلی را برای یک کار نسبتاً خاص نشان می دهد. فرض کنید، شما 2 ستون از رشته های متنی دارید که حاوی یک کاراکتر مهم برای شما هستند. هدف شما این است که بررسی کنید آیا دو سلول در هر ردیف دارای تعداد یکسانی از وقوع یک کاراکتر معین هستند یا خیر.

برای شفاف‌تر کردن موارد، موارد زیر را در نظر بگیرید.مثال. فرض کنید، شما دو لیست از سفارشات ارسال شده (ستون B) و دریافت شده (ستون C) دارید. هر ردیف شامل سفارشات برای یک مورد خاص است که شناسه منحصر به فرد آن در همه شناسه های سفارش گنجانده شده است و در همان ردیف در ستون A فهرست شده است (لطفاً به تصویر زیر مراجعه کنید). شما می خواهید مطمئن شوید که هر ردیف حاوی تعداد مساوی از کالاهای ارسال شده و دریافتی با آن شناسه خاص است.

برای حل این مشکل، فرمولی با منطق زیر بنویسید.

• ابتدا، با استفاده از تابع SUBSTITUTE، شناسه یکتا را با هیچ چیز جایگزین کنید:

  SUBSTITUTE(A1, character_to_count,"")

• سپس، محاسبه کنید که شناسه یکتا چند بار در هر سلول ظاهر می شود. برای این کار، طول رشته را بدون شناسه یکتا بدست آورید و آن را از طول کل رشته کم کنید. این قسمت باید برای سلول 1 و سلول 2 به صورت جداگانه نوشته شود، به عنوان مثال:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  و

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• در آخر، شما این 2 عدد را با هم مقایسه کنید. با قرار دادن علامت برابری (=) در بین قسمت های بالا.

LEN( سلول 2 ) - LEN(SUBSTITUTE( سلول 2 ، شخصیت_برای_شمارش ، ""))

در مثال ما، شناسه منحصر به فرد در A2 است ، و رشته های مقایسه در سلول های B2 و C2 هستند. بنابراین، فرمول کامل به صورت زیر است:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

در صورتی که سلول های B2 و C2 دارای تعداد مساوی از وقوع نویسه در A2 باشند، فرمول TRUE را برمی گرداند.FALSE در غیر این صورت. برای معنادارتر کردن نتایج برای کاربران خود، می توانید فرمول را در تابع IF قرار دهید:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

همانطور که در تصویر بالا می بینید ، با وجود چند پیچیدگی دیگر، فرمول کاملاً کار می کند:

• کاراکتر مورد شمارش (شناسه منحصر به فرد) می تواند در هر نقطه از یک رشته متن ظاهر شود.
• رشته ها دارای یک عدد متغیر هستند. کاراکترها و جداکننده های مختلف مانند نقطه ویرگول، کاما یا فاصله.

در اکسل رشته ها را به این صورت مقایسه می کنید. برای مشاهده دقیق فرمول های مورد بحث در این آموزش، می توانید کاربرگ Excel Compare Strings را دانلود کنید. از خواندن شما سپاسگزارم و امیدوارم هفته آینده شما را در وبلاگ خود ببینم.