Hoewol Microsoft Excel in array fan funksjes leveret om mei wurkdagen, moannen en jierren te wurkjen, mar ien is wiken beskikber - de WEEKNUM-funksje. Dus, as jo op syk binne nei in manier om in wikenûmer fan in datum te krijen, is WEEKNUM de funksje dy't jo wolle.

Yn dizze koarte tutorial sille wy koart prate oer de syntaksis en arguminten fan Excel WEEKNUM, en beprate dan in pear formulefoarbylden dy't demonstrearje hoe't jo de WEEKNUM-funksje brûke kinne om wikenûmers yn jo Excel-wurkblêden te berekkenjen.

Excel WEEKNUM-funksje - syntaksis

De WEEKNUM-funksje is brûkt yn Excel om it wikenûmer fan in spesifike datum yn it jier werom te jaan (in nûmer tusken 1 en 54). It hat twa arguminten, de 1e is fereaske en de 2e is opsjoneel:

• Serial_number - elke datum binnen de wike wêrfan jo it nûmer besykje te finen. Dit kin in ferwizing wêze nei in sel mei de datum, in datum ynfierd mei de DATE-funksje of weromjûn troch in oare formule.
• Return_type (opsjoneel) - in getal dat bepaalt op hokker dei de wike begjint. As it weilitten wurdt, wurdt it standerttype 1 brûkt (de wike dy't op snein begjint).

Hjir is in folsleine list fan de return_type wearden dy't stipe wurde yn WEEKNUM-formules.

Yn de WEEKNUM-funksje wurde twa ferskillende wikennûmeringsystemen brûkt:

• Systeem 1. De wike mei 1 jannewaris wurdt beskôge. de 1e wike fan it jier en is nûmere wike 1. Yn dit systeem begjint de wike tradisjoneel op snein.
• Systeem 2. Dit is it ISO-wikedatumsysteem dat diel útmakket fan de ISO 8601 datum en tiid standert. Yn dit systeem begjint de wike op moandei en wurdt de wike mei de earste tongersdei fan it jier beskôge as wike 1. It wurdt ornaris bekend as it Europeeske wikenûmeringsysteem en wurdt benammen brûkt yn oerheid en bedriuw foar begruttingsjierren en tiidmeting.

Alle hjirboppe neamde returntypen jilde foar Systeem 1, útsein foar returntype 21 dat brûkt wurdt yn Systeem 2.

Opmerking. Yn Excel 2007 en eardere ferzjes binne allinich opsjes 1 en 2 beskikber. Retourtypen 11 oant 21 wurde allinich stipe yn Excel 2010 en Excel 2013.

Excel WEEKNUM-formules om datum nei wikenûmer te konvertearjen (fan 1 nei 54)

De folgjende skermôfbylding lit sjen hoe't jo wikenûmers kinne krije fan datums mei de ienfâldichste =WEEKNUM(A2) -formule:

Yn it boppesteandeformule, it argumint return_type wurdt weilitten, wat betsjut dat it standerttype 1 brûkt wurdt - de wike dy't op snein begjint.

As jo ​​leaver begjinne mei in oare dei fan 'e wike, sis dan moandei, brûk dan 2 yn it twadde argumint:

=WEEKNUM(A2, 2)

Ynstee fan in sel te ferwizen, kinne jo de datum direkt yn 'e formule opjaan troch de funksje DATE(jier, moanne, dei) te brûken, bygelyks:

=WEEKNUM(DATE(2015,4,15), 2)

De boppesteande formule jout 16 werom, dat is it nûmer fan 'e wike mei 15 april 2015, mei in wike dy't op moandei begjint.

Yn echte senario's , de Excel WEEKNUM-funksje wurdt selden op himsels brûkt. Meastentiids soene jo it yn kombinaasje mei oare funksjes brûke om ferskate berekkeningen út te fieren op basis fan it wikenûmer, lykas oantoand yn fierdere foarbylden.

Hoe kinne jo wikenûmer nei datum konvertearje yn Excel

As jo haw krekt sjoen, it is gjin grut probleem om in datum yn in wikenûmer te feroarjen mei de Excel WEEKNUM-funksje. Mar wat as jo op syk binne nei it tsjinoerstelde, dus it konvertearjen fan in wikenûmer nei in datum? Och, d'r is gjin Excel-funksje dy't dit direkt koe dwaan. Dat, wy sille ús eigen formules moatte konstruearje.

Stel dat jo in jier yn sel A2 hawwe en in wikenûmer yn B2, en no wolle jo de Start- en Eindatums yn dizze wike berekkenje.

Opmerking. Dit formulefoarbyld is basearre op ISO-wikenûmers, mei in wike dy't op moandei begjint.

De formule om de Start werom te jaandatum fan 'e wike is as folget:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Dêr't A2 it jier is en B2 it wikenûmer is.

Tink derom dat de formule de datum weromjout as searjenûmer, en om it as datum werjûn te hawwen, moatte jo de sel neffens opmaak. Jo kinne de detaillearre ynstruksjes fine yn Datumformaat feroarje yn Excel. En hjir is it resultaat weromjûn troch de formule:

Fansels is de formule om in wikenûmer nei in datum te konvertearjen net triviaal, en it kin in skoft duorje om te krijen dyn holle om de logika. Hoe dan ek, ik sil myn bêst dwaan om sinfolle útlis te jaan foar dyjingen dy't nijsgjirrich binne om nei ûnderen te kommen.

Sa't jo sjogge, bestiet ús formule út 2 dielen:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - berekkent de datum fan 'e lêste moandei yn it foarige jier.
• B2 * 7 - foeget it oantal wiken ta fermannichfâldige mei 7 (it oantal dagen yn in wike) om de moandei (begjindatum) fan 'e wike te krijen yn fraach.

Yn it ISO-wikenûmeringsysteem is wike 1 de wike mei de earste tongersdei fan it jier. Dêrtroch is de earste moandei altyd tusken 29 desimber en 4 jannewaris. Dus, om dy datum te finen, moatte wy de moandei fuort foar 5 jannewaris fine.

Yn Microsoft Excel kinne jo in dei fan 'e wike útpakke út in datum troch de funksje WEEKDAY te brûken. En jo kinne de folgjende generyske formule brûke om moandei direkt foar elke opjûne datum te krijen:

As úsúteinlike doel wiene om moandei direkt foar de 5e jannewaris fan it jier te finen yn A2, kinne wy ​​de folgjende DATE-funksjes brûke:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Mar wat wy eins nedich binne is net de earste moandei fan dit jier, mar leaver de lêste moandei fan it foarige jier. Dat, jo moatte 7 dagen ôflûke fan 5 jannewaris en dus krije jo -2 yn 'e earste DATE-funksje:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Ferlike mei de lestige formule dy't jo krekt leard hawwe, it berekkenjen fan de Einddatum fan 'e wike is in flaubyt :) Om snein fan 'e wike te krijen, foegje jo gewoan 6 dagen ta oan de Begjindatum , dus =D2+6

Alternatyf kinne jo 6 direkt tafoegje yn 'e formule:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Om te soargjen dat de formules altyd de juste datums leverje, sjoch asjebleaft nei it folgjende skermprint. De hjirboppe besprutsen formules foar begjindatum en eindatum wurde kopiearre oer respektivelik kolom D en E:

Oare manieren om wikenûmer nei datum te konvertearjen yn Excel

As de boppesteande formule basearre op it ISO-wikedatumsysteem net oan jo easken foldocht, besykje dan ien fan de folgjende oplossingen.

Formule 1. In wike mei Jan-1 is wike 1, Mo-Sne wike

As jo ​​ûnthâlde, wurket de foarige formule basearre op it ISO-datumsysteem wêr't de earste tongersdei fan it jier as wike 1 wurdt beskôge. brûk de folgjendeformules:

Begjindatum:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Einddatum:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Formule 2. In wike mei Jan-1 is wike 1, Snein-Sat wike

Dizze formules binne fergelykber mei de boppesteande mei it ienige ferskil dat se skreaun binne foar snein - sneon wike.

Begjindatum:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Einddatum:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Formule 3. Begjin altyd te tellen op 1 jannewaris, moandei-snein wike

Wylst de foarige formules moandei (of snein) fan wike 1 weromkomme, nettsjinsteande of as falt binnen dit jier of it foarige jier, jout dizze startdatumformule altyd 1 jannewaris werom as de startdatum fan wike 1, nettsjinsteande de dei fan 'e wike. Nei analogy jout de eindatumformule altyd 31 desimber werom as de eindatum fan 'e lêste wike yn it jier, nettsjinsteande de dei fan 'e wike. Yn alle oare opsichten wurkje dizze formules fergelykber mei Formule 1 hjirboppe.

Begjindatum:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Einddatum:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Formule 4. Begjin altyd te tellen op 1 jannewaris, snein-satewike

Om de begjin- en eindatums te berekkenjen foar in snein - sneonswike is it allinnich mar ien lytse oanpassing yn de boppesteande formules :)

Begjindatum:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Einddatum:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Hoe krije jo moanne fan wikenûmer

Om in moanne te krijen dy't oerienkomt mei de wike getal, fine jo de earste dei yn in opjûne wike lykas útlein yn dizzefoarbyld, en wikkel dan dizze formule yn 'e Excel MOANNE-funksje sa:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Opmerking. Tink derom dat de boppesteande formule wurket op basis fan it ISO-wikedatumsysteem , wêrby't de wike op moandei begjint en de wike mei de 1e tongersdei fan it jier wurdt beskôge as wike 1. Bygelyks, yn it jier 2016, de earste tongersdei is 7 jannewaris, en dêrom begjint wike 1 op 4-Jan-2016.

Hoe krije jo in wikenûmer yn in moanne (fan 1 oant 6)

As jo ​​bedriuwslogika fereasket it konvertearjen fan in spesifike datum nei it wikenûmer binnen de oerienkommende moanne, kinne jo de kombinaasje fan WEEKNUM, DATUM- en MOANNE-funksjes:

Aannommen dat sel A2 de oarspronklike datum befettet, brûk dan de folgjende formule foar in wike dy't begjint op moandei (meidieling 21 yn it return_type-argumint fan WEEKNUM):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Foar in wike dy't begjint op Snein , lit it argumint return_type weilitte:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Hoe kinst som wearden en fyn gemiddelde troch it wikenûmer

No't jo witte hoe't jo in datum yn in wikenûmer omsette yn Excel, litte wy sjen hoe't jo wikenûmers brûke kinne yn oare berekkeningen.

Stel , jo hawwe wat moanlikse ferkeapsifers en jo wolle it totaal foar elke wike witte.

Om te begjinnen, litte wy in wikenûmer fine dat oerienkomt mei elke ferkeap. As jo ​​datums binne yn kolom A en ferkeap yn kolom B, kopiearje dan de formule =WEEKNUM(A2) oer kolom C begjin yn selC2.

En meitsje dan in list mei wikenûmers yn in oare kolom (bygelyks yn kolom E) en berekkenje de ferkeap foar elke wike mei de folgjende SUMIF-formule:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Dêr't E2 it wikenûmer is.

Yn dit foarbyld wurkje wy mei in list fan maartferkeap, dus hawwe wy wikenûmers 10 oant 14, lykas oantoand yn it folgjende skermôfbylding:

Op in fergelykbere manier kinne jo it ferkeapgemiddelde foar in opjûne wike berekkenje:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

As de helpkolom mei de WEEKNUM-formule net goed past yn jo gegevensopmaak, spyt ik jo te fertellen dat d'r gjin ienfâldige manier is om it kwyt te reitsjen, om't Excel WEEKNUM ien fan dy funksjes is dat akseptearret gjin berik arguminten. Dêrom kin it net brûkt wurde binnen SUMPRODUCT of in oare arrayformule lykas de MONTH-funksje yn in ferlykber senario.

Hoe kinne sellen markearje op basis fan it wikenûmer

Litte wy sizze dat jo in lange list hawwe fan datums yn guon kolom en jo wolle allinich dejingen markearje dy't relatearje oan in bepaalde wike. Alles wat jo nedich hawwe is in regel foar betingsten opmaak mei in WEEKNUM formule fergelykber mei dizze:

=WEEKNUM($A2)=10

Lykas oantoand yn 'e skermprint hjirûnder, markeart de regel ferkeapen dy't makke binne binnen wike 10, dat is de earste wike yn maart 2015. Sûnt de regel jildt foar A2: B15, markearret it wearden yn beide kolommen. Jo kinne hjiryn mear leare oer it meitsjen fan regels foar betingst opmaaktutorial: Excel conditional opmaak basearre op in oare sel wearde.

Dit is hoe't jo kinne berekkenje wike nûmers yn Excel, konvertearje wike nûmer nei datum en extract wike nûmer fan datum. Hooplik sille de WEEKNUM-formules dy't jo hjoed hawwe leard, nuttich wêze yn jo wurkblêden. Yn 'e folgjende tutorial sille wy prate oer it berekkenjen fan leeftyd en jierren yn Excel. Ik tankje jo foar it lêzen en hoopje jo nije wike te sjen!