మైక్రోసాఫ్ట్ ఎక్సెల్ వారాంతపు రోజులు, నెలలు మరియు సంవత్సరాలతో పని చేయడానికి అనేక రకాల ఫంక్షన్‌లను అందించినప్పటికీ, ఒకటి మాత్రమే వారాలకు అందుబాటులో ఉంటుంది - WEEKNUM ఫంక్షన్. కాబట్టి, మీరు తేదీ నుండి వారం సంఖ్యను పొందడానికి మార్గం కోసం చూస్తున్నట్లయితే, WEEKNUM అనేది మీకు కావలసిన ఫంక్షన్.

ఈ చిన్న ట్యుటోరియల్‌లో, మేము Excel WEEKNUM యొక్క సింటాక్స్ మరియు ఆర్గ్యుమెంట్‌ల గురించి క్లుప్తంగా మాట్లాడుతాము మరియు మీ Excel వర్క్‌షీట్‌లలో వారం సంఖ్యలను లెక్కించడానికి మీరు WEEKNUM ఫంక్షన్‌ని ఎలా ఉపయోగించవచ్చో ప్రదర్శించే కొన్ని ఫార్ములా ఉదాహరణలను చర్చించండి.

Excel WEEKNUM ఫంక్షన్ - సింటాక్స్

WEEKNUM ఫంక్షన్ సంవత్సరంలో నిర్దిష్ట తేదీ యొక్క వారం సంఖ్యను (1 మరియు 54 మధ్య ఉన్న సంఖ్య) తిరిగి ఇవ్వడానికి Excelలో ఉపయోగించబడుతుంది. దీనికి రెండు ఆర్గ్యుమెంట్‌లు ఉన్నాయి, 1వది అవసరం మరియు 2వది ఐచ్ఛికం:

• Serial_number - వారంలోపు మీరు ఎవరి సంఖ్యను ప్రయత్నిస్తున్నారో ఆ తేదీ కనుగొనేందుకు. ఇది తేదీని కలిగి ఉన్న సెల్‌కి సూచన కావచ్చు, DATE ఫంక్షన్‌ని ఉపయోగించి నమోదు చేసిన తేదీ లేదా ఏదైనా ఇతర ఫార్ములా ద్వారా అందించబడుతుంది.
• Return_type (ఐచ్ఛికం) - ఇది నిర్ణయించే సంఖ్య వారం ప్రారంభమయ్యే రోజు. విస్మరించబడితే, డిఫాల్ట్ రకం 1 ఉపయోగించబడుతుంది (ఆదివారం ప్రారంభమయ్యే వారం).

WEEKNUM ఫార్ములాల్లో మద్దతిచ్చే return_type విలువల పూర్తి జాబితా ఇక్కడ ఉంది.

WEEKNUM ఫంక్షన్‌లో, రెండు వేర్వేరు వారం నంబరింగ్ సిస్టమ్‌లు ఉపయోగించబడ్డాయి:

• సిస్టమ్ 1. జనవరి 1ని కలిగి ఉన్న వారం పరిగణించబడుతుంది. సంవత్సరంలో 1వ వారం మరియు వారం 1గా లెక్కించబడుతుంది. ఈ విధానంలో, వారం సంప్రదాయబద్ధంగా ఆదివారం ప్రారంభమవుతుంది.
• సిస్టమ్ 2. ఇది ISO వారం తేదీ వ్యవస్థ, ఇది ISO 8601 తేదీ మరియు సమయ ప్రమాణం. ఈ వ్యవస్థలో, వారం సోమవారం ప్రారంభమవుతుంది మరియు సంవత్సరంలో మొదటి గురువారం ఉన్న వారం వారం 1గా పరిగణించబడుతుంది. దీనిని సాధారణంగా యూరోపియన్ వీక్ నంబరింగ్ సిస్టమ్ అని పిలుస్తారు మరియు ఇది ప్రధానంగా ప్రభుత్వం మరియు వ్యాపారంలో ఆర్థిక సంవత్సరాలు మరియు సమయపాలన కోసం ఉపయోగించబడుతుంది.

సిస్టమ్ 2లో ఉపయోగించిన రిటర్న్ టైప్ 21 మినహా పైన జాబితా చేయబడిన అన్ని రిటర్న్ రకాలు సిస్టమ్ 1కి వర్తిస్తాయి.

గమనిక. Excel 2007 మరియు మునుపటి సంస్కరణల్లో, 1 మరియు 2 ఎంపికలు మాత్రమే అందుబాటులో ఉన్నాయి. రిటర్న్ రకాలు 11 నుండి 21 వరకు ఎక్సెల్ 2010 మరియు ఎక్సెల్ 2013లో మాత్రమే మద్దతు ఉంది.

Excel WEEKNUM ఫార్ములాలు తేదీని వారం సంఖ్యగా మార్చడానికి (1 నుండి 54 వరకు)

క్రింది స్క్రీన్‌షాట్ మీరు తేదీల నుండి వారం సంఖ్యలను సరళమైన =WEEKNUM(A2) ఫార్ములాతో ఎలా పొందవచ్చో చూపుతుంది:

<18

పైనఫార్ములా, return_type ఆర్గ్యుమెంట్ విస్మరించబడింది, అంటే డిఫాల్ట్ టైప్ 1 ఉపయోగించబడుతుంది - ఆదివారం ప్రారంభమయ్యే వారం.

మీరు వారంలోని ఇతర రోజుతో ప్రారంభించాలనుకుంటే, సోమవారం చెప్పండి, ఆపై 2 ఉపయోగించండి రెండవ ఆర్గ్యుమెంట్‌లో:

=WEEKNUM(A2, 2)

సెల్‌ని సూచించడానికి బదులుగా, మీరు DATE(సంవత్సరం, నెల, రోజు) ఫంక్షన్‌ని ఉపయోగించి నేరుగా ఫార్ములాలో తేదీని పేర్కొనవచ్చు, ఉదాహరణకు:

=WEEKNUM(DATE(2015,4,15), 2)

పై ఫార్ములా 16ని అందిస్తుంది, ఇది ఏప్రిల్ 15, 2015ని కలిగి ఉన్న వారం సంఖ్య, సోమవారం నుండి ఒక వారం ప్రారంభం అవుతుంది.

నిజ జీవిత దృశ్యాలలో , Excel WEEKNUM ఫంక్షన్ అరుదుగా స్వంతంగా ఉపయోగించబడుతుంది. మరిన్ని ఉదాహరణలలో ప్రదర్శించబడినట్లుగా, వారం సంఖ్య ఆధారంగా వివిధ గణనలను నిర్వహించడానికి మీరు చాలా తరచుగా దీన్ని ఇతర ఫంక్షన్‌లతో కలిపి ఉపయోగిస్తారు.

Excelలో వారం సంఖ్యను తేదీకి ఎలా మార్చాలి

మీలాగే ఇప్పుడే చూశాను, Excel WEEKNUM ఫంక్షన్‌ని ఉపయోగించి తేదీని వారం సంఖ్యగా మార్చడం పెద్ద విషయం కాదు. కానీ మీరు వ్యతిరేకం కోసం చూస్తున్నట్లయితే, అంటే వారం సంఖ్యను తేదీకి మార్చడం ఏమిటి? అయ్యో, దీన్ని వెంటనే చేయగల Excel ఫంక్షన్ ఏదీ లేదు. కాబట్టి, మేము మా స్వంత సూత్రాలను రూపొందించాలి.

మీరు సెల్ A2లో ఒక సంవత్సరం మరియు B2లో ఒక వారం సంఖ్యను కలిగి ఉంటే, ఇప్పుడు మీరు ఈ వారంలో ప్రారంభ మరియు ముగింపు తేదీలను లెక్కించాలనుకుంటున్నారు.

గమనిక. ఈ ఫార్ములా ఉదాహరణ ISO వారం సంఖ్యలపై ఆధారపడి ఉంటుంది, ఒక వారం సోమవారం ప్రారంభమవుతుంది.

ప్రారంభాన్ని తిరిగి ఇచ్చే ఫార్ములావారంలోని తేదీ క్రింది విధంగా ఉంది:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

ఎక్కడ A2 సంవత్సరం మరియు B2 అనేది వారం సంఖ్య.

దయచేసి ఫార్ములా తేదీని చూపుతుందని గమనించండి క్రమ సంఖ్యగా మరియు అది తేదీగా ప్రదర్శించబడాలంటే, మీరు సెల్‌ను తదనుగుణంగా ఫార్మాట్ చేయాలి. మీరు Excelలో తేదీ ఆకృతిని మార్చడంలో వివరణాత్మక సూచనలను కనుగొనవచ్చు. మరియు ఫార్ములా ద్వారా అందించబడిన ఫలితం ఇక్కడ ఉంది:

వాస్తవానికి, వారం సంఖ్యను తేదీకి మార్చే సూత్రం సామాన్యమైనది కాదు మరియు దాన్ని పొందడానికి కొంత సమయం పట్టవచ్చు మీ తల తర్కం చుట్టూ ఉంది. ఏది ఏమైనప్పటికీ, కిందికి దిగాలనే ఆసక్తి ఉన్నవారికి అర్థవంతమైన వివరణను అందించడానికి నేను నా వంతు కృషి చేస్తాను.

మీరు చూస్తున్నట్లుగా, మా సూత్రం 2 భాగాలను కలిగి ఉంటుంది:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - మునుపటి సంవత్సరంలో చివరి సోమవారం తేదీని గణిస్తుంది.
• B2 * 7 - వారంలోని సోమవారాన్ని (ప్రారంభ తేదీ) పొందడానికి 7 (వారంలో రోజుల సంఖ్య)తో గుణించిన వారాల సంఖ్యను జోడిస్తుంది. ప్రశ్న.

ISO వీక్ నంబరింగ్ సిస్టమ్‌లో, 1వ వారం అనేది సంవత్సరంలో మొదటి గురువారం ఉన్న వారం. పర్యవసానంగా, మొదటి సోమవారం ఎల్లప్పుడూ డిసెంబర్ 29 మరియు జనవరి 4 మధ్య ఉంటుంది. కాబట్టి, ఆ తేదీని కనుగొనడానికి, మేము జనవరి 5కి ముందు సోమవారాన్ని వెతకాలి.

Microsoft Excelలో, మీరు దీని నుండి వారంలోని ఒక రోజుని సంగ్రహించవచ్చు WEEKDAY ఫంక్షన్‌ని ఉపయోగించడం ద్వారా తేదీ. మరియు మీరు ఏదైనా తేదీకి ముందు సోమవారం పొందడానికి క్రింది సాధారణ సూత్రాన్ని ఉపయోగించవచ్చు:

మాది అయితేA2లో సంవత్సరం జనవరి 5వ తేదీకి ముందు సోమవారాన్ని కనుగొనడం అంతిమ లక్ష్యం, మేము ఈ క్రింది DATE ఫంక్షన్‌లను ఉపయోగించవచ్చు:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

కానీ మనకు నిజంగా కావలసింది మొదటి సోమవారం కాదు ఈ సంవత్సరం, కానీ మునుపటి సంవత్సరం చివరి సోమవారం. కాబట్టి, మీరు జనవరి 5 నుండి 7 రోజులను తీసివేయాలి మరియు అందువల్ల మీరు మొదటి DATE ఫంక్షన్‌లో -2ని పొందుతారు:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

మీరు ఇప్పుడే నేర్చుకున్న గమ్మత్తైన ఫార్ములాతో పోలిస్తే, <7ని లెక్కిస్తారు వారంలోని> ముగింపు తేదీ కేక్ ముక్క :) సందేహాస్పద వారంలోని ఆదివారం పొందడానికి, మీరు ప్రారంభ తేదీ కి 6 రోజులను జోడించండి, అంటే =D2+6

ప్రత్యామ్నాయంగా, మీరు ఫార్ములాలో నేరుగా 6ని జోడించవచ్చు:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

ఫార్ములాలు ఎల్లప్పుడూ సరైన తేదీలను అందజేస్తాయని నిర్ధారించుకోవడానికి, దయచేసి క్రింది వాటిని చూడండి స్క్రీన్షాట్. పైన చర్చించిన ప్రారంభ తేదీ మరియు ముగింపు తేదీ సూత్రాలు వరుసగా D మరియు E నిలువు వరుసలలో కాపీ చేయబడ్డాయి:

Excelలో వారం సంఖ్యను తేదీకి మార్చడానికి ఇతర మార్గాలు

ISO వీక్ డేట్ సిస్టమ్ ఆధారంగా పై ఫార్ములా మీ అవసరాలకు అనుగుణంగా లేకుంటే, కింది పరిష్కారాలలో ఒకదాన్ని ప్రయత్నించండి.

ఫార్ములా 1. జనవరి-1ని కలిగి ఉన్న వారం వారం 1, సోమ-ఆదివారం

మీకు గుర్తున్నట్లుగా, మునుపటి ఫార్ములా ISO తేదీ వ్యవస్థపై ఆధారపడి పని చేస్తుంది, ఇక్కడ సంవత్సరంలో మొదటి గురువారం వారం 1గా పరిగణించబడుతుంది. మీరు తేదీ సిస్టమ్ ఆధారంగా పని చేస్తే, జనవరి 1ని కలిగి ఉన్న వారం వారం 1గా పరిగణించబడుతుంది, కింది వాటిని ఉపయోగించండిసూత్రాలు:

ప్రారంభ తేదీ:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

ముగింపు తేదీ:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

ఫార్ములా 2. జనవరి-1ని కలిగి ఉన్న వారం 1వ వారం, ఆది-శని వారం

ఈ ఫార్ములాలు పైన పేర్కొన్న వాటితో సమానంగా ఉంటాయి, అవి వ్రాసిన ఒకే తేడాతో ఉంటాయి ఆదివారం - శనివారం వారానికి.

ప్రారంభ తేదీ:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

ముగింపు తేదీ:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

ఫార్ములా 3. ఎల్లప్పుడూ జనవరి 1, సోమ-ఆదివారం నుండి లెక్కింపు ప్రారంభించండి

మునుపటి సూత్రాలు 1వ వారంలోని సోమవారం (లేదా ఆదివారం)తో సంబంధం లేకుండా తిరిగి వస్తాయి ఈ సంవత్సరం లేదా అంతకు ముందు సంవత్సరంలోకి వస్తే, ఈ ప్రారంభ తేదీ ఫార్ములా ఎల్లప్పుడూ వారంలోని రోజుతో సంబంధం లేకుండా వారం 1 ప్రారంభ తేదీగా జనవరి 1 ని అందిస్తుంది. సారూప్యత ప్రకారం, ముగింపు తేదీ ఫార్ములా ఎల్లప్పుడూ డిసెంబర్ 31 ని వారంలోని రోజుతో సంబంధం లేకుండా సంవత్సరంలో చివరి వారం ముగింపు తేదీగా అందిస్తుంది. అన్ని ఇతర అంశాలలో, ఈ సూత్రాలు పైన ఉన్న ఫార్ములా 1 వలె పని చేస్తాయి.

ప్రారంభ తేదీ:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

ముగింపు తేదీ:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

ఫార్ములా 4. ఎల్లప్పుడూ జనవరి 1, ఆది-శని వారంలో లెక్కింపు ప్రారంభించండి

ప్రారంభ మరియు ముగింపు తేదీలను లెక్కించడానికి ఆదివారం - శనివారం వారానికి, పైన పేర్కొన్న సూత్రాలలో ఒక చిన్న సర్దుబాటు మాత్రమే అవసరం :)

ప్రారంభ తేదీ:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

చివరి తేదీ:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

వారం సంఖ్య నుండి నెలను ఎలా పొందాలి

వారానికి సంబంధించిన నెలను పొందడానికి సంఖ్య, ఇందులో వివరించిన విధంగా మీరు ఇచ్చిన వారంలో మొదటి రోజుని కనుగొంటారుఉదాహరణకు, ఆపై ఆ సూత్రాన్ని Excel MONTH ఫంక్షన్‌లో ఇలా చుట్టండి:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

గమనిక. దయచేసి ఎగువ ఫార్ములా ISO వారం తేదీ సిస్టమ్ పై ఆధారపడి పనిచేస్తుందని గుర్తుంచుకోండి, ఇక్కడ వారం సోమవారం ప్రారంభమవుతుంది మరియు సంవత్సరంలో 1వ గురువారం ఉన్న వారం వారం 1గా పరిగణించబడుతుంది. ఉదాహరణకు, 2016 సంవత్సరంలో, మొదటి గురువారం జనవరి 7, అందుకే 1వ వారం 4-జనవరి-2016న ప్రారంభమవుతుంది.

ఒక నెలలో (1 నుండి 6 వరకు) వారం సంఖ్యను ఎలా పొందాలి

మీ వ్యాపార తర్కం ప్రకారం నిర్దిష్ట తేదీని సంబంధిత నెలలోపు వారం సంఖ్యగా మార్చడం అవసరమైతే, మీరు WEEKNUM కలయికను ఉపయోగించవచ్చు, DATE మరియు MONTH ఫంక్షన్‌లు:

సెల్ A2 అసలు తేదీని కలిగి ఉందని ఊహిస్తే, సోమవారం నుండి ప్రారంభమయ్యే వారం పాటు క్రింది ఫార్ములాను ఉపయోగించండి (WEEKNUM యొక్క రిటర్న్_టైప్ ఆర్గ్యుమెంట్‌లో 21ని గమనించండి):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

ఆదివారం నుండి ప్రారంభమయ్యే వారం పాటు, రిటర్న్_టైప్ ఆర్గ్యుమెంట్‌ని వదిలివేయండి:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

ఎలా చేయాలి మొత్తం విలువలు మరియు వారం సంఖ్య ద్వారా సగటును కనుగొనండి

ఇప్పుడు Excelలో తేదీని వారం సంఖ్యగా ఎలా మార్చాలో మీకు తెలుసు, మీరు ఇతర గణనలలో వారం సంఖ్యలను ఎలా ఉపయోగించవచ్చో చూద్దాం.

అనుకుందాం. , మీ వద్ద కొన్ని నెలవారీ విక్రయాల గణాంకాలు ఉన్నాయి మరియు మీరు ప్రతి వారం మొత్తం తెలుసుకోవాలనుకుంటున్నారు.

ప్రారంభించడానికి, ప్రతి విక్రయానికి సంబంధించిన వారం సంఖ్యను కనుగొనండి. మీ తేదీలు కాలమ్ Aలో మరియు విక్రయాలు కాలమ్ Bలో ఉంటే, సెల్‌లో ప్రారంభమయ్యే C నిలువు వరుసలో =WEEKNUM(A2) సూత్రాన్ని కాపీ చేయండిC2.

ఆపై, కొన్ని ఇతర కాలమ్‌లో వారం సంఖ్యల జాబితాను రూపొందించండి (చెప్పండి, కాలమ్ E) మరియు క్రింది SUMIF సూత్రాన్ని ఉపయోగించి ప్రతి వారం అమ్మకాలను లెక్కించండి:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

E2 అనేది వారపు సంఖ్య.

ఈ ఉదాహరణలో, మేము మార్చి విక్రయాల జాబితాతో పని చేస్తున్నాము, కాబట్టి మేము 10 నుండి 14 వారాల సంఖ్యలను కలిగి ఉన్నాము. కింది స్క్రీన్‌షాట్‌లో ప్రదర్శించబడింది:

అదే పద్ధతిలో, మీరు ఇచ్చిన వారానికి అమ్మకాల సగటును లెక్కించవచ్చు:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

WEEKNUM ఫార్ములాతో సహాయక కాలమ్ మీ డేటా లేఅవుట్‌కి సరిగ్గా సరిపోకపోతే, Excel WEEKNUM ఆ ఫంక్షన్‌లలో ఒకటి కాబట్టి దాన్ని వదిలించుకోవడానికి సులభమైన మార్గం లేదని మీకు చెప్పడానికి చింతిస్తున్నాను. ఇది పరిధి వాదనలను అంగీకరించదు. కాబట్టి, ఇది SUMPRODUCTలో లేదా MONTH ఫంక్షన్ వంటి మరేదైనా ఇతర శ్రేణి ఫార్ములాలో ఉపయోగించబడదు.

వారం సంఖ్య ఆధారంగా సెల్‌లను ఎలా హైలైట్ చేయాలి

మీ దగ్గర సుదీర్ఘ జాబితా ఉందని చెప్పండి కొన్ని కాలమ్‌లోని తేదీలు మరియు మీరు ఇచ్చిన వారానికి సంబంధించిన వాటిని మాత్రమే హైలైట్ చేయాలనుకుంటున్నారు. మీకు కావలసిందల్లా ఇదే విధమైన WEEKNUM ఫార్ములాతో షరతులతో కూడిన ఆకృతీకరణ నియమం:

=WEEKNUM($A2)=10

దిగువ స్క్రీన్‌షాట్‌లో ప్రదర్శించినట్లుగా, నియమం 10వ వారంలోపు చేసిన విక్రయాలను హైలైట్ చేస్తుంది, ఇది మార్చి 2015లో మొదటి వారం. నియమం A2:B15కి వర్తిస్తుంది కాబట్టి, ఇది రెండు నిలువు వరుసలలోని విలువలను హైలైట్ చేస్తుంది. మీరు ఇందులో షరతులతో కూడిన ఫార్మాటింగ్ నియమాలను సృష్టించడం గురించి మరింత తెలుసుకోవచ్చుట్యుటోరియల్: మరొక సెల్ విలువ ఆధారంగా Excel షరతులతో కూడిన ఫార్మాటింగ్.

ఈ విధంగా మీరు Excelలో వారం సంఖ్యలను లెక్కించవచ్చు, వారం సంఖ్యను తేదీకి మార్చవచ్చు మరియు తేదీ నుండి వారం సంఖ్యను సేకరించవచ్చు. ఈ రోజు మీరు నేర్చుకున్న WEEKNUM సూత్రాలు మీ వర్క్‌షీట్‌లలో ఉపయోగకరంగా ఉంటాయని ఆశిస్తున్నాము. తదుపరి ట్యుటోరియల్‌లో, మేము ఎక్సెల్‌లో వయస్సు మరియు సంవత్సరాలను లెక్కించడం గురించి మాట్లాడుతాము. నేను చదివినందుకు ధన్యవాదాలు మరియు వచ్చే వారం మిమ్మల్ని కలుస్తానని ఆశిస్తున్నాను!