Terwijl Microsoft Excel een reeks functies biedt om te werken met weekdagen, maanden en jaren, is er slechts één beschikbaar voor weken - de functie WEEKNUM. Als u dus op zoek bent naar een manier om een weeknummer uit een datum te halen, is WEEKNUM de functie die u zoekt.

In deze korte tutorial gaan we kort in op de syntaxis en argumenten van Excel WEEKNUM, en vervolgens bespreken we enkele formulevoorbeelden die laten zien hoe u de WEEKNUM-functie kunt gebruiken om weeknummers te berekenen in uw Excel-werkbladen.

Excel WEEKNUM functie - syntaxis

De functie WEEKNUM wordt in Excel gebruikt om het weeknummer van een specifieke datum in het jaar terug te geven (een getal tussen 1 en 54). De functie heeft twee argumenten, het eerste is vereist en het tweede is optioneel:

• Serienummer - elke datum binnen de week waarvan u het nummer probeert te vinden. Dit kan een verwijzing zijn naar een cel die de datum bevat, een datum die is ingevoerd met de functie DATUM of die wordt teruggegeven door een andere formule.
• Return_type (optioneel) - een getal dat bepaalt op welke dag de week begint. Indien weggelaten, wordt het standaardtype 1 gebruikt (de week die op zondag begint).

Hier is een volledige lijst van de return_type waarden ondersteund in WEEKNUM formules.

In de functie WEEKNUM worden twee verschillende systemen voor weeknummering worden gebruikt:

• Systeem 1. De week die 1 januari bevat wordt beschouwd als de eerste week van het jaar en wordt genummerd als week 1. In dit systeem begint de week traditioneel op zondag.
• Systeem 2. Dit is het ISO weekdatumsysteem dat deel uitmaakt van de ISO 8601 datum- en tijdstandaard. In dit systeem begint de week op maandag en wordt de week met de eerste donderdag van het jaar beschouwd als week 1. Het staat algemeen bekend als het Europese weeknummeringsysteem en wordt vooral gebruikt in de overheid en het bedrijfsleven voor fiscale jaren en tijdregistratie.

Alle bovengenoemde retourtypen zijn van toepassing op systeem 1, behalve retourtype 21 dat in systeem 2 wordt gebruikt.

Opmerking. In Excel 2007 en eerdere versies zijn alleen opties 1 en 2 beschikbaar. Returntypes 11 tot en met 21 worden alleen ondersteund in Excel 2010 en Excel 2013.

Excel WEEKNUM formules om datum te converteren naar weeknummer (van 1 tot 54)

Het volgende screenshot laat zien hoe je weeknummers kunt krijgen uit datums met het eenvoudigste =WEEKNUM(A2) formule:

In de bovenstaande formule is de return_type argument is weggelaten, wat betekent dat het standaard type 1 wordt gebruikt - de week die op zondag begint.

Als u liever met een andere dag van de week begint, bijvoorbeeld maandag, gebruik dan 2 in het tweede argument:

=WEEKNUM(A2, 2)

In plaats van naar een cel te verwijzen, kunt u de datum rechtstreeks in de formule opgeven door bijvoorbeeld de functie DATUM(jaar, maand, dag) te gebruiken:

=WEEKNUM(DATE(2015,4,15), 2)

De bovenstaande formule geeft 16, dat is het nummer van de week waarin 15 april 2015 valt, met een week die begint op maandag.

In de praktijk wordt de functie WEEKNUM in Excel zelden alleen gebruikt, maar meestal in combinatie met andere functies om verschillende berekeningen uit te voeren op basis van het weeknummer, zoals in de volgende voorbeelden wordt aangetoond.

Hoe weeknummer converteren naar datum in Excel

Zoals u zojuist hebt gezien, is het geen probleem om een datum om te zetten in een weeknummer met behulp van de WEEKNUM-functie van Excel. Maar wat als u het omgekeerde wilt, namelijk een weeknummer omzetten in een datum? Helaas is er geen Excel-functie die dit meteen kan. We zullen dus onze eigen formules moeten construeren.

Stel, u hebt een jaartal in cel A2 en een weeknummer in B2, en nu wilt u de begin- en einddatum van deze week berekenen.

Opmerking. Dit formulevoorbeeld is gebaseerd op ISO-weeknummers, met een week die op maandag begint.

De formule om de Startdatum van de week is als volgt:

=DATUM(A2, 1, -2) - WEEKDAG(DATUM(A2, 1, 3)) + B2 * 7

Waarbij A2 het jaar is en B2 het weeknummer.

Merk op dat de formule de datum weergeeft als een volgnummer, en om het weer te geven als een datum, moet u de cel dienovereenkomstig opmaken. U vindt de gedetailleerde instructies in Datumnotatie wijzigen in Excel. En hier is het resultaat dat de formule oplevert:

Natuurlijk is de formule om een weeknummer om te zetten in een datum niet triviaal, en het kan even duren voor je de logica doorhebt. Hoe dan ook, ik zal mijn best doen om een zinvolle uitleg te geven voor degenen die nieuwsgierig zijn om tot op de bodem te gaan.

Zoals je ziet bestaat onze formule uit 2 delen:

• DATUM(A2, 1, -2) - WEEKDAG(DATUM(A2, 1, 3)) - berekent de datum van de laatste maandag in het voorgaande jaar.
• B2 * 7 - telt het aantal weken op vermenigvuldigd met 7 (het aantal dagen in een week) om de maandag (begindatum) van de betreffende week te krijgen.

In het ISO-weeknummeringssysteem is week 1 de week met de eerste donderdag van het jaar. De eerste maandag ligt dus altijd tussen 29 december en 4 januari. Om die datum te vinden, moeten we dus de maandag direct voor 5 januari zoeken.

In Microsoft Excel kunt u een dag van de week uit een datum halen met behulp van de functie WEEKDAY. En u kunt de volgende algemene formule gebruiken om de maandag direct voor een bepaalde datum te krijgen:

Als ons uiteindelijke doel is de maandag onmiddellijk vóór 5 januari van het jaar in A2 te vinden, kunnen we de volgende DATE-functies gebruiken:

=DATUM(A2,1,5) - WEEKDAG(DATUM(A2,1,3))

Maar wat we eigenlijk nodig hebben is niet de eerste maandag van dit jaar, maar de laatste maandag van het vorige jaar. Je moet dus 7 dagen aftrekken van 5 januari en dus krijg je -2 in de eerste DATE-functie:

=DATUM(A2,1,-2) - WEEKDAG(DATUM(A2,1,3))

Vergeleken met de lastige formule die u zojuist hebt geleerd, is het berekenen van de Einddatum van de week is een fluitje van een cent :) Om de zondag van de week in kwestie te krijgen, voeg je gewoon 6 dagen toe aan de Startdatum d.w.z. =D2+6

U kunt ook direct 6 toevoegen in de formule:

=DATUM(A2, 1, -2) - WEEKDAG(DATUM(A2, 1, 3)) + B2 * 7 + 6

Om er zeker van te zijn dat de formules altijd de juiste data opleveren, bekijkt u het volgende screenshot. De hierboven besproken formules Startdatum en Einddatum zijn gekopieerd over respectievelijk kolom D en E:

Andere manieren om weeknummer naar datum te converteren in Excel

Als de bovenstaande formule op basis van het ISO-weekdatumsysteem niet aan uw eisen voldoet, probeer dan een van de volgende oplossingen.

Formule 1. Een week met Jan-1 is week 1, week van ma t/m zo.

Zoals u zich herinnert, werkt de vorige formule op basis van het ISO-datumsysteem waarbij de eerste donderdag van het jaar wordt beschouwd als week 1. Als u werkt op basis van een datumsysteem waarbij de week waarin 1 januari valt, wordt beschouwd als week 1, gebruik dan de volgende formules:

Startdatum:

=DATUM(A2,1,1) - WEEKDAG(DATUM(A2,1,1),2) + (B2-1)*7 + 1

Einddatum:

=DATUM(A2,1,1)- WEEKDAG(DATUM(A2,1,1),2) + B2*7

Formule 2. Een week met Jan-1 is week 1, zon-zat week

Deze formules zijn vergelijkbaar met de bovenstaande, met als enige verschil dat ze geschreven zijn voor de week van zondag tot zaterdag.

Startdatum:

=DATUM(A2,1,1) - WEEKDAG(DATUM(A2,1,1),1) + (B2-1)*7 + 1

Einddatum:

=DATUM(A2,1,1)- WEEKDAG(DATUM(A2,1,1),1) + B2*7

Formule 3. Begin altijd te tellen op 1 januari, week van ma t/m zo.

Terwijl de vorige formules maandag (of zondag) van week 1 teruggeven, ongeacht of dat in dit jaar of in het voorgaande jaar valt, geeft deze startdatumformule altijd terug 1 januari als de begindatum van week 1, ongeacht de dag van de week. Naar analogie geeft de einddatumformule altijd het volgende resultaat 31 december als de einddatum van de laatste week van het jaar, ongeacht de dag van de week. In alle andere opzichten werken deze formules hetzelfde als formule 1 hierboven.

Startdatum:

=MAX(DATUM(A2,1,1), DATUM(A2,1,1) - WEEKDAG(DATUM(A2,1,1),2) + (B2-1)*7 + 1)

Einddatum:

=MIN(DATUM(A2+1,1,0), DATUM(A2,1,1) - WEEKDAG(DATUM(A2,1,1),2) + B2*7)

Formule 4. Begin altijd te tellen op 1 januari, zon-zaterdag week

Om de begin- en einddatum voor een week van zondag tot zaterdag te berekenen, volstaat een kleine aanpassing in de bovenstaande formules :)

Startdatum:

=MAX(DATUM(A2,1,1), DATUM(A2,1,1) - WEEKDAG(DATUM(A2,1,1),1) + (B2-1)*7 + 1)

Einddatum:

=MIN(DATUM(A2+1,1,0), DATUM(A2,1,1) - WEEKDAG(DATUM(A2,1,1),1) + B2*7)

Hoe krijg ik maand uit weeknummer

Om een maand te krijgen die overeenkomt met het weeknummer, zoekt u de eerste dag in een bepaalde week, zoals uitgelegd in dit voorbeeld, en verpakt u die formule in de Excel MONTH-functie als volgt:

=MAAND(DATUM(A2, 1, -2) - WEEKDAG(DATUM(A2, 1, 3)) + B2 * 7)

Opmerking: vergeet niet dat de bovenstaande formule werkt op basis van de ISO week datum systeem waarbij de week begint op maandag en de week met de 1e donderdag van het jaar wordt beschouwd als week 1. Bijvoorbeeld, in het jaar 2016 is de eerste donderdag 7 januari, en daarom begint week 1 op 4-Jan-2016.

Hoe een weeknummer in een maand te krijgen (van 1 tot 6)

Indien uw bedrijfslogica vereist dat een specifieke datum wordt omgezet naar het weeknummer binnen de overeenkomstige maand, kunt u de combinatie van de functies WEEKNUM, DATUM en MAAND gebruiken:

Ervan uitgaande dat cel A2 de oorspronkelijke datum bevat, gebruikt u de volgende formule voor een week die begint op Maandag (let op 21 in het return_type argument van WEEKNUM):

=WEEKNUM($A2,21)-WEEKNUM(DATUM(JAAR($A2), MAAND($A2),1),21)+1

Voor een week die begint op Zondag laat het argument return_type weg:

=WEEKNUM($A2)-WEEKNUM(DATUM(JAAR($A2), MAAND($A2),1))+1

Hoe waarden optellen en het gemiddelde vinden per weeknummer

Nu u weet hoe u in Excel een datum omzet in een weeknummer, laten we eens kijken hoe u weeknummers kunt gebruiken in andere berekeningen.

Stel, u hebt een aantal maandelijkse verkoopcijfers en u wilt het totaal voor elke week weten.

Om te beginnen zoeken we een weeknummer uit dat bij elke verkoop hoort. Als uw data in kolom A staan en de verkopen in kolom B, kopieert u de =WEEKNUM(A2) formule over kolom C beginnend in cel C2.

En maak dan een lijst met weeknummers in een andere kolom (bijvoorbeeld in kolom E) en bereken de verkoop voor elke week met de volgende SUMIF-formule:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Waarbij E2 het weeknummer is.

In dit voorbeeld werken we met een lijst van maartverkopen, dus met de weeknummers 10 tot en met 14, zoals de volgende schermafbeelding laat zien:

Op soortgelijke wijze kunt u het verkoopgemiddelde voor een bepaalde week berekenen:

=GEMIDDELDEIF($C$2:$C$15, $E2, $B$2:$B$15)

Indien de hulpkolom met de WEEKNUM-formule niet goed past in uw gegevenslay-out, moet ik u helaas vertellen dat er geen eenvoudige manier is om er vanaf te komen omdat Excel WEEKNUM een van die functies is die geen bereikargumenten accepteert. Daarom kan zij niet worden gebruikt binnen SUMPRODUCT of een andere matrixformule zoals de MONTH-functie in een soortgelijk scenario.

Hoe cellen markeren op basis van het weeknummer

Stel, u hebt een lange lijst met datums in een kolom en u wilt alleen die data markeren die betrekking hebben op een bepaalde week. Alles wat u nodig hebt is een voorwaardelijke opmaakregel met een WEEKNUM-formule zoals deze:

=WEEKNUM($A2)=10

Zoals getoond in de onderstaande schermafbeelding, benadrukt de regel de verkopen die zijn gedaan binnen week 10, dat is de eerste week van maart 2015. Omdat de regel van toepassing is op A2:B15, worden waarden in beide kolommen gemarkeerd. U kunt meer leren over het maken van regels voor voorwaardelijke opmaak in deze tutorial: Excel voorwaardelijke opmaak op basis van een andere celwaarde.

Zo kunt u in Excel weeknummers berekenen, weeknummer naar datum converteren en weeknummer uit datum halen. Hopelijk komen de WEEKNUM formules die u vandaag hebt geleerd van pas in uw werkbladen. In de volgende tutorial zullen we het hebben over het berekenen van leeftijd en jaren in Excel. Ik dank u voor het lezen en hoop u volgende week te zien!