જ્યારે માઈક્રોસોફ્ટ એક્સેલ અઠવાડિયાના દિવસો, મહિનાઓ અને વર્ષો સાથે કામ કરવા માટે ફંક્શનની શ્રેણી પૂરી પાડે છે, માત્ર એક અઠવાડિયા માટે ઉપલબ્ધ છે - WEEKNUM ફંક્શન. તેથી, જો તમે તારીખથી અઠવાડિયું નંબર મેળવવાનો માર્ગ શોધી રહ્યા છો, તો WEEKNUM એ તમને જોઈતું કાર્ય છે.

આ ટૂંકા ટ્યુટોરીયલમાં, અમે Excel WEEKNUM ના વાક્યરચના અને દલીલો વિશે ટૂંકમાં વાત કરીશું, અને પછી તમારી એક્સેલ વર્કશીટ્સમાં અઠવાડિયાની સંખ્યાની ગણતરી કરવા માટે તમે WEEKNUM ફંક્શનનો ઉપયોગ કેવી રીતે કરી શકો તે દર્શાવતા કેટલાક ફોર્મ્યુલા ઉદાહરણોની ચર્ચા કરો.

Excel WEEKNUM ફંક્શન - સિન્ટેક્સ

WEEKNUM ફંક્શન છે વર્ષમાં ચોક્કસ તારીખનો સપ્તાહ નંબર પરત કરવા માટે Excel માં વપરાય છે (1 અને 54 ની વચ્ચેની સંખ્યા). તેમાં બે દલીલો છે, 1લી જરૂરી છે અને 2જી વૈકલ્પિક છે:

• Serial_number - તમે જેનો નંબર અજમાવી રહ્યાં છો તે અઠવાડિયાની કોઈપણ તારીખ શોધવા માટે. આ તારીખ ધરાવતા કોષનો સંદર્ભ હોઈ શકે છે, DATE ફંક્શનનો ઉપયોગ કરીને દાખલ કરેલી તારીખ અથવા કોઈ અન્ય ફોર્મ્યુલા દ્વારા પરત કરવામાં આવી છે.
• Return_type (વૈકલ્પિક) - એક સંખ્યા જે નક્કી કરે છે કે જેના પર અઠવાડિયાનો દિવસ શરૂ થાય છે. જો અવગણવામાં આવે તો, ડિફૉલ્ટ પ્રકાર 1 નો ઉપયોગ થાય છે (રવિવારથી શરૂ થતું અઠવાડિયું).

અહીં WEEKNUM ફોર્મ્યુલામાં સમર્થિત return_type મૂલ્યોની સંપૂર્ણ સૂચિ છે.

WEEKNUM ફંક્શનમાં, બે અલગ અલગ સપ્તાહ નંબરિંગ સિસ્ટમ્સ નો ઉપયોગ થાય છે:

• સિસ્ટમ 1. 1 જાન્યુઆરી ધરાવતું સપ્તાહ ગણવામાં આવે છે. વર્ષનું 1મું અઠવાડિયું અને તેને ક્રમાંકિત અઠવાડિયું 1 છે. આ સિસ્ટમમાં, સપ્તાહ પરંપરાગત રીતે રવિવારે શરૂ થાય છે.
• સિસ્ટમ 2. આ ISO સપ્તાહની તારીખ સિસ્ટમનો ભાગ છે. ISO 8601 તારીખ અને સમય ધોરણ. આ સિસ્ટમમાં, અઠવાડિયું સોમવારથી શરૂ થાય છે અને વર્ષના પ્રથમ ગુરુવારનું અઠવાડિયું અઠવાડિયું 1 ગણવામાં આવે છે. તે સામાન્ય રીતે યુરોપિયન સપ્તાહની નંબરિંગ સિસ્ટમ તરીકે ઓળખાય છે અને તેનો ઉપયોગ મુખ્યત્વે નાણાકીય વર્ષ અને સમયની દેખરેખ માટે સરકાર અને વ્યવસાયમાં થાય છે.

ઉપર સૂચિબદ્ધ તમામ રીટર્ન પ્રકારો સિસ્ટમ 1 પર લાગુ થાય છે, રીટર્ન પ્રકાર 21 સિવાય કે જે સિસ્ટમ 2 માં વપરાય છે.

નોંધ. એક્સેલ 2007 અને પહેલાની આવૃત્તિઓમાં, ફક્ત 1 અને 2 વિકલ્પો ઉપલબ્ધ છે. રીટર્ન પ્રકારો 11 થી 21 માત્ર એક્સેલ 2010 અને એક્સેલ 2013 માં સમર્થિત છે.

તારીખને અઠવાડિયાના નંબરમાં રૂપાંતરિત કરવા માટે એક્સેલ WEEKNUM ફોર્મ્યુલા (1 થી 54 સુધી)

નીચેનો સ્ક્રીનશોટ દર્શાવે છે કે તમે સૌથી સરળ =WEEKNUM(A2) ફોર્મ્યુલા સાથે તારીખોમાંથી અઠવાડિયાના આંકડા કેવી રીતે મેળવી શકો છો:

<18

ઉપરમાંફોર્મ્યુલા, return_type દલીલ અવગણવામાં આવી છે, જેનો અર્થ છે કે ડિફૉલ્ટ પ્રકાર 1 નો ઉપયોગ થાય છે - રવિવારથી શરૂ થતું અઠવાડિયું.

જો તમે અઠવાડિયાના બીજા કોઈ દિવસથી શરૂઆત કરવા માંગતા હો, તો સોમવાર કહો, પછી 2 નો ઉપયોગ કરો બીજી દલીલમાં:

=WEEKNUM(A2, 2)

કોષનો ઉલ્લેખ કરવાને બદલે, તમે તારીખ(વર્ષ, મહિનો, દિવસ) ફંક્શનનો ઉપયોગ કરીને ફોર્મ્યુલામાં સીધી તારીખનો ઉલ્લેખ કરી શકો છો, ઉદાહરણ તરીકે:

=WEEKNUM(DATE(2015,4,15), 2)

ઉપરોક્ત સૂત્ર 16 પરત કરે છે, જે 15 એપ્રિલ, 2015 ધરાવતા અઠવાડિયાની સંખ્યા છે, જેમાં સોમવારથી એક સપ્તાહ શરૂ થાય છે.

વાસ્તવિક જીવનની પરિસ્થિતિઓમાં , Excel WEEKNUM ફંક્શન ભાગ્યે જ તેના પોતાના પર વપરાય છે. મોટાભાગે તમે તેનો ઉપયોગ અઠવાડિયાના નંબર પર આધારિત વિવિધ ગણતરીઓ કરવા માટે અન્ય કાર્યો સાથે સંયોજનમાં કરશો, જેમ કે આગળના ઉદાહરણોમાં દર્શાવવામાં આવ્યું છે.

એક્સેલમાં અઠવાડિયાની સંખ્યાને તારીખમાં કેવી રીતે કન્વર્ટ કરવી

તમે જેમ હમણાં જ જોયું છે, એક્સેલ WEEKNUM ફંક્શનનો ઉપયોગ કરીને તારીખને અઠવાડિયાના નંબરમાં ફેરવવી એ કોઈ મોટી વાત નથી. પરંતુ જો તમે તેનાથી વિપરીત શોધી રહ્યાં હોવ, એટલે કે અઠવાડિયાના નંબરને તારીખમાં રૂપાંતરિત કરો તો શું? અરે, ત્યાં કોઈ એક્સેલ ફંક્શન નથી જે આ તરત જ કરી શકે. તેથી, આપણે આપણા પોતાના સૂત્રો બનાવવા પડશે.

ધારો કે તમારી પાસે સેલ A2 માં એક વર્ષ છે અને B2 માં અઠવાડિયાની સંખ્યા છે, અને હવે તમે આ અઠવાડિયામાં પ્રારંભ અને સમાપ્તિ તારીખોની ગણતરી કરવા માંગો છો.

નોંધ. આ ફોર્મ્યુલાનું ઉદાહરણ ISO અઠવાડિયાની સંખ્યાઓ પર આધારિત છે, જેમાં સોમવારથી એક સપ્તાહ શરૂ થાય છે. પ્રારંભ પરત કરવા માટેનું સૂત્રઅઠવાડિયાની તારીખ નીચે મુજબ છે:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

જ્યાં A2 એ વર્ષ છે અને B2 એ અઠવાડિયાની સંખ્યા છે.

કૃપા કરીને નોંધ કરો કે સૂત્ર તારીખ પરત કરે છે. સીરીયલ નંબર તરીકે, અને તેને તારીખ તરીકે દર્શાવવા માટે, તમારે તે મુજબ સેલને ફોર્મેટ કરવાની જરૂર છે. તમે એક્સેલમાં તારીખ ફોર્મેટ બદલવામાં વિગતવાર સૂચનાઓ મેળવી શકો છો. અને અહીં ફોર્મ્યુલા દ્વારા પરત કરવામાં આવેલ પરિણામ છે:

અલબત્ત, અઠવાડિયાના નંબરને તારીખમાં રૂપાંતરિત કરવાનું સૂત્ર તુચ્છ નથી, અને તેને મેળવવામાં થોડો સમય લાગી શકે છે. તમારું માથું તર્કની આસપાસ છે. કોઈપણ રીતે, જે લોકો તળિયે જવા માટે ઉત્સુક છે તેમને અર્થપૂર્ણ સમજૂતી આપવા માટે હું મારા શ્રેષ્ઠ પ્રયાસો કરીશ.

તમે જુઓ છો તેમ, અમારું સૂત્ર 2 ભાગો ધરાવે છે:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - પાછલા વર્ષના છેલ્લા સોમવારની તારીખની ગણતરી કરે છે.
• B2 * 7 - અઠવાડિયાના સોમવાર (શરૂઆતની તારીખ) મેળવવા માટે 7 (અઠવાડિયામાં દિવસોની સંખ્યા) વડે ગુણાકાર કરેલ અઠવાડિયાની સંખ્યા ઉમેરે છે. પ્રશ્ન.

ISO સપ્તાહ નંબરિંગ સિસ્ટમમાં, અઠવાડિયું 1 એ અઠવાડિયું છે જેમાં વર્ષનો પ્રથમ ગુરુવાર હોય છે. પરિણામે, પહેલો સોમવાર હંમેશા 29 ડિસેમ્બર અને 4 જાન્યુઆરીની વચ્ચે હોય છે. તેથી, તે તારીખ શોધવા માટે, અમારે 5 જાન્યુઆરી પહેલાનો સોમવાર શોધવો પડશે.

માઈક્રોસોફ્ટ એક્સેલમાં, તમે અઠવાડિયાનો એક દિવસ અહીંથી કાઢી શકો છો. WEEKDAY ફંક્શનનો ઉપયોગ કરીને તારીખ. અને આપેલ તારીખ પહેલાં તરત જ સોમવાર મેળવવા માટે તમે નીચેના સામાન્ય સૂત્રનો ઉપયોગ કરી શકો છો:

જો અમારીઅંતિમ ધ્યેય A2 માં વર્ષના 5મી જાન્યુઆરીના તરત પહેલા સોમવાર શોધવાનો હતો, અમે નીચેના DATE કાર્યોનો ઉપયોગ કરી શકીએ છીએ:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

પરંતુ જે આપણને ખરેખર જોઈએ છે તે પ્રથમ સોમવાર નથી આ વર્ષે, પરંતુ તેના બદલે પાછલા વર્ષના છેલ્લા સોમવાર. તેથી, તમારે 5 જાન્યુઆરીથી 7 દિવસ બાદ કરવા પડશે અને તેથી તમને પ્રથમ DATE ફંક્શનમાં -2 મળશે:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

તમે હમણાં જ શીખ્યા છો તે મુશ્કેલ ફોર્મ્યુલાની સરખામણીમાં, <7 ની ગણતરી સપ્તાહની>અંતિમ તારીખ એ કેકનો ટુકડો છે :) પ્રશ્નમાં અઠવાડિયાનો રવિવાર મેળવવા માટે, તમે ફક્ત પ્રારંભ તારીખ માં 6 દિવસ ઉમેરો, એટલે કે =D2+6

વૈકલ્પિક રીતે, તમે ફોર્મ્યુલામાં સીધા જ 6 ઉમેરી શકો છો:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

સૂત્રો હંમેશા યોગ્ય તારીખો વિતરિત કરે છે તેની ખાતરી કરવા માટે, કૃપા કરીને નીચેના પર એક નજર નાખો સ્ક્રીનશોટ. ઉપર ચર્ચા કરેલ શરૂઆતની તારીખ અને સમાપ્તિ તારીખના સૂત્રો અનુક્રમે કૉલમ D અને Eમાં કૉપિ કરવામાં આવ્યા છે:

એક્સેલમાં અઠવાડિયાના નંબરને તારીખમાં કન્વર્ટ કરવાની અન્ય રીતો

જો ISO સપ્તાહની તારીખ સિસ્ટમ પર આધારિત ઉપરોક્ત સૂત્ર તમારી આવશ્યકતાઓને પૂર્ણ કરતું નથી, તો નીચેનામાંથી એક ઉકેલ અજમાવો.

ફોર્મ્યુલા 1. જાન્યુઆરી-1 ધરાવતું અઠવાડિયું સપ્તાહ 1, સોમ-રવિ સપ્તાહ છે

તમને યાદ છે તેમ, અગાઉનું સૂત્ર ISO તારીખ સિસ્ટમ પર આધારિત કામ કરે છે જ્યાં વર્ષના પ્રથમ ગુરુવારને અઠવાડિયું 1 ગણવામાં આવે છે. જો તમે તારીખ સિસ્ટમ પર આધારિત કામ કરો છો જ્યાં 1લી જાન્યુઆરીના સપ્તાહને સપ્તાહ 1 ​​ગણવામાં આવે છે, નીચેનાનો ઉપયોગ કરોસૂત્રો:

પ્રારંભ તારીખ:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

સમાપ્તિ તારીખ:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

સૂત્ર 2. જાન્યુ-1 ધરાવતું અઠવાડિયું એ અઠવાડિયું 1, રવિ-શનિ સપ્તાહ છે

આ સૂત્રો ઉપરોક્ત ફોર્મ્યુલા જેવા જ છે માત્ર એટલો જ તફાવત છે કે તેઓ લખેલા છે રવિવાર - શનિવાર સપ્તાહ માટે.

પ્રારંભ તારીખ:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

સમાપ્તિ તારીખ:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

સૂત્ર 3. હંમેશા 1 જાન્યુઆરી, સોમ-રવિ અઠવાડિયે ગણતરી શરૂ કરો

જ્યારે અગાઉના સૂત્રો અઠવાડિયા 1 ના સોમવાર (અથવા રવિવાર) પાછા ફરે છે, પછી ભલેને જો આ વર્ષની અંદર હોય કે પાછલા વર્ષની, આ શરૂઆતની તારીખ સૂત્ર હંમેશા અઠવાડિયાના દિવસને ધ્યાનમાં લીધા વિના અઠવાડિયા 1ની શરૂઆતની તારીખ તરીકે જાન્યુઆરી 1 પરત કરે છે. સાદ્રશ્ય દ્વારા, અઠવાડિયાના દિવસને ધ્યાનમાં લીધા વિના, અંતિમ તારીખ સૂત્ર હંમેશા વર્ષના છેલ્લા અઠવાડિયાની અંતિમ તારીખ તરીકે ડિસેમ્બર 31 પરત કરે છે. અન્ય તમામ બાબતોમાં, આ ફોર્મ્યુલા ઉપરના ફોર્મ્યુલા 1 ની જેમ જ કાર્ય કરે છે.

પ્રારંભ તારીખ:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

સમાપ્તિ તારીખ:<8

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

ફોર્મ્યુલા 4. હંમેશા 1 જાન્યુઆરી, રવિ-શનિ સપ્તાહથી ગણતરી શરૂ કરો

પ્રારંભ અને સમાપ્તિ તારીખોની ગણતરી કરવા માટે રવિવાર - શનિવાર અઠવાડિયા માટે, ઉપરોક્ત સૂત્રોમાં એક નાનું ગોઠવણ જરૂરી છે :)

પ્રારંભ તારીખ:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

સમાપ્તિ તારીખ:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

સપ્તાહ નંબરમાંથી મહિનો કેવી રીતે મેળવવો

સપ્તાહને અનુરૂપ મહિનો મેળવવા માટે નંબર, તમે આપેલ અઠવાડિયામાં પ્રથમ દિવસ આમાં સમજાવ્યા પ્રમાણે મેળવો છોઉદાહરણ તરીકે, અને પછી તે ફોર્મ્યુલાને Excel MONTH ફંક્શનમાં આ રીતે લપેટો:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

નોંધ. મહેરબાની કરીને યાદ રાખો કે ઉપરોક્ત સૂત્ર ISO સપ્તાહની તારીખ સિસ્ટમ પર આધારિત કામ કરે છે, જ્યાં સપ્તાહ સોમવારથી શરૂ થાય છે અને વર્ષના 1લા ગુરુવારને સમાવિષ્ટ સપ્તાહને અઠવાડિયું 1 ગણવામાં આવે છે. ઉદાહરણ તરીકે, વર્ષ 2016માં, પહેલો ગુરુવાર 7 જાન્યુઆરી છે અને તેથી જ અઠવાડિયું 1 4-જાન્યુઆરી-2016 ના રોજ શરૂ થાય છે.

એક મહિનામાં અઠવાડિયાનો નંબર કેવી રીતે મેળવવો (1 થી 6 સુધી)

જો તમારા વ્યવસાયના તર્કને અનુરૂપ મહિનાની અંદર ચોક્કસ તારીખને અઠવાડિયાના નંબરમાં રૂપાંતરિત કરવાની જરૂર હોય, તો તમે WEEKNUM ના સંયોજનનો ઉપયોગ કરી શકો છો, DATE અને MONTH ફંક્શન્સ:

ધારી રહ્યા છીએ કે સેલ A2 મૂળ તારીખ ધરાવે છે, સોમવાર થી શરૂ થતા અઠવાડિયા માટે નીચેના સૂત્રનો ઉપયોગ કરો (WEEKNUM ની રીટર્ન_ટાઇપ દલીલમાં 21 નોટિસ):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

રવિવાર થી શરૂ થતા એક અઠવાડિયા માટે, return_type દલીલને છોડી દો:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

કેવી રીતે મૂલ્યોનો સરવાળો કરો અને અઠવાડિયાના નંબર દ્વારા સરેરાશ શોધો

હવે તમે જાણો છો કે એક્સેલમાં તારીખને અઠવાડિયાના નંબરમાં કેવી રીતે રૂપાંતરિત કરવી, ચાલો જોઈએ કે તમે અન્ય ગણતરીઓમાં અઠવાડિયાના આંકડાનો ઉપયોગ કેવી રીતે કરી શકો છો.

ધારો કે , તમારી પાસે કેટલાક માસિક વેચાણના આંકડાઓ છે અને તમે દરેક અઠવાડિયે કુલ જાણવા માંગો છો.

શરૂઆત કરવા માટે, ચાલો દરેક વેચાણને અનુરૂપ એક સપ્તાહનો નંબર શોધીએ. જો તમારી તારીખો કૉલમ Aમાં છે અને કૉલમ Bમાં વેચાણ છે, તો સેલમાં શરૂ થતા કૉલમ Cમાં =WEEKNUM(A2) ફોર્મ્યુલા કૉપિ કરોC2.

અને પછી, અમુક અન્ય કૉલમમાં અઠવાડિયાના નંબરોની સૂચિ બનાવો (કહો, કૉલમ E માં) અને નીચેના SUMIF સૂત્રનો ઉપયોગ કરીને દરેક અઠવાડિયા માટે વેચાણની ગણતરી કરો:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

જ્યાં E2 એ અઠવાડિયાનો નંબર છે.

આ ઉદાહરણમાં, અમે માર્ચના વેચાણની સૂચિ સાથે કામ કરી રહ્યા છીએ, તેથી અમારી પાસે સપ્તાહની સંખ્યા 10 થી 14 છે. નીચેના સ્ક્રીનશોટમાં દર્શાવવામાં આવ્યું છે:

તે જ રીતે, તમે આપેલ અઠવાડિયા માટે વેચાણ સરેરાશની ગણતરી કરી શકો છો:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

જો WEEKNUM ફોર્મ્યુલા સાથેની સહાયક કૉલમ તમારા ડેટા લેઆઉટમાં સારી રીતે બંધબેસતી ન હોય, તો મને તમને જણાવતા અફસોસ થાય છે કે તેનાથી છૂટકારો મેળવવાનો કોઈ સરળ રસ્તો નથી કારણ કે Excel WEEKNUM તે કાર્યોમાંનું એક છે. જે શ્રેણીની દલીલોને સ્વીકારતું નથી. તેથી, તેનો ઉપયોગ SUMPRODUCT અથવા સમાન દૃશ્યમાં MONTH ફંક્શન જેવા અન્ય કોઈપણ એરે ફોર્મ્યુલામાં કરી શકાતો નથી.

સપ્તાહ નંબરના આધારે કોષોને કેવી રીતે પ્રકાશિત કરવું

ચાલો કહીએ કે તમારી પાસે લાંબી સૂચિ છે અમુક કૉલમમાં તારીખો અને તમે ફક્ત તે જ પ્રકાશિત કરવા માંગો છો જે આપેલ અઠવાડિયાથી સંબંધિત છે. તમારે ફક્ત આના જેવું જ WEEKNUM ફોર્મ્યુલા સાથેના શરતી ફોર્મેટિંગ નિયમની જરૂર છે:

=WEEKNUM($A2)=10

નીચેના સ્ક્રીનશૉટમાં દર્શાવ્યા મુજબ, નિયમ 10 અઠવાડિયામાં કરવામાં આવેલા વેચાણને હાઇલાઇટ કરે છે, જે માર્ચ 2015 માં પ્રથમ અઠવાડિયું. નિયમ A2:B15 પર લાગુ થતો હોવાથી, તે બંને કૉલમમાં મૂલ્યોને હાઇલાઇટ કરે છે. તમે આમાં શરતી ફોર્મેટિંગ નિયમો બનાવવા વિશે વધુ જાણી શકો છોટ્યુટોરીયલ: એક્સેલ કન્ડીશનલ ફોર્મેટિંગ અન્ય સેલ વેલ્યુ પર આધારિત છે.

આ રીતે તમે એક્સેલમાં અઠવાડિયાની સંખ્યાની ગણતરી કરી શકો છો, અઠવાડિયાના નંબરને તારીખમાં રૂપાંતરિત કરી શકો છો અને તારીખમાંથી અઠવાડિયાની સંખ્યા કાઢી શકો છો. આશા છે કે, આજે તમે જે WEEKNUM ફોર્મ્યુલા શીખ્યા તે તમારી વર્કશીટ્સમાં ઉપયોગી સાબિત થશે. આગળના ટ્યુટોરીયલમાં, આપણે Excel માં ઉંમર અને વર્ષોની ગણતરી કરવા વિશે વાત કરીશું. હું વાંચવા બદલ તમારો આભાર માનું છું અને તમને આવતા અઠવાડિયે મળવાની આશા રાખું છું!