Hướng dẫn chỉ ra cách so sánh các chuỗi văn bản trong Excel để khớp chính xác và không phân biệt chữ hoa chữ thường. Bạn sẽ tìm hiểu một số công thức để so sánh hai ô theo giá trị của chúng, độ dài chuỗi hoặc số lần xuất hiện của một ký tự cụ thể cũng như cách so sánh nhiều ô.

Khi sử dụng Excel cho phân tích dữ liệu, độ chính xác là mối quan tâm quan trọng nhất. Thông tin không chính xác dẫn đến trễ hạn, đánh giá sai xu hướng, quyết định sai và mất doanh thu.

Mặc dù các công thức Excel luôn hoàn toàn đúng nhưng kết quả của chúng có thể sai do một số dữ liệu sai sót đã xâm nhập vào hệ thống. Trong trường hợp này, biện pháp khắc phục duy nhất là kiểm tra độ chính xác của dữ liệu. Việc so sánh hai ô theo cách thủ công không phải là vấn đề lớn, nhưng gần như không thể phát hiện ra sự khác biệt giữa hàng trăm và hàng nghìn chuỗi văn bản.

Hướng dẫn này sẽ hướng dẫn bạn cách tự động hóa nhiệm vụ tẻ nhạt và dễ mắc lỗi của ô so sánh và công thức nào là tốt nhất để sử dụng trong từng trường hợp cụ thể.

Cách so sánh hai ô trong Excel

Có hai cách khác nhau để so sánh các chuỗi trong Excel tùy thuộc vào cho dù bạn muốn so sánh phân biệt chữ hoa chữ thường hay không phân biệt chữ hoa chữ thường.

Công thức không phân biệt chữ hoa chữ thường để so sánh 2 ô

Để so sánh hai ô trong Excel bỏ qua chữ hoa chữ thường, hãy sử dụng một công thức đơn giản như sau:

=A1=B1

Trong đó A1 và B1 là các ô bạn đang so sánh. Kết quả của công thức là các giá trị Boolean TRUEvà FALSE.

Nếu bạn muốn xuất văn bản của riêng mình để tìm sự trùng khớp và khác biệt, hãy nhúng câu lệnh trên vào bài kiểm tra logic của hàm IF. Ví dụ:

=IF(A1=B1, "Equal", "Not equal")

Như bạn thấy trong ảnh chụp màn hình bên dưới, cả hai công thức đều so sánh chuỗi văn bản, ngày và số tốt như nhau:

Công thức phân biệt chữ hoa chữ thường để so sánh các chuỗi trong Excel

Trong một số trường hợp, điều quan trọng không chỉ là so sánh giá trị văn bản của hai ô mà còn so sánh trường hợp ký tự. So sánh văn bản phân biệt chữ hoa chữ thường có thể được thực hiện bằng cách sử dụng hàm EXACT của Excel:

Trong đó text1 và text2 là hai ô bạn đang so sánh.

Giả sử các chuỗi của bạn nằm trong các ô A2 và B2, công thức sẽ như sau:

=EXACT(A2, B2)

Kết quả là bạn nhận được TRUE đối với các chuỗi văn bản khớp chính xác bao gồm cả trường hợp của từng ký tự, ngược lại là FALSE.

Nếu bạn muốn hàm EXACT cung cấp một số kết quả khác, hãy nhúng hàm đó vào công thức IF và nhập văn bản của riêng bạn cho value_if_true và value_if_false đối số:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Ảnh chụp màn hình sau đây hiển thị kết quả so sánh chuỗi phân biệt chữ hoa chữ thường trong Excel:

Cách so sánh nhiều ô trong Excel

Để so sánh nhiều hơn 2 ô trong một hàng, hãy sử dụng các công thức được thảo luận trong các ví dụ trên kết hợp với toán tử AND. Chi tiết đầy đủ theo bên dưới.

Công thức không phân biệt chữ hoa chữ thường để so sánhnhiều hơn 2 ô

Tùy thuộc vào cách bạn muốn hiển thị kết quả, hãy sử dụng một trong các công thức sau:

=AND(A2=B2, A2=C2)

hoặc

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

Công thức AND trả về TRUE nếu tất cả các ô chứa cùng một giá trị, FALSE nếu bất kỳ giá trị nào khác. Công thức IF xuất các nhãn mà bạn nhập vào đó, " Bằng " và " Không bằng " trong ví dụ này.

Như minh họa trong ảnh chụp màn hình bên dưới, công thức công thức hoạt động hoàn hảo với mọi loại dữ liệu - văn bản, ngày tháng và giá trị số:

Công thức phân biệt chữ hoa chữ thường để so sánh văn bản trong một số ô

Để so sánh nhiều chuỗi với nhau để xem chúng có khớp chính xác hay không, hãy sử dụng các công thức sau:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Hoặc

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Giống như trong ví dụ trước, số đầu tiên công thức cung cấp các giá trị TRUE và FALSE, trong khi công thức thứ hai hiển thị văn bản của riêng bạn để biết các giá trị trùng khớp và khác biệt:

So sánh một dải ô với một ô mẫu

Các ví dụ sau đây cho thấy cách bạn có thể xác minh rằng tất cả các ô trong một phạm vi nhất định chứa cùng một văn bản như trong một ô mẫu.

Công thức phân biệt chữ hoa chữ thường để so sánh các ô với văn bản mẫu

Nếu trường hợp ký tự không thực sự quan trọng, bạn có thể sử dụng công thức sau để so sánh các ô với một mẫu:

Trong bài kiểm tra logic của hàm IF, bạn so sánh hai số:

• Tổng số ôtrong một phạm vi đã chỉ định (số hàng nhân với số cột) và
• Số ô chứa giá trị giống như trong ô mẫu (được trả về bởi hàm COUNTIF).

Giả sử văn bản mẫu ở C2 và các chuỗi cần so sánh nằm trong phạm vi A2:B6, công thức sẽ như sau:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Để làm cho kết quả phù hợp hơn với người dùng- thân thiện, tức là xuất ra nội dung như "Tất cả trùng khớp" và "Không phải tất cả trùng khớp" thay vì TRUE và FALSE, hãy sử dụng hàm IF như chúng ta đã làm trong các ví dụ trước:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Như minh họa trong ảnh chụp màn hình ở trên, công thức này hoàn toàn phù hợp với một loạt các chuỗi văn bản, nhưng nó cũng có thể được sử dụng để so sánh các số và ngày.

Công thức phân biệt chữ hoa chữ thường để so sánh các chuỗi với một văn bản mẫu

Nếu trường hợp ký tự tạo ra sự khác biệt, bạn có thể so sánh các chuỗi với văn bản mẫu bằng cách sử dụng các công thức mảng sau.

Với phạm vi nguồn nằm trong A2:B6 và văn bản mẫu trong C2, công thức có dạng sau:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Không giống như các công thức Excel thông thường , công thức mảng được hoàn thành bằng cách nhấn Ctrl + Shift + Enter . Nếu nhập đúng, Excel sẽ đặt công thức mảng trong {dấu ngoặc nhọn}, như minh họa trong ảnh chụp màn hình:

Cách so sánh hai ô theo chuỗiđộ dài

Đôi khi bạn có thể muốn kiểm tra xem các chuỗi văn bản trong mỗi hàng có chứa số lượng ký tự bằng nhau hay không. Công thức cho nhiệm vụ này rất đơn giản. Trước tiên, bạn lấy độ dài chuỗi của hai ô bằng cách sử dụng hàm LEN, sau đó so sánh các số.

Giả sử các chuỗi được so sánh nằm trong ô A2 và B2, hãy sử dụng một trong hai công thức sau:

=LEN(A2)=LEN(B2)

Hoặc

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Như bạn đã biết, công thức đầu tiên trả về giá trị Boolean TRUE hoặc FALSE, trong khi công thức thứ hai đưa ra kết quả của riêng bạn:

Như minh họa trong ảnh chụp màn hình ở trên, các công thức hoạt động cho chuỗi văn bản cũng như số.

Mẹo. Nếu hai chuỗi có vẻ bằng nhau trả về độ dài khác nhau, rất có thể vấn đề nằm ở dẫn đầu hoặc dấu cách dấu cách trong một hoặc cả hai ô. Trong trường hợp này, hãy xóa khoảng trắng thừa bằng hàm TRIM. Bạn có thể tìm thấy giải thích chi tiết và các ví dụ về công thức tại đây: Cách cắt bớt khoảng trắng trong Excel.

So sánh hai ô theo số lần xuất hiện của một ký tự cụ thể

Đây là ví dụ cuối cùng trong hướng dẫn So sánh chuỗi Excel của chúng tôi và nó cho thấy giải pháp cho một nhiệm vụ khá cụ thể. Giả sử, bạn có 2 cột chuỗi văn bản chứa một ký tự quan trọng đối với bạn. Mục tiêu của bạn là kiểm tra xem hai ô trong mỗi hàng có chứa cùng số lần xuất hiện của một ký tự đã cho hay không.

Để hiểu rõ hơn, hãy xem xét những điều sauthí dụ. Giả sử bạn có hai danh sách đơn hàng đã giao (cột B) và đã nhận (cột C). Mỗi hàng chứa các đơn đặt hàng cho một mặt hàng cụ thể, có số nhận dạng duy nhất được bao gồm trong tất cả các ID đơn đặt hàng và được liệt kê trong cùng một hàng trong cột A (vui lòng xem ảnh chụp màn hình bên dưới). Bạn muốn đảm bảo rằng mỗi hàng chứa số lượng mặt hàng được giao và nhận bằng nhau với ID cụ thể đó.

Để giải quyết vấn đề này, hãy viết một công thức theo logic sau.

• Đầu tiên, thay thế mã định danh duy nhất bằng không có gì bằng hàm SUBSTITUTE:

  SUBSTITUTE(A1, character_to_count,"")

• Sau đó, tính số lần mã định danh duy nhất xuất hiện trong mỗi ô. Đối với điều này, hãy lấy độ dài chuỗi không có mã định danh duy nhất và trừ nó khỏi tổng độ dài của chuỗi. Phần này viết riêng cho ô 1 và ô 2, ví dụ:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  Xem thêm: Hàm Excel XLOOKUP với các ví dụ về công thức

  và

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Cuối cùng bạn so sánh 2 số này bằng cách đặt dấu đẳng thức (=) ở giữa các phần trên.

LEN( cell 2 ) - LEN(SUBSTITUTE( cell 2 , character_to_count , ""))

Trong ví dụ của chúng tôi, mã định danh duy nhất nằm trong A2 , và các chuỗi để so sánh nằm trong các ô B2 và C2. Vì vậy, công thức hoàn chỉnh như sau:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Công thức trả về TRUE nếu ô B2 và C2 chứa số lần xuất hiện của ký tự trong ô A2 bằng nhau,FALSE ngược lại. Để làm cho kết quả có ý nghĩa hơn đối với người dùng của bạn, bạn có thể nhúng công thức vào hàm IF:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Như bạn có thể thấy trong ảnh chụp màn hình ở trên , công thức hoạt động hoàn hảo mặc dù có một số vấn đề phức tạp khác:

• Ký tự được tính (số nhận dạng duy nhất) có thể xuất hiện ở bất kỳ đâu trong chuỗi văn bản.
• Các chuỗi chứa một biến số ký tự và các dấu phân tách khác nhau như dấu chấm phẩy, dấu phẩy hoặc khoảng trắng.

Đây là cách bạn so sánh các chuỗi trong Excel. Để xem kỹ hơn các công thức được thảo luận trong hướng dẫn này, bạn có thể tải xuống Bảng tính so sánh chuỗi Excel. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới.