Udhëzuesi tregon se si të krahasohen vargjet e tekstit në Excel për përputhje të pandjeshme ndaj shkronjave dhe përputhshmëri të saktë. Do të mësoni një numër formulash për të krahasuar dy qeliza sipas vlerave të tyre, gjatësisë së vargut ose numrit të shfaqjeve të një karakteri specifik, si dhe si të krahasoni disa qeliza.

Kur përdorni Excel për analiza e të dhënave, saktësia është shqetësimi më jetik. Informacioni i pasaktë çon në afate të humbura, tendenca të keqvlerësuara, vendime të gabuara dhe humbje të të ardhurave.

Ndërsa formulat e Excel janë gjithmonë plotësisht të vërteta, rezultatet e tyre mund të jenë të gabuara sepse disa të dhëna me të meta depërtuan në sistem. Në këtë rast, e vetmja zgjidhje është të kontrolloni saktësinë e të dhënave. Nuk është gjë e madhe të krahasosh dy qeliza me dorë, por është pothuajse e pamundur të dallosh dallimet midis qindra e mijëra vargjeve të tekstit.

Ky tutorial do t'ju mësojë se si të automatizoni detyrën e lodhshme dhe të prirur ndaj gabimeve të qelizës krahasimi dhe cilat formula janë më të mira për t'u përdorur në çdo rast të veçantë.

Si të krahasoni dy qeliza në Excel

Ka dy mënyra të ndryshme për të krahasuar vargjet në Excel në varësi të nëse kërkoni krahasim të ndjeshëm ndaj shkronjave të vogla ose të vogla.

Formulë e pandjeshme ndaj shkronjave për të krahasuar 2 qeliza

Për të krahasuar dy qeliza në Excel duke injoruar shkronjat, përdorni një formulë të thjeshtë si kjo:

=A1=B1

Ku A1 dhe B1 janë qelizat që po krahasoni. Rezultati i formulës janë vlerat Boolean TRUEdhe FALSE.

Nëse doni të nxirrni tekstet tuaja për përputhje dhe dallime, futni deklaratën e mësipërme në testin logjik të funksionit IF. Për shembull:

=IF(A1=B1, "Equal", "Not equal")

Siç e shihni në pamjen e mëposhtme të ekranit, të dyja formulat krahasojnë vargjet e tekstit, datat dhe numrat në mënyrë të barabartë:

Formula e ndjeshme ndaj shkronjave për të krahasuar vargjet në Excel

Në disa situata, mund të jetë e rëndësishme jo vetëm krahasimi i vlerave të tekstit të dy qelizave, por edhe krahasimi i shkronjave. Krahasimi i tekstit me ndjeshmëri të madhe mund të bëhet duke përdorur funksionin Excel EXACT:

Ku tekst1 dhe teksti2 janë dy qelizat që po krahasoni.

Duke supozuar se vargjet tuaja janë në qelizat A2 dhe B2, formula shkon si më poshtë:

=EXACT(A2, B2)

Si rezultat, ju merrni TRUE për vargjet e tekstit që përputhen saktësisht duke përfshirë rastin për çdo karakter, FALSE ndryshe.

Nëse dëshironi që funksioni EXACT të japë disa rezultate të tjera, futeni atë në një formulë IF dhe shkruani tekstin tuaj për value_if_true dhe value_if_false argumente:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Pamja e mëposhtme e ekranit tregon rezultatet e krahasimit të vargjeve të ndjeshme ndaj shkronjave në Excel:

Si të krahasoni qelizat e shumta në Excel

Për të krahasuar më shumë se 2 qeliza me radhë, përdorni formulat e diskutuara në shembujt e mësipërm në kombinim me operatorin AND. Detajet e plota vijojnë më poshtë.

Formulë e pandjeshme ndaj rasteve për t'u krahasuarmë shumë se 2 qeliza

Në varësi të mënyrës se si dëshironi të shfaqni rezultatet, përdorni një nga formulat e mëposhtme:

=AND(A2=B2, A2=C2)

ose

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

Formula AND kthen TRUE nëse të gjitha qelizat përmbajnë të njëjtën vlerë, FALSE nëse ndonjë vlerë është e ndryshme. Formula IF nxjerr etiketat që shkruani në të, " E barabartë " dhe " Jo e barabartë " në këtë shembull.

Siç tregohet në pamjen e mëposhtme të ekranit, formula funksionon në mënyrë të përsosur me çdo lloj të dhënash - tekst, data dhe vlera numerike:

Formulë e ndjeshme ndaj shkronjave të vogla për të krahasuar tekstin në disa qeliza

Për të krahasuar vargje të shumta me njëri-tjetrin për të parë nëse përputhen saktësisht, përdorni formulat e mëposhtme:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Ose

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Si në shembullin e mëparshëm, i pari formula jep vlerat TRUE dhe FALSE, ndërsa e dyta shfaq tekstet tuaja për përputhje dhe dallime:

Krahasoni një varg qelizash me një qelizë mostër

Shembujt e mëposhtëm tregojnë se si mund të verifikoni që të gjitha qelizat në një gamë të caktuar përmbajnë të njëjtin tekst si në një qelizë të mostrës.

Formulë e pandjeshme ndaj shkronjave për të krahasuar qelizat me një tekst mostër

Nëse rasti i karakterit nuk ka vërtet rëndësi, mund të përdorni formulën e mëposhtme për të krahasuar qelizat me një mostër:

Në testin logjik të funksionit IF, ju krahasoni dy numra:

• Numri i përgjithshëm i qelizavenë një interval të caktuar (numri i rreshtave shumëzuar me numrin e kolonave) dhe
• Numri i qelizave që përmbajnë të njëjtën vlerë si në qelizën e mostrës (kthyer nga funksioni COUNTIF).

Duke supozuar se teksti i mostrës është në C2 dhe vargjet për t'u krahasuar janë në rangun A2:B6, formula shkon si më poshtë:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Për t'i bërë rezultatet më të përdoruesit- miqësore, d.m.th. nxirr diçka si "Të gjitha përputhen" dhe "Jo të gjitha përputhen" në vend të TRUE dhe FALSE, përdorni funksionin IF siç bëmë në shembujt e mëparshëm:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Siç tregohet në pamjen e mësipërme të ekranit, formula përputhet në mënyrë të përsosur me një sërë vargjesh teksti, por mund të përdoret gjithashtu për të krahasuar numrat dhe datat.

Formula e ndjeshme ndaj shkronjave të vogla për të krahasuar vargjet me një mostër teksti

Nëse rasti i shkronjave bën një ndryshim, mund të krahasoni vargjet me tekstin e mostrës duke përdorur formulat e mëposhtme të grupit.

Me diapazonin e burimit që ndodhet në A2:B6 dhe tekstin e mostrës në C2, formula merr formën e mëposhtme:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Ndryshe nga formulat e zakonshme të Excel , formulat e grupeve plotësohen duke shtypur Ctrl + Shift + Enter. Nëse futet saktë, Excel e mbyll formulën e grupit në {kllapa kaçurrelë}, siç tregohet në pamjen e ekranit:

Si të krahasoni dy qeliza me varggjatësi

Ndonjëherë mund të dëshironi të kontrolloni nëse vargjet e tekstit në çdo rresht përmbajnë një numër të barabartë karakteresh. Formula për këtë detyrë është shumë e thjeshtë. Së pari, ju merrni gjatësinë e vargut të dy qelizave duke përdorur funksionin LEN dhe më pas krahasoni numrat.

Duke supozuar se vargjet që do të krahasohen janë në qelizat A2 dhe B2, përdorni njërën nga formulat e mëposhtme:

=LEN(A2)=LEN(B2)

Ose

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Siç e dini tashmë, formula e parë kthen vlerat Boolean TRUE ose FALSE, ndërsa formula e dytë nxjerr rezultatet tuaja:

Siç tregohet në pamjen e mësipërme, formulat funksionojnë si për vargjet e tekstit ashtu edhe për numrat.

Këshillë. Nëse dy vargje në dukje të barabarta kthejnë gjatësi të ndryshme, me shumë mundësi problemi është në hapësirat kryesore ose pastaj hapësirat në njërën ose të dyja qelizat. Në këtë rast, hiqni hapësirat shtesë duke përdorur funksionin TRIM. Shpjegimet e hollësishme dhe shembujt e formulës mund të gjenden këtu: Si të shkurtohen hapësirat në Excel.

Krahasoni dy qeliza sipas dukurive të një karakteri specifik

Ky është shembulli i fundit në tutorialin tonë Excel Compare Strings dhe tregon një zgjidhje për një detyrë mjaft specifike. Supozoni se keni 2 kolona vargjesh teksti që përmbajnë një karakter të rëndësishëm për ju. Qëllimi juaj është të kontrolloni nëse dy qeliza në çdo rresht përmbajnë të njëjtin numër dukurish të një karakteri të caktuar.

Për t'i bërë gjërat më të qarta, merrni parasysh sa vijonshembull. Le të themi, ju keni dy lista porosish të dërguara (kolona B) dhe të marra (kolona C). Çdo rresht përmban porosi për një artikull specifik, identifikuesi unik i të cilit përfshihet në të gjitha ID-të e porosive dhe renditet në të njëjtin rresht në kolonën A (ju lutemi shikoni pamjen e ekranit më poshtë). Ju dëshironi të siguroheni që çdo rresht të përmbajë një numër të barabartë artikujsh të dërguar dhe të marrë me atë ID specifike.

Për të zgjidhur këtë problem, shkruani një formulë me logjikën e mëposhtme.

• Së pari, zëvendësoni identifikuesin unik me asgjë duke përdorur funksionin SUBSTITUTE:

  SUBSTITUTE(A1, character_to_count,"")

• Më pas, llogaritni sa herë identifikuesi unik shfaqet në secilën qelizë. Për këtë, merrni gjatësinë e vargut pa identifikuesin unik dhe zbriteni atë nga gjatësia totale e vargut. Kjo pjesë do të shkruhet individualisht për qelizën 1 dhe qelizën 2, për shembull:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  dhe

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Së fundi, krahasoni këta 2 numra duke vendosur shenjën e barazisë (=) ndërmjet pjesëve të mësipërme.

LEN( qeliza 2 ) - LEN(SUBSTITUTE( qeliza 2 , karakteri_për t'u numëruar , ""))

Në shembullin tonë, identifikuesi unik është në A2 , dhe vargjet për të krahasuar janë në qelizat B2 dhe C2. Pra, formula e plotë është si më poshtë:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Formula kthen E VËRTETË nëse qelizat B2 dhe C2 përmbajnë një numër të barabartë dukurish të karakterit në A2,E rreme ndryshe. Për t'i bërë rezultatet më kuptimplote për përdoruesit tuaj, mund të futni formulën në funksionin IF:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Siç mund ta shihni në pamjen e mësipërme. , formula funksionon në mënyrë perfekte pavarësisht nga disa ndërlikime shtesë:

• Karakteri që do të numërohet (identifikuesi unik) mund të shfaqet kudo në një varg teksti.
• Rreshtat përmbajnë një numër të ndryshueshëm të karaktereve dhe ndarësve të ndryshëm si pikëpresje, presje ose hapësirë.

Kështu i krahasoni vargjet në Excel. Për të parë më nga afër formulat e diskutuara në këtë tutorial, jeni të mirëpritur të shkarkoni Excel Excel Compare Strings Worksheet. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën e ardhshme.