Mặc dù Microsoft Excel cung cấp một loạt các hàm để làm việc với ngày trong tuần, tháng và năm nhưng chỉ có một hàm khả dụng cho tuần - hàm WEEKNUM. Vì vậy, nếu bạn đang tìm cách lấy số tuần từ một ngày, thì WEEKNUM là hàm bạn muốn.

Trong hướng dẫn ngắn này, chúng ta sẽ nói ngắn gọn về cú pháp và đối số của WEEKNUM trong Excel và sau đó thảo luận về một số ví dụ về công thức minh họa cách bạn có thể sử dụng hàm WEEKNUM để tính số tuần trong trang tính Excel của mình.

Hàm WEEKNUM Excel - cú pháp

Hàm WEEKNUM là được sử dụng trong Excel để trả về số tuần của một ngày cụ thể trong năm (một số từ 1 đến 54). Nó có hai đối số, đối số thứ nhất là bắt buộc và đối số thứ hai là tùy chọn:

• Serial_number - bất kỳ ngày nào trong tuần có số bạn đang thử để tìm. Đây có thể là một tham chiếu đến một ô chứa ngày, một ngày được nhập bằng cách sử dụng hàm DATE hoặc được trả về bởi một số công thức khác.
• Kiểu_trả_về (tùy chọn) - một số xác định ngày đầu tuần. Nếu bị bỏ qua, loại 1 mặc định sẽ được sử dụng (tuần bắt đầu vào Chủ Nhật).

Dưới đây là danh sách đầy đủ return_type giá trị được hỗ trợ trong công thức WEEKNUM.

Trong hàm WEEKNUM, hai hệ thống đánh số tuần khác nhau được sử dụng:

• Hệ thống 1. Tuần chứa ngày 1 tháng 1 được xem xét tuần đầu tiên của năm và được đánh số là tuần 1. Trong hệ thống này, tuần theo truyền thống bắt đầu vào Chủ nhật.
• Hệ thống 2. Đây là hệ thống ngày tháng theo tuần ISO, là một phần của Tiêu chuẩn ngày giờ ISO 8601. Trong hệ thống này, tuần bắt đầu vào thứ Hai và tuần có ngày thứ Năm đầu tiên của năm được coi là tuần 1. Nó thường được gọi là hệ thống đánh số tuần châu Âu và nó được sử dụng chủ yếu trong chính phủ và doanh nghiệp cho các năm tài chính và chấm công.

Tất cả các loại trả hàng được liệt kê ở trên đều áp dụng cho Hệ thống 1, ngoại trừ loại trả hàng 21 được sử dụng trong Hệ thống 2.

Lưu ý. Trong Excel 2007 và các phiên bản cũ hơn, chỉ có tùy chọn 1 và 2. Các loại trả về từ 11 đến 21 chỉ được hỗ trợ trong Excel 2010 và Excel 2013.

Các công thức WEEKNUM của Excel để chuyển đổi ngày thành số tuần (từ 1 đến 54)

Ảnh chụp màn hình sau đây minh họa cách bạn có thể lấy số tuần từ ngày bằng công thức =WEEKNUM(A2) đơn giản nhất:

Ở trêncông thức, đối số return_type bị bỏ qua, có nghĩa là loại 1 mặc định được sử dụng - tuần bắt đầu vào Chủ Nhật.

Nếu bạn muốn bắt đầu với một số ngày khác trong tuần, chẳng hạn như Thứ Hai, thì hãy sử dụng 2 trong đối số thứ hai:

=WEEKNUM(A2, 2)

Thay vì tham chiếu đến một ô, bạn có thể chỉ định ngày trực tiếp trong công thức bằng cách sử dụng hàm DATE(năm, tháng, ngày), chẳng hạn:

=WEEKNUM(DATE(2015,4,15), 2)

Công thức trên trả về 16, là số tuần chứa ngày 15 tháng 4 năm 2015, với một tuần bắt đầu vào Thứ Hai.

Trong các tình huống thực tế , hàm WEEKNUM trong Excel hiếm khi được sử dụng riêng lẻ. Thông thường, bạn sẽ sử dụng nó kết hợp với các hàm khác để thực hiện các phép tính khác nhau dựa trên số tuần, như được minh họa trong các ví dụ khác.

Cách chuyển đổi số tuần thành ngày trong Excel

Là bạn vừa thấy, không có gì to tát khi biến một ngày thành một số tuần bằng cách sử dụng hàm WEEKNUM trong Excel. Nhưng nếu bạn đang tìm kiếm điều ngược lại, tức là chuyển đổi số tuần thành ngày thì sao? Than ôi, không có chức năng Excel nào có thể thực hiện việc này ngay lập tức. Vì vậy, chúng ta sẽ phải xây dựng các công thức của riêng mình.

Giả sử bạn có một năm trong ô A2 và một số tuần trong B2, và bây giờ bạn muốn tính ngày Bắt đầu và Ngày kết thúc trong tuần này.

Lưu ý. Ví dụ về công thức này dựa trên số tuần ISO, với một tuần bắt đầu vào Thứ Hai.

Công thức trả về Bắt đầungày của tuần như sau:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Trong đó A2 là năm và B2 là số tuần.

Xin lưu ý rằng công thức trả về ngày dưới dạng số sê-ri và để nó hiển thị dưới dạng ngày tháng, bạn cần định dạng ô tương ứng. Bạn có thể tìm thấy các hướng dẫn chi tiết trong Thay đổi định dạng ngày trong Excel. Và đây là kết quả trả về theo công thức:

Tất nhiên, công thức chuyển đổi số tuần thành ngày không đơn giản và có thể mất một lúc để có được đầu của bạn vòng logic. Dù sao đi nữa, tôi sẽ cố gắng hết sức để cung cấp lời giải thích có ý nghĩa cho những ai tò mò muốn tìm hiểu sâu hơn.

Như bạn thấy, công thức của chúng tôi bao gồm 2 phần:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - tính ngày của Thứ Hai cuối cùng trong năm trước.
• B2 * 7 - cộng số tuần nhân với 7 (số ngày trong một tuần) để có Thứ Hai (ngày bắt đầu) của tuần trong câu hỏi.

Trong hệ thống đánh số tuần theo tiêu chuẩn ISO, tuần 1 là tuần có ngày thứ Năm đầu tiên của năm. Do đó, Thứ Hai đầu tiên luôn nằm trong khoảng từ ngày 29 tháng 12 đến ngày 4 tháng 1. Vì vậy, để tìm ngày đó, chúng ta phải tìm Thứ Hai ngay trước ngày 5 tháng 1.

Trong Microsoft Excel, bạn có thể trích xuất một ngày trong tuần từ một ngày bằng cách sử dụng hàm WEEKDAY. Và bạn có thể sử dụng công thức chung sau để lấy Thứ Hai ngay trước bất kỳ ngày nào:

If ourmục tiêu cuối cùng là tìm Thứ Hai ngay trước ngày 5 tháng 1 của năm trong A2, chúng ta có thể sử dụng các hàm DATE sau:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Nhưng thứ chúng ta thực sự cần không phải là Thứ Hai đầu tiên của năm nay, mà là thứ Hai cuối cùng của năm trước. Vì vậy, bạn phải trừ 7 ngày kể từ ngày 5 tháng 1 và do đó, bạn nhận được -2 trong hàm DATE đầu tiên:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

So với công thức phức tạp mà bạn vừa học, hãy tính Ngày kết thúc của tuần dễ như ăn bánh :) Để biết Chủ nhật của tuần được đề cập, bạn chỉ cần thêm 6 ngày vào Ngày bắt đầu , tức là =D2+6

Ngoài ra, bạn có thể thêm 6 trực tiếp vào công thức:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Để đảm bảo công thức luôn gửi đúng ngày, vui lòng xem thông tin sau ảnh chụp màn hình. Các công thức Ngày bắt đầu và Ngày kết thúc được thảo luận ở trên lần lượt được sao chép qua cột D và E:

Các cách khác để chuyển đổi số tuần thành ngày trong Excel

Nếu công thức trên dựa trên hệ thống ngày trong tuần ISO không đáp ứng yêu cầu của bạn, hãy thử một trong các giải pháp sau.

Công thức 1. Một tuần có từ ngày 1 tháng 1 là tuần 1, tuần từ Thứ Hai đến Chủ nhật

Như bạn còn nhớ, công thức trước hoạt động dựa trên hệ thống ngày tháng ISO trong đó Thứ Năm đầu tiên của năm được coi là tuần 1. Nếu bạn làm việc dựa trên hệ thống ngày tháng trong đó tuần chứa ngày 1 tháng 1 được coi là tuần 1, sử dụng như saucông thức:

Ngày bắt đầu:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Ngày kết thúc:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Công thức 2. Tuần chứa Jan-1 là tuần 1, chủ nhật-thứ bảy tuần

Các công thức này tương tự như các công thức trên chỉ khác ở cách viết cho Chủ Nhật - Thứ Bảy trong tuần.

Ngày bắt đầu:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Ngày kết thúc:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Công thức 3. Luôn bắt đầu tính vào ngày 1 tháng 1, tuần từ Thứ Hai đến Chủ Nhật

Trong khi các công thức trước đó trả về Thứ Hai (hoặc Chủ nhật) của tuần 1, bất kể cho dù rơi vào năm nay hay năm trước, công thức ngày bắt đầu này luôn trả về Ngày 1 tháng 1 là ngày bắt đầu của tuần 1 bất kể ngày nào trong tuần. Tương tự, công thức ngày kết thúc luôn trả về Ngày 31 tháng 12 là ngày kết thúc của tuần cuối cùng trong năm, bất kể ngày nào trong tuần. Trong tất cả các khía cạnh khác, các công thức này hoạt động tương tự như Công thức 1 ở trên.

Ngày bắt đầu:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Ngày kết thúc:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Công thức 4. Luôn bắt đầu đếm vào ngày 1 tháng 1, tuần CN-Thứ Bảy

Để tính ngày bắt đầu và ngày kết thúc đối với tuần Chủ Nhật - Thứ Bảy, chỉ cần một điều chỉnh nhỏ trong các công thức trên :)

Ngày bắt đầu:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Ngày kết thúc:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Cách lấy tháng từ số tuần

Để lấy tháng tương ứng với tuần số, bạn tìm thấy ngày đầu tiên trong một tuần nhất định như được giải thích trong phần nàyví dụ, sau đó bọc công thức đó trong hàm MONTH của Excel như sau:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Lưu ý. Hãy nhớ rằng công thức trên hoạt động dựa trên Hệ thống ngày trong tuần ISO , trong đó tuần bắt đầu vào thứ Hai và tuần có ngày thứ Năm đầu tiên của năm được coi là tuần 1. Ví dụ: trong năm 2016, Thứ Năm đầu tiên là ngày 7 tháng 1 và đó là lý do tại sao tuần 1 bắt đầu vào ngày 4 tháng 1 năm 2016.

Cách nhận số tuần trong một tháng (từ 1 đến 6)

Nếu logic kinh doanh của bạn yêu cầu chuyển đổi một ngày cụ thể thành số tuần trong tháng tương ứng, bạn có thể sử dụng kết hợp WEEKNUM, Các hàm DATE và MONTH:

Giả sử ô A2 chứa ngày ban đầu, hãy sử dụng công thức sau cho một tuần bắt đầu vào Monday (chú ý 21 trong đối số return_type của WEEKNUM):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Đối với tuần bắt đầu vào Chủ nhật , hãy bỏ qua đối số return_type:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Cách tổng các giá trị và tìm giá trị trung bình theo số tuần

Bây giờ bạn đã biết cách chuyển đổi ngày thành số tuần trong Excel, hãy xem cách bạn có thể sử dụng số tuần trong các phép tính khác.

Giả sử , bạn có một số số liệu bán hàng hàng tháng và bạn muốn biết tổng doanh số cho mỗi tuần.

Để bắt đầu, hãy tìm ra số tuần tương ứng với mỗi lần bán hàng. Nếu ngày tháng của bạn ở cột A và doanh số bán hàng ở cột B, hãy sao chép công thức =WEEKNUM(A2) qua cột C bắt đầu từ ôC2.

Sau đó, tạo danh sách các số tuần trong một số cột khác (ví dụ: trong cột E) và tính doanh số bán hàng cho mỗi tuần bằng cách sử dụng công thức SUMIF sau:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Trong đó E2 là số tuần.

Trong ví dụ này, chúng tôi đang làm việc với danh sách bán hàng tháng 3, vì vậy chúng tôi có số tuần từ 10 đến 14, như minh họa trong ảnh chụp màn hình sau:

Theo cách tương tự, bạn có thể tính doanh số bán hàng trung bình trong một tuần nhất định:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Nếu cột trợ giúp có công thức WEEKNUM không phù hợp với bố cục dữ liệu của bạn, tôi rất tiếc phải nói với bạn rằng không có cách nào đơn giản để loại bỏ nó vì WEEKNUM trong Excel là một trong những hàm đó điều đó không chấp nhận các đối số phạm vi. Do đó, nó không thể được sử dụng trong TÓM TẮT hoặc bất kỳ công thức mảng nào khác như hàm MONTH trong trường hợp tương tự.

Cách tô sáng các ô dựa trên số tuần

Giả sử bạn có một danh sách dài ngày trong một số cột và bạn chỉ muốn đánh dấu những ngày liên quan đến một tuần nhất định. Tất cả những gì bạn cần là quy tắc định dạng có điều kiện với công thức WEEKNUM tương tự như sau:

=WEEKNUM($A2)=10

Như minh họa trong ảnh chụp màn hình bên dưới, quy tắc nêu bật doanh số bán hàng được thực hiện trong tuần thứ 10, đó là tuần đầu tiên vào tháng 3 năm 2015. Vì quy tắc áp dụng cho A2:B15 nên nó làm nổi bật các giá trị trong cả hai cột. Bạn có thể tìm hiểu thêm về cách tạo quy tắc định dạng có điều kiện trong phần nàyhướng dẫn: Định dạng có điều kiện của Excel dựa trên một giá trị ô khác.

Đây là cách bạn có thể tính số tuần trong Excel, chuyển đổi số tuần thành ngày và trích xuất số tuần từ ngày. Hy vọng rằng các công thức WEEKNUM mà bạn đã học hôm nay sẽ hữu ích trong trang tính của bạn. Trong hướng dẫn tiếp theo, chúng ta sẽ nói về cách tính tuổi và năm trong Excel. Tôi cảm ơn bạn đã đọc và hy vọng được gặp bạn vào tuần tới!