जबकि माइक्रोसफ्ट एक्सेलले साताका दिन, महिना र वर्षहरूसँग काम गर्नका लागि कार्यहरूको एर्रे प्रदान गर्दछ, केवल एउटा हप्ताको लागि उपलब्ध छ - WEEKNUM प्रकार्य। त्यसोभए, यदि तपाइँ मितिबाट हप्ता नम्बर प्राप्त गर्ने तरिका खोज्दै हुनुहुन्छ भने, WEEKNUM तपाइँले चाहानु भएको प्रकार्य हो।

यस छोटो ट्युटोरियलमा, हामी एक्सेल WEEKNUM को वाक्यविन्यास र तर्कहरूको बारेमा छोटकरीमा कुरा गर्नेछौं, र त्यसपछि तपाइँ तपाइँको एक्सेल कार्यपत्रमा हप्ता संख्याहरू गणना गर्न WEEKNUM प्रकार्य कसरी प्रयोग गर्न सक्नुहुन्छ भनेर प्रदर्शन गर्ने केही सूत्र उदाहरणहरू छलफल गर्नुहोस्। वर्षमा निर्दिष्ट मितिको हप्ता नम्बर फिर्ता गर्न Excel मा प्रयोग गरिन्छ (1 र 54 बीचको संख्या)। यसमा दुईवटा तर्कहरू छन्, पहिलो आवश्यक छ र दोस्रो वैकल्पिक छ:

• Serial_number - तपाईंले प्रयास गरिरहनुभएको हप्ता भित्रको कुनै पनि मिति पत्ता लाउनु। यो मिति समावेश भएको सेलको सन्दर्भ हुन सक्छ, DATE प्रकार्य प्रयोग गरेर प्रविष्ट गरिएको मिति वा कुनै अन्य सूत्रद्वारा फर्काइएको।
• Return_type (वैकल्पिक) - एउटा संख्या जसले निर्धारण गर्छ हप्ताको दिन सुरु हुन्छ। यदि हटाइयो भने, पूर्वनिर्धारित प्रकार १ प्रयोग गरिन्छ (आइतबारबाट सुरु हुने हप्ता)।

यहाँ WEEKNUM सूत्रहरूमा समर्थित ३८५५ मानहरूको पूर्ण सूची छ।

WEEKNUM प्रकार्यमा, दुई फरक हप्ता नम्बरिङ प्रणाली प्रयोग गरिन्छ:

• प्रणाली १। जनवरी १ भएको हप्तालाई मानिन्छ। वर्षको 1st हप्ता र हप्ता 1 नम्बर गरिएको छ। यस प्रणालीमा, हप्ता परम्परागत रूपमा आइतबार सुरु हुन्छ।
• प्रणाली 2। यो ISO हप्ताको मिति प्रणाली हो जुन ISO 8601 मिति र समय मानक। यस प्रणालीमा, हप्ता सोमबारबाट सुरु हुन्छ र वर्षको पहिलो बिहीबार समावेश भएको हप्तालाई हप्ता 1 मानिन्छ। यसलाई सामान्यतया युरोपेली हप्ता नम्बरिङ प्रणाली भनिन्छ र यो मुख्यतया आर्थिक वर्ष र टाइमकिपिङको लागि सरकार र व्यापारमा प्रयोग गरिन्छ।

माथि सूचीबद्ध सबै फिर्ता प्रकारहरू प्रणाली 1 मा लागू हुन्छन्, प्रणाली 2 मा प्रयोग गरिएको फिर्ता प्रकार 21 बाहेक।

नोट। Excel 2007 र अघिल्लो संस्करणहरूमा, केवल 1 र 2 विकल्पहरू उपलब्ध छन्। रिटर्न प्रकारहरू 11 देखि 21 सम्म Excel 2010 र Excel 2013 मा मात्र समर्थित छन्।

Excel WEEKNUM सूत्रहरू मितिलाई हप्ता नम्बरमा रूपान्तरण गर्न (१ देखि ५४ सम्म)

निम्न स्क्रिनसटले तपाइँ कसरी सरल ५२८० सूत्रको साथ मितिबाट हप्ता नम्बरहरू प्राप्त गर्न सक्नुहुन्छ भनेर देखाउँछ:

<18

माथिको मासूत्र, return_type तर्क हटाइएको छ, जसको मतलब पूर्वनिर्धारित प्रकार 1 प्रयोग गरिन्छ - आइतवारबाट सुरु हुने हप्ता।

यदि तपाईं हप्ताको कुनै अन्य दिनबाट सुरु गर्न चाहनुहुन्छ भने, सोमबार भन्नुहोस्, त्यसपछि 2 प्रयोग गर्नुहोस्। दोस्रो तर्कमा:

=WEEKNUM(A2, 2)

सेललाई सन्दर्भ गर्नुको सट्टा, तपाईंले DATE(वर्ष, महिना, दिन) प्रकार्य प्रयोग गरेर सूत्रमा मिति निर्दिष्ट गर्न सक्नुहुन्छ, उदाहरणका लागि:

=WEEKNUM(DATE(2015,4,15), 2)

माथिको सूत्रले 16 फर्काउँछ, जुन हप्ताको संख्या हो जुन अप्रिल 15, 2015, सोमबारबाट सुरु हुने हप्ताको साथमा हुन्छ।

वास्तविक-जीवन परिदृश्यहरूमा , Excel WEEKNUM प्रकार्य विरलै आफ्नै मा प्रयोग गरिन्छ। धेरै जसो तपाईले यसलाई हप्ताको संख्यामा आधारित विभिन्न गणनाहरू प्रदर्शन गर्न अन्य प्रकार्यहरूसँग संयोजनमा प्रयोग गर्नुहुन्छ, जसरी थप उदाहरणहरूमा देखाइएको छ। भर्खरै देखेको छ, एक्सेल WEEKNUM प्रकार्य प्रयोग गरेर मितिलाई हप्ताको नम्बरमा परिणत गर्नु ठूलो कुरा होइन। तर के यदि तपाइँ विपरित खोज्दै हुनुहुन्छ, अर्थात् हप्ताको नम्बरलाई मितिमा रूपान्तरण गर्दै हुनुहुन्छ? काश, त्यहाँ कुनै एक्सेल प्रकार्य छैन जुन यो तुरुन्तै गर्न सक्छ। त्यसोभए, हामीले हाम्रो आफ्नै सूत्रहरू निर्माण गर्नुपर्नेछ।

मानौं तपाईंसँग सेल A2 मा एक वर्ष र B2 मा एक हप्ता संख्या छ, र अब तपाईं यस हप्तामा सुरु र अन्त्य मितिहरू गणना गर्न चाहनुहुन्छ।

नोट। यो सूत्र उदाहरण आईएसओ हप्ता संख्याहरूमा आधारित छ, सोमबारबाट सुरु हुने हप्ताको साथ।

सुरु फर्काउने सूत्रहप्ताको मिति निम्नानुसार छ:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

जहाँ A2 वर्ष हो र B2 हप्ताको संख्या हो।

कृपया नोट गर्नुहोस् कि सूत्रले मिति फर्काउँछ। सिरियल नम्बरको रूपमा, र यसलाई मितिको रूपमा देखाउनको लागि, तपाईंले सेललाई तदनुसार ढाँचा गर्न आवश्यक छ। तपाईले एक्सेलमा परिवर्तन मिति ढाँचामा विस्तृत निर्देशनहरू फेला पार्न सक्नुहुन्छ। र यहाँ सूत्रद्वारा फर्काइएको नतिजा हो:

निस्सन्देह, एक हप्ताको नम्बरलाई मितिमा रूपान्तरण गर्ने सूत्र मामूली छैन, र यो प्राप्त गर्न केही समय लाग्न सक्छ। तर्कको वरिपरि तिम्रो टाउको। जे भए पनि, म तल जान उत्सुक हुनेहरूका लागि अर्थपूर्ण व्याख्या प्रदान गर्न सक्दो प्रयास गर्नेछु।

तपाईले देख्नुभए जस्तै, हाम्रो सूत्र २ भागहरू मिलेर बनेको छ:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - अघिल्लो वर्षको अन्तिम सोमबारको मिति गणना गर्दछ।
• B2 * 7 - हप्ताको सोमबार (सुरु मिति) प्राप्त गर्न 7 (एक हप्तामा दिनहरूको संख्या) ले गुणन गरिएको हप्ताको संख्या थप्छ। प्रश्न।

ISO हप्ता नम्बरिङ प्रणालीमा, हप्ता 1 वर्षको पहिलो बिहीबार समावेश गरिएको हप्ता हो। फलस्वरूप, पहिलो सोमबार सधैं डिसेम्बर 29 र जनवरी 4 को बीचमा हुन्छ। त्यसैले, त्यो मिति पत्ता लगाउन, हामीले जनवरी 5 भन्दा पहिलेको सोमबार फेला पार्नु पर्छ।

Microsoft Excel मा, तपाईंले हप्ताको एक दिन निकाल्न सक्नुहुन्छ। WEEKDAY प्रकार्य प्रयोग गरेर मिति। र तपाईंले कुनै पनि दिइएको मिति भन्दा तुरुन्तै सोमबार प्राप्त गर्न निम्न सामान्य सूत्र प्रयोग गर्न सक्नुहुन्छ:

यदि हाम्रोअन्तिम लक्ष्य A2 मा वर्षको 5 जनवरीको तुरुन्तै सोमबार फेला पार्नु थियो, हामीले निम्न DATE प्रकार्यहरू प्रयोग गर्न सक्छौं:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

तर हामीलाई वास्तवमा के चाहिन्छ त्यो पहिलो सोमबार होइन। यो वर्ष, तर अघिल्लो वर्षको अन्तिम सोमबार। त्यसोभए, तपाईंले जनवरी 5 देखि 7 दिन घटाउनुपर्छ र त्यसैले तपाईंले पहिलो DATE प्रकार्यमा -2 प्राप्त गर्नुहुन्छ:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

तपाईले भर्खरै सिकेको कठिन सूत्रको तुलनामा, <7 गणना गर्दै>सप्ताहको अन्तिम मिति केकको टुक्रा हो :) प्रश्नमा रहेको हप्ताको आइतवार प्राप्त गर्न, तपाईंले सुरु मिति मा ६ दिन थप्नुहोस्, अर्थात् ४२८२

वैकल्पिक रूपमा, तपाईंले सूत्रमा सीधै 6 थप्न सक्नुहुन्छ:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

सूत्रहरूले सधैँ सही मितिहरू डेलिभर गर्ने सुनिश्चित गर्न, कृपया निम्नमा हेर्नुहोस् स्क्रिनसट। माथि चर्चा गरिएको सुरु मिति र अन्त्य मिति सूत्रहरू क्रमशः स्तम्भ D र E मा प्रतिलिपि गरिएका छन्:

अन्य तरिकाहरू एक्सेलमा हप्ताको नम्बरलाई मितिमा रूपान्तरण गर्ने

यदि ISO हप्ता मिति प्रणालीमा आधारित माथिको सूत्रले तपाइँका आवश्यकताहरू पूरा गर्दैन भने, निम्न समाधानहरू मध्ये एउटा प्रयास गर्नुहोस्।

सूत्र 1. जनवरी-1 समावेश भएको हप्ता हप्ता 1, सोम-रवि हप्ता हो

तपाईलाई सम्झना अनुसार, अघिल्लो सूत्रले ISO मिति प्रणालीमा आधारित काम गर्दछ जहाँ वर्षको पहिलो बिहीबार हप्ता 1 मानिन्छ। यदि तपाइँ मिति प्रणालीमा आधारित काम गर्नुहुन्छ जहाँ जनवरी 1 को हप्तालाई हप्ता 1 मानिन्छ, निम्न प्रयोग गर्नुहोस्सूत्र:

सुरु मिति:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

अन्तिम मिति:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

सूत्र २. जनवरी-१ समावेश भएको हप्ता १ हप्ता, सूर्य-शनि हप्ता हो

यी सूत्रहरू माथिका सूत्रहरूसँग मिल्दोजुल्दो छन् कि तिनीहरू लेखिएका छन्। आइतबार - शनिबार हप्ताको लागि।

सुरु मिति:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

अन्तिम मिति:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

30>

सूत्र 3. सधैं जनवरी 1 मा गणना सुरु गर्नुहोस्, सोम-रवि हप्ता

जब कि अघिल्लो सूत्रहरू हप्ता 1 को सोमबार (वा आइतबार) फर्किन्छन्, चाहे यदि यो वर्ष वा अघिल्लो वर्ष भित्र पर्छ भने, यो सुरु मिति सूत्र सधैं हप्ताको दिन 1 को शुरुवात मितिको रूपमा जनवरी 1 फर्काउँछ। समानता अनुसार, अन्तिम मिति सूत्र सधैं डिसेम्बर 31 वर्षको अन्तिम हप्ताको अन्तिम मितिको रूपमा फर्काउँछ, हप्ताको दिनको ख्याल नगरी। अन्य सबै सन्दर्भमा, यी सूत्रहरूले माथिको सूत्र १ जस्तै काम गर्छ।

सुरु मिति:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

अन्तिम मिति:<8

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

सूत्र ४। सधैं जनवरी १ मा गणना सुरु गर्नुहोस्, सूर्य-शनि हप्ता

सुरु र अन्त्य मितिहरू गणना गर्न आइतवार - शनिबार हप्ताको लागि, माथिको सूत्रहरूमा एउटा सानो समायोजन मात्र लिन्छ :)

सुरु मिति:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

अन्तिम मिति:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

हप्ता नम्बरबाट महिना कसरी प्राप्त गर्ने

हप्तासँग सम्बन्धित महिना प्राप्त गर्न नम्बर, तपाईले दिइएको हप्ताको पहिलो दिन फेला पार्नुहुन्छ जसमा व्याख्या गरिएको छउदाहरण, र त्यसपछि त्यो सूत्र एक्सेल MONTH प्रकार्यमा यसरी लपेट्नुहोस्:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

नोट। कृपया याद गर्नुहोस् कि माथिको सूत्रले ISO हप्ता मिति प्रणाली मा आधारित काम गर्दछ, जहाँ हप्ता सोमबारबाट सुरु हुन्छ र वर्षको पहिलो बिहीबार भएको हप्तालाई हप्ता 1 मानिन्छ। उदाहरणका लागि, वर्ष 2016 मा, पहिलो बिहीबार जनवरी 7 हो, र यसैले हप्ता 1 4-जनवरी-2016 मा सुरु हुन्छ।

एक महिनामा हप्ताको नम्बर कसरी प्राप्त गर्ने (१ देखि ६ सम्म)

यदि तपाईंको व्यापार तर्कले कुनै निश्चित मितिलाई सम्बन्धित महिना भित्रको हप्ता नम्बरमा रूपान्तरण गर्न आवश्यक छ भने, तपाईंले WEEKNUM को संयोजन प्रयोग गर्न सक्नुहुन्छ, DATE र MONTH प्रकार्यहरू:

सेल A2 मा मूल मिति समावेश छ भनी मान्दै, सोमबार (WEEKNUM को रिटर्न_टाइप आर्गुमेन्टमा सूचना २१) मा सुरु हुने हप्ताको लागि निम्न सूत्र प्रयोग गर्नुहोस्:

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

आइतबार मा सुरु हुने हप्ताको लागि, रिटर्न_टाइप आर्गुमेन्ट छोड्नुहोस्:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

34>

कसरी गर्ने योग मानहरू र हप्ता नम्बरद्वारा औसत फेला पार्नुहोस्

अब तपाईंले एक्सेलमा मितिलाई हप्ताको नम्बरमा कसरी रूपान्तरण गर्ने भनेर जान्नुहुन्छ, आउनुहोस्, तपाईंले अन्य गणनाहरूमा हप्ता संख्याहरू कसरी प्रयोग गर्न सक्नुहुन्छ हेरौं।

मान्नुहोस् , तपाइँसँग केहि मासिक बिक्री आंकडाहरू छन् र तपाइँ प्रत्येक हप्ताको लागि कुल जान्न चाहनुहुन्छ।

सुरु गर्नको लागि, प्रत्येक बिक्रीसँग सम्बन्धित हप्ता संख्या पत्ता लगाउनुहोस्। यदि तपाईंको मितिहरू स्तम्भ A मा छन् र स्तम्भ B मा बिक्री छन् भने, कक्षमा सुरु हुने स्तम्भ C मा =WEEKNUM(A2) सूत्र प्रतिलिपि गर्नुहोस्।C2.

र त्यसपछि, केहि अन्य स्तम्भमा (भन्नुहोस्, स्तम्भ E मा) हप्ता संख्याहरूको सूची बनाउनुहोस् र निम्न SUMIF सूत्र प्रयोग गरी प्रत्येक हप्ताको बिक्री गणना गर्नुहोस्:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

जहाँ E2 हप्ताको नम्बर हो।

यस उदाहरणमा, हामी मार्च बिक्रीको सूचीमा काम गरिरहेका छौं, त्यसैले हामीसँग 10 देखि 14 हप्ताको संख्याहरू छन्, जस्तै निम्न स्क्रिनसटमा देखाइएको छ:

उस्तै तरिकाले, तपाईंले दिइएको हप्ताको बिक्री औसत गणना गर्न सक्नुहुन्छ:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

यदि WEEKNUM सूत्रको साथ सहायक स्तम्भ तपाईंको डेटा लेआउटमा राम्रोसँग फिट हुँदैन भने, म तपाईंलाई बताउन पाउँदा खेद चाहन्छु कि यसबाट छुटकारा पाउने कुनै सरल उपाय छैन किनभने Excel WEEKNUM ती कार्यहरू मध्ये एक हो। यसले दायरा तर्कहरू स्वीकार गर्दैन। त्यसकारण, यो SUMPRODUCT वा अन्य कुनै एरे सूत्र जस्तै MONTH प्रकार्यमा प्रयोग गर्न सकिँदैन।

हप्ता संख्यामा आधारित कक्षहरूलाई कसरी हाइलाइट गर्ने

मानौं तपाईंसँग लामो सूची छ। केहि स्तम्भमा मितिहरू र तपाइँ दिइएको हप्तासँग सम्बन्धित ती मात्र हाइलाइट गर्न चाहनुहुन्छ। तपाईलाई आवश्यक पर्ने एक सशर्त ढाँचा नियम हो जसको WEEKNUM सूत्रसँग मिल्दोजुल्दो छ:

=WEEKNUM($A2)=10

तलको स्क्रिनसटमा देखाइएको अनुसार, नियमले 10 हप्ता भित्र गरिएको बिक्रीलाई हाइलाइट गर्दछ, जुन मार्च 2015 मा पहिलो हप्ता। नियम A2:B15 मा लागू हुने भएकोले, यसले दुबै स्तम्भहरूमा मानहरू हाइलाइट गर्दछ। तपाईं यसमा सशर्त ढाँचा नियमहरू सिर्जना गर्ने बारे थप जान्न सक्नुहुन्छट्यूटोरियल: अर्को सेल मानमा आधारित एक्सेल सशर्त ढाँचा।

यसरी तपाईँले एक्सेलमा हप्ता संख्याहरू गणना गर्न सक्नुहुन्छ, हप्ताको नम्बरलाई मितिमा रूपान्तरण गर्न सक्नुहुन्छ र मितिबाट हप्ताको संख्या निकाल्न सक्नुहुन्छ। आशा छ, तपाईंले आज सिकेका WEEKNUM सूत्रहरू तपाईंको कार्यपत्रहरूमा उपयोगी साबित हुनेछन्। अर्को ट्युटोरियलमा, हामी एक्सेलमा उमेर र वर्ष गणना गर्ने बारे कुरा गर्नेछौं। म पढ्नको लागि धन्यवाद र अर्को हप्ता भेट्ने आशा गर्दछु!