O'quv qo'llanma Excelda matn satrlarini katta-kichik harflarga sezgir bo'lmagan va aniq moslik uchun qanday solishtirishni ko'rsatadi. Siz ikkita katakchani qiymatlari, satr uzunligi yoki ma'lum bir belgining takrorlanish soni bo'yicha taqqoslash uchun bir qator formulalarni, shuningdek, bir nechta katakchalarni qanday solishtirishni o'rganasiz.

Exceldan foydalanganda ma'lumotlarni tahlil qilish, aniqlik eng muhim masala. Noto'g'ri ma'lumotlar o'tkazib yuborilgan muddatlarga, noto'g'ri baholangan tendentsiyalarga, noto'g'ri qarorlar va yo'qolgan daromadlarga olib keladi.

Excel formulalari har doim to'liq to'g'ri bo'lsa-da, ularning natijalari noto'g'ri bo'lishi mumkin, chunki ba'zi noto'g'ri ma'lumotlar tizimga kirib ketgan. Bunday holda, yagona chora ma'lumotlarning to'g'riligini tekshirishdir. Ikki katakchani qo‘lda solishtirish unchalik katta ish emas, lekin yuzlab va minglab matn qatorlari orasidagi farqni aniqlashning iloji yo‘q.

Ushbu qo‘llanma sizga hujayraning zerikarli va xatoga yo‘l qo‘yadigan vazifasini qanday avtomatlashtirishni o‘rgatadi. solishtirish va har bir alohida holatda qaysi formulalardan foydalanish yaxshiroq.

Excelda ikkita katakchani qanday solishtirish mumkin

Excelda satrlarni solishtirishning ikki xil usuli mavjud. katta-kichik harf sezgir yoki katta-kichik kichik harflar bilan solishtirishni xohlaysizmi.

2 katakchani solishtirish uchun katta-kichik harflarni sezgir bo'lmagan formula

Excelda katta-kichik harflarni hisobga olmagan holda ikkita katakchani solishtirish uchun quyidagi oddiy formuladan foydalaning:

=A1=B1

Bu erda A1 va B1 - siz solishtirayotgan hujayralar. Formulaning natijasi mantiqiy qiymatlar TRUEva FALSE.

Agar siz moslik va farqlar uchun o'zingizning matnlaringizni chiqarmoqchi bo'lsangiz, yuqoridagi bayonotni IF funktsiyasining mantiqiy testiga kiriting. Masalan:

=IF(A1=B1, "Equal", "Not equal")

Quyidagi skrinshotda ko'rib turganingizdek, ikkala formula ham matn qatorlari, sana va raqamlarni bir xil darajada taqqoslaydi:

Excel'da satrlarni solishtirish uchun katta-kichik harf sezgir formulasi

Ba'zi holatlarda nafaqat ikkita katakchaning matn qiymatlarini solishtirish, balki belgilar registrini solishtirish ham muhim bo'lishi mumkin. Katta-kichik harflarni hisobga olgan holda matn solishtirish Excel EXACT funksiyasi yordamida amalga oshirilishi mumkin:

Bu yerda matn1 va matn2 siz solishtirayotgan ikkita katakdir.

Sizning satrlaringiz A2 va B2 katakchalarida bo'lsa, formula quyidagicha bo'ladi:

=EXACT(A2, B2)

Natijada siz matn satrlari katta-kichik harf bilan to'liq mos kelishi uchun TRUE olasiz. har bir belgi uchun FALSE, aks holda.

Agar siz EXACT funksiyasi boshqa natijalarni berishini istasangiz, uni IF formulasiga kiriting va agar_to'g'ri_qiymat va agar_noto'g'ri qiymat argumentlar:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Quyidagi skrinshotda Excelda katta-kichik harflar bilan taqqoslash natijalari ko'rsatilgan:

Qanday qilib Excelda bir nechta katakchalarni solishtirish

Ketma-ket 2 dan ortiq katakchalarni solishtirish uchun yuqoridagi misollarda muhokama qilingan formulalardan AND operatori bilan birgalikda foydalaning. Toʻliq maʼlumotlar quyida keltirilgan.

Taqqoslash uchun katta-kichik harflarni sezmaydigan formula2 dan ortiq katakchalar

Natijalarni qanday ko'rsatishni xohlayotganingizga qarab, quyidagi formulalardan birini ishlating:

=AND(A2=B2, A2=C2)

yoki

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

Agar barcha hujayralar bir xil qiymatga ega bo'lsa, AND formulasi TRUE qiymatini, har qanday qiymat boshqacha bo'lsa, FALSEni qaytaradi. IF formulasi siz kiritgan teglarni chiqaradi, bu misolda " Teng " va " Teng emas ".

Quyidagi skrinshotda ko'rsatilganidek, formula har qanday ma'lumotlar turlari bilan mukammal ishlaydi - matn, sana va raqamli qiymatlar:

Bir nechta kataklardagi matnni solishtirish uchun katta-kichik harflarga sezgir formula

Bir nechta satrlarni solishtirish uchun bir-biriga mos kelishini bilish uchun quyidagi formulalardan foydalaning:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Yoki

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Avvalgi misoldagi kabi, birinchi formula TRUE va FALSE qiymatlarini beradi, ikkinchisi esa moslik va farqlar uchun o'z matnlaringizni ko'rsatadi:

Bir qator katakchalarni namunali katak bilan solishtiring

Quyidagi misollar berilgan diapazondagi barcha hujayralar namunaviy katakdagi kabi bir xil matnni o‘z ichiga olganligini qanday tekshirishingiz mumkinligini ko‘rsatadi.

Yacheykalarni namunali matn bilan solishtirish uchun katta-kichik harflarni sezmaydigan formula

Agar belgilar kattaligi muhim emas, siz hujayralarni namunaga solishtirish uchun quyidagi formuladan foydalanishingiz mumkin:

IF funktsiyasining mantiqiy testida siz ikkita raqamni solishtirasiz:

• Hujayralarning umumiy sonibelgilangan diapazonda (satrlar soni ustunlar soniga ko'paytiriladi) va
• Namunaviy yacheykadagi bilan bir xil qiymatga ega bo'lgan katakchalar soni (COUNTIF funktsiyasi bilan qaytariladi).

Namunaviy matn C2 da va taqqoslanadigan satrlar A2:B6 oralig'ida bo'lsa, formula quyidagicha bo'ladi:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Natijalarni yanada foydalanuvchi qilish uchun- do'stona, ya'ni TRUE va FALSE o'rniga "Hammasi mos emas" va "Hammasi mos emas" kabi narsalarni chiqaring, oldingi misollardagi kabi IF funktsiyasidan foydalaning:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Yuqoridagi skrinshotda ko'rsatilganidek, formula bir qator matn qatorlari bilan mukammal tarzda ishlay oladi, lekin undan raqamlar va sanalarni solishtirish uchun ham foydalanish mumkin.

Stringlarni katta-kichik harflar bilan taqqoslash uchun formuladan foydalanish mumkin. namuna matni

Agar belgilar katta-kichikligi farq qilsa, quyidagi massiv formulalari yordamida satrlarni namunali matn bilan solishtirishingiz mumkin.

Manba diapazoni A2:B6 va namuna matni C2da joylashgan bo'lsa, formula quyidagi shaklni oladi:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Oddiy Excel formulalaridan farqli o'laroq , massiv formulalari Ctrl + Shift + Enter tugmalarini bosib to'ldiriladi. To'g'ri kiritilsa, Excel skrinshotda ko'rsatilganidek, massiv formulasini {jingalak qavslar} ichiga oladi:

Ikki katakchani qator bo'yicha qanday solishtirish mumkinuzunlik

Ba'zan siz har bir satrdagi matn satrlarida teng miqdordagi belgilar mavjudligini tekshirishingiz mumkin. Ushbu vazifaning formulasi juda oddiy. Birinchidan, LEN funksiyasidan foydalanib, ikkita katakchaning satr uzunligini olasiz, so‘ngra raqamlarni solishtirasiz.

Taqqoslanadigan satrlar A2 va B2 kataklarida bo‘lsa, quyidagi formulalardan birini ishlating:

=LEN(A2)=LEN(B2)

Yoki

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Ma'lumki, birinchi formula mantiqiy qiymatlarni TRUE yoki FALSE qaytaradi, ikkinchi formula esa sizning natijalaringizni chiqaradi:

Yuqoridagi skrinshotda ko'rsatilganidek, formulalar raqamlar bilan bir qatorda matn qatorlari uchun ham ishlaydi.

Maslahat. Agar ikkita teng ko'rinadigan satrlar turli uzunliklarni qaytarsa, muammo bir yoki ikkala katakdagi boshlovchi yoki oxirgi bo'shliqlar da bo'lishi mumkin. Bunday holda, TRIM funksiyasidan foydalanib, qo'shimcha bo'shliqlarni olib tashlang. Batafsil tushuntirish va formula misollarini bu yerda topishingiz mumkin: Excelda bo'shliqlarni qanday kesish mumkin.

Ikki katakchani ma'lum belgilarning paydo bo'lishi bo'yicha solishtiring

Bu Excel satrlarini solishtirish bo'yicha o'quv qo'llanmamizdagi oxirgi misol bo'lib, u juda aniq vazifa uchun yechimni ko'rsatadi. Aytaylik, sizda siz uchun muhim bo'lgan belgini o'z ichiga olgan matn satrlarining 2 ta ustuni bor. Maqsadingiz - har bir qatordagi ikkita katakda berilgan belgining bir xil sonli takrorlanishini tekshirish.

Taniqroq qilish uchun quyidagilarni ko'rib chiqing.misol. Aytaylik, sizda jo'natilgan (B ustuni) va qabul qilingan (C ustuni) buyurtmalarning ikkita ro'yxati mavjud. Har bir qatorda noyob identifikatori barcha buyurtma identifikatorlariga kiritilgan va A ustunidagi bir qatorda ko'rsatilgan ma'lum bir element uchun buyurtmalarni o'z ichiga oladi (iltimos, quyidagi skrinshotga qarang). Siz har bir satrda oʻziga xos identifikatorga ega boʻlgan joʻnatilgan va qabul qilingan elementlarning teng miqdorda boʻlishiga ishonch hosil qilishni xohlaysiz.

Ushbu muammoni hal qilish uchun quyidagi mantiq bilan formula yozing.

• Birinchidan, SUBSTITUTE funksiyasidan foydalanib, noyob identifikatorni hech narsa bilan almashtiring:

  SUBSTITUTE(A1, character_to_count,"")

• Keyin, har bir katakda noyob identifikator necha marta paydo bo'lishini hisoblang. Buning uchun noyob identifikatorsiz satr uzunligini oling va uni satrning umumiy uzunligidan ayiring. Bu qism 1 va 2 katakchalar uchun alohida yoziladi, masalan:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  va

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Nihoyat, siz ushbu 2 raqamni solishtirasiz. yuqoridagi qismlar orasiga tenglik belgisini (=) qo'yish orqali.

LEN( yacheyka 2 ) - LEN(SUBSTITUTE( yacheyka 2 , hisoblash_belgi , ""))

Bizning misolimizda yagona identifikator A2 formatida joylashgan , va solishtirish uchun satrlar B2 va C2 ​​kataklarida. Shunday qilib, to'liq formula quyidagicha bo'ladi:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Agar B2 va C2 ​​kataklari A2 dagi belgilarning teng soniga ega bo'lsa, formula TRUE qiymatini qaytaradi,Aks holda FALSE. Natijalarni foydalanuvchilaringiz uchun yanada mazmunli qilish uchun siz formulani IF funksiyasiga joylashtirishingiz mumkin:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Yuqoridagi skrinshotda ko'rib turganingizdek , formula bir nechta qo'shimcha qiyinchiliklarga qaramay mukammal ishlaydi:

• Hisoblanishi kerak bo'lgan belgi (noyob identifikator) matn satrining istalgan joyida paydo bo'lishi mumkin.
• Qatorlar o'zgaruvchi raqamni o'z ichiga oladi. nuqtali vergul, vergul yoki bo'sh joy kabi belgilar va turli ajratgichlar.

Excelda satrlarni shu tarzda solishtirasiz. Ushbu qo'llanmada muhokama qilingan formulalar bilan yaqindan tanishish uchun Excel satrlarni solishtirish ish varag'ini yuklab olishingiz mumkin. O'qiganingiz uchun minnatdorchilik bildiraman va kelgusi hafta blogimizda ko'rishga umid qilaman.