بينما يوفر Microsoft Excel مجموعة من الوظائف للعمل مع أيام الأسبوع والشهور والسنوات ، يتوفر واحد فقط لأسابيع - وظيفة WEEKNUM. لذلك ، إذا كنت تبحث عن طريقة للحصول على رقم أسبوع من تاريخ ما ، فإن WEEKNUM هي الوظيفة التي تريدها.

في هذا البرنامج التعليمي القصير ، سنتحدث بإيجاز عن بناء جملة وحجج Excel WEEKNUM ، و ثم ناقش بعض أمثلة الصيغ التي توضح كيف يمكنك استخدام دالة WEEKNUM لحساب أرقام الأسابيع في أوراق عمل Excel.

دالة WEEKNUM في Excel - بناء الجملة

الدالة WEEKNUM هي تستخدم في Excel لإرجاع رقم الأسبوع لتاريخ محدد في السنة (رقم بين 1 و 54). يحتوي على وسيطتين ، الأولى مطلوبة والثانية اختيارية:

• Serial_number - أي تاريخ خلال الأسبوع الذي تحاول رقمه لايجاد. يمكن أن يكون هذا مرجعًا لخلية تحتوي على التاريخ ، أو تاريخ تم إدخاله باستخدام الدالة DATE أو يتم إرجاعه بواسطة صيغة أخرى.
• نوع الإرجاع (اختياري) - رقم يحدد في أي يوم يبدأ الأسبوع. إذا تم حذفه ، فسيتم استخدام النوع الافتراضي 1 (الأسبوع الذي يبدأ يوم الأحد).

فيما يلي قائمة كاملة من return_type قيمة مدعومة في صيغ WEEKNUM.

في دالة WEEKNUM ، يتم استخدام نظامي ترقيم مختلفين للأسبوع :

• النظام 1. يتم اعتبار الأسبوع الذي يحتوي على 1 يناير الأسبوع الأول من العام وهو مُرقّم بالأسبوع 1. في هذا النظام ، يبدأ الأسبوع تقليديًا يوم الأحد.
• النظام 2. هذا هو نظام تاريخ أسبوع ISO الذي يعد جزءًا من معيار التاريخ والوقت ISO 8601. في هذا النظام ، يبدأ الأسبوع يوم الإثنين ويعتبر الأسبوع الذي يحتوي على أول خميس من العام هو الأسبوع الأول. ويُعرف عمومًا بنظام ترقيم الأسابيع الأوروبي ويستخدم بشكل أساسي في الحكومة والأعمال للسنوات المالية وضبط الوقت.

تنطبق جميع أنواع الإرجاع المذكورة أعلاه على النظام 1 ، باستثناء نوع الإرجاع 21 المستخدم في النظام 2.

ملاحظة. في Excel 2007 والإصدارات السابقة ، يتوفر الخياران 1 و 2 فقط. أنواع الإرجاع من 11 إلى 21 مدعومة في Excel 2010 و Excel 2013 فقط.

صيغ Excel WEEKNUM لتحويل التاريخ إلى رقم الأسبوع (من 1 إلى 54)

توضح لقطة الشاشة التالية كيف يمكنك الحصول على أرقام الأسبوع من التواريخ بأبسط صيغة =WEEKNUM(A2) :

في ما سبقالصيغة ، تم حذف الوسيطة return_type ، مما يعني أنه يتم استخدام النوع الافتراضي 1 - الأسبوع الذي يبدأ يوم الأحد.

إذا كنت تفضل البدء في يوم آخر من أيام الأسبوع ، على سبيل المثال الاثنين ، فاستخدم 2 في الوسيطة الثانية:

=WEEKNUM(A2, 2)

بدلاً من الإشارة إلى خلية ، يمكنك تحديد التاريخ مباشرةً في الصيغة باستخدام الدالة DATE (السنة ، الشهر ، اليوم) ، على سبيل المثال:

=WEEKNUM(DATE(2015,4,15), 2)

تُرجع الصيغة أعلاه 16 ، وهو رقم الأسبوع الذي يحتوي على 15 أبريل 2015 ، مع بداية الأسبوع يوم الاثنين.

في سيناريوهات الحياة الواقعية ، نادرًا ما يتم استخدام وظيفة Excel WEEKNUM بمفردها. غالبًا ما تستخدمه مع وظائف أخرى لإجراء عمليات حسابية متنوعة بناءً على رقم الأسبوع ، كما هو موضح في أمثلة أخرى.

كيفية تحويل رقم الأسبوع إلى تاريخ في Excel

كما أنت لقد رأيت للتو ، ليس من المهم تحويل تاريخ إلى رقم أسبوع باستخدام وظيفة Excel WEEKNUM. ولكن ماذا لو كنت تبحث عن العكس ، أي تحويل رقم أسبوع إلى تاريخ؟ للأسف ، لا توجد وظيفة Excel يمكنها القيام بذلك على الفور. لذلك ، سيتعين علينا إنشاء الصيغ الخاصة بنا.

لنفترض أن لديك سنة في الخلية A2 ورقم أسبوع في B2 ، والآن تريد حساب تاريخي البدء والانتهاء في هذا الأسبوع.

ملاحظة. يعتمد مثال الصيغة هذا على أرقام أسبوع ISO ، حيث يبدأ الأسبوع يوم الاثنين.

الصيغة لإرجاع ابدأالتاريخ الأسبوع كما يلي:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

حيث A2 السنة و B2 هو رقم الأسبوع.

يرجى ملاحظة أن الصيغة ترجع التاريخ كرقم تسلسلي ، ولعرضه كتاريخ ، تحتاج إلى تنسيق الخلية وفقًا لذلك. يمكنك العثور على الإرشادات التفصيلية في تغيير تنسيق التاريخ في Excel. وإليك النتيجة التي تم إرجاعها بواسطة الصيغة:

بالطبع ، صيغة تحويل رقم أسبوع إلى تاريخ ليست تافهة ، وقد يستغرق الأمر بعض الوقت للحصول عليها تدور رأسك حول المنطق. على أي حال ، سأبذل قصارى جهدي لتقديم شرح مفيد لأولئك الذين لديهم فضول للوصول إلى أسفل.

كما ترى ، تتكون صيغتنا من جزأين:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - يحسب تاريخ آخر يوم اثنين في العام السابق.
• B2 * 7 - يضيف عدد الأسابيع مضروبًا في 7 (عدد الأيام في الأسبوع) للحصول على يوم الاثنين (تاريخ البدء) من الأسبوع في السؤال.

في نظام ترقيم الأسابيع ISO ، الأسبوع 1 هو الأسبوع الذي يحتوي على أول خميس من السنة. وبالتالي ، يكون أول يوم اثنين دائمًا بين 29 كانون الأول (ديسمبر) و 4 كانون الثاني (يناير). لذلك ، للعثور على هذا التاريخ ، يتعين علينا العثور على يوم الاثنين قبل 5 كانون الثاني (يناير) مباشرة.

في Microsoft Excel ، يمكنك استخراج يوم من أيام الأسبوع من تاريخ باستخدام وظيفة WEEKDAY. ويمكنك استخدام الصيغة العامة التالية للحصول على يوم الاثنين مباشرة قبل أي تاريخ معين:

إذا كان لديناكان الهدف النهائي هو العثور على يوم الاثنين قبل الخامس من كانون الثاني (يناير) من العام مباشرةً في A2 ، يمكننا استخدام وظائف DATE التالية:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

ولكن ما نحتاج إليه في الواقع ليس أول يوم اثنين من هذا العام ، بل يوم الاثنين الأخير من العام السابق. لذلك ، عليك أن تطرح 7 أيام من 5 يناير ، وبالتالي تحصل على -2 في أول دالة DATE:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

مقارنة بالصيغة الصعبة التي تعلمتها للتو ، حساب تاريخ الانتهاء الأسبوع عبارة عن قطعة حلوى :) للحصول على يوم أحد من الأسبوع المعني ، ما عليك سوى إضافة 6 أيام إلى تاريخ البدء ، أي =D2+6

بدلاً من ذلك ، يمكنك إضافة 6 مباشرةً في الصيغة:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

للتأكد من أن الصيغ تقدم دائمًا التواريخ الصحيحة ، يرجى إلقاء نظرة على ما يلي لقطة شاشة. يتم نسخ صيغتي تاريخ البدء وتاريخ الانتهاء اللذين تمت مناقشتهما أعلاه عبر العمود D و E ، على التوالي:

طرق أخرى لتحويل رقم الأسبوع إلى تاريخ في Excel

إذا كانت الصيغة أعلاه المستندة إلى نظام تاريخ أسبوع ISO لا تفي بمتطلباتك ، فجرّب أحد الحلول التالية.

الصيغة 1. الأسبوع الذي يحتوي على 1 يناير هو الأسبوع الأول ، والأسبوع من الأحد إلى الأحد

كما تتذكر ، تعمل الصيغة السابقة استنادًا إلى نظام تاريخ ISO حيث يعتبر أول خميس من العام الأسبوع الأول. إذا كنت تعمل وفقًا لنظام التاريخ حيث يعتبر الأسبوع الذي يحتوي على الأول من يناير هو الأسبوع الأول ، استخدم ما يليالصيغ:

تاريخ البدء:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

تاريخ الانتهاء:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

الصيغة 2. الأسبوع الذي يحتوي على 1 يناير هو الأسبوع الأول ، والأسبوع من الأحد إلى السبت

هذه الصيغ مماثلة للصيغ المذكورة أعلاه مع الاختلاف الوحيد الذي تمت كتابته ليوم الأحد - السبت الأسبوع.

تاريخ البدء:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

تاريخ الانتهاء:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

الصيغة 3. ابدأ العد دائمًا في 1 يناير ، من الإثنين إلى الأحد

بينما تعود الصيغ السابقة يوم الإثنين (أو الأحد) من الأسبوع الأول ، بغض النظر عما إذا كان يقع ضمن هذا العام أو العام السابق ، تُرجع صيغة تاريخ البدء هذه دائمًا 1 يناير كتاريخ بدء الأسبوع 1 بغض النظر عن يوم الأسبوع. بالقياس ، تُرجع صيغة تاريخ الانتهاء دائمًا 31 ديسمبر كتاريخ انتهاء الأسبوع الأخير في السنة ، بغض النظر عن يوم الأسبوع. من جميع النواحي الأخرى ، تعمل هذه الصيغ بشكل مشابه للصيغة 1 أعلاه.

تاريخ البدء:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

تاريخ الانتهاء:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

الصيغة 4. ابدأ العد دائمًا في 1 يناير ، من الأحد إلى السبت الأسبوع

لحساب تاريخي البدء والانتهاء لأيام الأحد - السبت في الأسبوع ، كل ما يتطلبه الأمر هو تعديل صغير واحد في الصيغ أعلاه :)

تاريخ البدء:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

تاريخ الانتهاء:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

كيفية الحصول على رقم شهر من الأسبوع

للحصول على شهر مطابق للأسبوع الرقم ، ستجد اليوم الأول في أسبوع معين كما هو موضح في هذاعلى سبيل المثال ، ثم قم بلف هذه الصيغة في وظيفة Excel MONTH كما يلي:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

ملاحظة. يرجى تذكر أن الصيغة أعلاه تعمل على أساس نظام تاريخ أسبوع ISO ، حيث يبدأ الأسبوع يوم الاثنين والأسبوع الذي يحتوي على أول خميس من العام يعتبر الأسبوع 1. على سبيل المثال ، في عام 2016 ، أول خميس هو 7 يناير ، ولهذا السبب يبدأ الأسبوع الأول في 4 يناير 2016.

كيفية الحصول على رقم أسبوع في الشهر (من 1 إلى 6)

إذا كان منطق عملك يتطلب تحويل تاريخ محدد إلى رقم الأسبوع خلال الشهر المقابل ، فيمكنك استخدام مجموعة WEEKNUM ، الدالتان DATE و MONTH:

بافتراض أن الخلية A2 تحتوي على التاريخ الأصلي ، استخدم الصيغة التالية لمدة أسبوع يبدأ في الاثنين (لاحظ 21 في WEEKNUM's return_type الوسيطة):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

لمدة أسبوع يبدأ يوم الأحد ، احذف وسيطة return_type:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

How to قيم الجمع والعثور على المتوسط ​​برقم الأسبوع

الآن بعد أن عرفت كيفية تحويل تاريخ إلى رقم أسبوع في Excel ، دعنا نرى كيف يمكنك استخدام أرقام الأسبوع في حسابات أخرى.

افترض ، لديك بعض أرقام المبيعات الشهرية وتريد معرفة الإجمالي لكل أسبوع.

للبدء ، دعنا نتعرف على رقم الأسبوع المقابل لكل عملية بيع. إذا كانت التواريخ في العمود A والمبيعات في العمود B ، فانسخ الصيغة =WEEKNUM(A2) عبر العمود C بدءًا من الخليةC2.

ثم قم بعمل قائمة بأرقام الأسبوع في عمود آخر (على سبيل المثال ، في العمود E) وحساب المبيعات لكل أسبوع باستخدام صيغة SUMIF التالية:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

حيث E2 هو رقم الأسبوع.

في هذا المثال ، نحن نعمل بقائمة مبيعات شهر مارس ، لذلك لدينا أرقام الأسبوع من 10 إلى 14 ، مثل موضح في لقطة الشاشة التالية:

بطريقة مماثلة ، يمكنك حساب متوسط ​​المبيعات لأسبوع معين:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

إذا كان العمود المساعد مع صيغة WEEKNUM لا يتناسب بشكل جيد مع تخطيط البيانات الخاص بك ، يؤسفني أن أخبرك أنه لا توجد طريقة بسيطة للتخلص منه لأن Excel WEEKNUM هو إحدى هذه الوظائف لا يقبل نطاق الحجج. لذلك ، لا يمكن استخدامه داخل SUMPRODUCT أو أي صيغة مصفوفة أخرى مثل الدالة MONTH في سيناريو مشابه.

كيفية تمييز الخلايا بناءً على رقم الأسبوع

لنفترض أن لديك قائمة طويلة من التواريخ في عمود ما وتريد إبراز تلك التي تتعلق فقط بأسبوع معين. كل ما تحتاجه هو قاعدة تنسيق شرطي مع صيغة WEEKNUM مشابهة لما يلي:

=WEEKNUM($A2)=10

كما هو موضح في لقطة الشاشة أدناه ، تسلط القاعدة الضوء على المبيعات التي تم إجراؤها خلال الأسبوع العاشر ، وهو الأسبوع الأول في مارس 2015. نظرًا لأن القاعدة تنطبق على A2: B15 ، فإنها تبرز القيم في كلا العمودين. يمكنك معرفة المزيد حول إنشاء قواعد التنسيق الشرطي في هذاالبرنامج التعليمي: تنسيق Excel الشرطي استنادًا إلى قيمة خلية أخرى.

هذه هي الطريقة التي يمكنك بها حساب أرقام الأسبوع في Excel ، وتحويل رقم الأسبوع إلى تاريخ واستخراج رقم الأسبوع من التاريخ. نأمل أن تكون صيغ WEEKNUM التي تعلمتها اليوم مفيدة في أوراق العمل الخاصة بك. في البرنامج التعليمي التالي ، سنتحدث عن حساب العمر والسنوات في Excel. أشكرك على القراءة وآمل أن أراك الأسبوع المقبل!