이 자습서에서는 대소문자를 구분하지 않고 정확히 일치하도록 Excel에서 텍스트 문자열을 비교하는 방법을 보여줍니다. 값, 문자열 길이 또는 특정 문자의 발생 횟수를 기준으로 두 셀을 비교하는 여러 공식과 여러 셀을 비교하는 방법을 배웁니다.

Excel을 사용하는 경우 데이터 분석, 정확성이 가장 중요한 관심사입니다. 잘못된 정보는 마감일을 놓치고, 추세를 잘못 판단하고, 잘못된 결정을 내리고, 수익 손실로 이어집니다.

Excel 공식은 항상 완벽하게 사실이지만 일부 결함이 있는 데이터가 시스템에 침투하여 결과가 잘못될 수 있습니다. 이 경우 유일한 해결책은 데이터의 정확성을 확인하는 것입니다. 두 개의 셀을 수동으로 비교하는 것은 큰 문제가 아니지만 수백, 수천 개의 텍스트 문자열 간의 차이점을 찾아내는 것은 거의 불가능합니다.

이 자습서에서는 지루하고 오류가 발생하기 쉬운 셀 작업을 자동화하는 방법을 알려줍니다. 비교 및 각각의 특정 경우에 사용하는 가장 적합한 수식.

Excel에서 두 셀을 비교하는 방법

Excel에서 문자열을 비교하는 두 가지 방법은 대소문자 구분 여부 비교.

두 개의 셀을 비교하는 대소문자 구분 수식

대소문자를 무시하고 Excel에서 두 셀을 비교하려면 다음과 같은 간단한 수식을 사용하십시오.

=A1=B1

여기서 A1과 B1은 비교하려는 셀입니다. 수식의 결과는 부울 값 TRUE입니다.및 FALSE.

일치 및 차이점에 대한 고유한 텍스트를 출력하려면 IF 함수의 논리 테스트에 위의 명령문을 포함하십시오. 예:

=IF(A1=B1, "Equal", "Not equal")

아래 스크린샷에서 볼 수 있듯이 두 수식은 텍스트 문자열, 날짜 및 숫자를 동일하게 잘 비교합니다.

Excel에서 문자열을 비교하는 대소문자 구분 공식

경우에 따라 두 셀의 텍스트 값을 비교하는 것뿐만 아니라 문자 대소문자를 비교하는 것도 중요할 수 있습니다. 대소문자 구분 텍스트 비교는 Excel EXACT 함수를 사용하여 수행할 수 있습니다.

여기서 text1 및 text2 는 비교하려는 두 셀입니다.

문자열이 셀 A2와 B2에 있다고 가정하면 수식은 다음과 같습니다.

=EXACT(A2, B2)

결과적으로 텍스트 문자열이 대소문자를 포함하여 정확히 일치하면 TRUE가 됩니다. 그렇지 않으면 FALSE.

EXACT 함수가 다른 결과를 제공하도록 하려면 함수를 IF 수식에 포함하고 value_if_true 및 value_if_false<에 대한 고유한 텍스트를 입력하십시오. 2> arguments:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

다음 스크린샷은 Excel에서 대/소문자 구분 문자열 비교 결과를 보여줍니다.

방법 Excel에서 여러 셀 비교

연속으로 2개 이상의 셀을 비교하려면 AND 연산자와 함께 위의 예에서 설명한 수식을 사용합니다. 자세한 내용은 다음과 같습니다.

대소문자를 구분하지 않는 비교 수식3개 이상의 셀

결과를 표시하려는 방법에 따라 다음 수식 중 하나를 사용합니다.

=AND(A2=B2, A2=C2)

또는

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

AND 수식은 모든 셀이 동일한 값을 포함하면 TRUE를 반환하고 다른 값이 있으면 FALSE를 반환합니다. IF 수식은 이 예에서 " 같음 " 및 " 같지 않음 "과 같이 입력한 레이블을 출력합니다.

아래 스크린샷에서 볼 수 있듯이 수식은 텍스트, 날짜 및 숫자 값과 같은 모든 데이터 유형과 완벽하게 작동합니다.

여러 셀의 텍스트를 비교하는 대소문자 구분 수식

여러 문자열을 비교하려면 정확히 일치하는지 확인하려면 다음 수식을 사용하십시오.

=AND(EXACT(A2,B2), EXACT(A2, C2))

또는

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

이전 예와 마찬가지로 첫 번째 수식은 TRUE 및 FALSE 값을 제공하는 반면 두 번째 수식은 일치 및 차이점에 대한 고유한 텍스트를 표시합니다.

셀 범위를 샘플 셀과 비교

다음 예는 지정된 범위의 모든 셀에 샘플 셀과 동일한 텍스트가 포함되어 있는지 확인하는 방법을 보여줍니다.

셀을 샘플 텍스트와 비교하는 대소문자 구분 수식

대소문자는 중요하지 않으므로 다음 수식을 사용하여 셀을 샘플과 비교할 수 있습니다.

IF 함수의 논리 테스트에서 두 숫자를 비교합니다.

• 총 셀 수지정된 범위(행 수에 열 수를 곱한 값) 및
• 샘플 셀과 동일한 값을 포함하는 셀 수(COUNTIF 함수에 의해 반환됨).

샘플 텍스트가 C2에 있고 비교할 문자열이 A2:B6 범위에 있다고 가정하면 공식은 다음과 같습니다.

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

결과를 좀 더 사용자에게 즉, TRUE 및 FALSE 대신 "모두 일치" 및 "모두 일치하지 않음"과 같은 것을 출력하려면 이전 예제에서와 같이 IF 함수를 사용하십시오.

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

위의 스크린샷과 같이 수식은 다양한 텍스트 문자열을 완벽하게 처리하지만 숫자와 날짜를 비교하는 데에도 사용할 수 있습니다.

문자열을 비교하는 대소문자 구분 수식 샘플 텍스트

대소문자가 다를 경우 다음 배열 수식을 사용하여 문자열을 샘플 텍스트와 비교할 수 있습니다.

원본 범위가 A2:B6에 있고 샘플 텍스트가 C2에 있는 경우 수식의 모양은 다음과 같습니다.

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

일반 Excel 수식과 달리 , 배열 수식은 Ctrl + Shift + Enter 를 누르면 완성됩니다. 올바르게 입력한 경우 Excel은 스크린샷에 표시된 것처럼 배열 수식을 {중괄호}로 묶습니다.

문자열로 두 셀을 비교하는 방법length

때로는 각 행의 텍스트 문자열에 동일한 수의 문자가 포함되어 있는지 확인해야 할 수 있습니다. 이 작업의 공식은 매우 간단합니다. 먼저 LEN 함수를 사용하여 두 셀의 문자열 길이를 구한 다음 숫자를 비교합니다.

비교할 문자열이 셀 A2와 B2에 있다고 가정하면 다음 수식 중 하나를 사용합니다.

=LEN(A2)=LEN(B2)

또는

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

이미 알고 있듯이 첫 번째 수식은 부울 값 TRUE 또는 FALSE를 반환하는 반면 두 번째 수식은 자체 결과를 출력합니다.

위의 스크린샷에서 볼 수 있듯이 수식은 숫자뿐만 아니라 텍스트 문자열에도 적용됩니다.

팁. 두 개의 겉보기에 동일한 문자열이 다른 길이를 반환하는 경우 문제는 하나 또는 두 셀의 leading 또는 trailing spaces 에 있을 가능성이 큽니다. 이 경우 TRIM 함수를 사용하여 여분의 공백을 제거하십시오. 자세한 설명과 수식 예제는 Excel에서 공백을 자르는 방법에서 찾을 수 있습니다.

특정 문자 발생으로 두 셀 비교

이것은 Excel 문자열 비교 자습서의 마지막 예이며 다소 구체적인 작업에 대한 솔루션을 보여줍니다. 중요한 문자가 포함된 텍스트 문자열 열이 2개 있다고 가정합니다. 귀하의 목표는 각 행의 두 셀에 주어진 문자가 동일한 횟수로 포함되어 있는지 확인하는 것입니다.

더 명확하게 하려면 다음을 고려하십시오.예시. 배송된 주문 목록(B 열)과 받은 주문 목록(C 열)이 두 개 있다고 가정해 보겠습니다. 각 행에는 특정 항목에 대한 주문이 포함되며 고유 식별자는 모든 주문 ID에 포함되며 A 열의 동일한 행에 나열됩니다(아래 스크린샷 참조). 각 행에 특정 ID를 가진 동일한 수의 배송 및 수령 항목이 포함되어 있는지 확인하려고 합니다.

이 문제를 해결하려면 다음 논리로 수식을 작성합니다.

• 먼저 SUBSTITUTE 함수를 사용하여 고유 식별자를 아무 것도 없는 것으로 바꿉니다.

  SUBSTITUTE(A1, character_to_count,"")

• 그런 다음 고유 식별자가 각 셀에 몇 번 나타나는지 계산합니다. 이를 위해 고유 식별자가 없는 문자열 길이를 가져와 전체 문자열 길이에서 뺍니다. 이 부분은 셀 1과 셀 2에 대해 개별적으로 작성해야 합니다. 예:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  및

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• 마지막으로 이 두 숫자를 비교합니다 위 부분 사이에 등호(=)를 배치합니다.

LEN( cell 2 ) - LEN(SUBSTITUTE( cell 2 , character_to_count , ""))

이 예에서 고유 식별자는 A2에 있습니다. , 비교할 문자열은 셀 B2와 C2에 있습니다. 따라서 완전한 수식은 다음과 같습니다.

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

B2 셀과 C2 셀이 A2에 있는 문자의 동일한 수를 포함하는 경우 이 수식은 TRUE를 반환합니다.그렇지 않으면 거짓입니다. 사용자에게 보다 의미 있는 결과를 제공하기 위해 IF 함수에 수식을 포함할 수 있습니다.

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

위 스크린샷에서 볼 수 있듯이 , 수식은 몇 가지 추가적인 복잡성에도 불구하고 완벽하게 작동합니다.

• 계산할 문자(고유 식별자)는 텍스트 문자열의 어디에나 나타날 수 있습니다.
• 문자열에는 변수 번호가 포함되어 있습니다. 문자 및 세미콜론, 쉼표 또는 공백과 같은 다른 구분 기호.

이것은 Excel에서 문자열을 비교하는 방법입니다. 이 자습서에서 설명하는 수식을 자세히 살펴보려면 Excel 문자열 비교 워크시트를 다운로드하세요. 읽어 주셔서 감사합니다. 다음 주 블로그에서 뵙겠습니다.