जबकि Microsoft Excel सप्ताह के दिनों, महीनों और वर्षों के साथ काम करने के लिए कार्यों की एक श्रृंखला प्रदान करता है, सप्ताहों के लिए केवल एक ही उपलब्ध है - WEEKNUM फ़ंक्शन। इसलिए, यदि आप किसी दिनांक से सप्ताह संख्या प्राप्त करने का कोई तरीका ढूंढ रहे हैं, तो WEEKNUM वह फ़ंक्शन है जो आप चाहते हैं।

इस संक्षिप्त ट्यूटोरियल में, हम संक्षेप में एक्सेल WEEKNUM के सिंटैक्स और तर्कों के बारे में बात करेंगे, और फिर कुछ सूत्र उदाहरणों पर चर्चा करें कि आप अपने एक्सेल वर्कशीट में सप्ताह संख्या की गणना करने के लिए WEEKNUM फ़ंक्शन का उपयोग कैसे कर सकते हैं।

एक्सेल WEEKNUM फ़ंक्शन - सिंटैक्स

WEEKNUM फ़ंक्शन है वर्ष में किसी विशिष्ट तिथि की सप्ताह संख्या (1 और 54 के बीच की संख्या) वापस करने के लिए एक्सेल में उपयोग किया जाता है। इसके दो तर्क हैं, पहला आवश्यक है और दूसरा वैकल्पिक है:

• Serial_number - सप्ताह के भीतर कोई भी दिनांक जिसका नंबर आप आज़मा रहे हैं ढूँढ़ने के लिए। यह दिनांक वाले सेल का संदर्भ हो सकता है, दिनांक फ़ंक्शन का उपयोग करके दर्ज किया गया दिनांक या किसी अन्य सूत्र द्वारा लौटाया गया। दिन सप्ताह शुरू होता है। यदि छोड़ा जाता है, तो डिफ़ॉल्ट प्रकार 1 का उपयोग किया जाता है (रविवार से शुरू होने वाला सप्ताह)।

WEEKNUM सूत्रों में समर्थित return_type मानों की पूरी सूची यहां दी गई है।

WEEKNUM फ़ंक्शन में, दो भिन्न सप्ताह क्रमांकन सिस्टम का उपयोग किया जाता है:

• सिस्टम 1. 1 जनवरी वाले सप्ताह को माना जाता है वर्ष का पहला सप्ताह और सप्ताह 1 गिना जाता है। इस प्रणाली में, सप्ताह पारंपरिक रूप से रविवार को शुरू होता है।
• सिस्टम 2। यह आईएसओ सप्ताह तिथि प्रणाली है जो कि आईएसओ 8601 दिनांक और समय मानक। इस प्रणाली में, सप्ताह सोमवार से शुरू होता है और वर्ष के पहले गुरुवार वाले सप्ताह को सप्ताह 1 माना जाता है। इसे आमतौर पर यूरोपीय सप्ताह संख्या प्रणाली के रूप में जाना जाता है और इसका उपयोग मुख्य रूप से सरकार और व्यापार में वित्तीय वर्षों और टाइमकीपिंग के लिए किया जाता है।

ऊपर सूचीबद्ध सभी रिटर्न प्रकार सिस्टम 1 पर लागू होते हैं, सिस्टम 2 में उपयोग किए जाने वाले रिटर्न प्रकार 21 को छोड़कर।

नोट। Excel 2007 और पुराने संस्करणों में, केवल विकल्प 1 और 2 उपलब्ध हैं। रिटर्न प्रकार 11 से 21 केवल Excel 2010 और Excel 2013 में समर्थित हैं।

एक्सेल WEEKNUM सूत्र दिनांक को सप्ताह संख्या में बदलने के लिए (1 से 54 तक)

निम्नलिखित स्क्रीनशॉट दर्शाता है कि आप सबसे सरल =WEEKNUM(A2) सूत्र के साथ दिनांक से सप्ताह संख्या कैसे प्राप्त कर सकते हैं:

<18

उपरोक्त मेंसूत्र, return_type तर्क छोड़ दिया गया है, जिसका अर्थ है कि डिफ़ॉल्ट प्रकार 1 का उपयोग किया जाता है - रविवार से शुरू होने वाला सप्ताह।

यदि आप सप्ताह के किसी अन्य दिन से शुरू करना चाहते हैं, तो सोमवार कहें, फिर 2 दूसरे तर्क में:

=WEEKNUM(A2, 2)

किसी सेल को संदर्भित करने के बजाय, आप DATE(वर्ष, माह, दिन) फ़ंक्शन का उपयोग करके सीधे सूत्र में दिनांक निर्दिष्ट कर सकते हैं, उदाहरण के लिए:

=WEEKNUM(DATE(2015,4,15), 2)

उपरोक्त सूत्र 16 लौटाता है, जो 15 अप्रैल, 2015 वाले सप्ताह की संख्या है, जिसमें एक सप्ताह सोमवार से शुरू होता है।

वास्तविक जीवन परिदृश्य में , एक्सेल WEEKNUM फ़ंक्शन शायद ही कभी अपने आप में प्रयोग किया जाता है। जैसा कि आगे के उदाहरणों में दिखाया गया है, अक्सर आप सप्ताह संख्या के आधार पर विभिन्न गणना करने के लिए अन्य कार्यों के संयोजन में इसका उपयोग करेंगे।

एक्सेल में सप्ताह संख्या को दिनांक में कैसे परिवर्तित करें

जैसा कि आप अभी देखा है, Excel WEEKNUM फ़ंक्शन का उपयोग करके दिनांक को सप्ताह संख्या में बदलना कोई बड़ी बात नहीं है। लेकिन क्या होगा यदि आप विपरीत की तलाश कर रहे हैं, यानी एक सप्ताह की संख्या को एक तिथि में परिवर्तित करना? काश, ऐसा कोई एक्सेल फंक्शन नहीं होता जो इसे तुरंत कर सके। इसलिए, हमें अपने स्वयं के सूत्र बनाने होंगे।

मान लें कि आपके पास कक्ष A2 में एक वर्ष और B2 में एक सप्ताह संख्या है, और अब आप इस सप्ताह में प्रारंभ और समाप्ति तिथियों की गणना करना चाहते हैं।

ध्यान दें। यह सूत्र उदाहरण सोमवार से शुरू होने वाले सप्ताह के साथ ISO सप्ताह संख्याओं पर आधारित है।

वापसी का सूत्र प्रारंभ करेंदिनांक सप्ताह इस प्रकार है:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

जहां A2 वर्ष है और B2 सप्ताह संख्या है।

कृपया ध्यान दें कि सूत्र दिनांक लौटाता है एक सीरियल नंबर के रूप में, और इसे एक तिथि के रूप में प्रदर्शित करने के लिए, आपको तदनुसार सेल को प्रारूपित करना होगा। आप एक्सेल में चेंजिंग डेट फॉर्मेट में विस्तृत निर्देश पा सकते हैं। और यहाँ सूत्र द्वारा लौटाया गया परिणाम है:

बेशक, सप्ताह संख्या को दिनांक में बदलने का सूत्र मामूली नहीं है, और इसे प्राप्त करने में कुछ समय लग सकता है आपका सिर तर्क के चारों ओर। वैसे भी, मैं उन लोगों के लिए सार्थक व्याख्या प्रदान करने की पूरी कोशिश करूँगा जो नीचे जाने के लिए उत्सुक हैं।

जैसा कि आप देखते हैं, हमारे सूत्र में 2 भाग होते हैं:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - पिछले वर्ष के अंतिम सोमवार की तिथि की गणना करता है। प्रश्न।

आईएसओ सप्ताह संख्या प्रणाली में, सप्ताह 1 वह सप्ताह है जिसमें वर्ष का पहला गुरुवार होता है। नतीजतन, पहला सोमवार हमेशा 29 दिसंबर और 4 जनवरी के बीच होता है। इसलिए, उस तिथि को खोजने के लिए, हमें 5 जनवरी से ठीक पहले सोमवार को खोजना होगा।

माइक्रोसॉफ्ट एक्सेल में, आप सप्ताह का एक दिन निकाल सकते हैं WEEKDAY फ़ंक्शन का उपयोग करके दिनांक। और आप किसी भी तारीख से ठीक पहले सोमवार प्राप्त करने के लिए निम्न सामान्य सूत्र का उपयोग कर सकते हैं:

अगरअंतिम लक्ष्य A2 में वर्ष की 5 जनवरी से ठीक पहले सोमवार को खोजना था, हम निम्नलिखित DATE फ़ंक्शंस का उपयोग कर सकते हैं:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

लेकिन हमें वास्तव में जो चाहिए वह पहला सोमवार नहीं है इस साल, बल्कि पिछले साल के आखिरी सोमवार। इसलिए, आपको 5 जनवरी से 7 दिन घटाना है और इसलिए आपको पहले DATE फ़ंक्शन में -2 मिलता है:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

आपके द्वारा अभी-अभी सीखे गए ट्रिकी फॉर्मूले की तुलना में, <7 की गणना करना>सप्ताह की समाप्ति तिथि केक का एक टुकड़ा है :) प्रश्न में सप्ताह का रविवार प्राप्त करने के लिए, आप केवल प्रारंभ तिथि में 6 दिन जोड़ते हैं, अर्थात =D2+6

वैकल्पिक रूप से, आप सूत्र में सीधे 6 जोड़ सकते हैं:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

यह सुनिश्चित करने के लिए कि सूत्र हमेशा सही दिनांक प्रदान करते हैं, कृपया निम्नलिखित पर एक नज़र डालें स्क्रीनशॉट। ऊपर चर्चा की गई आरंभ तिथि और समाप्ति तिथि सूत्र क्रमशः कॉलम डी और ई में कॉपी किए गए हैं:

एक्सेल में सप्ताह संख्या को तिथि में बदलने के अन्य तरीके

यदि ISO सप्ताह दिनांक प्रणाली पर आधारित उपरोक्त सूत्र आपकी आवश्यकताओं को पूरा नहीं करता है, तो निम्न समाधानों में से किसी एक का प्रयास करें।

फ़ॉर्मूला 1. जनवरी -1 वाला सप्ताह सप्ताह 1, सोम-रवि सप्ताह है

जैसा कि आपको याद है, पिछला सूत्र ISO तिथि प्रणाली पर आधारित है जहां वर्ष के पहले गुरुवार को सप्ताह 1 माना जाता है। यदि आप दिनांक प्रणाली के आधार पर काम करते हैं जहां 1 जनवरी वाले सप्ताह को 1 सप्ताह माना जाता है निम्न का उपयोग करेंसूत्र:

प्रारंभ तिथि:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

अंतिम तिथि:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

सूत्र 2। जनवरी -1 वाला सप्ताह 1, सूर्य-शनि सप्ताह है

ये सूत्र उपर्युक्त के समान हैं, केवल अंतर यह है कि वे लिखे गए हैं रविवार - शनिवार सप्ताह के लिए।

प्रारंभ तिथि:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

समाप्ति तिथि:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

फॉर्मूला 3. हमेशा 1 जनवरी, सोम-रवि सप्ताह पर गिनती शुरू करें

जबकि पिछले सूत्र सप्ताह 1 के सोमवार (या रविवार) को लौटाते हैं, भले ही इस वर्ष या पिछले वर्ष के भीतर आता है या नहीं, यह आरंभ तिथि सूत्र हमेशा जनवरी 1 सप्ताह के दिन की परवाह किए बिना सप्ताह 1 की प्रारंभ तिथि के रूप में देता है। सादृश्य से, समाप्ति तिथि सूत्र हमेशा 31 दिसंबर को वर्ष के अंतिम सप्ताह की समाप्ति तिथि के रूप में लौटाता है, सप्ताह के दिन की परवाह किए बिना। अन्य सभी मामलों में, ये सूत्र उपरोक्त सूत्र 1 के समान ही काम करते हैं।

प्रारंभ तिथि:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

अंतिम तिथि:<8

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

फॉर्मूला 4. हमेशा 1 जनवरी, सूर्य-शनि सप्ताह से गिनती शुरू करें

प्रारंभ और समाप्ति तिथियों की गणना करने के लिए रविवार-शनिवार सप्ताह के लिए, उपरोक्त सूत्रों में केवल एक छोटा सा समायोजन करना पड़ता है:)

प्रारंभ तिथि:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

समाप्ति तिथि:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

सप्ताह संख्या से माह कैसे प्राप्त करें

सप्ताह के अनुरूप माह प्राप्त करने के लिए संख्या, आप दिए गए सप्ताह में पहला दिन पाते हैं जैसा कि इसमें बताया गया हैउदाहरण, और फिर उस फॉर्मूले को एक्सेल मंथ फंक्शन में इस तरह रैप करें:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

नोट। कृपया याद रखें कि उपरोक्त सूत्र आईएसओ सप्ताह तिथि प्रणाली पर आधारित है, जहां सप्ताह सोमवार को शुरू होता है और वर्ष के पहले गुरुवार वाले सप्ताह को सप्ताह 1 माना जाता है। उदाहरण के लिए, वर्ष 2016 में, पहला गुरुवार 7 जनवरी है, और इसीलिए सप्ताह 1 4-जनवरी-2016 से शुरू होता है।

एक महीने में एक सप्ताह संख्या कैसे प्राप्त करें (1 से 6 तक)

यदि आपके व्यावसायिक तर्क को संबंधित महीने के भीतर एक विशिष्ट तिथि को सप्ताह संख्या में बदलने की आवश्यकता है, तो आप WEEKNUM के संयोजन का उपयोग कर सकते हैं, DATE और MONTH फ़ंक्शन:

यह मानते हुए कि सेल A2 में मूल दिनांक शामिल है, सोमवार से शुरू होने वाले सप्ताह के लिए निम्न सूत्र का उपयोग करें (WEEKNUM के रिटर्न_टाइप तर्क में नोटिस 21):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

रविवार से शुरू होने वाले एक सप्ताह के लिए, return_type तर्क को छोड़ दें:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

कैसे करें मानों का योग करें और सप्ताह की संख्या से औसत निकालें

अब जब आप जानते हैं कि Excel में किसी दिनांक को सप्ताह की संख्या में कैसे परिवर्तित किया जाता है, तो आइए देखें कि आप अन्य गणनाओं में सप्ताह संख्याओं का उपयोग कैसे कर सकते हैं।

मान लीजिए , आपके पास मासिक बिक्री के कुछ आंकड़े हैं और आप प्रत्येक सप्ताह के लिए कुल राशि जानना चाहते हैं।

शुरुआत में, आइए प्रत्येक बिक्री से संबंधित एक सप्ताह संख्या ज्ञात करें। यदि आपकी तिथियां कॉलम ए में हैं और बिक्री कॉलम बी में है, तो सेल में शुरू होने वाले कॉलम सी में =WEEKNUM(A2) सूत्र की प्रतिलिपि बनाएँC2.

और फिर, किसी अन्य कॉलम (जैसे, कॉलम E में) में सप्ताह की संख्या की एक सूची बनाएं और निम्नलिखित SUMIF सूत्र का उपयोग करके प्रत्येक सप्ताह की बिक्री की गणना करें:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

जहां E2 सप्ताह की संख्या है।

इस उदाहरण में, हम मार्च की बिक्री की सूची के साथ काम कर रहे हैं, इसलिए हमारे पास सप्ताह संख्या 10 से 14 है, जैसा कि निम्नलिखित स्क्रीनशॉट में दिखाया गया है:

इसी तरह, आप किसी दिए गए सप्ताह के लिए औसत बिक्री की गणना कर सकते हैं:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

यदि WEEKNUM सूत्र वाला हेल्पर कॉलम आपके डेटा लेआउट में अच्छी तरह से फिट नहीं होता है, तो मुझे आपको यह बताते हुए खेद है कि इससे छुटकारा पाने का कोई आसान तरीका नहीं है क्योंकि एक्सेल WEEKNUM उन कार्यों में से एक है वह श्रेणी तर्कों को स्वीकार नहीं करता है। इसलिए, इसे समान परिदृश्य में SUMPRODUCT या किसी अन्य सरणी सूत्र जैसे MONTH फ़ंक्शन के भीतर उपयोग नहीं किया जा सकता है।

सप्ताह संख्या के आधार पर सेल को कैसे हाइलाइट करें

मान लें कि आपके पास एक लंबी सूची है किसी कॉलम में तारीखों की संख्या और आप केवल उन्हीं को हाइलाइट करना चाहते हैं जो किसी दिए गए सप्ताह से संबंधित हैं। आपको केवल इसी तरह के WEEKNUM सूत्र के साथ एक सशर्त स्वरूपण नियम की आवश्यकता है:

=WEEKNUM($A2)=10

जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, नियम 10 सप्ताह के भीतर की गई बिक्री को हाइलाइट करता है, जो कि मार्च 2015 में पहला सप्ताह। चूँकि नियम A2:B15 पर लागू होता है, यह दोनों स्तंभों में मानों को हाइलाइट करता है। आप इसमें सशर्त स्वरूपण नियम बनाने के बारे में अधिक जान सकते हैंट्यूटोरियल: अन्य सेल मान के आधार पर एक्सेल सशर्त स्वरूपण।

इस तरह आप एक्सेल में सप्ताह की संख्या की गणना कर सकते हैं, सप्ताह की संख्या को तिथि में परिवर्तित कर सकते हैं और सप्ताह की संख्या को तिथि से निकाल सकते हैं। उम्मीद है, आज आपने जो WEEKNUM सूत्र सीखे हैं, वे आपके वर्कशीट में उपयोगी साबित होंगे। अगले ट्यूटोरियल में हम एक्सेल में उम्र और साल की गणना के बारे में बात करेंगे। मैं आपको पढ़ने के लिए धन्यवाद देता हूं और उम्मीद करता हूं कि अगले हफ्ते आपसे मुलाकात होगी!