Tra bod Microsoft Excel yn darparu amrywiaeth o swyddogaethau i weithio gyda dyddiau'r wythnos, misoedd a blynyddoedd, dim ond un sydd ar gael am wythnosau - y swyddogaeth WEEKNUM. Felly, os ydych chi'n chwilio am ffordd i gael rhif wythnos o ddyddiad, WEEKNUM yw'r swyddogaeth rydych chi ei heisiau.

Yn y tiwtorial byr hwn, byddwn yn siarad yn fyr am gystrawen a dadleuon Excel WEEKNUM, a yna trafodwch ychydig o enghreifftiau fformiwla sy'n dangos sut y gallwch ddefnyddio'r ffwythiant WEEKNUM i gyfrifo rhifau wythnos yn eich taflenni gwaith Excel.

Swyddogaeth WEEKNUM Excel - cystrawen

Y ffwythiant WEEKNUM yw a ddefnyddir yn Excel i ddychwelyd rhif wythnos dyddiad penodol yn y flwyddyn (rhif rhwng 1 a 54). Mae ganddo ddwy arg, mae angen y 1af ac mae'r 2il yn ddewisol:

• Rhif_Cyfres - unrhyw ddyddiad o fewn yr wythnos yr ydych yn ceisio'i rif i ddod o hyd. Gall hwn fod yn gyfeiriad at gell sy'n cynnwys y dyddiad, dyddiad a gofnodwyd gan ddefnyddio'r ffwythiant DATE neu a ddychwelwyd gan ryw fformiwla arall.
• Return_type (dewisol) - rhif sy'n pennu ar ba un diwrnod mae'r wythnos yn dechrau. Os caiff ei hepgor, defnyddir y math rhagosodedig 1 (yr wythnos sy'n dechrau ar ddydd Sul).

Dyma restr gyflawn o'r gwerthoedd return_type sy'n cael eu cefnogi yn fformiwlâu WEEKNUM.

Yn y ffwythiant WEEKNUM, defnyddir dwy system rhifo wythnos wahanol:

• System 1. Ystyrir yr wythnos sy'n cynnwys Ionawr 1 wythnos 1af y flwyddyn ac mae wedi'i rhifo wythnos 1. Yn y system hon, mae'r wythnos yn draddodiadol yn dechrau ar ddydd Sul.
• System 2. Dyma'r system dyddiad wythnos ISO sy'n rhan o'r Safon dyddiad ac amser ISO 8601. Yn y system hon, mae'r wythnos yn dechrau ar ddydd Llun ac mae'r wythnos sy'n cynnwys dydd Iau cyntaf y flwyddyn yn cael ei hystyried yn wythnos 1. Fe'i gelwir yn gyffredin yn system rifo'r wythnos Ewropeaidd ac fe'i defnyddir yn bennaf mewn llywodraeth a busnes ar gyfer blynyddoedd ariannol a chadw amser.

Mae pob un o'r mathau dychwelyd a restrir uchod yn berthnasol i System 1, ac eithrio math dychwelyd 21 a ddefnyddir yn System 2.

Nodyn. Yn Excel 2007 a fersiynau cynharach, dim ond opsiynau 1 a 2 sydd ar gael. Cefnogir mathau o ffurflenni 11 i 21 yn Excel 2010 ac Excel 2013 yn unig.

Excel WEEKNUM fformiwlâu i drosi dyddiad i rif wythnos (o 1 i 54)

Mae'r sgrinlun canlynol yn dangos sut y gallwch gael rhifau wythnos o ddyddiadau gyda'r fformiwla =WEEKNUM(A2) symlaf:

<18

Yn yr uchodfformiwla, mae dadl return_type wedi'i hepgor, sy'n golygu bod y math 1 rhagosodedig yn cael ei ddefnyddio - yr wythnos sy'n dechrau ar ddydd Sul.

Os byddai'n well gennych ddechrau gyda rhyw ddiwrnod arall o'r wythnos, dywedwch ddydd Llun, defnyddiwch 2 yn yr ail arg:

=WEEKNUM(A2, 2)

Yn lle cyfeirio at gell, gallwch chi nodi'r dyddiad yn uniongyrchol yn y fformiwla drwy ddefnyddio'r ffwythiant DATE(blwyddyn, mis, diwrnod), er enghraifft:

=WEEKNUM(DATE(2015,4,15), 2)

Mae'r fformiwla uchod yn dychwelyd 16, sef rhif yr wythnos sy'n cynnwys Ebrill 15, 2015, gydag wythnos yn dechrau ar ddydd Llun.

Mewn senarios bywyd go iawn , anaml y defnyddir swyddogaeth Excel WEEKNUM ar ei ben ei hun. Gan amlaf byddech yn ei ddefnyddio ar y cyd â swyddogaethau eraill i wneud cyfrifiadau amrywiol yn seiliedig ar rif yr wythnos, fel y dangosir mewn enghreifftiau pellach.

Sut i drosi rhif wythnos hyd yn hyn yn Excel

Fel chi newydd weld, nid yw'n fawr o beth troi dyddiad yn rif wythnos gan ddefnyddio swyddogaeth Excel WEEKNUM. Ond beth os ydych yn chwilio am y gwrthwyneb, h.y. trosi rhif wythnos i ddyddiad? Ysywaeth, nid oes unrhyw swyddogaeth Excel a allai wneud hyn ar unwaith. Felly, bydd yn rhaid i ni lunio ein fformiwlâu ein hunain.

A chymryd bod gennych flwyddyn yng nghell A2 a rhif wythnos yn B2, a nawr rydych am gyfrifo'r dyddiadau Dechrau a Gorffen yn yr wythnos hon.

Nodyn. Mae'r enghraifft fformiwla hon yn seiliedig ar niferoedd wythnos ISO, gydag wythnos yn dechrau ddydd Llun.

Y fformiwla i ddychwelyd y Cychwynmae dyddiad yr wythnos fel a ganlyn:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Lle A2 yw'r flwyddyn a B2 yw rhif yr wythnos.

Sylwer bod y fformiwla yn dychwelyd y dyddiad fel rhif cyfresol, ac i'w ddangos fel dyddiad, mae angen ichi fformatio'r gell yn unol â hynny. Gallwch ddod o hyd i'r cyfarwyddiadau manwl yn fformat Newid dyddiad yn Excel. A dyma'r canlyniad a ddychwelwyd gan y fformiwla:

Wrth gwrs, nid yw'r fformiwla i drosi rhif wythnos i ddyddiad yn ddibwys, a gall gymryd peth amser i'w gael eich pen rownd y rhesymeg. Beth bynnag, fe wnaf fy ngorau glas i roi esboniad ystyrlon i'r rhai sy'n chwilfrydig i ddod i lawr i'r gwaelod.

Fel y gwelwch, mae ein fformiwla yn cynnwys 2 ran:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - yn cyfrifo dyddiad y dydd Llun olaf yn y flwyddyn flaenorol.
• B2 * 7 - yn ychwanegu nifer yr wythnosau wedi'i luosi â 7 (nifer y dyddiau mewn wythnos) i gael dydd Llun (dyddiad cychwyn) yr wythnos yn cwestiwn.

Yn y system rhifo wythnos ISO, wythnos 1 yw'r wythnos sy'n cynnwys dydd Iau cyntaf y flwyddyn. O ganlyniad, mae'r dydd Llun cyntaf bob amser rhwng Rhagfyr 29 a Ionawr 4. Felly, i ddod o hyd i'r dyddiad hwnnw, mae'n rhaid i ni ddod o hyd i'r dydd Llun yn union cyn Ionawr 5.

Yn Microsoft Excel, gallwch dynnu diwrnod o'r wythnos o dyddiad gan ddefnyddio'r swyddogaeth WYTHNOS DDIWRNOD. A gallwch ddefnyddio'r fformiwla generig ganlynol i gael dydd Llun yn union cyn unrhyw ddyddiad penodol:

Os yw einY nod yn y pen draw oedd dod o hyd i ddydd Llun yn union cyn y 5ed o Ionawr y flwyddyn yn A2, gallem ddefnyddio'r swyddogaethau DYDDIAD canlynol:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Ond nid yr hyn sydd ei angen arnom mewn gwirionedd yw dydd Llun cyntaf eleni, ond yn hytrach dydd Llun olaf y flwyddyn flaenorol. Felly, mae'n rhaid i chi dynnu 7 diwrnod o Ionawr 5 ac felly rydych chi'n cael -2 yn y ffwythiant DYDDIAD cyntaf:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

O'i gymharu â'r fformiwla anodd rydych chi newydd ei ddysgu, wrth gyfrifo'r Dyddiad gorffen yr wythnos yw darn o gacen :) I gael dydd Sul yr wythnos dan sylw, yn syml iawn rydych chi'n ychwanegu 6 diwrnod at y dyddiad cychwyn , h.y. =D2+6

Fel arall, gallech ychwanegu 6 yn uniongyrchol yn y fformiwla:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

I wneud yn siŵr bod y fformiwlâu bob amser yn darparu'r dyddiadau cywir, edrychwch ar y canlynol sgrinlun. Mae'r fformiwlâu Dyddiad Dechrau a Dyddiad Gorffen a drafodir uchod yn cael eu copïo ar draws colofnau D ac E, yn y drefn honno:

Ffyrdd eraill o drosi rhif wythnos hyd yn hyn yn Excel

Os nad yw'r fformiwla uchod sy'n seiliedig ar system dyddiad wythnos ISO yn cwrdd â'ch gofynion, rhowch gynnig ar un o'r atebion canlynol.

Fformiwla 1. Wythnos sy'n cynnwys Ionawr-1 yw wythnos 1, wythnos Llun-Sul

Fel y cofiwch, mae'r fformiwla flaenorol yn gweithio yn seiliedig ar y system dyddiad ISO lle mae dydd Iau cyntaf y flwyddyn yn cael ei ystyried yn wythnos 1. Os ydych yn gweithio ar sail system ddyddiad lle mae'r wythnos sy'n cynnwys y 1af o Ionawr yn cael ei hystyried yn wythnos 1, defnyddiwch y canlynolfformiwlâu:

Dyddiad cychwyn:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Dyddiad gorffen:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Fformiwla 2. Wythnos sy'n cynnwys Ionawr-1 yw wythnos 1, wythnos Sul-Sul

Mae'r fformiwlâu hyn yn debyg i'r rhai uchod gyda'r unig wahaniaeth y maent wedi'u hysgrifennu ar gyfer wythnos dydd Sul - dydd Sadwrn.

Dyddiad cychwyn:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Dyddiad gorffen:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Fformiwla 3. Dechreuwch gyfrif bob amser ar Ionawr 1, wythnos Llun-Sul

Tra bod y fformiwlâu blaenorol yn dychwelyd Dydd Llun (neu Ddydd Sul) o wythnos 1, beth bynnag o p'un a yw'n dod o fewn y flwyddyn hon neu'r flwyddyn flaenorol, mae'r fformiwla dyddiad cychwyn hon bob amser yn dychwelyd Ionawr 1 fel dyddiad dechrau wythnos 1 waeth beth fo'r diwrnod o'r wythnos. Drwy gyfatebiaeth, mae'r fformiwla dyddiad gorffen bob amser yn dychwelyd Rhagfyr 31 fel dyddiad gorffen yr wythnos olaf yn y flwyddyn, waeth beth fo'r diwrnod o'r wythnos. Ym mhob ffordd arall, mae'r fformiwlâu hyn yn gweithio'n debyg i Fformiwla 1 uchod.

Dyddiad cychwyn:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Dyddiad gorffen:<8

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

I gyfrifo'r dyddiadau dechrau a gorffen ar gyfer wythnos Sul - Sadwrn, y cyfan sydd ei angen yw un addasiad bach yn y fformiwlâu uchod :)

Dyddiad cychwyn:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

>Dyddiad gorffen:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Sut i gael rhif mis o'r wythnos

I gael mis sy'n cyfateb i'r wythnos rhif, fe welwch y diwrnod cyntaf mewn wythnos benodol fel yr eglurir yn hwnenghraifft, ac yna lapiwch y fformiwla honno yn y ffwythiant Excel MONTH fel hyn:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Nodyn. Cofiwch fod y fformiwla uchod yn gweithio ar sail system dyddiad wythnos ISO , lle mae'r wythnos yn dechrau ar ddydd Llun a'r wythnos sy'n cynnwys dydd Iau 1af y flwyddyn yn cael ei hystyried yn wythnos 1. Er enghraifft, yn y flwyddyn 2016, y dydd Iau cyntaf yw Ionawr 7, a dyna pam mae wythnos 1 yn dechrau ar 4-Ionawr-2016.

Sut i gael rhif wythnos mewn mis (o 1 i 6)

Os yw rhesymeg eich busnes yn gofyn am drosi dyddiad penodol i rif yr wythnos o fewn y mis cyfatebol, gallwch ddefnyddio'r cyfuniad o WEEKNUM, Swyddogaethau DYDDIAD a MIS:

Gan dybio bod cell A2 yn cynnwys y dyddiad gwreiddiol, defnyddiwch y fformiwla ganlynol am wythnos yn dechrau ar Dydd Llun (hysbysiad 21 yn nadl return_type arg WEEKNUM):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Am wythnos yn dechrau ar Dydd Sul , hepgorer y ddadl return_type:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Sut i gwerthoedd swm a dod o hyd i gyfartaledd yn ôl rhif yr wythnos

Nawr eich bod yn gwybod sut i drosi dyddiad i rif wythnos yn Excel, gadewch i ni weld sut y gallwch chi ddefnyddio rhifau wythnos mewn cyfrifiadau eraill.

Tybiwch , mae gennych rai ffigurau gwerthiant misol ac rydych am wybod y cyfanswm ar gyfer pob wythnos.

I ddechrau, gadewch i ni ddarganfod rhif wythnos sy'n cyfateb i bob gwerthiant. Os yw eich dyddiadau yng ngholofn A a gwerthiannau yng ngholofn B, copïwch fformiwla =WEEKNUM(A2) ar draws colofn C gan ddechrau yn y gellC2.

Ac wedyn, gwnewch restr o rifau wythnos mewn rhyw golofn arall (dyweder, yng ngholofn E) a chyfrifwch y gwerthiannau ar gyfer pob wythnos gan ddefnyddio’r fformiwla SUMIF ganlynol:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Lle E2 yw rhif yr wythnos.

Yn yr enghraifft hon, rydym yn gweithio gyda rhestr o werthiannau mis Mawrth, felly mae gennym rifau wythnos 10 i 14, fel dangosir yn y sgrinlun a ganlyn:

Mewn modd tebyg, gallwch gyfrifo'r cyfartaledd gwerthiant ar gyfer wythnos benodol:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Os nad yw'r golofn cynorthwyydd gyda'r fformiwla WEEKNUM yn cyd-fynd yn dda â'ch cynllun data, mae'n ddrwg gennyf ddweud wrthych nad oes ffordd syml o gael gwared arno oherwydd mae Excel WEEKNUM yn un o'r swyddogaethau hynny nid yw hynny'n derbyn dadleuon amrediad. Felly, ni ellir ei ddefnyddio o fewn SUMPRODUCT nac unrhyw fformiwla arae arall fel y ffwythiant MONTH mewn senario tebyg.

Sut i amlygu celloedd yn seiliedig ar rif yr wythnos

Dewch i ni ddweud bod gennych restr hir o ddyddiadau mewn rhai colofnau ac rydych am dynnu sylw at y rhai sy'n ymwneud ag wythnos benodol yn unig. Y cyfan sydd ei angen arnoch yw rheol fformatio amodol gyda fformiwla WEEKNUM tebyg i hyn:

=WEEKNUM($A2)=10

Fel y dangosir yn y sgrinlun isod, mae'r rheol yn amlygu gwerthiannau a wnaed o fewn wythnos 10, sef y wythnos gyntaf ym mis Mawrth 2015. Gan fod y rheol yn berthnasol i A2:B15, mae'n amlygu gwerthoedd yn y ddwy golofn. Gallwch ddysgu mwy am greu rheolau fformatio amodol yn hyntiwtorial: fformatio amodol Excel yn seiliedig ar werth cell arall.

Dyma sut y gallwch gyfrifo rhifau wythnos yn Excel, trosi rhif wythnos i ddyddiad a thynnu rhif wythnos o'r dyddiad. Gobeithio y bydd y fformiwlâu WEEKNUM rydych chi wedi'u dysgu heddiw yn ddefnyddiol yn eich taflenni gwaith. Yn y tiwtorial nesaf, byddwn yn siarad am gyfrifo oedran a blynyddoedd yn Excel. Diolch i chi am ddarllen a gobeithio eich gweld chi wythnos nesaf!