Walaupun Microsoft Excel menyediakan pelbagai fungsi untuk berfungsi dengan hari bekerja, bulan dan tahun, hanya satu yang tersedia untuk minggu - fungsi WEEKNUM. Jadi, jika anda mencari cara untuk mendapatkan nombor minggu dari tarikh, WEEKNUM ialah fungsi yang anda mahukan.

Dalam tutorial ringkas ini, kita akan bercakap secara ringkas tentang sintaks dan hujah Excel WEEKNUM dan kemudian bincangkan beberapa contoh formula yang menunjukkan cara anda boleh menggunakan fungsi WEEKNUM untuk mengira nombor minggu dalam lembaran kerja Excel anda.

Fungsi WEEKNUM Excel - sintaks

Fungsi WEEKNUM ialah digunakan dalam Excel untuk mengembalikan nombor minggu tarikh tertentu dalam tahun tersebut (nombor antara 1 dan 54). Ia mempunyai dua argumen, yang pertama diperlukan dan yang kedua adalah pilihan:

• nombor_siri - sebarang tarikh dalam minggu yang nombornya anda cuba untuk mencari. Ini boleh menjadi rujukan kepada sel yang mengandungi tarikh, tarikh yang dimasukkan menggunakan fungsi DATE atau dikembalikan oleh beberapa formula lain.
• Return_type (pilihan) - nombor yang menentukan yang mana hari minggu bermula. Jika ditinggalkan, jenis lalai 1 digunakan (minggu bermula pada hari Ahad).

Berikut ialah senarai lengkap nilai return_type yang disokong dalam formula WEEKNUM.

Dalam fungsi WEEKNUM, dua sistem penomboran minggu berbeza digunakan:

• Sistem 1. Minggu yang mengandungi 1 Januari dianggap minggu pertama dalam tahun dan dinomborkan minggu 1. Dalam sistem ini, minggu secara tradisinya bermula pada hari Ahad.
• Sistem 2. Ini ialah sistem tarikh minggu ISO yang merupakan sebahagian daripada Piawaian tarikh dan masa ISO 8601. Dalam sistem ini, minggu bermula pada hari Isnin dan minggu yang mengandungi Khamis pertama tahun itu dianggap minggu 1. Ia biasanya dikenali sebagai sistem penomboran minggu Eropah dan ia digunakan terutamanya dalam kerajaan dan perniagaan untuk tahun fiskal dan ketepatan masa.

Semua jenis pemulangan yang disenaraikan di atas digunakan untuk Sistem 1, kecuali untuk jenis pemulangan 21 yang digunakan dalam Sistem 2.

Nota. Dalam Excel 2007 dan versi terdahulu, hanya pilihan 1 dan 2 tersedia. Jenis pengembalian 11 hingga 21 disokong dalam Excel 2010 dan Excel 2013 sahaja.

Rumus Excel WEEKNUM untuk menukar tarikh kepada nombor minggu (dari 1 hingga 54)

Tangkapan skrin berikut menunjukkan cara anda boleh mendapatkan nombor minggu daripada tarikh dengan formula =WEEKNUM(A2) yang paling mudah:

Dalam perkara di atasformula, hujah return_type ditinggalkan, yang bermaksud jenis lalai 1 digunakan - minggu bermula pada hari Ahad.

Jika anda lebih suka bermula dengan hari lain dalam seminggu, katakan Isnin, kemudian gunakan 2 dalam hujah kedua:

=WEEKNUM(A2, 2)

Daripada merujuk kepada sel, anda boleh menentukan tarikh secara langsung dalam formula dengan menggunakan fungsi DATE(tahun, bulan, hari), contohnya:

=WEEKNUM(DATE(2015,4,15), 2)

Formula di atas mengembalikan 16, iaitu bilangan minggu yang mengandungi 15 April 2015, dengan seminggu bermula pada hari Isnin.

Dalam senario kehidupan sebenar , fungsi Excel WEEKNUM jarang digunakan sendiri. Selalunya anda akan menggunakannya dalam kombinasi dengan fungsi lain untuk melakukan pelbagai pengiraan berdasarkan nombor minggu, seperti yang ditunjukkan dalam contoh selanjutnya.

Cara menukar nombor minggu kepada tarikh dalam Excel

Sambil anda baru nampak, bukan masalah besar untuk menukar tarikh kepada nombor minggu menggunakan fungsi Excel WEEKNUM. Tetapi bagaimana jika anda mencari sebaliknya, iaitu menukar nombor minggu kepada tarikh? Malangnya, tiada fungsi Excel yang boleh melakukan ini dengan segera. Jadi, kami perlu membina formula kami sendiri.

Andaikan anda mempunyai setahun dalam sel A2 dan nombor minggu dalam B2, dan kini anda ingin mengira tarikh Mula dan Tamat dalam minggu ini.

Nota. Contoh formula ini adalah berdasarkan nombor minggu ISO, dengan seminggu bermula pada hari Isnin.

Formula untuk mengembalikan Mulatarikh minggu adalah seperti berikut:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Di mana A2 ialah tahun dan B2 ialah nombor minggu.

Sila ambil perhatian bahawa formula mengembalikan tarikh sebagai nombor siri, dan untuk memaparkannya sebagai tarikh, anda perlu memformatkan sel dengan sewajarnya. Anda boleh mendapatkan arahan terperinci dalam Menukar format tarikh dalam Excel. Dan berikut ialah hasil yang dikembalikan oleh formula:

Sudah tentu, formula untuk menukar nombor minggu kepada tarikh bukanlah remeh dan mungkin mengambil sedikit masa untuk mendapatkannya. kepala anda bulatkan logik. Bagaimanapun, saya akan melakukan yang terbaik untuk memberikan penjelasan yang bermakna bagi mereka yang ingin tahu untuk turun ke bahagian bawah.

Seperti yang anda lihat, formula kami terdiri daripada 2 bahagian:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - mengira tarikh Isnin terakhir pada tahun sebelumnya.
• B2 * 7 - menambah bilangan minggu didarab dengan 7 (bilangan hari dalam seminggu) untuk mendapatkan hari Isnin (tarikh mula) minggu itu dalam soalan.

Dalam sistem penomboran minggu ISO, minggu 1 ialah minggu yang mengandungi hari Khamis pertama dalam setahun. Akibatnya, Isnin pertama sentiasa antara 29 Disember dan 4 Januari. Jadi, untuk mencari tarikh itu, kita perlu mencari hari Isnin sejurus sebelum 5 Januari.

Dalam Microsoft Excel, anda boleh mengekstrak hari dalam seminggu daripada tarikh dengan menggunakan fungsi WEEKDAY. Dan anda boleh menggunakan formula generik berikut untuk mendapatkan hari Isnin serta-merta sebelum mana-mana tarikh tertentu:

Jika kamimatlamat utama adalah untuk mencari hari Isnin sejurus sebelum 5 Januari tahun dalam A2, kita boleh menggunakan fungsi DATE berikut:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Tetapi apa yang sebenarnya kita perlukan bukanlah hari Isnin pertama bagi tahun ini, sebaliknya Isnin terakhir tahun sebelumnya. Jadi, anda perlu menolak 7 hari dari 5 Januari dan dengan itu anda mendapat -2 dalam fungsi DATE yang pertama:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Berbanding dengan formula rumit yang baru anda pelajari, mengira Tarikh tamat minggu ini adalah sesuatu yang menarik :) Untuk mendapatkan Ahad dalam minggu berkenaan, anda hanya perlu menambah 6 hari pada Tarikh mula , iaitu =D2+6

Sebagai alternatif, anda boleh menambah 6 terus dalam formula:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Untuk memastikan formula sentiasa menyampaikan tarikh yang betul, sila lihat perkara berikut tangkapan skrin. Formula Tarikh Mula dan Tarikh Tamat yang dibincangkan di atas disalin merentas lajur D dan E, masing-masing:

Cara lain untuk menukar nombor minggu kepada tarikh dalam Excel

Jika formula di atas berdasarkan sistem tarikh minggu ISO tidak memenuhi keperluan anda, cuba salah satu daripada penyelesaian berikut.

Formula 1. Minggu yang mengandungi Jan-1 ialah minggu 1, minggu Isnin-Ahad

Seperti yang anda ingat, formula sebelumnya berfungsi berdasarkan sistem tarikh ISO di mana Khamis pertama dalam tahun dianggap minggu 1. Jika anda bekerja berdasarkan sistem tarikh di mana minggu yang mengandungi 1 Januari dianggap minggu 1, gunakan yang berikutformula:

Tarikh mula:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Tarikh tamat:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Formula 2. Minggu yang mengandungi Jan-1 ialah minggu 1, minggu Ahad-Sab

Formula ini serupa dengan formula di atas dengan satu-satunya perbezaan ia ditulis untuk minggu Ahad - Sabtu.

Tarikh mula:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Tarikh tamat:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Formula 3. Sentiasa mula mengira pada 1 Januari, minggu Isnin-Ahad

Sementara formula sebelumnya kembali pada hari Isnin (atau Ahad) minggu 1, tanpa mengira sama ada jika jatuh dalam tahun ini atau tahun sebelumnya, formula tarikh mula ini sentiasa mengembalikan 1 Januari sebagai tarikh mula minggu 1 tanpa mengira hari dalam seminggu. Secara analogi, formula tarikh tamat sentiasa mengembalikan 31 Disember sebagai tarikh tamat minggu terakhir dalam tahun tersebut, tanpa mengira hari dalam seminggu. Dalam semua aspek lain, formula ini berfungsi sama seperti Formula 1 di atas.

Tarikh mula:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Tarikh tamat:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Formula 4. Sentiasa mula mengira pada 1 Januari, minggu Ahad-Sabtu

Untuk mengira tarikh mula dan tamat untuk minggu Ahad - Sabtu, yang diperlukan hanyalah satu pelarasan kecil dalam formula di atas :)

Tarikh mula:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Tarikh tamat:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Cara mendapatkan bulan dari nombor minggu

Untuk mendapatkan bulan yang sepadan dengan minggu nombor, anda dapati hari pertama dalam minggu tertentu seperti yang dijelaskan dalam inicontoh, dan kemudian bungkus formula itu dalam fungsi BULAN Excel seperti ini:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Nota. Sila ingat bahawa formula di atas berfungsi berdasarkan sistem tarikh minggu ISO , di mana minggu bermula pada hari Isnin dan minggu yang mengandungi hari Khamis pertama dalam tahun itu dianggap minggu 1. Contohnya, pada tahun 2016, Khamis pertama ialah 7 Januari, dan itulah sebabnya minggu 1 bermula pada 4-Jan-2016.

Cara mendapatkan nombor minggu dalam sebulan (dari 1 hingga 6)

Jika logik perniagaan anda memerlukan penukaran tarikh tertentu kepada nombor minggu dalam bulan yang sepadan, anda boleh menggunakan gabungan WEEKNUM, Fungsi DATE dan MONTH:

Dengan mengandaikan bahawa sel A2 mengandungi tarikh asal, gunakan formula berikut untuk seminggu bermula pada Isnin (notis 21 dalam hujah return_type WEEKNUM):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Selama seminggu bermula pada Ahad , tinggalkan hujah return_type:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Cara untuk jumlah nilai dan cari purata mengikut nombor minggu

Sekarang anda tahu cara menukar tarikh kepada nombor minggu dalam Excel, mari lihat cara anda boleh menggunakan nombor minggu dalam pengiraan lain.

Andaikan , anda mempunyai beberapa angka jualan bulanan dan anda ingin mengetahui jumlah untuk setiap minggu.

Sebagai permulaan, mari kita ketahui nombor minggu yang sepadan dengan setiap jualan. Jika tarikh anda berada dalam lajur A dan jualan dalam lajur B, salin formula =WEEKNUM(A2) merentas lajur C bermula dalam selC2.

Dan kemudian, buat senarai nombor minggu dalam beberapa lajur lain (katakan, dalam lajur E) dan hitung jualan untuk setiap minggu menggunakan formula SUMIF berikut:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Di mana E2 ialah nombor minggu.

Dalam contoh ini, kami sedang bekerja dengan senarai jualan Mac, jadi kami mempunyai nombor minggu 10 hingga 14, sebagai ditunjukkan dalam tangkapan skrin berikut:

Dengan cara yang sama, anda boleh mengira purata jualan untuk minggu tertentu:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Jika lajur pembantu dengan formula WEEKNUM tidak sesuai dengan reka letak data anda, saya kesal untuk memberitahu anda bahawa tiada cara mudah untuk menyingkirkannya kerana Excel WEEKNUM ialah salah satu fungsi tersebut yang tidak menerima hujah julat. Oleh itu, ia tidak boleh digunakan dalam SUMPRODUCT atau mana-mana formula tatasusunan lain seperti fungsi MONTH dalam senario yang serupa.

Cara menyerlahkan sel berdasarkan nombor minggu

Katakanlah anda mempunyai senarai yang panjang tarikh dalam beberapa lajur dan anda hanya ingin menyerlahkan tarikh yang berkaitan dengan minggu tertentu. Apa yang anda perlukan ialah peraturan pemformatan bersyarat dengan formula WEEKNUM yang serupa dengan ini:

=WEEKNUM($A2)=10

Seperti yang ditunjukkan dalam tangkapan skrin di bawah, peraturan itu menyerlahkan jualan yang dibuat dalam minggu 10, iaitu minggu pertama pada bulan Mac 2015. Memandangkan peraturan berkenaan digunakan pada A2:B15, ia menyerlahkan nilai dalam kedua-dua lajur. Anda boleh mengetahui lebih lanjut tentang membuat peraturan pemformatan bersyarat dalam perkara initutorial: Pemformatan bersyarat Excel berdasarkan nilai sel lain.

Ini adalah cara anda boleh mengira nombor minggu dalam Excel, menukar nombor minggu kepada tarikh dan mengeluarkan nombor minggu dari tarikh. Mudah-mudahan, formula WEEKNUM yang telah anda pelajari hari ini akan terbukti berguna dalam lembaran kerja anda. Dalam tutorial seterusnya, kita akan bercakap tentang mengira umur dan tahun dalam Excel. Saya berterima kasih kerana membaca dan berharap dapat berjumpa anda minggu hadapan!