Kennsluforritið sýnir hvernig á að bera saman textastrengi í Excel fyrir hástafaónæmi og nákvæma samsvörun. Þú munt læra fjölda formúla til að bera saman tvær frumur eftir gildum þeirra, lengd strengs eða fjölda tilvika tiltekins stafs, sem og hvernig á að bera saman margar frumur.

Þegar þú notar Excel fyrir gagnagreining, nákvæmni er mikilvægasta áhyggjuefnið. Rangar upplýsingar leiða til misskilinna tímafresta, rangrar þróunar, rangra ákvarðana og tapaðra tekna.

Þó að Excel formúlur séu alltaf fullkomlega sannar, gætu niðurstöður þeirra verið rangar vegna þess að einhver gölluð gögn komust inn í kerfið. Í þessu tilviki er eina úrræðið að athuga hvort gögnin séu nákvæm. Það er ekkert mál að bera saman tvær frumur handvirkt, en það er næstum ómögulegt að sjá muninn á hundruðum og þúsundum textastrengja.

Þessi kennsla mun kenna þér hvernig á að gera sjálfvirkt leiðinlegt og villuviðkvæmt verkefni reitsins. samanburð og hvaða formúlur er best að nota í hverju einstöku tilviki.

Hvernig á að bera saman tvær frumur í Excel

Það eru tvær mismunandi leiðir til að bera saman strengi í Excel eftir hvort sem þú leitar að hástöfum eða hástöfum næmum samanburði.

Staðalaus formúla til að bera saman 2 hólfa

Til að bera saman tvær hólfa í Excel sem hunsar hástöfum, notaðu einfalda formúlu eins og þessa:

=A1=B1

Þar sem A1 og B1 eru frumurnar sem þú ert að bera saman. Niðurstaða formúlunnar eru Boolean gildi TRUEog FALSE.

Ef þú vilt gefa út þinn eigin texta fyrir samsvörun og mismun skaltu fella ofangreinda setningu inn í rökrétta prófið á IF fallinu. Til dæmis:

=IF(A1=B1, "Equal", "Not equal")

Eins og þú sérð á skjámyndinni hér að neðan bera báðar formúlurnar saman textastrengi, dagsetningar og tölur jafn vel:

Hástafa-næm formúla til að bera saman strengi í Excel

Í sumum tilfellum getur verið mikilvægt að bera saman textagildi tveggja hólfa líka, heldur einnig að bera saman stafina. Hægt er að gera hástafanæman textasamanburð með því að nota Excel EXACT aðgerðina:

Þar sem texti1 og texti2 eru frumurnar tvær sem þú ert að bera saman.

Að því gefnu að strengirnir þínir séu í hólfum A2 og B2, þá er formúlan sem hér segir:

=EXACT(A2, B2)

Þar sem niðurstaðan er, færðu TRUE fyrir textastrengi sem passa nákvæmlega, þar með talið hástafi af hverjum staf, FALSE annars.

Ef þú vilt að EXACT fallið skili einhverjum öðrum niðurstöðum skaltu fella það inn í IF formúlu og slá inn þinn eigin texta fyrir value_if_true og value_if_false rök:

=IF(EXACT(A2 ,B2), "Exactly equal", "Not equal")

Eftirfarandi skjáskot sýnir niðurstöður hástafanæma strengjasamanburðar í Excel:

Hvernig á að bera saman margar frumur í Excel

Til að bera saman fleiri en 2 frumur í röð, notaðu formúlurnar sem fjallað er um í dæmunum hér að ofan ásamt OG stjórnandanum. Allar upplýsingarnar fylgja hér að neðan.

Staðalaus formúla til að bera samanfleiri en 2 frumur

Það fer eftir því hvernig þú vilt birta niðurstöðurnar, notaðu eina af eftirfarandi formúlum:

=AND(A2=B2, A2=C2)

eða

=IF(AND(A2=B2, A2=C2), "Equal", "Not equal")

AND formúlan skilar TRUE ef allar frumurnar innihalda sama gildi, FALSE ef eitthvað gildi er öðruvísi. IF formúlan gefur út merkin sem þú slærð inn í hana, " Jafn " og " Ekki jafn " í þessu dæmi.

Eins og sýnt er á skjámyndinni hér að neðan, formúla virkar fullkomlega með hvaða gagnategundum sem er - texti, dagsetningar og tölugildi:

Hástafa- og hástafaviðkvæm formúla til að bera saman texta í nokkrum hólfum

Til að bera saman marga strengi hvert við annað til að sjá hvort þær passa nákvæmlega, notaðu eftirfarandi formúlur:

=AND(EXACT(A2,B2), EXACT(A2, C2))

Eða

=IF(AND(EXACT(A2,B2), EXACT(A2, C2)),"Exactly equal", "Not equal")

Eins og í fyrra dæmi, fyrsta formúlan gefur TRUE og FALSE gildi, en sú seinni sýnir eigin texta fyrir samsvörun og mismun:

Berðu saman svið frumna við sýnishorn

Eftirfarandi dæmi sýna hvernig þú getur sannreynt að allar frumur á tilteknu bili innihaldi sama texta og í sýnishorni.

Háfallalaus formúla til að bera saman reiti við sýnistexta

Ef stafi skiptir ekki öllu máli, þú getur notað eftirfarandi formúlu til að bera saman frumur við sýnishorn:

Í rökréttu prófinu á IF fallinu berðu saman tvær tölur:

• Heildarfjöldi frumnaá tilteknu bili (fjöldi lína margfaldaður með fjölda dálka), og
• Fjöldi frumna sem innihalda sama gildi og í sýnishólfi (skilað með COUNTIF fallinu).

Að því gefnu að sýnishornstextinn sé í C2 og strengirnir til að bera saman séu á bilinu A2:B6, þá er formúlan sem hér segir:

=ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2)

Til að gera niðurstöðurnar notendameiri- vingjarnlegur, þ.e. gefa út eitthvað eins og "Allar passa" og "Ekki allir passa" í stað TRUE og FALSE, notaðu IF fallið eins og við gerðum í fyrri dæmunum:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=COUNTIF(A2:B6,C2),"All match", "Not all match")

Eins og sést á skjáskotinu hér að ofan, þá tekst formúlan fullkomlega við margskonar textastrengi, en það er líka hægt að nota hana til að bera saman tölur og dagsetningar.

Hástafa- og hástafanæm formúla til að bera saman strengi við a sýnishornstexti

Ef stóra og hástafir skipta máli geturðu borið saman strengi við sýnistextann með því að nota eftirfarandi fylkisformúlur.

Þar sem upprunasviðið er í A2:B6 og sýnishornstextanum í C2 tekur formúlan eftirfarandi lögun:

=IF(ROWS(A2:B6)*COLUMNS(A2:B6)=SUM(--EXACT(C2, A2:B6)), "All match", "Not all match")

Ólíkt venjulegum Excel formúlum , er fylkisformúlum lokið með því að ýta á Ctrl + Shift + Enter. Ef rétt er slegið inn, umlykur Excel fylkisformúluna í {hrokkin axlabönd}, eins og sýnt er á skjámyndinni:

Hvernig á að bera saman tvær frumur eftir strenglengd

Stundum gætirðu viljað athuga hvort textastrengirnir í hverri röð innihalda jafnmarga stafi. Formúlan fyrir þetta verkefni er mjög einföld. Fyrst færðu strengjalengd tveggja hólfa með því að nota LEN fallið og berðu síðan saman tölurnar.

Svo sem að strengirnir sem á að bera saman séu í hólfum A2 og B2, notaðu aðra hvora af eftirfarandi formúlum:

=LEN(A2)=LEN(B2)

Eða

=IF(LEN(A2)=LEN(B2), "Equal", "Not equal")

Eins og þú veist nú þegar, skilar fyrsta formúlan Boolean gildi TRUE eða FALSE, en önnur formúlan gefur út þínar eigin niðurstöður:

Eins og sýnt er á skjámyndinni hér að ofan virka formúlurnar fyrir textastrengi og tölur.

Ábending. Ef tveir, sem virðast jafnir strengir, skila mismunandi lengdum, er vandamálið líklegast í frama eða aftandi bilum í annarri eða báðum hólfum. Í þessu tilviki skaltu fjarlægja aukabil með því að nota TRIM aðgerðina. Ítarlegri skýringu og formúludæmi má finna hér: Hvernig á að klippa bil í Excel.

Bera saman tvær frumur eftir tilvikum af ákveðnum staf

Þetta er síðasta dæmið í Excel Compare Strings kennsluefninu okkar og það sýnir lausn fyrir frekar ákveðið verkefni. Segjum sem svo að þú sért með 2 dálka af textastrengjum sem innihalda staf sem er mikilvægur fyrir þig. Markmið þitt er að athuga hvort tvær frumur í hverri röð innihalda sama fjölda tilvika af tilteknum staf.

Til að gera hlutina skýrari skaltu íhuga eftirfarandidæmi. Segjum að þú sért með tvo lista yfir pantanir sendar (dálkur B) og mótteknar (dálkur C). Hver röð inniheldur pantanir fyrir tiltekna vöru, þar sem einstakt auðkenni er innifalið í öllum pöntunarauðkennum og er skráð í sömu röð í dálki A (vinsamlega sjá skjámyndina hér að neðan). Þú vilt ganga úr skugga um að hver röð innihaldi jafnan fjölda sendra og móttekinna vara með þetta tiltekna auðkenni.

Til að leysa þetta vandamál skaltu skrifa formúlu með eftirfarandi rökfræði.

• Í fyrsta lagi skaltu skipta út einkvæma auðkenninu fyrir ekkert með því að nota SUBSTITUTE aðgerðina:

  SUBSTITUTE(A1, character_to_count,"")

• Reiknið síðan út hversu oft einkvæma auðkennið birtist í hverjum reit. Fyrir þetta, fáðu strenglengdina án einstaka auðkennisins og dragðu hana frá heildarlengd strengsins. Þessi hluti skal skrifaður fyrir reit 1 og reit 2 fyrir sig, til dæmis:

  LEN(cell 1) - LEN(SUBSTITUTE(cell 1, character_to_count, ""))

  og

  LEN(cell 2) - LEN(SUBSTITUTE(cell 2, character_to_count, ""))

• Að lokum berðu þessar 2 tölur saman með því að setja jafnréttismerkið (=) á milli ofangreindra hluta.

LEN( reitur 2 ) - LEN(SUBSTITUTE( reitur 2 , staf_að_tala , ""))

Í okkar dæmi er einkvæma auðkennið í A2 , og strengirnir til að bera saman eru í frumum B2 og C2. Svo, heildarformúlan er sem hér segir:

=LEN(B2)-LEN(SUBSTITUTE(B2,$A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2,$A2,""))

Formúlan skilar TRUE ef frumur B2 og C2 innihalda jafnmarga tilvik af stafnum í A2,RANGT annars. Til að gera niðurstöðurnar þýðingarmeiri fyrir notendur þína geturðu fellt formúluna inn í IF aðgerðina:

=IF(LEN(B2)-LEN(SUBSTITUTE(B2, $A2,""))=LEN(C2)-LEN(SUBSTITUTE(C2, $A2,"")), "Equal", "Not equal")

Eins og þú sérð á skjámyndinni hér að ofan , formúlan virkar fullkomlega þrátt fyrir nokkra aukaflækjur:

• Táknið sem á að telja (einstakt auðkenni) getur birst hvar sem er í textastreng.
• Strengir innihalda breytilegt númer af stöfum og mismunandi skiljum eins og semíkommu, kommu eða bili.

Svona berðu saman strengi í Excel. Til að skoða betur formúlurnar sem fjallað er um í þessari kennslu er þér velkomið að hlaða niður Excel Compare Strings Worksheet. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku.