მიუხედავად იმისა, რომ Microsoft Excel უზრუნველყოფს ფუნქციების მთელ რიგს სამუშაო დღეებთან, თვეებთან და წლებთან მუშაობისთვის, მხოლოდ ერთია ხელმისაწვდომი კვირების განმავლობაში - WEEKNUM ფუნქცია. ასე რომ, თუ თქვენ ეძებთ გზას, რომ მიიღოთ კვირის რიცხვი თარიღიდან, WEEKNUM არის თქვენთვის სასურველი ფუნქცია.

ამ მოკლე სახელმძღვანელოში მოკლედ ვისაუბრებთ Excel WEEKNUM-ის სინტაქსისა და არგუმენტების შესახებ და შემდეგ განიხილეთ რამდენიმე ფორმულის მაგალითი, რომლებიც აჩვენებენ, თუ როგორ შეგიძლიათ გამოიყენოთ WEEKNUM ფუნქცია თქვენი Excel-ის სამუშაო ფურცლებში კვირის ნომრების გამოსათვლელად.

Excel WEEKNUM ფუნქცია - სინტაქსი

WEEKNUM ფუნქცია არის გამოიყენება Excel-ში წელიწადის კონკრეტული თარიღის კვირის ნომრის დასაბრუნებლად (რიცხვი 1-დან 54-მდე). მას აქვს ორი არგუმენტი, პირველი სავალდებულოა, ხოლო მეორე არჩევითი:

• სერიული_ნომერი - კვირის ნებისმიერი თარიღი, რომლის ნომერსაც ცდილობთ პოვნა. ეს შეიძლება იყოს მითითება უჯრედზე, რომელიც შეიცავს თარიღს, თარიღს, რომელიც შეყვანილია DATE ფუნქციის გამოყენებით ან დაბრუნებულია სხვა ფორმულით.
• Return_type (სურვილისამებრ) - რიცხვი, რომელიც განსაზღვრავს, თუ რომელი კვირის დაწყების დღე. თუ გამოტოვებულია, გამოიყენება ნაგულისხმევი ტიპი 1 (კვირა იწყება კვირას).

აქ არის WEEKNUM ფორმულებში მხარდაჭერილი return_type მნიშვნელობების სრული სია.

WEEKNUM ფუნქციაში გამოიყენება ორი განსხვავებული კვირის ნუმერაციის სისტემა :

• სისტემა 1. ითვლება კვირა, რომელიც შეიცავს 1 იანვარს. წელიწადის 1 კვირა და დანომრილია კვირა 1. ამ სისტემაში კვირა ტრადიციულად იწყება კვირას.
• სისტემა 2. ეს არის ISO კვირის თარიღის სისტემა, რომელიც არის ნაწილი ISO 8601 თარიღისა და დროის სტანდარტი. ამ სისტემაში კვირა იწყება ორშაბათს და კვირა, რომელიც შეიცავს წლის პირველ ხუთშაბათს, ითვლება 1 კვირა. ის საყოველთაოდ ცნობილია, როგორც ევროპული კვირის ნუმერაციის სისტემა და ის ძირითადად გამოიყენება მთავრობასა და ბიზნესში ფისკალური წლებისა და დროის აღრიცხვისთვის.

ყველა ზემოთ ჩამოთვლილი დაბრუნების ტიპი ვრცელდება სისტემა 1-ზე, გარდა დაბრუნების ტიპის 21-ისა, რომელიც გამოიყენება სისტემა 2-ში.

შენიშვნა. Excel 2007 და ადრინდელ ვერსიებში ხელმისაწვდომია მხოლოდ 1 და 2 ვარიანტები. დაბრუნების ტიპები 11-დან 21-მდე მხარდაჭერილია მხოლოდ Excel 2010-სა და Excel 2013-ში.

Excel WEEKNUM ფორმულები თარიღის კვირის რიცხვზე გადასაყვანად (1-დან 54-მდე)

შემდეგი ეკრანის ანაბეჭდი აჩვენებს, თუ როგორ შეგიძლიათ მიიღოთ კვირის ნომრები თარიღებიდან უმარტივესი =WEEKNUM(A2) ფორმულით:

ზემოთფორმულა, return_type არგუმენტი გამოტოვებულია, რაც ნიშნავს, რომ გამოყენებულია ნაგულისხმევი ტიპი 1 - კვირა დაწყებული კვირა.

თუ გირჩევნიათ კვირის სხვა დღით დავიწყოთ, ვთქვათ ორშაბათი, შემდეგ გამოიყენეთ 2. მეორე არგუმენტში:

=WEEKNUM(A2, 2)

უჯრედზე მითითების ნაცვლად, შეგიძლიათ მიუთითოთ თარიღი პირდაპირ ფორმულაში DATE(წელი, თვე, დღე) ფუნქციის გამოყენებით, მაგალითად:

=WEEKNUM(DATE(2015,4,15), 2)

ზემოხსენებული ფორმულა აბრუნებს 16-ს, რაც არის კვირის რიცხვი, რომელიც შეიცავს 2015 წლის 15 აპრილს, კვირას, რომელიც იწყება ორშაბათს.

რეალურ სცენარებში. Excel WEEKNUM ფუნქცია იშვიათად გამოიყენება დამოუკიდებლად. ყველაზე ხშირად იყენებდით მას სხვა ფუნქციებთან კომბინაციაში კვირის რიცხვის მიხედვით სხვადასხვა გამოთვლების შესასრულებლად, როგორც ეს ნაჩვენებია შემდგომ მაგალითებში.

როგორ გადაიყვანოთ კვირის რიცხვი თარიღად Excel-ში

როგორც თქვენ ახლახან ვნახე, დიდი საქმე არ არის თარიღის კვირის რიცხვად გადაქცევა Excel WEEKNUM ფუნქციის გამოყენებით. მაგრამ რა მოხდება, თუ თქვენ ეძებთ საპირისპიროს, ანუ კვირის რიცხვის თარიღად გადაქცევას? სამწუხაროდ, არ არსებობს Excel ფუნქცია, რომელსაც შეუძლია ამის გაკეთება დაუყოვნებლივ. ასე რომ, ჩვენ მოგვიწევს საკუთარი ფორმულების აგება.

დავუშვათ, რომ თქვენ გაქვთ წელი A2 უჯრედში და კვირის ნომერი B2-ში და ახლა გსურთ გამოთვალოთ დაწყების და დასრულების თარიღები ამ კვირაში.

შენიშვნა. ეს ფორმულის მაგალითი დაფუძნებულია ISO კვირის ნომრებზე, კვირა იწყება ორშაბათს.

ფორმულა დაწყების დასაბრუნებლადკვირის თარიღი არის შემდეგი:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

სადაც A2 არის წელი და B2 არის კვირის ნომერი.

გთხოვთ, გაითვალისწინოთ, რომ ფორმულა აბრუნებს თარიღს სერიული ნომრის სახით და თარიღად რომ გამოჩნდეს, საჭიროა უჯრედის შესაბამისად ფორმატირება. თქვენ შეგიძლიათ იპოვოთ დეტალური ინსტრუქციები თარიღის შეცვლა ფორმატში Excel-ში. და აი, შედეგი დაბრუნებული ფორმულით:

რა თქმა უნდა, კვირის რიცხვის თარიღად გადაქცევის ფორმულა არ არის ტრივიალური და მის მიღებას შეიძლება გარკვეული დრო დასჭირდეს შენი თავი ლოგიკის გარშემო. ყოველ შემთხვევაში, ყველაფერს გავაკეთებ იმისათვის, რომ მნიშვნელოვანი ახსნა მივაწოდო მათ, ვისაც აინტერესებს ბოლოში ჩასვლა.

როგორც ხედავთ, ჩვენი ფორმულა შედგება 2 ნაწილისგან:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - ითვლის წინა წლის ბოლო ორშაბათის თარიღს.
• B2 * 7 - ამატებს 7-ზე გამრავლებული კვირების რაოდენობას (კვირის დღეების რაოდენობა), რათა მიიღოთ კვირის ორშაბათი (დაწყების თარიღი) კითხვა.

ISO კვირის ნუმერაციის სისტემაში 1 კვირა არის კვირა, რომელიც შეიცავს წლის პირველ ხუთშაბათს. შესაბამისად, პირველი ორშაბათი ყოველთვის 29 დეკემბრიდან 4 იანვრამდეა. ასე რომ, ამ თარიღის საპოვნელად, ჩვენ უნდა ვიპოვოთ ორშაბათი 5 იანვრის წინ.

Microsoft Excel-ში შეგიძლიათ კვირის დღეების ამოღება. თარიღი WEEKDAY ფუნქციის გამოყენებით. და თქვენ შეგიძლიათ გამოიყენოთ შემდეგი ზოგადი ფორმულა ორშაბათის მისაღებად ნებისმიერ მოცემულ თარიღამდე:

თუ ჩვენისაბოლოო მიზანი იყო ორშაბათის მოძებნა წლის 5 იანვრამდე A2-ში, ჩვენ შეგვიძლია გამოვიყენოთ შემდეგი DATE ფუნქციები:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

მაგრამ ის, რაც რეალურად გვჭირდება, არ არის პირველი ორშაბათი. წელს, არამედ წინა წლის ბოლო ორშაბათს. ასე რომ, თქვენ უნდა გამოაკლოთ 7 დღე 5 იანვრიდან და, შესაბამისად, მიიღებთ -2-ს პირველ DATE ფუნქციაში:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

თქვენ მიერ ახლახან ნასწავლი რთულ ფორმულასთან შედარებით, გამოთვალეთ კვირის დასრულების თარიღი არის ნამცხვარი :) იმისათვის, რომ მიიღოთ მოცემული კვირის კვირა, თქვენ უბრალოდ დაამატეთ 6 დღე დაწყების თარიღს , ანუ =D2+6

<. 23>

ალტერნატიულად, შეგიძლიათ დაამატოთ 6 პირდაპირ ფორმულაში:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

იმისათვის, რომ დარწმუნდეთ, რომ ფორმულები ყოველთვის სწორ თარიღებს აწვდიან, გთხოვთ, გადახედოთ შემდეგს. ეკრანის ანაბეჭდი. ზემოთ განხილული დაწყების თარიღის და დასრულების თარიღის ფორმულები კოპირებულია სვეტებში D და E, შესაბამისად:

კვირის რიცხვის თარიღად გადაქცევის სხვა გზები Excel-ში

თუ ზემოაღნიშნული ფორმულა, რომელიც დაფუძნებულია ISO კვირის თარიღის სისტემაზე, არ აკმაყოფილებს თქვენს მოთხოვნებს, სცადეთ ერთ-ერთი შემდეგი გადაწყვეტა.

ფორმულა 1. კვირა, რომელიც შეიცავს იან-1 არის კვირა 1, ორშაბათი-მზე კვირა

როგორც გახსოვთ, წინა ფორმულა მუშაობს ISO თარიღის სისტემაზე დაყრდნობით, სადაც წლის პირველი ხუთშაბათი ითვლება 1 კვირა. თუ მუშაობთ თარიღის სისტემაზე დაყრდნობით, სადაც კვირა, რომელიც შეიცავს 1 იანვარს, ითვლება 1 კვირა, გამოიყენეთ შემდეგიფორმულები:

დაწყების თარიღი:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

დამთავრების თარიღი:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

ფორმულა 2. კვირა, რომელიც შეიცავს იან-1-ს არის კვირა 1, მზე-შაბათი კვირა

ეს ფორმულები მსგავსია ზემოხსენებულის იმ განსხვავებით, რომ ისინი დაწერილია. კვირა - შაბათი კვირისთვის.

დაწყების თარიღი:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

დამთავრების თარიღი:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

ფორმულა 3. ყოველთვის დაიწყეთ თვლა 1 იანვარს, ორშაბათს-მზის კვირას

მაშინ, როცა წინა ფორმულები ბრუნდება 1 კვირის ორშაბათს (ან კვირას), მიუხედავად ამ დაწყების თარიღის ფორმულა ყოველთვის იბრუნებს 1 იანვარს , როგორც 1 კვირის დაწყების თარიღს, მიუხედავად კვირის დღისა. ანალოგიით, დასრულების თარიღის ფორმულა ყოველთვის აბრუნებს 31 დეკემბერს , როგორც წლის ბოლო კვირის ბოლოს, კვირის დღის მიუხედავად. ყველა სხვა თვალსაზრისით, ეს ფორმულები მუშაობს ზემოთ ფორმულა 1-ის მსგავსად.

დაწყების თარიღი:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

დამთავრების თარიღი:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

ფორმულა 4. ყოველთვის დაიწყეთ დათვლა 1 იანვარს, მზე-შაბათ კვირას

დაწყების და დასრულების თარიღების გამოსათვლელად კვირა-შაბათი კვირისთვის საკმარისია მხოლოდ ერთი მცირე კორექტირება ზემოთ მოცემულ ფორმულებში :)

დაწყების თარიღი:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

დამთავრების თარიღი:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

როგორ მივიღოთ თვე კვირის ნომრიდან

მიიღოთ კვირის შესაბამისი თვე ნომერი, თქვენ იპოვით მოცემულ კვირაში პირველ დღეს, როგორც ეს აღწერილიამაგალითად, და შემდეგ გადაიტანეთ ეს ფორმულა Excel MONTH ფუნქციაში ასე:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

შენიშვნა. გახსოვდეთ, რომ ზემოაღნიშნული ფორმულა მუშაობს ISO კვირის თარიღების სისტემაზე , სადაც კვირა იწყება ორშაბათს და კვირა, რომელიც შეიცავს წლის პირველ ხუთშაბათს, ითვლება კვირა 1. მაგალითად, 2016 წელს, პირველი ხუთშაბათი არის 7 იანვარი და ამიტომ პირველი კვირა იწყება 4-იან-2016.

როგორ მივიღოთ კვირის რიცხვი თვეში (1-დან 6-მდე)

თუ თქვენი ბიზნეს ლოგიკა მოითხოვს კონკრეტული თარიღის კვირის რიცხვად გადაყვანას შესაბამის თვეში, შეგიძლიათ გამოიყენოთ WEEKNUM-ის კომბინაცია, DATE და MONTH ფუნქციები:

თუ ვივარაუდებთ, რომ უჯრედი A2 შეიცავს თავდაპირველ თარიღს, გამოიყენეთ შემდეგი ფორმულა ერთი კვირისთვის, რომელიც იწყება ორშაბათს (შენიშნეთ 21 WEEKNUM-ის return_type არგუმენტში):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

ერთი კვირის განმავლობაში, დაწყებული კვირა , გამოტოვეთ return_type არგუმენტი:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

როგორ ჯამის მნიშვნელობები და იპოვეთ საშუალო კვირის რიცხვის მიხედვით

ახლა, როცა იცით, როგორ გადაიყვანოთ თარიღი კვირის რიცხვად Excel-ში, ვნახოთ, როგორ შეგიძლიათ გამოიყენოთ კვირის ნომრები სხვა გამოთვლებში.

დავუშვათ, , თქვენ გაქვთ თვიური გაყიდვების მაჩვენებლები და გსურთ იცოდეთ ჯამი ყოველი კვირისთვის.

დასაწყისად, მოდით გავარკვიოთ ყოველი გაყიდვის შესაბამისი კვირის რიცხვი. თუ თქვენი თარიღები არის A სვეტში და გაყიდვები სვეტში B, დააკოპირეთ =WEEKNUM(A2) ფორმულა C სვეტში, უჯრედიდან დაწყებულიC2.

და შემდეგ შეადგინეთ კვირის ნომრების სია სხვა სვეტში (მაგალითად, სვეტში E) და გამოთვალეთ გაყიდვები ყოველი კვირისთვის შემდეგი SUMIF ფორმულის გამოყენებით:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

სადაც E2 არის კვირის ნომერი.

ამ მაგალითში, ჩვენ ვმუშაობთ მარტის გაყიდვების ჩამონათვალზე, ასე რომ, გვაქვს კვირის ნომრები 10-დან 14-მდე, როგორც ნაჩვენებია შემდეგ ეკრანის სურათზე:

მსგავსი წესით, შეგიძლიათ გამოთვალოთ გაყიდვების საშუალო მაჩვენებელი მოცემული კვირისთვის:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

თუ დამხმარე სვეტი WEEKNUM ფორმულით კარგად არ ჯდება თქვენს მონაცემთა განლაგებაში, ვნანობ, გითხრათ, რომ არ არსებობს მარტივი გზა მისგან თავის დასაღწევად, რადგან Excel WEEKNUM ერთ-ერთი ასეთი ფუნქციაა. რომელიც არ იღებს დიაპაზონის არგუმენტებს. მაშასადამე, მისი გამოყენება შეუძლებელია SUMPRODUCT-ში ან მასივის სხვა ფორმულაში, როგორიცაა MONTH ფუნქცია მსგავს სცენარში.

როგორ გამოვყოთ უჯრედები კვირის რიცხვზე დაყრდნობით

ვთქვათ, რომ გაქვთ გრძელი სია. თარიღების ზოგიერთ სვეტში და გსურთ მონიშნოთ მხოლოდ ის, რაც ეხება მოცემულ კვირას. ყველაფერი რაც თქვენ გჭირდებათ არის პირობითი ფორმატირების წესი WEEKNUM მსგავსი ფორმულით:

=WEEKNUM($A2)=10

როგორც ნაჩვენებია ქვემოთ მოცემულ ეკრანის სურათზე, წესი ხაზს უსვამს გაყიდვებს, რომლებიც განხორციელდა მე-10 კვირაში, რაც არის 2015 წლის მარტის პირველი კვირა. ვინაიდან წესი ვრცელდება A2:B15-ზე, ის ხაზს უსვამს მნიშვნელობებს ორივე სვეტში. თქვენ შეგიძლიათ გაიგოთ მეტი პირობითი ფორმატირების წესების შექმნის შესახებსახელმძღვანელო: Excel-ის პირობითი ფორმატირება სხვა უჯრედის მნიშვნელობის საფუძველზე.

ასე შეგიძლიათ გამოთვალოთ კვირის ნომრები Excel-ში, გადაიყვანოთ კვირის რიცხვი თარიღად და ამოიღოთ კვირის ნომერი თარიღიდან. იმედია, WEEKNUM ფორმულები, რომლებიც დღეს ისწავლეთ, სასარგებლო იქნება თქვენს სამუშაო ფურცლებში. შემდეგ გაკვეთილზე ვისაუბრებთ Excel-ში ასაკისა და წლების გამოთვლაზე. მადლობას გიხდით რომ კითხულობთ და იმედი მაქვს მომავალ კვირას შევხვდებით!