در حالی که مایکروسافت اکسل مجموعه‌ای از توابع را برای کار با روزهای هفته، ماه‌ها و سال‌ها ارائه می‌کند، تنها یکی برای هفته‌ها در دسترس است - تابع WEEKNUM. بنابراین، اگر به دنبال راهی برای بدست آوردن یک عدد هفته از تاریخ هستید، WEEKNUM تابعی است که می خواهید.

در این آموزش کوتاه، به طور خلاصه در مورد نحو و آرگومان های Excel WEEKNUM صحبت خواهیم کرد و سپس چند مثال فرمول را مورد بحث قرار دهید که نشان می دهد چگونه می توانید از تابع WEEKNUM برای محاسبه اعداد هفته در کاربرگ های اکسل خود استفاده کنید. در اکسل برای برگرداندن شماره هفته یک تاریخ خاص در سال (عددی بین 1 تا 54) استفاده می شود. دارای دو آرگومان است، اولی لازم است و دومی اختیاری است:

• شماره_سریال - هر تاریخی در هفته که شماره آن را امتحان می کنید برای پیدا کردن این می‌تواند ارجاع به سلولی باشد که حاوی تاریخ است، تاریخی که با استفاده از تابع DATE وارد شده یا با فرمول دیگری برگردانده شده است.
• Return_type (اختیاری) - عددی که تعیین می‌کند کدام یک روز شروع هفته اگر حذف شود، از نوع پیش‌فرض 1 استفاده می‌شود (هفته‌ای که از یکشنبه شروع می‌شود).

در اینجا فهرست کاملی از return_type مقدار پشتیبانی شده در فرمول‌های WEEKNUM وجود دارد.

در تابع WEEKNUM، دو سیستم شماره گذاری هفته مختلف استفاده می شود:

• سیستم 1. هفته حاوی 1 ژانویه در نظر گرفته می شود. هفته اول سال است و هفته 1 شماره گذاری می شود. در این سیستم، هفته به طور سنتی از یکشنبه شروع می شود.
• سیستم 2. این سیستم تاریخ هفته ISO است که بخشی از استاندارد تاریخ و زمان ISO 8601. در این سیستم، هفته از دوشنبه شروع می شود و هفته ای که شامل اولین پنجشنبه سال است، هفته 1 در نظر گرفته می شود. معمولاً به عنوان سیستم شماره گذاری هفته اروپایی شناخته می شود و عمدتاً در دولت و تجارت برای سال های مالی و زمان بندی استفاده می شود. 9>

همه انواع بازگشت فهرست شده در بالا برای سیستم 1 اعمال می شود، به جز نوع برگشتی 21 که در سیستم 2 استفاده می شود.

توجه داشته باشید. در اکسل 2007 و نسخه های قبلی، فقط گزینه های 1 و 2 در دسترس هستند. انواع برگشتی 11 تا 21 فقط در Excel 2010 و Excel 2013 پشتیبانی می شوند.

فرمول های Excel WEEKNUM برای تبدیل تاریخ به شماره هفته (از 1 به 54)

تصویر صفحه زیر نشان می دهد که چگونه می توانید اعداد هفته را از تاریخ ها با ساده ترین فرمول =WEEKNUM(A2) بدست آورید:

در موارد فوقفرمول، آرگومان return_type حذف شده است، به این معنی که از نوع پیش فرض 1 استفاده می شود - هفته ای که از یکشنبه شروع می شود.

اگر ترجیح می دهید با روز دیگری از هفته شروع کنید، مثلا دوشنبه، سپس از 2 استفاده کنید. در آرگومان دوم:

=WEEKNUM(A2, 2)

به جای ارجاع به سلول، می توانید با استفاده از تابع DATE(سال، ماه، روز)، تاریخ را مستقیماً در فرمول مشخص کنید، به عنوان مثال:

=WEEKNUM(DATE(2015,4,15), 2)

فرمول بالا 16 را برمی گرداند، که تعداد هفته حاوی 15 آوریل 2015 است، با هفته ای که از دوشنبه شروع می شود.

در سناریوهای واقعی ، تابع Excel WEEKNUM به ندرت به تنهایی استفاده می شود. همانطور که در مثال های بعدی نشان داده شده است، اغلب از آن در ترکیب با توابع دیگر برای انجام محاسبات مختلف بر اساس شماره هفته استفاده می کنید.

نحوه تبدیل شماره هفته به تاریخ در اکسل

همانطور که شما به تازگی دیدم، تبدیل تاریخ به شماره هفته با استفاده از تابع Excel WEEKNUM کار مهمی نیست. اما اگر به دنبال خلاف آن هستید، یعنی تبدیل یک عدد هفته به تاریخ چه؟ افسوس، هیچ تابع اکسل وجود ندارد که بتواند این کار را فوراً انجام دهد. بنابراین، ما باید فرمول های خود را بسازیم.

فرض کنید شما یک سال در سلول A2 و یک عدد هفته در B2 دارید، و اکنون می خواهید تاریخ شروع و پایان این هفته را محاسبه کنید.

توجه داشته باشید. این مثال فرمول بر اساس اعداد هفته ISO است که یک هفته از دوشنبه شروع می شود.

فرمول بازگشت شروعتاریخ هفته به شرح زیر است:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

که در آن A2 سال و B2 عدد هفته است.

لطفاً توجه داشته باشید که فرمول تاریخ را برمی گرداند. به عنوان شماره سریال، و برای نمایش آن به عنوان تاریخ، باید سلول را بر اساس آن فرمت کنید. می توانید دستورالعمل های دقیق را در تغییر فرمت تاریخ در اکسل بیابید. و این هم نتیجه ای که با فرمول برمی گردد:

البته فرمول تبدیل یک عدد هفته به تاریخ بی اهمیت نیست و ممکن است مدتی طول بکشد تا به دست آید. سر خود را دور منطق. به هر حال، من تمام تلاش خود را می کنم تا برای کسانی که کنجکاو هستند تا به انتها برسند، توضیحات معنی داری ارائه کنم.

همانطور که می بینید، فرمول ما از 2 قسمت تشکیل شده است:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - تاریخ آخرین دوشنبه سال قبل را محاسبه می کند.
• B2 * 7 - تعداد هفته های ضربدر 7 (تعداد روزهای یک هفته) را جمع می کند تا دوشنبه (تاریخ شروع) هفته را بدست آورد. سوال.

در سیستم شماره گذاری هفته ایزو، هفته 1 هفته ای است که شامل اولین پنجشنبه سال می شود. در نتیجه، اولین دوشنبه همیشه بین 29 دسامبر و 4 ژانویه است. بنابراین، برای یافتن آن تاریخ، باید دوشنبه را بلافاصله قبل از 5 ژانویه پیدا کنیم.

در مایکروسافت اکسل، می توانید یک روز از هفته را از آن استخراج کنید. یک تاریخ با استفاده از تابع WEEKDAY. و می توانید از فرمول عمومی زیر برای دریافت دوشنبه بلافاصله قبل از هر تاریخ معین استفاده کنید:

اگر ماهدف نهایی این بود که دوشنبه را بلافاصله قبل از پنجم ژانویه سال در A2 پیدا کنیم، می‌توانیم از توابع DATE زیر استفاده کنیم:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

اما آنچه در واقع به آن نیاز داریم اولین دوشنبه نیست. امسال، بلکه آخرین دوشنبه سال قبل است. بنابراین، باید 7 روز از 5 ژانویه کم کنید و در نتیجه در اولین تابع DATE -2 به دست می آورید:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

در مقایسه با فرمول پیچیده ای که به تازگی یاد گرفته اید، محاسبه تاریخ پایان هفته یک تکه کیک است :) برای دریافت یکشنبه هفته مورد نظر، کافی است 6 روز به تاریخ شروع ، یعنی =D2+6

<اضافه کنید. 23>

از طرف دیگر، می‌توانید 6 را مستقیماً در فرمول اضافه کنید:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

برای اطمینان از اینکه فرمول‌ها همیشه تاریخ‌های مناسب را ارائه می‌دهند، لطفاً به موارد زیر نگاهی بیندازید. اسکرین شات فرمول‌های تاریخ شروع و تاریخ پایان که در بالا توضیح داده شد، به ترتیب در ستون D و E کپی می‌شوند:

روش‌های دیگر برای تبدیل شماره هفته به تاریخ در اکسل

اگر فرمول فوق بر اساس سیستم تاریخ هفته ISO مطابق با الزامات شما نیست، یکی از راه حل های زیر را امتحان کنید.

فرمول 1. یک هفته حاوی Jan-1 هفته 1 است، هفته دوشنبه تا یکشنبه

همانطور که به یاد دارید، فرمول قبلی بر اساس سیستم تاریخ ISO کار می کند که در آن اولین پنجشنبه سال هفته اول در نظر گرفته می شود. از موارد زیر استفاده کنیدفرمول ها:

تاریخ شروع:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

تاریخ پایان:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

فرمول 2. یک هفته حاوی Jan-1 هفته 1 است، هفته یکشنبه و شنبه

این فرمول ها مشابه فرمول های بالا هستند تنها با این تفاوت که نوشته شده اند. برای یکشنبه - شنبه هفته.

تاریخ شروع:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

تاریخ پایان:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7 فرمول 3 این فرمول تاریخ شروع همیشه 1 ژانویه را به عنوان تاریخ شروع هفته 1 بدون توجه به روز هفته برمی گرداند. بر اساس قیاس، فرمول تاریخ پایان همیشه 31 دسامبر را به عنوان تاریخ پایان آخرین هفته در سال، صرف نظر از روز هفته، برمی گرداند. از همه جنبه‌های دیگر، این فرمول‌ها مشابه فرمول 1 بالا عمل می‌کنند.

تاریخ شروع:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

تاریخ پایان:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

فرمول 4. همیشه از اول ژانویه، هفته یکشنبه و شنبه شروع به شمارش کنید

برای محاسبه تاریخ شروع و پایان برای یک هفته یکشنبه تا شنبه، تنها یک تنظیم کوچک در فرمول های بالا لازم است :)

تاریخ شروع:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

تاریخ پایان:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

نحوه دریافت ماه از شماره هفته

برای دریافت یک ماه مطابق با هفته شماره، اولین روز در یک هفته مشخص را همانطور که در این توضیح داده شده است، پیدا می کنیدبه عنوان مثال، و سپس آن فرمول را در تابع MONTH اکسل به شکل زیر بپیچید:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

توجه داشته باشید. لطفاً به یاد داشته باشید که فرمول فوق بر اساس سیستم تاریخ هفته ISO کار می کند، که در آن هفته از دوشنبه شروع می شود و هفته ای که شامل اولین پنجشنبه سال است، هفته 1 در نظر گرفته می شود. به عنوان مثال، در سال 2016، اولین پنجشنبه 7 ژانویه است و به همین دلیل است که هفته اول از 4 ژانویه 2016 آغاز می شود.

نحوه بدست آوردن شماره هفته در ماه (از 1 تا 6)

اگر منطق کسب و کار شما مستلزم تبدیل تاریخ خاصی به شماره هفته در ماه مربوطه است، می توانید از ترکیب WEEKNUM استفاده کنید. توابع DATE و MONTH:

با فرض اینکه سلول A2 حاوی تاریخ اصلی است، از فرمول زیر برای یک هفته از دوشنبه استفاده کنید (به 21 در آرگومان return_type WEEKNUM توجه کنید):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

برای یک هفته از یکشنبه ، آرگومان return_type را حذف کنید:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

چگونه مجموع مقادیر و یافتن میانگین بر اساس شماره هفته

اکنون که می دانید چگونه یک تاریخ را در اکسل به عدد هفته تبدیل کنید، بیایید ببینیم چگونه می توانید از اعداد هفته در محاسبات دیگر استفاده کنید.

فرض کنید ، شما چند رقم فروش ماهانه دارید و می خواهید کل هر هفته را بدانید.

برای شروع، بیایید یک عدد هفته مربوط به هر فروش را پیدا کنیم. اگر تاریخ شما در ستون A و فروش در ستون B است، فرمول =WEEKNUM(A2) را در ستون C که در سلول شروع می شود کپی کنید.C2.

و سپس، فهرستی از اعداد هفته را در ستون دیگری تهیه کنید (مثلاً در ستون E) و فروش هر هفته را با استفاده از فرمول SUMIF زیر محاسبه کنید:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

که در آن E2 عدد هفته است.

در این مثال، ما با لیستی از فروش های ماه مارس کار می کنیم، بنابراین شماره های هفته 10 تا 14 را داریم، به عنوان مثال در تصویر زیر نشان داده شده است:

به روشی مشابه، می توانید میانگین فروش را برای یک هفته مشخص محاسبه کنید:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

اگر ستون کمکی با فرمول WEEKNUM به خوبی با طرح داده های شما مطابقت ندارد، متأسفم به شما بگویم که هیچ راه ساده ای برای خلاص شدن از شر آن وجود ندارد زیرا Excel WEEKNUM یکی از این توابع است. که آرگومان های محدوده را نمی پذیرد. بنابراین، نمی‌توان آن را در SUMPRODUCT یا هر فرمول آرایه دیگری مانند تابع MONTH در یک سناریوی مشابه استفاده کرد.

نحوه برجسته کردن سلول‌ها بر اساس شماره هفته

بیایید فرض کنیم یک لیست طولانی دارید. از تاریخ‌ها در برخی از ستون‌ها استفاده می‌شود و می‌خواهید فقط آن‌هایی را که مربوط به یک هفته خاص هستند برجسته کنید. تنها چیزی که نیاز دارید یک قانون قالب بندی مشروط با فرمول WEEKNUM مشابه این است:

=WEEKNUM($A2)=10

همانطور که در تصویر زیر نشان داده شده است، این قانون فروش هایی را که در هفته 10 انجام شده است برجسته می کند. هفته اول مارس 2015. از آنجایی که این قانون برای A2:B15 اعمال می شود، مقادیر را در هر دو ستون برجسته می کند. در این مطلب می‌توانید درباره ایجاد قوانین قالب‌بندی شرطی اطلاعات بیشتری کسب کنیدآموزش: قالب بندی شرطی اکسل بر اساس مقدار سلول دیگر.

به این ترتیب می توانید اعداد هفته را در اکسل محاسبه کنید، شماره هفته را به تاریخ تبدیل کنید و شماره هفته را از تاریخ استخراج کنید. امیدواریم فرمول های WEEKNUM که امروز آموخته اید در کاربرگ های شما مفید واقع شوند. در آموزش بعدی در مورد محاسبه سن و سال در اکسل صحبت خواهیم کرد. از خواندن شما سپاسگزارم و امیدوارم هفته آینده شما را ببینم!