Sanaos Microsoft Excel nyayogikeun sababaraha fungsi pikeun dianggo sareng dinten minggu, bulan sareng taun, ngan ukur hiji anu sayogi pikeun minggu - fungsi WEEKNUM. Janten, upami anjeun milarian cara pikeun kéngingkeun nomer minggu ti tanggal hiji, WEEKNUM mangrupikeun fungsi anu anjeun pikahoyong.

Dina tutorial pondok ieu, urang bakal ngobrol sakedap ngeunaan sintaksis sareng argumen Excel WEEKNUM, sareng teras bahas sababaraha conto rumus anu nunjukkeun kumaha anjeun tiasa nganggo fungsi WEEKNUM pikeun ngitung nomer minggu dina lembar kerja Excel anjeun.

Fungsi Excel WEEKNUM - sintaksis

Fungsi WEEKNUM nyaéta dipaké dina Excel pikeun mulangkeun jumlah minggu ti tanggal husus dina taun (angka antara 1 jeung 54). Éta ngagaduhan dua argumen, anu ka-1 diperyogikeun sareng anu ka-2 opsional:

• Nomer_seri - tanggal naon waé dina saminggu anu nomerna anjeun nyobian pikeun manggihan. Ieu tiasa janten rujukan ka sél anu ngandung tanggal, tanggal anu diasupkeun nganggo pungsi DATE atanapi dipulangkeun ku sababaraha rumus sanés.
• Return_type (opsional) - angka anu nangtukeun mana dinten minggu dimimitian. Upami dileungitkeun, jinis standar 1 dianggo (minggu dimimitian dina dinten Minggu).

Di handap ieu daptar lengkep tina return_type nilai anu dirojong dina rumus WEEKNUM.

Dina pungsi WEEKNUM, dua béda sistem panomeran minggu dipaké:

• Sistem 1. Minggu anu ngandung 1 Januari dianggap minggu ka-1 dina sataun tur dinomerkeun minggu 1. Dina sistem ieu, minggu tradisional dimimitian dina Minggu.
• Sistem 2. Ieu sistem tanggal minggu ISO anu mangrupa bagian tina Standar tanggal sareng waktos ISO 8601. Dina sistem ieu, minggu dimimitian dina Senén jeung minggu ngandung Kemis mimiti taun dianggap minggu 1. Biasana dipikawanoh salaku sistem panomeran minggu Éropa sarta dipaké utamana dina pamaréntah jeung bisnis keur taun fiskal jeung timekeeping.

Sadaya tipeu balik nu didaptarkeun di luhur manglaku ka Sistem 1, iwal ti tipe mulang 21 nu dipaké dina Sistem 2.

Catetan. Dina Excel 2007 sareng versi sateuacana, ngan pilihan 1 sareng 2 anu sayogi. Jenis mulang 11 dugi ka 21 dirojong dina Excel 2010 sareng Excel 2013 wungkul.

Rumus Excel WEEKNUM pikeun ngarobah tanggal ka nomer minggu (tina 1 nepi ka 54)

Potret layar di handap ieu nunjukkeun kumaha anjeun tiasa kéngingkeun nomer minggu ti tanggal nganggo rumus =WEEKNUM(A2) pangbasajanna:

Di luhurrumus, argumen return_type dileungitkeun, nu hartina tipe standar 1 dipaké - minggu dimimitian dina Minggu.

Lamun anjeun leuwih resep dimimitian ku poé séjén dina saminggu, sebutkeun Senén, teras nganggo 2 dina argumen kadua:

=WEEKNUM(A2, 2)

Tinimbang ngarujuk kana sél, anjeun tiasa netepkeun tanggal langsung dina rumus nganggo fungsi DATE(taun, bulan, dinten), contona:

=WEEKNUM(DATE(2015,4,15), 2)

Rumus di luhur ngabalikeun 16, nyaéta jumlah minggu anu ngandung 15 April 2015, kalayan saminggu dimimitian dina Senén.

Dina skenario kahirupan nyata , pungsi Excel WEEKNUM jarang dipake sorangan. Paling sering anjeun bakal ngagunakeun éta dina kombinasi jeung fungsi séjén pikeun ngalakukeun rupa-rupa itungan dumasar kana jumlah minggu, sakumaha ditémbongkeun dina conto salajengna.

Kumaha ngarobah angka minggu ka tanggal dina Excel

Salaku anjeun geus ngan katempo, éta euweuh deal badag ngahurungkeun tanggal hiji kana angka minggu ngagunakeun fungsi Excel WEEKNUM. Tapi kumaha upami anjeun milarian sabalikna, nyaéta ngarobih nomer minggu ka tanggal? Hanjakal, teu aya fungsi Excel anu tiasa ngalakukeun ieu langsung. Jadi, urang kudu nyieun rumus sorangan.

Misalna anjeun boga sataun dina sél A2 jeung nomer minggu di B2, sarta ayeuna rék ngitung tanggal Mimitian jeung Ahir dina minggu ieu.

Catetan. Conto rumus ieu dumasar kana nomer minggu ISO, kalayan saminggu dimimitian dina Senén.

Rumus pikeun mulangkeun Mimitiantitimangsa dina saminggu nyaéta kieu:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Dimana A2 mangrupa taun jeung B2 mangrupa nomer minggu.

Perhatikeun yén rumusna mulangkeun tanggal salaku nomer serial, sarta pikeun dipintonkeun salaku tanggal hiji, anjeun kudu pormat sél sasuai. Anjeun tiasa mendakan pitunjuk lengkep dina Ngarobih format tanggal dina Excel. Sareng ieu mangrupikeun hasil anu dipulangkeun ku rumus:

Tangtosna, rumus pikeun ngarobih nomer minggu ka tanggal sanés sakedik, sareng peryogi sababaraha waktos kanggo kéngingkeun. sirah anjeun buleud logika. Atoh, kuring bakal ngalakukeun anu pangsaéna pikeun masihan katerangan anu bermakna pikeun anu panasaran pikeun turun ka handap.

Sapertos anu anjeun tingali, rumus kami diwangun ku 2 bagian:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - ngitung tanggal poé Senén panungtungan dina taun saméméhna.
• B2 * 7 - nambahan jumlah minggu dikali 7 (jumlah poé dina saminggu) pikeun meunangkeun Senén (tanggal mimiti) minggu dina patarosan.

Dina sistem penomeran minggu ISO, minggu ka-1 nyaéta minggu anu ngandung poé Kemis munggaran dina sataun. Akibatna, Senén kahiji sok antara 29 Désémber nepi ka 4 Januari. Ku kituna, pikeun manggihan tanggal éta, urang kudu manggihan poé Senén langsung saméméh 5 Januari.

Dina Microsoft Excel, Anjeun bisa nimba poé dina minggu ti tanggal ku ngagunakeun fungsi WEEKDAY. Sareng anjeun tiasa nganggo rumus umum di handap ieu pikeun kéngingkeun Senén langsung sateuacan tanggal anu dipasihkeun:

Upami urangTujuan pamungkas nya éta pikeun manggihan Senén langsung saméméh 5 Januari taun dina A2, urang bisa ngagunakeun fungsi DATE di handap ieu:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Tapi naon anu sabenerna urang butuhkeun téh lain Senén kahiji tina taun ieu, tapi rada Senén panungtungan taun saméméhna. Janten, anjeun kedah ngirangan 7 dinten ti 5 Januari sareng ku kituna anjeun nampi -2 dina fungsi DATE munggaran:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Dibandingkeun sareng rumus rumit anu anjeun nembé diajar, ngitung Tanggal ahir dina saminggu téh sapotong kueh :) Pikeun meunangkeun Minggu dina minggu anu dimaksud, anjeun ngan saukur nambahan 6 poé ka Tanggal mimiti , nyaéta =D2+6

Alternatipna, Anjeun bisa nambahkeun 6 langsung dina rumus:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Pikeun mastikeun rumus salawasna ngirimkeun tanggal nu bener, mangga tingali ieu di handap. screenshot. Rumus Tanggal Mimitian sareng Tanggal Ahir anu dibahas di luhur ditiron dina kolom D sareng E, masing-masing:

Cara-cara sanés pikeun ngarobih nomer minggu ka tanggal dina Excel

Upami rumus di luhur dumasar kana sistem tanggal minggu ISO henteu nyumponan sarat anjeun, cobian salah sahiji solusi ieu.

Rumus 1. Saminggu anu ngandung Jan-1 nyaéta minggu 1, Minggu-Minggu

Sakumaha anjeun émut, rumus saméméhna dianggo dumasar kana sistem tanggal ISO dimana Kemis munggaran dina taun dianggap minggu 1. Upami anjeun damel dumasar kana sistem tanggal dimana minggu anu ngandung tanggal 1 Januari dianggap minggu ka-1, ngagunakeun ieu di handaprumus:

Kaping mimiti:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Kaping tungtung:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Rumus 2. Saminggu anu ngandung Jan-1 nyaéta minggu 1, Minggu-Sab minggu

Rumus ieu sami sareng anu di luhur ngan ukur bédana anu ditulis. pikeun Minggu - Saptu minggu.

Kaping ngamimitian:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Kaping tungtung:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Rumus 3. Salawasna mimitian cacah dina 1 Januari, Minggu-Minggu minggu

Sedengkeun rumus saméméhna balik Senén (atawa Minggu) minggu 1, paduli naha lamun ragrag dina taun ieu atawa taun saméméhna, rumus tanggal mimiti ieu salawasna balik Januari 1 salaku tanggal mimiti minggu 1 paduli poé minggu. Sacara analogi, rumus tanggal tungtung salawasna balik 31 Désémber salaku tanggal tungtung minggu panungtungan dina taun, paduli poé dina saminggu. Dina sagala hal séjén, rumus ieu jalanna sarua jeung Formula 1 di luhur.

Kaping mimiti:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Kaping ahir:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Rumus 4. Salawasna mimitian cacah dina 1 Januari, Minggu-Saptu minggu

Pikeun ngitung tanggal mimiti jeung ahir. pikeun minggu Minggu - Saptu, ngan ukur hiji panyesuaian leutik dina rumus di luhur :)

Tanggal mimiti:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Kaping tungtung:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Kumaha carana meunangkeun bulan ti nomer minggu

Pikeun meunangkeun sabulan nu pakait jeung minggu angka, Anjeun manggihan dinten kahiji dina minggu dibikeun sakumaha dipedar di ieuconto, teras bungkus rumus éta dina fungsi BULAN Excel sapertos kieu:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Catetan. Punten émut yén rumus di luhur tiasa dianggo dumasar kana Sistem tanggal minggu ISO , dimana minggu dimimitian dina Senén sareng minggu anu ngandung Kemis 1 dina taun dianggap minggu 1. Contona, dina taun 2016, kahiji Kemis 7 Januari, jeung nu naha minggu 1 dimimitian dina 4-Jan-2016.

Kumaha carana kéngingkeun nomer minggu dina sabulan (tina 1 dugi ka 6)

Upami logika bisnis anjeun kedah ngarobih tanggal khusus kana nomer minggu dina sasih anu sami, anjeun tiasa nganggo kombinasi WEEKNUM, Fungsi DATE jeung MONTH:

Anggap sél A2 ngandung tanggal aslina, paké rumus di handap pikeun saminggu dimimitian dina Senén (perhatikeun 21 dina argumen return_type WEEKNUM):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Pikeun saminggu dimimitian dina Minggu , hapus argumen return_type:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Kumaha carana jumlah nilai jeung manggihan rata-rata ku jumlah minggu

Ayeuna anjeun terang kumaha carana ngarobah tanggal kana angka minggu dina Excel, hayu urang tingali kumaha anjeun bisa make angka minggu dina itungan lianna.

Anggap , anjeun gaduh sababaraha angka penjualan bulanan sareng anjeun hoyong terang jumlahna unggal minggu.

Pikeun mimitian, hayu urang milarian nomer minggu anu cocog sareng unggal penjualan. Upami kaping anjeun aya dina kolom A sareng penjualan dina kolom B, salin rumus =WEEKNUM(A2) dina kolom C dimimitian dina sélC2.

Terus, jieun daptar nomer minggu dina sababaraha kolom séjén (sebutkeun, dina kolom E) jeung hitung penjualan pikeun tiap minggu ngagunakeun rumus SUMIF ieu:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Dimana E2 nyaéta nomer minggu.

Dina conto ieu, urang nuju damel sareng daptar penjualan Maret, janten urang gaduh nomer minggu 10 dugi ka 14, sapertos ditingalikeun dina screenshot ieu:

Ku cara nu sarua, Anjeun bisa ngitung rata-rata penjualan pikeun minggu nu tangtu:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Upami kolom pembantu anu nganggo rumus WEEKNUM henteu pas kana tata perenah data anjeun, hanjakal kuring nyarioskeun yén teu aya cara anu gampang pikeun ngaleungitkeun éta kusabab Excel WEEKNUM mangrupikeun salah sahiji fungsi éta. nu teu narima argumen rentang. Ku alatan éta, éta henteu tiasa dianggo dina SUMPRODUCT atanapi rumus array anu sanés sapertos fungsi MONTH dina skenario anu sami.

Kumaha nyorot sél dumasar kana nomer minggu

Anggap anjeun gaduh daptar panjang. tina kaping dina sababaraha kolom sareng anjeun hoyong nyorot ngan ukur anu aya hubunganana sareng minggu anu ditangtukeun. Sadaya anu anjeun peryogikeun nyaéta aturan pormat kondisional kalayan rumus WEEKNUM anu sami sareng ieu:

=WEEKNUM($A2)=10

Sapertos anu dipidangkeun dina screenshot di handap, aturan ieu nyorot penjualan anu dilakukeun dina minggu ka-10, nyaéta minggu kahiji dina Maret 2015. Kusabab aturan manglaku ka A2: B15, highlights nilai dina duanana kolom. Anjeun tiasa leuwih jéntré ngeunaan nyieun aturan pormat kondisional dina ieututorial: pormat kondisional Excel dumasar kana nilai sél sejen.

Kieu kumaha anjeun tiasa ngitung angka minggu dina Excel, ngarobah nomer minggu ka tanggal sareng nimba nomer minggu ti tanggal. Mudah-mudahan, rumus WEEKNUM anu anjeun pelajari ayeuna bakal mangpaat dina lembar kerja anjeun. Dina tutorial salajengna, urang bakal ngobrol ngeunaan ngitung umur sareng taun dina Excel. Abdi ngahaturkeun nuhun pikeun maca sareng mugia tiasa pendak sareng anjeun minggu payun!