Ndërsa Microsoft Excel ofron një sërë funksionesh për të punuar me ditët e javës, muajt dhe vitet, vetëm një është i disponueshëm për javë - funksioni WEEKNUM. Pra, nëse po kërkoni një mënyrë për të marrë një numër javor nga një datë, WEEKNUM është funksioni që dëshironi.

Në këtë tutorial të shkurtër, ne do të flasim shkurtimisht për sintaksën dhe argumentet e Excel WEEKNUM, dhe më pas diskutoni disa shembuj formulash që demonstrojnë se si mund të përdorni funksionin WEEKNUM për të llogaritur numrat e javëve në fletët tuaja të punës në Excel.

Funksioni WEEKNUM Excel - sintaksa

Funksioni WEEKNUM është përdoret në Excel për të kthyer numrin e javës të një date specifike në vit (një numër midis 1 dhe 54). Ka dy argumente, i pari kërkohet dhe i dyti është fakultativ:

• Numri_serial - çdo datë brenda javës, numrin e së cilës po provoni per te gjetur. Kjo mund të jetë një referencë për një qelizë që përmban datën, një datë e futur duke përdorur funksionin DATE ose e kthyer nga ndonjë formulë tjetër.
• Tipi_kthimi (opsionale) - një numër që përcakton se në cilin dita e fillimit të javës. Nëse hiqet, përdoret tipi i paracaktuar 1 (java që fillon të dielën).

Këtu është një listë e plotë e return_type vlerave të mbështetura në formulat WEEKNUM.

Në funksionin WEEKNUM, përdoren dy sisteme të ndryshme javore të numërimit :

• Sistemi 1. Java që përmban 1 janar konsiderohet java e parë e vitit dhe numërohet java 1. Në këtë sistem, java tradicionalisht fillon të dielën.
• Sistemi 2. Ky është sistemi ISO i datës së javës që është pjesë e Standardi i datës dhe kohës ISO 8601. Në këtë sistem, java fillon të hënën dhe java që përmban të enjten e parë të vitit konsiderohet java 1. Zakonisht njihet si sistemi evropian i numërimit të javëve dhe përdoret kryesisht në qeveri dhe biznes për vitet fiskale dhe matjen e kohës.

Të gjitha llojet e kthimit të listuara më sipër zbatohen për Sistemin 1, me përjashtim të llojit të kthimit 21 që përdoret në Sistemin 2.

Shënim. Në Excel 2007 dhe versionet e mëparshme, janë të disponueshme vetëm opsionet 1 dhe 2. Llojet e kthimit 11 deri në 21 mbështeten vetëm në Excel 2010 dhe Excel 2013.

Formulat e Excel WEEKNUM për të kthyer datën në numrin e javës (nga 1 në 54)

Pamja e mëposhtme tregon se si mund të merrni numrat e javëve nga datat me formulën më të thjeshtë =WEEKNUM(A2) :

Në sa më sipërformula, argumenti return_type është hequr, që do të thotë se përdoret tipi i paracaktuar 1 - java që fillon të dielën.

Nëse preferoni të filloni me një ditë tjetër të javës, le të themi të hënën, atëherë përdorni 2 në argumentin e dytë:

=WEEKNUM(A2, 2)

Në vend që t'i referoheni një qelize, mund të specifikoni datën direkt në formulë duke përdorur funksionin DATE(viti, muaji, ditë), për shembull:

B2 * 7

Formula e mësipërme kthen 16, që është numri i javës që përmban 15 prill 2015, me një javë që fillon të hënën.

Në skenarët e jetës reale , funksioni Excel WEEKNUM përdoret rrallë më vete. Më shpesh do ta përdorni atë në kombinim me funksione të tjera për të kryer llogaritje të ndryshme bazuar në numrin e javës, siç tregohet në shembuj të mëtejshëm.

Si të konvertohet numri i javës në datën në Excel

Si ju sapo e pashë, nuk është gjë e madhe të kthesh një datë në një numër javor duke përdorur funksionin Excel WEEKNUM. Por, çka nëse kërkoni të kundërtën, pra konvertimin e një numri të javës në një datë? Mjerisht, nuk ka asnjë funksion Excel që mund ta bëjë këtë menjëherë. Pra, do të na duhet të ndërtojmë formulat tona.

Duke supozuar se keni një vit në qelizën A2 dhe një numër jave në B2, dhe tani doni të llogaritni datat e fillimit dhe të mbarimit në këtë javë.

Shënim. Ky shembull i formulës bazohet në numrat e javës ISO, me një javë që fillon të hënën.

Formula për të kthyer Startdata e javës është si më poshtë:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Ku A2 është viti dhe B2 është numri i javës.

Ju lutemi vini re se formula kthen datën si numër serial dhe që të shfaqet si datë, duhet të formatoni qelizën në përputhje me rrethanat. Udhëzimet e detajuara mund t'i gjeni në Ndryshimi i formatit të datës në Excel. Dhe këtu është rezultati i kthyer nga formula:

Sigurisht, formula për të kthyer një numër javor në një datë nuk është e parëndësishme dhe mund të duhet pak kohë për të marrë kokën rreth logjikës. Gjithsesi, do të bëj çmos për të dhënë shpjegime kuptimplotë për ata që janë kuriozë të zbresin deri në fund.

Siç e shihni, formula jonë përbëhet nga 2 pjesë:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - llogarit datën e të hënës së fundit në vitin e kaluar.
• B2 * 7 - shton numrin e javëve të shumëzuar me 7 (numrin e ditëve në javë) për të marrë të hënën (datën e fillimit) të javës në pyetje.

Në sistemin e numërimit të javës ISO, java 1 është java që përmban të enjten e parë të vitit. Rrjedhimisht, e hëna e parë është gjithmonë ndërmjet 29 dhjetorit dhe 4 janarit. Pra, për të gjetur atë datë, duhet të gjejmë të hënën menjëherë para 5 janarit.

Në Microsoft Excel, ju mund të nxirrni një ditë të javës nga një datë duke përdorur funksionin WEEKDAY. Dhe mund të përdorni formulën e mëposhtme të përgjithshme për të marrë të hënën menjëherë përpara një date të caktuar:

Nëseqëllimi përfundimtar ishte të gjejmë të hënën menjëherë përpara datës 5 janar të vitit në A2, ne mund të përdorim funksionet e mëposhtme të DATE:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Por ajo që na duhet në të vërtetë nuk është e hëna e parë e vitit. këtë vit, por më tepër të hënën e fundit të një viti më parë. Pra, ju duhet të zbrisni 7 ditë nga 5 janari dhe kështu ju merrni -2 në funksionin e parë DATE:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Krahasuar me formulën e ndërlikuar që sapo keni mësuar, duke llogaritur Data e përfundimit e javës është një copë tortë :) Për të marrë të dielën e javës në fjalë, thjesht shtoni 6 ditë në Data e fillimit , d.m.th. =D2+6

Përndryshe, ju mund të shtoni 6 direkt në formulën:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Për t'u siguruar që formulat japin gjithmonë datat e duhura, ju lutemi hidhni një sy në vijim pamje nga ekrani. Formulat e datës së fillimit dhe datës së mbarimit të diskutuara më sipër janë kopjuar në kolonën D dhe E, përkatësisht:

Mënyra të tjera për të kthyer numrin e javës në datë në Excel

Nëse formula e mësipërme e bazuar në sistemin ISO të datave të javës nuk i plotëson kërkesat tuaja, provoni një nga zgjidhjet e mëposhtme.

Formula 1. Një javë që përmban Jan-1 është java 1, javë e Hënë-Diell

Siç e mbani mend, formula e mëparshme funksionon bazuar në sistemin e datave ISO ku e enjtja e parë e vitit konsiderohet java 1. Nëse punoni bazuar në një sistem datash ku java që përmban 1 janarin konsiderohet java 1, përdorni sa vijonformulat:

Data e fillimit:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Data e përfundimit:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Formula 2. Një javë që përmban Jan-1 është java 1, java Diell-Sat

Këto formula janë të ngjashme me ato të mësipërme me të vetmin ndryshim se janë të shkruara për javën e diel - të shtunën.

Data e fillimit:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Data e përfundimit:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Formula 3. Gjithmonë filloni të numëroni në 1 janar, javën e hënë-diell

Ndërsa formulat e mëparshme kthehen të hënën (ose të dielën) të javës 1, pavarësisht nëse bie brenda këtij viti apo vitit të mëparshëm, kjo formulë e datës së fillimit kthehet gjithmonë 1 janar si datë e fillimit të javës 1 pavarësisht nga dita e javës. Për analogji, formula e datës së përfundimit gjithmonë kthen 31 dhjetor si datë mbarimi të javës së fundit të vitit, pavarësisht nga dita e javës. Në të gjitha aspektet e tjera, këto formula funksionojnë në mënyrë të ngjashme me Formulën 1 më sipër.

Data e fillimit:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Data e përfundimit:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Formula 4. Gjithmonë filloni të numëroni në 1 Janar, javën e Diell-Sat

Për të llogaritur datat e fillimit dhe të mbarimit për një javë të diel - të shtunë, mjafton vetëm një rregullim i vogël në formulat e mësipërme :)

Data e fillimit:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Data e përfundimit:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Si të merrni muajin nga numri i javës

Për të marrë një muaj që korrespondon me javën numër, ju gjeni ditën e parë në një javë të caktuar siç shpjegohet në këtëshembull, dhe më pas mbështilleni atë formulë në funksionin MUAJ Excel si ky:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Shënim. Ju lutemi mbani mend se formula e mësipërme funksionon bazuar në Sistemin e datave të javës ISO , ku java fillon të hënën dhe java që përmban të enjten 1 të vitit konsiderohet java 1. Për shembull, në vitin 2016, e enjtja e parë është 7 janar, dhe kjo është arsyeja pse java e parë fillon më 4 janar 2016.

Si të merrni një numër jave në një muaj (nga 1 në 6)

Nëse logjika e biznesit tuaj kërkon konvertimin e një date specifike në numrin e javës brenda muajit përkatës, mund të përdorni kombinimin e WEEKNUM, Funksionet DATE dhe MONTH:

Duke supozuar se qeliza A2 përmban datën origjinale, përdorni formulën e mëposhtme për një javë duke filluar nga E hënë (vini re 21 në argumentin WEEKNUM return_type):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Për një javë duke filluar nga E diel , hiq argumentin return_type:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Si të shuma e vlerave dhe për të gjetur mesataren sipas numrit të javës

Tani që dini se si të konvertoni një datë në një numër javor në Excel, le të shohim se si mund t'i përdorni numrat e javës në llogaritjet e tjera.

Supozoni , ju keni disa shifra mujore të shitjeve dhe dëshironi të dini totalin për çdo javë.

Për të filluar, le të gjejmë një numër javor që korrespondon me secilën shitje. Nëse datat tuaja janë në kolonën A dhe shitjet në kolonën B, kopjoni formulën =WEEKNUM(A2) përgjatë kolonës C duke filluar në qelizëC2.

Dhe më pas, bëni një listë të numrave të javëve në një kolonë tjetër (të themi, në kolonën E) dhe llogaritni shitjet për çdo javë duke përdorur formulën e mëposhtme SUMIF:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Ku E2 është numri i javës.

Në këtë shembull, ne po punojmë me një listë të shitjeve të marsit, kështu që kemi numrat e javës 10 deri në 14, si demonstruar në pamjen e mëposhtme të ekranit:

Në mënyrë të ngjashme, ju mund të llogarisni mesataren e shitjeve për një javë të caktuar:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Nëse kolona ndihmëse me formulën WEEKNUM nuk përshtatet mirë në paraqitjen e të dhënave tuaja, më vjen keq t'ju them se nuk ka asnjë mënyrë të thjeshtë për ta hequr atë sepse Excel WEEKNUM është një nga ato funksione që nuk pranon argumentet e diapazonit. Prandaj, nuk mund të përdoret brenda SUMPRODUCT ose ndonjë formule tjetër grupi si funksioni MONTH në një skenar të ngjashëm.

Si të theksohen qelizat bazuar në numrin e javës

Le të themi se keni një listë të gjatë të datave në një kolonë dhe dëshironi të nënvizoni vetëm ato që kanë të bëjnë me një javë të caktuar. Gjithçka që ju nevojitet është një rregull i formatimit të kushtëzuar me një formulë WEEKNUM të ngjashme me këtë:

=WEEKNUM($A2)=10

Siç tregohet në pamjen e mëposhtme të ekranit, rregulli thekson shitjet që janë bërë brenda javës së 10-të, që është javën e parë në mars 2015. Meqenëse rregulli zbatohet për A2:B15, ai thekson vlerat në të dyja kolonat. Mund të mësoni më shumë rreth krijimit të rregullave të formatimit të kushtëzuar në këtëtutorial: Formatimi i kushtëzuar i Excel bazuar në një vlerë tjetër qelize.

Kjo është mënyra se si mund të llogaritni numrat e javëve në Excel, të konvertoni numrin e javës në datë dhe të nxirrni numrin e javës nga data. Shpresojmë, formulat WEEKNUM që keni mësuar sot do të jenë të dobishme në fletët tuaja të punës. Në tutorialin e ardhshëm, do të flasim për llogaritjen e moshës dhe viteve në Excel. Ju falënderoj që lexoni dhe shpresoj të shihemi javën tjetër!