Microsoft Excel нь ажлын өдөр, сар, жилээр ажиллах олон төрлийн функцээр хангадаг ч долоо хоногийн турш зөвхөн нэгийг нь ашиглах боломжтой - WEEKNUM функц. Тиймээс, хэрэв та огнооноос долоо хоногийн дугаар авах арга хайж байгаа бол WEEKNUM бол таны хүссэн функц юм.

Энэхүү богино зааварт бид Excel WEEKNUM-ийн синтакс болон аргументуудын талаар товч ярих болно. дараа нь Excel-ийн ажлын хуудсан дээрх WEEKNUM функцийг хэрхэн долоо хоногийн тоог тооцоолох боломжтойг харуулсан хэдэн томьёоны жишээг ярилц.

Excel-ийн WEEKNUM функц - синтакс

WEEKNUM функц нь Excel-д тухайн жилийн тодорхой огнооны долоо хоногийн дугаарыг буцаахад ашигладаг (1-ээс 54 хүртэлх тоо). Энэ нь хоёр аргументтай бөгөөд 1 дэх нь шаардлагатай, 2 дахь нь сонголттой:

• Цуваа_дугаар - таны дугаарыг ашиглах гэж буй долоо хоногийн доторх дурын огноо Олох. Энэ нь огноо, DATE функцийг ашиглан оруулсан эсвэл өөр томьёогоор буцаасан огноо агуулсан нүдний лавлагаа байж болно.
• Буцах_төрөл (заавал биш) - алийг нь тодорхойлох тоо. долоо хоног эхэлдэг өдөр. Хэрэв орхигдуулсан бол өгөгдмөл 1-р төрлийг ашиглана (ням гарагт эхлэх долоо хоног).

WEEKNUM томьёонд дэмжигдсэн return_type утгын бүрэн жагсаалтыг энд үзүүлэв.

WEEKNUM функцэд хоёр өөр долоо хоног дугаарлах системийг ашигладаг:

• Систем 1. 1-р сарын 1-ийг агуулсан долоо хоногийг авч үзнэ. жилийн 1 дэх долоо хоног бөгөөд 1 долоо хоногоор дугаарлагдсан байдаг. Энэ системд долоо хоног уламжлал ёсоор Ням гарагт эхэлдэг.
• Систем 2. Энэ нь ISO долоо хоногийн огнооны систем бөгөөд ISO 8601 огноо, цагийн стандарт. Энэ системд долоо хоног нь Даваа гаригт эхэлдэг бөгөөд жилийн эхний пүрэв гарагийг агуулсан долоо хоногийг 1 дэх долоо хоног гэж үздэг. Энэ нь Европын долоо хоногийн дугаарлалтын систем гэж нэрлэгддэг бөгөөд төсвийн жил, цаг хэмжигдэхүүнд голчлон засгийн газар, бизнест ашиглагддаг.

Дээр дурдсан бүх төрлийн буцаах төрлүүд нь Систем 2-д хэрэглэгддэг 21 төрлийн буцаахаас бусад нь Систем 1-д хамаарна.

Тайлбар. Excel 2007 болон өмнөх хувилбаруудад зөвхөн 1 ба 2-р сонголтууд боломжтой. 11-ээс 21 хүртэлх буцаах төрлийг зөвхөн Excel 2010 болон Excel 2013-д дэмждэг.

Огноог долоо хоногийн дугаар болгон хөрвүүлэх Excel-ийн WEEKNUM томьёо (1-ээс 54 хүртэл)

Дараах дэлгэцийн агшин нь хамгийн энгийн =WEEKNUM(A2) томъёогоор долоо хоногийн дугаарыг огнооноос хэрхэн авахыг харуулж байна:

Дээрхтомьёоны хувьд return_type аргументыг орхигдуулсан бөгөөд энэ нь өгөгдмөл төрлийн 1-ийг ашигладаг гэсэн үг - долоо хоногийн ням гаригаас эхэлнэ.

Хэрэв та долоо хоногийн өөр өдөр буюу Даваа гараг гэж хэлвэл 2-г ашиглана уу. Хоёрдахь аргумент дээр:

=WEEKNUM(A2, 2)

Нүдэнд хандахын оронд та DATE(жил, сар, өдөр) функцийг ашиглан томьёонд шууд огноог зааж өгч болно, жишээ нь:

=WEEKNUM(DATE(2015,4,15), 2)

Дээрх томьёо нь 16-г буцаадаг бөгөөд энэ нь 2015 оны 4-р сарын 15-ны өдрийг агуулсан долоо хоногийн Даваа гарагаас эхлэх долоо хоногийн тоо юм.

Бодит нөхцөл байдалд , Excel WEEKNUM функцийг дангаар нь ашиглах нь ховор. Ихэнх тохиолдолд та үүнийг бусад функцуудтай хослуулан ашиглан долоо хоногийн тоон дээр тулгуурлан янз бүрийн тооцооллыг хийдэг бөгөөд үүнийг дараагийн жишээн дээр харуулав.

Excel дээр долоо хоногийн тоог огноо руу хэрхэн хөрвүүлэх вэ

Таны хувьд. Сая харлаа, Excel-ийн WEEKNUM функцийг ашиглан огноог долоо хоногийн тоо болгох нь тийм ч чухал зүйл биш юм. Хэрэв та эсрэгээр нь хайж байгаа бол, өөрөөр хэлбэл долоо хоногийн тоог огноо руу хөрвүүлэх гэж байгаа бол яах вэ? Харамсалтай нь үүнийг шууд хийх Excel функц байхгүй байна. Тиймээс бид өөрсдөө томьёо бүтээх хэрэгтэй болно.

Та А2 нүдэнд нэг жил, В2 нүдэнд долоо хоногийн дугаар байгаа гэж үзвэл одоо энэ долоо хоногт эхлэх болон дуусах огноог тооцоолохыг хүсэж байна.

Тайлбар. Энэ томьёоны жишээ нь Даваа гаригаас эхлэх долоо хоногтой ISO долоо хоногийн тоон дээр үндэслэсэн болно.

Эхлэлийг буцаах томьёоогноо долоо хоногийн дараах байдалтай байна:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

А2 нь жил, В2 нь долоо хоногийн дугаар юм.

Томьёо нь огноог буцаадаг гэдгийг анхаарна уу. серийн дугаар болгож, огноогоор харуулахын тулд нүдийг зохих ёсоор форматлах хэрэгтэй. Та дэлгэрэнгүй зааврыг Excel-ийн Огнооны форматыг өөрчлөх хэсгээс олж болно. Дараах томьёогоор буцаасан үр дүн нь энд байна:

Мэдээжийн хэрэг, долоо хоногийн тоог огноо болгон хөрвүүлэх томьёо нь тийм ч энгийн зүйл биш бөгөөд үүнийг авахад хэсэг хугацаа шаардагдана. Таны толгой логикийг тойрон эргэлддэг. Юутай ч би доод тал руугаа орох сонирхолтой хүмүүст утга учиртай тайлбар өгөхийн тулд чадах бүхнээ хийх болно.

Таны харж байгаагаар манай томъёо 2 хэсгээс бүрдэнэ:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - өмнөх жилийн сүүлийн Даваа гарагийн огноог тооцно.
• B2 * 7 - долоо хоногийн Даваа гарагийг (эхлэх огноо) авахын тулд долоо хоногийн тоог 7-оор (долоо хоногийн өдрийн тоо) үржүүлнэ. асуулт.

ISO долоо хоногийн дугаарлалтын системд 1 дэх долоо хоног нь жилийн эхний пүрэв гарагийг агуулсан долоо хоног юм. Тиймээс эхний даваа үргэлж 12-р сарын 29-өөс 1-р сарын 4-ний хооронд байдаг. Тиймээс тэр огноог олохын тулд бид 1-р сарын 5-ны өмнөх даваа гарагийг шууд олох ёстой.

Microsoft Excel-д та долоо хоногийн өдрийг дараахаас гаргаж авч болно. WEEKDAY функцийг ашиглан огноо. Мөн та дараах ерөнхий томъёог ашиглан Даваа гарагийг өгөгдсөн огнооны өмнө шууд авах боломжтой:

Хэрэв манайЭцсийн зорилго нь жилийн 1-р сарын 5-ны өмнөх даваа гарагийг А2 дээр шууд олох явдал байсан тул бид дараах DATE функцуудыг ашиглаж болно:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Гэхдээ бидэнд хэрэгтэй зүйл бол эхний Даваа гараг биш юм. энэ жил, харин өмнөх оны сүүлийн Даваа гариг. Тиймээс та 1-р сарын 5-аас 7 хоногийг хасах хэрэгтэй бөгөөд ингэснээр та эхний DATE функцэд -2 гарна:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Таны дөнгөж сурсан төвөгтэй томъёотой харьцуулахад <7-г тооцоолоход. Долоо хоногийн>Төгсгөлийн огноо бол бялуу юм :) Долоо хоногийн Ням гарагийг авахын тулд та Эхлэх огноо дээр 6 хоног нэмэхэд л хангалттай, өөрөөр хэлбэл =D2+6

Өөр нэг хувилбараар та томьёонд шууд 6-г нэмж болно:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Томьёонууд үргэлж зөв огноог өгөхийн тулд дараахь зүйлийг харна уу. дэлгэцийн агшин. Дээр дурдсан Эхлэх огноо ба Дуусах огнооны томьёог D ба E баганад тус тус хуулсан:

Excel дээр долоо хоногийн тоог огноо руу хөрвүүлэх бусад аргууд

Хэрэв ISO долоо хоногийн огнооны системд үндэслэсэн дээрх томъёо нь таны шаардлагад нийцэхгүй байвал дараах шийдлүүдийн аль нэгийг туршиж үзээрэй.

Формула 1. 1-р сарын 1-ийг агуулсан долоо хоног нь 1-р долоо хоног, Даваа-Ням гараг

Таны санаж байгаагаар өмнөх томьёо нь жилийн эхний пүрэв гарагийг 1 дэх долоо хоног гэж тооцдог ISO огнооны системд тулгуурлан ажилладаг. Хэрэв та 1-р сарын 1-ний өдрийг агуулсан долоо хоногийг 1 дэх долоо хоног гэж тооцдог огнооны системд тулгуурлан ажилладаг бол, дараахыг ашиглана уутомъёо:

Эхлэх огноо:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Төгсгөлийн огноо:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Формула 2. 1-р долоо хоногийг агуулсан долоо хоног нь 1-р долоо хоног, Ням-Бямба долоо хоног

Эдгээр томьёо нь дээр дурдсантай төстэй бөгөөд зөвхөн бичсэнээрээ ялгаатай. Ням - Бямба гарагуудад.

Эхлэх огноо:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Дуусгах огноо:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Формула 3. Үргэлж 1-р сарын 1-ний Даваа-Ням гарагаас эхлэн тоолоорой

Өмнөх томъёонууд 1-р долоо хоногийн Даваа гариг ​​(эсвэл Ням) буцаж ирдэг. Хэрэв энэ жил эсвэл өмнөх жилд таарч байгаа эсэхээс үл хамааран энэхүү эхлэх огнооны томъёо нь үргэлж 1-р сарын 1 -ийг долоо хоногийн өдрөөс үл хамааран 1-р долоо хоногийн эхлэх огноо болгож буцаана. Үүнтэй адилтгаж үзвэл дуусах огнооны томъёо нь долоо хоногийн өдрөөс үл хамааран жилийн сүүлийн долоо хоногийн төгсгөлийн огноо гэж үргэлж 12-р сарын 31 -г буцаана. Бусад бүх талаараа эдгээр томьёо нь дээрх Формула 1-тэй адилхан ажилладаг.

Эхлэх огноо:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Төгсгөлийн огноо:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Формула 4. Үргэлж 1-р сарын 1, Ням-Бямба гаригт тоолж эхлэх

Эхлэх болон дуусах огноог тооцоолохын тулд Ням - Бямба гаригийн долоо хоногт дээрх томьёог нэг жижиг тохируулга хийхэд л хангалттай :)

Эхлэх огноо:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Төгсгөлийн огноо:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Долоо хоногийн дугаараас сарыг хэрхэн авах вэ

Долоо хоногт тохирох сарыг авахын тулд тоо, та энд тайлбарласны дагуу тухайн долоо хоногийн эхний өдрийг олноЖишээ нь, дараа нь Excel-ийн САРЫН функцэд томъёог дараах байдлаар боож өгнө үү:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Тайлбар. Дээрх томьёо нь долоо хоног Даваа гаригт эхэлдэг бөгөөд жилийн 1 дэх Пүрэв гарагийг агуулсан долоо хоногийг 1 дэх долоо хоног гэж тооцдог ISO долоо хоногийн огнооны систем дээр суурилдаг гэдгийг санаарай. Жишээлбэл, 2016 онд, Эхний Пүрэв гараг бол 1-р сарын 7, тиймээс 1-р долоо хоног 2016 оны 1-р сарын 4-нд эхэлдэг.

Сарын дотор долоо хоногийн дугаарыг хэрхэн авах вэ (1-ээс 6 хүртэл)

Хэрэв таны бизнесийн логик тодорхой огноог тухайн сарын доторх долоо хоногийн дугаар руу хөрвүүлэх шаардлагатай бол та WEEKNUM, DATE болон MONTH функцууд:

А2 нүдэнд анхны огноо орсон гэж үзвэл Даваа -аас эхлэн долоо хоногийн турш дараах томьёог ашиглана уу (WEEKNUM-ийн буцах_төрлийн аргумент дахь 21-ийг анхаарна уу):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Ням гараг -аас эхлэн долоо хоногийн турш return_type аргументыг орхи:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Хэрхэн нийлбэр дүнгүүд болон долоо хоногийн тоогоор дундажийг олоорой

Одоо та Excel дээр огноог долоо хоногийн тоо руу хэрхэн хөрвүүлэхээ мэддэг болсон тул бусад тооцоололд долоо хоногийн тоог хэрхэн ашиглахыг харцгаая.

, танд хэдэн сарын борлуулалтын тоо байгаа бөгөөд та долоо хоног бүрийн нийт дүнг мэдэхийг хүсч байна.

Эхлэхийн тулд борлуулалт бүрт тохирох долоо хоногийн тоог олж мэдье. Хэрэв таны огноо А баганад, борлуулалт В баганад байгаа бол =WEEKNUM(A2) томьёог нүднээс эхлэн С баганад хуулна уу.C2.

Дараа нь өөр баганад (Е баганад гэх мэт) долоо хоногийн тоонуудын жагсаалтыг гаргаж, дараах SUMIF томъёог ашиглан долоо хоног бүрийн борлуулалтыг тооцоол.

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Э2 нь долоо хоногийн дугаар юм.

Энэ жишээнд бид 3-р сарын борлуулалтын жагсаалттай ажиллаж байгаа тул 10-аас 14 хүртэлх долоо хоногтой байна. дараах дэлгэцийн агшинд үзүүлэв:

Үүнтэй адилаар та тухайн долоо хоногийн борлуулалтын дундажийг тооцоолж болно:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Хэрэв WEEKNUM томьёо бүхий туслах багана таны өгөгдлийн загварт тохирохгүй байвал Excel WEEKNUM нь эдгээр функцуудын нэг учраас үүнийг арилгах энгийн арга байхгүй гэдгийг би харамсаж байна. Энэ нь мужын аргументуудыг хүлээн зөвшөөрдөггүй. Тиймээс үүнийг SUMPRODUCT эсвэл ижил төстэй хувилбарт MONTH функц гэх мэт бусад массивын томьёо дотор ашиглах боломжгүй.

Долоо хоногийн дугаар дээр үндэслэн нүдийг хэрхэн тодруулах вэ

Танд урт жагсаалт байна гэж бодъё. огноог зарим баганад байгаа бөгөөд та зөвхөн тухайн долоо хоногтой холбоотой огноог тодруулахыг хүсч байна. Танд хэрэгтэй зүйл бол WEEKNUM-тэй төстэй томъёо бүхий нөхцөлт форматын дүрэм юм:

=WEEKNUM($A2)=10

Доорх дэлгэцийн зурган дээр харуулсанчлан дүрэм нь 10-р долоо хоногт хийгдсэн борлуулалтыг онцолж өгдөг. 2015 оны 3-р сарын эхний долоо хоног. Дүрэм нь A2:B15-д хамаарах тул хоёр баганад утгыг онцолсон. Та үүнээс нөхцөлт форматын дүрмийг бий болгох талаар илүү ихийг мэдэж болнозаавар: Өөр нүдний утга дээр суурилсан Excel-ийн нөхцөлт форматлалт.

Ингэснээр та Excel дээр долоо хоногийн тоог тооцоолж, долоо хоногийн тоог огноо руу хөрвүүлж, огнооноос долоо хоногийн дугаарыг гаргаж авах боломжтой. Өнөөдөр таны сурсан WEEKNUM томъёонууд таны ажлын хуудсанд хэрэг болно гэж найдаж байна. Дараагийн зааварт бид Excel-д нас, жилийг тооцоолох талаар ярих болно. Уншиж байгаад баярлалаа, дараа долоо хоногт уулзана гэж найдаж байна!