Terwyl Microsoft Excel 'n verskeidenheid funksies bied om weeksdae, maande en jare mee te werk, is slegs een vir weke beskikbaar - die WEEKNUM-funksie. Dus, as jy op soek is na 'n manier om 'n weeknommer vanaf 'n datum te kry, is WEEKNUM die funksie wat jy wil hê.

In hierdie kort tutoriaal sal ons kortliks praat oor die sintaksis en argumente van Excel WEEKNUM, en bespreek dan 'n paar formule-voorbeelde wat demonstreer hoe jy die WEEKNUM-funksie kan gebruik om weeknommers in jou Excel-werkblaaie te bereken.

Excel WEEKNUM-funksie - sintaksis

Die WEEKNUM-funksie is gebruik in Excel om die weeknommer van 'n spesifieke datum in die jaar terug te gee ('n nommer tussen 1 en 54). Dit het twee argumente, die 1ste word vereis en die 2de is opsioneel:

• Reeksnommer - enige datum binne die week wie se nommer jy probeer te vind. Dit kan 'n verwysing wees na 'n sel wat die datum bevat, 'n datum wat ingevoer is deur die DATUM-funksie te gebruik of deur 'n ander formule teruggestuur word.
• Terugvoertipe (opsioneel) - 'n getal wat bepaal waarop dag wat die week begin. As dit weggelaat word, word die verstek tipe 1 gebruik (die week wat op Sondag begin).

Hier is 'n volledige lys van die return_type waardes wat in WEEKNUM-formules ondersteun word.

In die WEEKNUM-funksie word twee verskillende weeknommerstelsels gebruik:

• Stelsel 1. Die week wat 1 Januarie bevat, word beskou as die 1ste week van die jaar en is genommer week 1. In hierdie stelsel begin die week tradisioneel op Sondag.
• Stelsel 2. Dit is die ISO-weekdatumstelsel wat deel is van die ISO 8601 datum en tyd standaard. In hierdie stelsel begin die week op Maandag en die week wat die eerste Donderdag van die jaar bevat, word as week 1 beskou. Dit staan ​​algemeen bekend as die Europese weeknommerstelsel en word hoofsaaklik in die regering en besigheid gebruik vir boekjare en tydmeting.

Al die opgawe tipes hierbo gelys is van toepassing op Stelsel 1, behalwe vir terugkeer tipe 21 wat in Stelsel 2 gebruik word.

Let wel. In Excel 2007 en vroeër weergawes is slegs opsies 1 en 2 beskikbaar. Retourtipes 11 tot 21 word slegs in Excel 2010 en Excel 2013 ondersteun.

Excel WEEKNUM-formules om datum na weeknommer om te skakel (van 1 tot 54)

Die volgende skermkiekie demonstreer hoe jy weeknommers vanaf datums kan kry met die eenvoudigste =WEEKNUM(A2) -formule:

In bogenoemdeformule, word die return_type -argument weggelaat, wat beteken dat die verstek tipe 1 gebruik word - die week wat op Sondag begin.

As jy eerder met 'n ander dag van die week wil begin, sê Maandag, gebruik dan 2 in die tweede argument:

=WEEKNUM(A2, 2)

In plaas daarvan om na 'n sel te verwys, kan jy die datum direk in die formule spesifiseer deur die DATUM(jaar, maand, dag) funksie te gebruik, byvoorbeeld:

=WEEKNUM(DATE(2015,4,15), 2)

Die formule hierbo gee 16 terug, wat die nommer van die week is wat 15 April 2015 bevat, met 'n week wat op Maandag begin.

In werklike scenario's , word die Excel WEEKNUM-funksie selde op sy eie gebruik. Meestal sal jy dit in kombinasie met ander funksies gebruik om verskeie berekeninge op grond van die weeknommer uit te voer, soos gedemonstreer in verdere voorbeelde.

Hoe om weeknommer na datum in Excel om te skakel

Soos jy het sopas gesien, dit is nie 'n groot probleem om 'n datum in 'n weeknommer te verander deur die Excel WEEKNUM-funksie te gebruik nie. Maar wat as jy die teenoorgestelde soek, dit wil sê om 'n weeknommer na 'n datum om te skakel? Helaas, daar is geen Excel-funksie wat dit dadelik kan doen nie. Dus, ons sal ons eie formules moet saamstel.

Gestel jy het 'n jaar in sel A2 en 'n weeknommer in B2, en nou wil jy die begin- en einddatums in hierdie week bereken.

Let wel. Hierdie formulevoorbeeld is gebaseer op ISO-weeknommers, met 'n week wat op Maandag begin.

Die formule om die Start terug te geedatum van die week is soos volg:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Waar A2 die jaar en B2 die weeknommer is.

Neem asseblief kennis dat die formule die datum gee as 'n reeksnommer, en om dit as 'n datum te vertoon, moet jy die sel dienooreenkomstig formateer. U kan die gedetailleerde instruksies vind in Verander datumformaat in Excel. En hier is die resultaat wat deur die formule teruggegee word:

Natuurlik is die formule om 'n weeknommer na 'n datum om te skakel nie triviaal nie, en dit kan 'n rukkie neem om te kry jou kop om die logika. In elk geval, ek sal my bes doen om betekenisvolle verduideliking te gee vir diegene wat nuuskierig is om tot onder te kom.

Soos jy sien, bestaan ​​ons formule uit 2 dele:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - bereken die datum van die laaste Maandag in die vorige jaar.
• B2 * 7 - voeg die aantal weke vermenigvuldig met 7 (die aantal dae in 'n week) by om die Maandag (begindatum) van die week in te kry vraag.

In die ISO-weeknommerstelsel is week 1 die week wat die eerste Donderdag van die jaar bevat. Gevolglik is die eerste Maandag altyd tussen 29 Desember en 4 Januarie. Dus, om daardie datum te vind, moet ons die Maandag onmiddellik voor 5 Januarie vind.

In Microsoft Excel kan jy 'n dag van die week onttrek vanaf 'n datum deur die WEEKDAY-funksie te gebruik. En jy kan die volgende generiese formule gebruik om Maandag onmiddellik voor enige gegewe datum te kry:

As onsuiteindelike doel was om Maandag onmiddellik voor die 5de Januarie van die jaar in A2 te vind, ons kon die volgende DATUM-funksies gebruik:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Maar wat ons eintlik nodig het, is nie die eerste Maandag van vanjaar, maar eerder die laaste Maandag van die vorige jaar. So, jy moet 7 dae van 5 Januarie aftrek en dus kry jy -2 in die eerste DATUM-funksie:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Vergeleke met die moeilike formule wat jy pas geleer het, bereken die Einddatum van die week is 'n stukkie koek :) Om Sondag van die betrokke week te kry, voeg jy eenvoudig 6 dae by die Begindatum , dit wil sê =D2+6

Alternatiewelik kan jy 6 direk in die formule byvoeg:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Om seker te maak dat die formules altyd die regte datums lewer, kyk asseblief na die volgende skermkiekie. Die begindatum- en einddatumformules wat hierbo bespreek is, word onderskeidelik oor kolom D en E gekopieer:

Ander maniere om weeknommer na datum in Excel om te skakel

As die formule hierbo gebaseer op die ISO-weekdatumstelsel nie aan jou vereistes voldoen nie, probeer een van die volgende oplossings.

Formule 1. 'n Week wat Jan-1 bevat is week 1, Ma-Son week

Soos jy onthou, werk die vorige formule gebaseer op die ISO-datumstelsel waar die eerste Donderdag van die jaar as week 1 beskou word. As jy op 'n datumstelsel werk waar die week wat die 1ste Januarie bevat, as week 1 beskou word, gebruik die volgendeformules:

Begindatum:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Einddatum:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Formule 2. 'n Week wat Jan-1 bevat is week 1, So-Sat week

Hierdie formules is soortgelyk aan die bogenoemde met die enigste verskil dat hulle geskryf is vir Sondag - Saterdag week.

Begindatum:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Einddatum:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Formule 3. Begin altyd tel op 1 Januarie, Ma-Son week

Terwyl die vorige formules Maandag (of Sondag) van week 1 terugkeer, ongeag of dit binne hierdie jaar of die vorige jaar val, hierdie begindatumformule gee altyd 1 Januarie terug as die begindatum van week 1, ongeag die dag van die week. Volgens analogie gee die einddatumformule altyd 31 Desember terug as die einddatum van die laaste week in die jaar, ongeag die dag van die week. In alle ander opsigte werk hierdie formules soortgelyk aan Formule 1 hierbo.

Begindatum:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Einddatum:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Formule 4. Begin altyd tel op 1 Januarie, So-Saterdag week

Om die begin- en einddatums te bereken vir 'n Sondag - Saterdag week is al wat nodig is een klein aanpassing in die bogenoemde formules :)

Begindatum:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Einddatum:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Hoe om maand vanaf weeknommer te kry

Om 'n maand te kry wat ooreenstem met die week nommer, vind jy die eerste dag in 'n gegewe week soos hierin verduidelikvoorbeeld, en draai dan daardie formule in die Excel MAAND-funksie soos volg:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Nota. Onthou asseblief dat die bogenoemde formule op die ISO-weekdatumstelsel werk, waar die week op Maandag begin en die week wat die 1ste Donderdag van die jaar bevat, as week 1 beskou word. Byvoorbeeld, in die jaar 2016, die eerste Donderdag is 7 Januarie, en daarom begin week 1 op 4-Jan-2016.

Hoe om 'n weeknommer in 'n maand te kry (van 1 tot 6)

As jou besigheidslogika vereis dat 'n spesifieke datum na die weeknommer binne die ooreenstemmende maand omgeskakel word, kan jy die kombinasie van WEEKNUM, DATUM- en MAAND-funksies:

As aangeneem word dat sel A2 die oorspronklike datum bevat, gebruik die volgende formule vir 'n week wat begin op Maandag (kennisgewing 21 in WEEKNUM se return_type argument):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Voor 'n week wat op Sondag begin, laat die return_type-argument weg:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Hoe om somwaardes op en vind gemiddeld volgens die weeknommer

Noudat jy weet hoe om 'n datum na 'n weeknommer in Excel om te skakel, kom ons kyk hoe jy weeknommers in ander berekeninge kan gebruik.

Gestel , jy het 'n paar maandelikse verkoopsyfers en jy wil die totaal vir elke week weet.

Om mee te begin, kom ons vind 'n weeknommer uit wat ooreenstem met elke uitverkoping. As jou datums in kolom A en verkope in kolom B is, kopieer die =WEEKNUM(A2) -formule oor kolom C wat in sel beginC2.

En maak dan 'n lys van weeknommers in 'n ander kolom (sê in kolom E) en bereken die verkope vir elke week deur die volgende SUMIF-formule te gebruik:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Waar E2 die weeknommer is.

In hierdie voorbeeld werk ons ​​met 'n lys van Maartverkope, dus het ons weeknommers 10 tot 14, soos gedemonstreer in die volgende skermkiekie:

Op 'n soortgelyke wyse kan jy die verkoopsgemiddelde vir 'n gegewe week bereken:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

As die helperkolom met die WEEKNUM-formule nie goed in jou data-uitleg pas nie, is dit spyt om vir jou te sê dat daar geen eenvoudige manier is om daarvan ontslae te raak nie, want Excel WEEKNUM is een van daardie funksies wat nie reeksargumente aanvaar nie. Daarom kan dit nie binne SUMPRODUCT of enige ander skikkingsformule soos die MONTH-funksie in 'n soortgelyke scenario gebruik word nie.

Hoe om selle op grond van die weeknommer uit te lig

Kom ons sê jy het 'n lang lys van datums in een of ander kolom en jy wil net dié uitlig wat met 'n gegewe week verband hou. Al wat jy nodig het, is 'n voorwaardelike formateringreël met 'n WEEKNUM-formule soortgelyk aan hierdie:

=WEEKNUM($A2)=10

Soos gedemonstreer in die skermkiekie hieronder, beklemtoon die reël verkope wat binne week 10 gemaak is, wat die eerste week in Maart 2015. Aangesien die reël op A2:B15 van toepassing is, beklemtoon dit waardes in beide kolomme. Jy kan hierin meer leer oor die skep van voorwaardelike formateringreëlstutoriaal: Excel-voorwaardelike formatering gebaseer op 'n ander selwaarde.

Dit is hoe jy weeknommers in Excel kan bereken, weeknommer na datum kan omskakel en weeknommer vanaf datum kan onttrek. Hopelik sal die WEEKNUM-formules wat jy vandag geleer het nuttig wees in jou werkblaaie. In die volgende tutoriaal sal ons praat oor die berekening van ouderdom en jare in Excel. Ek bedank jou vir die lees en hoop om jou volgende week te sien!