ټیوټوریل ښیې چې څنګه په Excel کې د قضیې غیر حساس او دقیق میچ لپاره د متن تارونه پرتله کړئ. تاسو به یو شمیر فورمولونه زده کړئ چې دوه حجرې د دوی ارزښتونو، تار اوږدوالی، یا د یو ځانګړي کرکټر د پیښو شمیر سره پرتله کړئ، او همدارنګه د څو حجرو پرتله کولو څرنګوالی.

کله چې د Excel کارول د معلوماتو تحلیل، دقت ترټولو مهم اندیښنه ده. ناسم معلومات د ورک شوي مهال ویش، ناسم اټکل شوي تمایلاتو، غلطو پریکړو او د عوایدو له لاسه ورکولو لامل کیږي.

پداسې حال کې چې د Excel فورمولونه تل په بشپړ ډول ریښتیا وي، د دوی پایلې ممکن غلطې وي ځکه چې ځینې نیمګړتیاوې سیسټم ته ننوځي. په دې حالت کې، یوازینۍ درملنه د دقت لپاره د معلوماتو چک کول دي. دا کومه لویه خبره نه ده چې دوه حجرې په لاسي ډول پرتله کړئ، مګر د سلګونو او زرګونو متن تارونو ترمنځ توپیر په ګوته کول ناممکن دي.

دا ټیوټوریل به تاسو ته درس درکړي چې څنګه د حجرو ستړیا او غلط کار اتومات کړئ. پرتله کول او کوم فورمولونه په هره ځانګړې قضیه کې د کارولو لپاره غوره دي.

په Excel کې د دوه حجرو پرتله کولو څرنګوالی

په Excel کې د تارونو پرتله کولو دوه مختلفې لارې شتون لري. که تاسو د قضیې حساس یا د قضیې غیر حساس پرتله په لټه کې یاست.

د قضیې غیر حساس فورمول د 2 حجرو پرتله کولو لپاره

په Excel کې د دوه حجرو پرتله کولو لپاره د قضیې په پام کې نیولو سره، د دې په څیر ساده فورمول وکاروئ:

=A1=B1

چیرې چې A1 او B1 هغه حجرې دي چې تاسو یې پرتله کوئ. د فورمول پایله د بولین ارزښتونه ریښتیا دياو غلط.

که تاسو غواړئ خپل متنونه د میچونو او توپیرونو لپاره تولید کړئ، پورتني بیان د IF فنکشن منطقي ازموینې کې ځای په ځای کړئ. د مثال په توګه:

=IF(A1=B1, "Equal", "Not equal")

لکه څنګه چې تاسو په لاندې سکرین شاټ کې ګورئ، دواړه فورمولونه د متن تارونه، نیټې او شمیرې په مساوي ډول پرتله کوي:

10>

په ځینو حاالتو کې، دا ممکن نه یوازې د دوه حجرو متن ارزښتونو پرتله کول مهم وي، بلکې د کریکټ کیس پرتله کول هم مهم وي. د قضیې حساس متن پرتله کول د Excel EXACT فنکشن په کارولو سره ترسره کیدی شي:

چیرته text1 او text2 هغه دوه حجرې دي چې تاسو یې پرتله کوئ.

فرض کړئ چې ستاسو تارونه په A2 او B2 حجرو کې دي، فورمول په لاندې ډول ځي:

=EXACT(A2, B2)

د پایلې په توګه، تاسو د متن تارونو لپاره ریښتیا ترلاسه کوئ د قضیې په شمول په سمه توګه سره سمون لري د هر کرکټر څخه، په بل ډول غلط.

که تاسو غواړئ چې دقیق فعالیت ځینې نورې پایلې وړاندې کړي، دا په IF فورمول کې ځای پرځای کړئ او د value_if_true او value_if_false<لپاره خپل متن ولیکئ 2> دلیلونه:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

لاندې سکرین شاټ په Excel کې د قضیې حساس سټینګ پرتله کولو پایلې ښیې:

11>

څنګه په Excel کې د څو حجرو پرتله کول

په یو قطار کې د 2 څخه ډیرو حجرو پرتله کولو لپاره، هغه فورمولونه وکاروئ چې په پورتنیو مثالونو کې بحث شوي د AND آپریټر سره په ترکیب کې. بشپړ توضیحات لاندې تعقیب کړئ.

د پرتله کولو لپاره د قضیې غیر حساس فورمولله 2 څخه زیات حجرې

په دې پورې اړه لري چې تاسو څنګه پایلې ښکاره کول غواړئ، د لاندې فورمولونو څخه یو وکاروئ:

=AND(A2=B2, A2=C2)

یا

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

د AND فورمول سم راګرځي که چیرې ټول حجرې ورته ارزښت ولري، FALSE که کوم ارزښت توپیر ولري. د IF فورمول هغه لیبلونه تولیدوي چې تاسو یې په دې مثال کې ټایپ کوئ، " مساوي " او " مساوي نه " په دې مثال کې.

لکه څنګه چې لاندې سکرین شاټ کې ښودل شوي، فورمول د هر ډول ډیټا ډولونو سره په بشپړ ډول کار کوي - متن، نیټې او شمیرې ارزښتونه:

د قضیې حساس فورمول په څو حجرو کې د متن پرتله کولو لپاره

د ډیری تارونو پرتله کولو لپاره د یو بل سره د لیدلو لپاره چې دوی دقیقا سره سمون لري، لاندې فورمولونه وکاروئ:

=AND(EXACT(A2,B2), EXACT(A2, C2))

یا

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

لکه په تیرو مثال کې، لومړی فورمول ریښتیني او غلط ارزښتونه وړاندې کوي، پداسې حال کې چې دویم ستاسو خپل متنونه د میچونو او توپیرونو لپاره ښکاره کوي:

د نمونې حجرې سره د حجرو لړۍ پرتله کړئ

لاندې مثالونه ښیي چې تاسو څنګه تصدیق کولی شئ چې په یوه ورکړل شوي سلسله کې ټولې حجرې ورته متن لري لکه څنګه چې د نمونې حجرې کې دي.

د قضیې غیر حساس فورمول د نمونې متن سره حجرې پرتله کولو لپاره

که د کرکټر قضیه واقعیا مهمه نده ، تاسو کولی شئ لاندې فارمول وکاروئ ترڅو حجرې نمونې سره پرتله کړئ:

د IF فنکشن منطقي ازموینې کې، تاسو دوه شمیرې پرتله کوئ:

• د حجرو ټولیز شمیرپه یو ټاکلی حد کې (د قطارونو شمیر چې د کالمونو شمیر سره ضرب شوی)، او
• د حجرو شمیر چې ورته ارزښت لري د نمونې په حجره کې (د COUNTIF فعالیت لخوا بیرته راستانه شوی).

فرض کړئ چې د نمونې متن په C2 کې دی او د پرتله کولو لپاره تارونه په A2:B6 کې دي، فورمول په لاندې ډول ځي:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

د دې لپاره چې پایلې ډیر کاروونکي کړي- دوستانه، د مثال په توګه یو څه تولید کړئ لکه "ټول میچ" او "ټول میچ نه" د ریښتیا او غلط پر ځای، د IF فنکشن وکاروئ لکه څنګه چې موږ په تیرو مثالونو کې کړی و:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

لکه څنګه چې پورته سکرین شاټ ښودل شوی، فورمول په بشپړ ډول د متن تارونو لړۍ سره سمون لري، مګر دا د شمیرو او نیټو پرتله کولو لپاره هم کارول کیدی شي.

د قضیې حساس فورمول د تارونو سره پرتله کولو لپاره د نمونې متن

که د کرکټر قضیه توپیر وکړي، تاسو کولی شئ د لاندې صف فارمولونو په کارولو سره د نمونې متن سره تارونه پرتله کړئ.

د سرچینې رینج سره چې په A2:B6 کې اوسیږي او په C2 کې د نمونې متن، فورمول لاندې شکل اخلي:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

د عادي Excel فارمولونو برعکس , د صف فورمولونه د Ctrl + Shift + Enter په فشارولو سره بشپړیږي. که په سمه توګه داخل شوی وي، Excel د سرې فورمول په { curly braces} کې تړلی دی، لکه څنګه چې په سکرین شاټ کې ښودل شوي:

څنګه د تار په واسطه دوه حجرې پرتله کړئاوږدوالی

کله ناکله تاسو غواړئ وګورئ چې په هر قطار کې د متن تارونه د حروفونو مساوي شمیر لري. د دې کار لپاره فورمول خورا ساده دی. لومړی، تاسو د LEN فنکشن په کارولو سره د دوه حجرو تار اوږدوالی ترلاسه کړئ، او بیا شمیرې پرتله کړئ.

فرض کړئ چې تارونه په A2 او B2 حجرو کې پرتله کیږي، د لاندې فورمولونو څخه یو کار واخلئ:

=LEN(A2)=LEN(B2)

یا

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

لکه څنګه چې تاسو دمخه پوهیږئ، لومړی فورمول د بولین ارزښتونه ریښتیا یا غلط راګرځوي، پداسې حال کې چې دویمه فورمول ستاسو خپلې پایلې راوړي:

لکه څنګه چې پورته په سکرین شاټ کې ښودل شوي، فورمولونه د متن تارونو او شمیرو لپاره کار کوي.

لارښوونه. که دوه ښکاري مساوي تارونه مختلف اوږدوالی بیرته راوباسي، ډیری احتمال ستونزه د مخکښ یا وروسته ځایونو په یوه یا دواړو حجرو کې وي. پدې حالت کې ، د TRIM فنکشن په کارولو سره اضافي ځایونه لرې کړئ. تفصيلي توضیحات او د فورمول مثالونه دلته موندل کیدی شي: په Excel کې د ځایونو کمولو څرنګوالی.

دوه حجرې د یو ځانګړي کرکټر د پیښو په واسطه پرتله کړئ

دا زموږ د Excel Compare Strings ټیوټوریل کې وروستۍ بیلګه ده، او دا د یو ځانګړي کار لپاره حل ښیي. فرض کړئ، تاسو د متن تارونو 2 کالمونه لرئ چې ستاسو لپاره مهم کرکټر لري. ستاسو هدف دا دی چې وګورو چې آیا په هر قطار کې دوه حجرې د ورکړل شوي کریکټر په ورته شمیر کې شتون لري.

د شیانو روښانه کولو لپاره ، لاندې په پام کې ونیسئمثال راځئ چې ووایو، تاسو د لیږل شوي امرونو دوه لیستونه لرئ (کالم B) او ترلاسه شوي (کالم C). هر قطار د یو ځانګړي توکي لپاره فرمایشونه لري، چې ځانګړی پیژندونکی په ټولو ترتیب IDs کې شامل دی او په ورته قطار کې په A کالم کې لیست شوی (مهرباني وکړئ لاندې سکرین شاټ وګورئ). تاسو غواړئ ډاډ ترلاسه کړئ چې په هر قطار کې د ورته ځانګړي ID سره د لیږل شوي او ترلاسه شوي توکو مساوي شمیر شتون لري.

د دې ستونزې د حل لپاره، د لاندې منطق سره یو فورمول ولیکئ.

• لومړی، ځانګړی پیژندونکی د SUBSTITUTE فعالیت په کارولو سره هیڅ شی سره ځای په ځای کړئ:

  SUBSTITUTE(A1, character_to_count,"")

• بیا، محاسبه کړئ چې په هر حجره کې څو ځله ځانګړی پیژندونکی څرګندیږي. د دې لپاره، د ځانګړي پیژندونکي پرته د تار اوږدوالی ترلاسه کړئ او د تار له ټول اوږدوالي څخه یې کم کړئ. دا برخه باید د 1 حجرې او 2 حجرې لپاره په انفرادي ډول ولیکل شي، د بیلګې په توګه:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  او

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• په پای کې، تاسو دا 2 شمیرې پرتله کړئ د پورتنیو برخو په مینځ کې د مساوات نښه (=) کېښودلو سره.

LEN( حجره 2 ) - LEN(SUBSTITUTE( cell 2 , character_to_count , ""))

زموږ په مثال کې، ځانګړی پیژندونکی په A2 کې دی ، او د پرتله کولو تارونه په B2 او C2 حجرو کې دي. نو، بشپړ فورمول په لاندې ډول دی:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

فارمول د ریښتیا بیرته راګرځي که چیرې حجرې B2 او C2 په A2 کې د کرکټرونو مساوي شمیر شتون ولري،بل ډول غلط. د دې لپاره چې پایلې ستاسو د کاروونکو لپاره ډیر معنی ولري، تاسو کولی شئ فورمول د IF فنکشن کې ځای په ځای کړئ:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

لکه څنګه چې تاسو پورته سکرین شاټ کې لیدلی شئ , فورمول د یو څو اضافي پیچلتیاوو سره سره په بشپړ ډول کار کوي:

• هغه کرکټر چې شمیرل کیږي (ځانګړی پیژندونکی) کیدای شي په متن کې هرچیرې ښکاره شي.
• تارونه یو متغیر شمیر لري د حروفونو او مختلف جلا کونکو لکه سیمیکولون، کوما یا خلا.

دا څنګه تاسو په Excel کې تارونه پرتله کوئ. په دې ټیوټوریل کې بحث شوي فورمولونو ته د نږدې لید لپاره، تاسو ته ښه راغلاست د Excel Compare Strings Worksheet ډاونلوډ کړئ. زه ستاسو د لوستلو لپاره مننه کوم او هیله لرم چې راتلونکې اونۍ زموږ په بلاګ کې وګورم.