Habang ang Microsoft Excel ay nagbibigay ng hanay ng mga function upang gumana sa mga karaniwang araw, buwan at taon, isa lang ang available para sa mga linggo - ang WEEKNUM function. Kaya, kung naghahanap ka ng paraan para makakuha ng isang linggong numero mula sa isang petsa, WEEKNUM ang gusto mong function.

Sa maikling tutorial na ito, maikling pag-uusapan natin ang tungkol sa syntax at argumento ng Excel WEEKNUM, at pagkatapos ay talakayin ang ilang halimbawa ng formula na nagpapakita kung paano mo magagamit ang WEEKNUM function upang kalkulahin ang mga numero ng linggo sa iyong mga Excel worksheet.

Excel WEEKNUM function - syntax

Ang WEEKNUM function ay ginamit sa Excel upang ibalik ang numero ng linggo ng isang tiyak na petsa sa taon (isang numero sa pagitan ng 1 at 54). Mayroon itong dalawang argumento, ang una ay kinakailangan at ang ika-2 ay opsyonal:

• Serial_number - anumang petsa sa loob ng linggo na ang numero ay sinusubukan mo Hanapin. Ito ay maaaring isang reference sa isang cell na naglalaman ng petsa, isang petsa na ipinasok sa pamamagitan ng paggamit ng DATE function o ibinalik ng ilang iba pang formula.
• Return_type (opsyonal) - isang numero na tumutukoy kung saan araw na magsisimula ang linggo. Kung aalisin, ginagamit ang default na uri 1 (ang linggong nagsisimula sa Linggo).

Narito ang kumpletong listahan ng return_type na mga value na sinusuportahan sa mga formula ng WEEKNUM.

Sa WEEKNUM function, dalawang magkaibang week numbering system ang ginagamit:

• System 1. Ang linggong naglalaman ng Enero 1 ay isinasaalang-alang ang unang linggo ng taon at binibilang na linggo 1. Sa sistemang ito, tradisyonal na nagsisimula ang linggo sa Linggo.
• System 2. Ito ang ISO week date system na bahagi ng ISO 8601 na pamantayan ng petsa at oras. Sa sistemang ito, magsisimula ang linggo sa Lunes at ang linggong naglalaman ng unang Huwebes ng taon ay itinuturing na linggo 1. Karaniwan itong kilala bilang European week numbering system at ito ay pangunahing ginagamit sa gobyerno at negosyo para sa mga taon ng pananalapi at timekeeping.

Lahat ng mga uri ng pagbabalik na nakalista sa itaas ay nalalapat sa System 1, maliban sa uri ng pagbabalik 21 na ginagamit sa System 2.

Tandaan. Sa Excel 2007 at mga naunang bersyon, ang mga opsyon 1 at 2 lamang ang available. Ang mga uri ng pagbabalik 11 hanggang 21 ay sinusuportahan lamang sa Excel 2010 at Excel 2013.

Mga formula ng Excel WEEKNUM upang i-convert ang petsa sa numero ng linggo (mula 1 hanggang 54)

Ipinapakita ng sumusunod na screenshot kung paano ka makakakuha ng mga numero ng linggo mula sa mga petsa gamit ang pinakasimpleng formula na =WEEKNUM(A2) :

Sa itaasformula, ang return_type argument ay inalis, na nangangahulugan na ang default na uri 1 ay ginagamit - ang linggo na nagsisimula sa Linggo.

Kung mas gusto mong magsimula sa ibang araw ng linggo, sabihin ang Lunes, pagkatapos ay gamitin ang 2 sa pangalawang argumento:

=WEEKNUM(A2, 2)

Sa halip na mag-refer sa isang cell, maaari mong tukuyin ang petsa nang direkta sa formula sa pamamagitan ng paggamit ng DATE(year, month, day) function, halimbawa:

=WEEKNUM(DATE(2015,4,15), 2)

Ang formula sa itaas ay nagbabalik ng 16, na siyang bilang ng linggong naglalaman ng Abril 15, 2015, na may isang linggong magsisimula sa Lunes.

Sa totoong buhay na mga sitwasyon , ang Excel WEEKNUM function ay bihirang gamitin sa sarili nitong. Kadalasan ay gagamitin mo ito kasama ng iba pang mga function upang magsagawa ng iba't ibang mga kalkulasyon batay sa numero ng linggo, tulad ng ipinapakita sa mga karagdagang halimbawa.

Paano i-convert ang numero ng linggo sa petsa sa Excel

Habang ikaw Nakita ko lang, hindi malaking bagay na gawing isang linggong numero ang petsa gamit ang Excel WEEKNUM function. Ngunit paano kung naghahanap ka ng kabaligtaran, ibig sabihin, pag-convert ng isang linggong numero sa isang petsa? Naku, walang Excel function na makakagawa nito kaagad. Kaya, kakailanganin naming bumuo ng sarili naming mga formula.

Ipagpalagay na mayroon kang isang taon sa cell A2 at isang linggong numero sa B2, at ngayon gusto mong kalkulahin ang mga petsa ng Pagsisimula at Pagtatapos sa linggong ito.

Tandaan. Ang halimbawa ng formula na ito ay batay sa mga numero ng linggo ng ISO, na may isang linggo na magsisimula sa Lunes.

Ang formula para ibalik ang Startang petsa ng linggo ay ang mga sumusunod:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Kung saan ang A2 ang taon at ang B2 ang numero ng linggo.

Pakitandaan na ibinabalik ng formula ang petsa bilang isang serial number, at upang maipakita ito bilang isang petsa, kailangan mong i-format ang cell nang naaayon. Makikita mo ang mga detalyadong tagubilin sa Pagbabago ng format ng petsa sa Excel. At narito ang resulta na ibinalik ng formula:

Siyempre, ang formula upang i-convert ang isang linggong numero sa isang petsa ay hindi mahalaga, at maaaring tumagal ng ilang sandali upang makuha iikot ang iyong ulo sa lohika. Anyway, gagawin ko ang lahat ng aking makakaya upang magbigay ng makabuluhang paliwanag para sa mga gustong bumaba sa ibaba.

Sa nakikita mo, ang aming formula ay binubuo ng 2 bahagi:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - kinakalkula ang petsa ng huling Lunes sa nakaraang taon.
• B2 * 7 - idinaragdag ang bilang ng mga linggo na pinarami ng 7 (ang bilang ng mga araw sa isang linggo) upang makuha ang Lunes (petsa ng pagsisimula) ng linggo sa tanong.

Sa ISO week numbering system, ang linggo 1 ay ang linggong naglalaman ng unang Huwebes ng taon. Dahil dito, ang unang Lunes ay palaging nasa pagitan ng Disyembre 29 at Enero 4. Kaya, upang mahanap ang petsang iyon, kailangan nating hanapin ang Lunes kaagad bago ang Enero 5.

Sa Microsoft Excel, maaari mong i-extract ang isang araw ng linggo mula sa isang petsa sa pamamagitan ng paggamit ng WEEKDAY function. At maaari mong gamitin ang sumusunod na generic na formula upang makuha kaagad ang Lunes bago ang anumang ibinigay na petsa:

Kung ang amingang pinakalayunin ay mahanap kaagad ang Lunes bago ang ika-5 ng Enero ng taon sa A2, magagamit namin ang mga sumusunod na function ng DATE:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Ngunit ang talagang kailangan namin ay hindi ang unang Lunes ng ngayong taon, ngunit sa halip ang huling Lunes ng nakaraang taon. Kaya, kailangan mong ibawas ang 7 araw mula Enero 5 at samakatuwid ay makakakuha ka ng -2 sa unang function na DATE:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Kumpara sa nakakalito na formula na natutunan mo lang, na kinakalkula ang Ang petsa ng pagtatapos ng linggo ay isang piraso ng cake :) Upang makuha ang Linggo ng linggong pinag-uusapan, magdagdag ka lang ng 6 na araw sa Petsa ng pagsisimula , ibig sabihin, =D2+6

Bilang kahalili, maaari kang magdagdag ng 6 nang direkta sa formula:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Upang matiyak na ang mga formula ay palaging naghahatid ng mga tamang petsa, mangyaring tingnan ang sumusunod screenshot. Ang mga formula ng Petsa ng Pagsisimula at Petsa ng Pagtatapos na tinalakay sa itaas ay kinopya sa column D at E, ayon sa pagkakabanggit:

Iba pang mga paraan upang i-convert ang numero ng linggo sa petsa sa Excel

Kung ang formula sa itaas batay sa ISO week date system ay hindi nakakatugon sa iyong mga kinakailangan, subukan ang isa sa mga sumusunod na solusyon.

Formula 1. Ang isang linggong naglalaman ng Jan-1 ay linggo 1, Lun-Sun linggo

Tulad ng naaalala mo, gumagana ang nakaraang formula batay sa ISO date system kung saan ang unang Huwebes ng taon ay itinuturing na linggo 1. Kung nagtatrabaho ka batay sa isang sistema ng petsa kung saan ang linggong naglalaman ng ika-1 ng Enero ay itinuturing na linggo 1, gamitin ang sumusunodmga formula:

Petsa ng pagsisimula:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Petsa ng pagtatapos:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Formula 2. Ang isang linggong naglalaman ng Ene-1 ay linggo 1, Linggo-Sab linggo

Ang mga formula na ito ay katulad ng mga nasa itaas na may pagkakaiba lamang na ang mga ito ay nakasulat para sa Linggo - Sabado linggo.

Petsa ng pagsisimula:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Petsa ng pagtatapos:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Formula 3. Palaging magsimulang magbilang sa Enero 1, Lunes-Linggo linggo

Habang ang mga nakaraang formula ay bumabalik sa Lunes (o Linggo) ng linggo 1, anuman ang kung sa loob ng taong ito o sa nakaraang taon, ang formula ng petsa ng pagsisimula na ito ay palaging nagbabalik ng Enero 1 bilang petsa ng pagsisimula ng linggo 1 anuman ang araw ng linggo. Sa pamamagitan ng pagkakatulad, ang formula ng petsa ng pagtatapos ay palaging nagbabalik ng Disyembre 31 bilang petsa ng pagtatapos ng huling linggo sa taon, anuman ang araw ng linggo. Sa lahat ng iba pang aspeto, ang mga formula na ito ay gumagana nang katulad sa Formula 1 sa itaas.

Petsa ng pagsisimula:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Petsa ng pagtatapos:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Formula 4. Palaging simulang magbilang sa Enero 1, Linggo-Sab linggo

Upang kalkulahin ang mga petsa ng pagsisimula at pagtatapos para sa Linggo - Sabado na linggo, ang kailangan lang ay isang maliit na pagsasaayos sa mga formula sa itaas :)

Petsa ng pagsisimula:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Petsa ng pagtatapos:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Paano makakuha ng buwan mula sa numero ng linggo

Upang makakuha ng buwan na katumbas ng linggo bilang, makikita mo ang unang araw sa isang partikular na linggo gaya ng ipinaliwanag ditohalimbawa, at pagkatapos ay i-wrap ang formula na iyon sa Excel MONTH function na tulad nito:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Tandaan. Pakitandaan na gumagana ang formula sa itaas batay sa ISO week date system , kung saan magsisimula ang linggo sa Lunes at ang linggong naglalaman ng ika-1 Huwebes ng taon ay itinuturing na linggo 1. Halimbawa, sa taong 2016, ang unang Huwebes ay Enero 7, at iyon ang dahilan kung bakit magsisimula ang linggo 1 sa 4-Ene-2016.

Paano makakuha ng isang linggong numero sa isang buwan (mula 1 hanggang 6)

Kung ang lohika ng iyong negosyo ay nangangailangan ng pag-convert ng isang partikular na petsa sa numero ng linggo sa loob ng kaukulang buwan, maaari mong gamitin ang kumbinasyon ng WEEKNUM, DATE at MONTH function:

Ipagpalagay na ang cell A2 ay naglalaman ng orihinal na petsa, gamitin ang sumusunod na formula para sa isang linggo simula Lunes (notice 21 sa return_type argument ng WEEKNUM):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Para sa isang linggo simula Linggo , tanggalin ang return_type argument:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Paano sum values ​​at maghanap ng average ayon sa numero ng linggo

Ngayong alam mo na kung paano mag-convert ng petsa sa isang linggong numero sa Excel, tingnan natin kung paano mo magagamit ang mga numero ng linggo sa iba pang mga kalkulasyon.

Ipagpalagay na , mayroon kang ilang buwanang bilang ng mga benta at gusto mong malaman ang kabuuan para sa bawat linggo.

Upang magsimula, alamin natin ang isang linggong numero na tumutugma sa bawat benta. Kung ang iyong mga petsa ay nasa column A at mga benta sa column B, kopyahin ang =WEEKNUM(A2) formula sa column C simula sa cellC2.

At pagkatapos, gumawa ng listahan ng mga numero ng linggo sa ibang column (sabihin, sa column E) at kalkulahin ang mga benta para sa bawat linggo gamit ang sumusunod na formula ng SUMIF:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Kung saan ang E2 ang numero ng linggo.

Sa halimbawang ito, nagtatrabaho kami sa isang listahan ng mga benta sa Marso, kaya mayroon kaming mga numero ng linggo 10 hanggang 14, bilang ipinakita sa sumusunod na screenshot:

Sa katulad na paraan, maaari mong kalkulahin ang average na benta para sa isang partikular na linggo:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Kung ang helper column na may WEEKNUM formula ay hindi angkop sa iyong data layout, ikinalulungkot kong sabihin sa iyo na walang simpleng paraan para maalis ito dahil ang Excel WEEKNUM ay isa sa mga function na iyon. hindi iyon tumatanggap ng mga argumento ng saklaw. Samakatuwid, hindi ito magagamit sa loob ng SUMPRODUCT o anumang iba pang array formula tulad ng MONTH function sa isang katulad na sitwasyon.

Paano i-highlight ang mga cell batay sa numero ng linggo

Ipagpalagay nating mayroon kang mahabang listahan ng mga petsa sa ilang column at gusto mong i-highlight lang ang mga nauugnay sa isang partikular na linggo. Ang kailangan mo lang ay isang kondisyong tuntunin sa pag-format na may WEEKNUM na formula na katulad nito:

=WEEKNUM($A2)=10

Tulad ng ipinakita sa screenshot sa ibaba, hina-highlight ng panuntunan ang mga benta na ginawa sa loob ng linggo 10, na kung saan ay ang unang linggo ng Marso 2015. Dahil nalalapat ang panuntunan sa A2:B15, hina-highlight nito ang mga value sa parehong column. Maaari kang matuto nang higit pa tungkol sa paggawa ng mga tuntunin sa pag-format ng kondisyon ditotutorial: Excel conditional formatting batay sa isa pang cell value.

Ito ay kung paano mo makalkula ang mga numero ng linggo sa Excel, i-convert ang numero ng linggo sa petsa at i-extract ang numero ng linggo mula sa petsa. Sana, ang WEEKNUM formula na natutunan mo ngayon ay mapatunayang kapaki-pakinabang sa iyong mga worksheet. Sa susunod na tutorial, pag-uusapan natin ang tungkol sa pagkalkula ng edad at taon sa Excel. Salamat sa pagbabasa at umaasa akong magkita tayo sa susunod na linggo!