Microsoft Excel-ek lanegun, hilabete eta urteekin lan egiteko funtzio sorta bat eskaintzen duen arren, asteetan bakarra dago erabilgarri: WEEKNUM funtzioa. Beraz, data batetik aste-zenbaki bat lortzeko modu bat bilatzen ari bazara, WEEKNUM da nahi duzun funtzioa.

Tutorial labur honetan, Excel-en WEEKNUM-en sintaxia eta argumentuei buruz hitz egingo dugu laburki, eta ondoren, eztabaidatu WEEKNUM funtzioa nola erabil dezakezun zure Excel-eko lan-orrietako asteko zenbakiak kalkulatzeko zenbait formula adibide.

Excel WEEKNUM funtzioa - sintaxia

WEEKNUM funtzioa da. Excel-en erabiltzen da urteko data zehatz baten asteko zenbakia itzultzeko (1 eta 54 arteko zenbakia). Bi argumentu ditu, 1.a beharrezkoa da eta 2.a aukerakoa da:

• Serie_zenbakia - saiatzen ari zaren asteko edozein data. aurkitu. Hau data duen gelaxka baten erreferentzia izan daiteke, DATE funtzioa erabiliz sartutako data edo beste formularen baten bidez itzultzen dena.
• Itzuli_mota (aukerakoa) - zein den zehazten duen zenbakia. astea hasten den egunean. Salbatuz gero, lehenetsitako 1 mota erabiltzen da (igandean hasten den astea).

Hona hemen WEEKNUM formuletan onartzen diren return_type balioen zerrenda osoa.

WEEKNUM funtzioan, bi asteko zenbaketa-sistema desberdin erabiltzen dira:

• 1. sistema. Urtarrilaren 1a duen astea hartzen da kontuan. urteko 1. astea eta 1. astea zenbatzen du. Sistema honetan, astea, tradizionalki, igandean hasten da.
• 2. sistema. Hau da ISO asteko data sistema, eta sistemaren parte da. ISO 8601 data eta ordu estandarra. Sistema honetan, astea astelehenean hasten da eta urteko lehen osteguna daukan astea 1. astea hartzen da. Europako asteen zenbaketa-sistema bezala ezagutzen da eta batez ere gobernuan eta negozioetan erabiltzen da ekitaldi fiskaletarako eta kronologia egiteko.

Goian zerrendatutako itzulera mota guztiak 1. sistemari aplikatzen zaizkio, 2. sisteman erabiltzen den 21. itzulera mota izan ezik.

Oharra. Excel 2007 eta aurreko bertsioetan, 1 eta 2 aukerak bakarrik daude eskuragarri. 11tik 21era bitarteko itzulera motak Excel 2010 eta Excel 2013-en soilik onartzen dira.

Excel WEEKNUM formulak data asteko zenbaki bihurtzeko (1etik 54ra)

Ondoko pantaila-argazkiak erakusten du nola lor ditzakezun aste zenbakiak =WEEKNUM(A2) formula errazeneko datetatik:

Aurrekoanformula, return_type argumentua baztertzen da, eta horrek esan nahi du lehenetsitako 1 mota erabiltzen dela - igandean hasten den astea.

Asteko beste egun batekin hasi nahi baduzu, esan astelehena, eta erabili 2. bigarren argumentuan:

=WEEKNUM(A2, 2)

Gelula bati erreferentzia egin beharrean, data zuzenean zehaztu dezakezu formulan DATA(urtea, hilabetea, eguna) funtzioa erabiliz, adibidez:

=WEEKNUM(DATE(2015,4,15), 2)

Goiko formulak 16 ematen du, hau da, 2015eko apirilaren 15a duen astearen zenbakia, astelehenean hasten den astea.

Bizitza errealeko eszenatokietan , Excel WEEKNUM funtzioa oso gutxitan erabiltzen da bere kabuz. Gehienetan beste funtzio batzuekin batera erabiliko zenuke aste-zenbakian oinarritutako hainbat kalkulu egiteko, adibide gehiagotan erakusten den moduan.

Nola bihurtu aste zenbakia Excel-en datara

Zuk bezala. ikusi berri du, ez da gauza handirik data bat asteko zenbaki bihurtzea Excel WEEKNUM funtzioa erabiliz. Baina zer gertatzen da kontrakoa bilatzen baduzu, hau da, aste-zenbaki bat data bihurtzea? Ai, ez dago Excel funtziorik hori berehala egin dezakeenik. Beraz, gure formulak eraiki beharko ditugu.

Demagun A2 gelaxkan urte bat duzula eta B2 aste zenbakia, eta orain aste honetako Hasiera eta Amaiera datak kalkulatu nahi dituzula.

Oharra. Formula adibide hau ISO asteko zenbakietan oinarritzen da, aste bat astelehenean hasten dena.

Hasi itzultzeko formulaasteko data hau da:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Non A2 urtea den eta B2 asteko zenbakia den.

Kontuan izan formulak data itzultzen duela. serie-zenbaki gisa, eta data gisa bistaratzeko, gelaxka horren arabera formateatu behar duzu. Argibide zehatzak Excel-en data-formatua aldatzea atalean aurki ditzakezu. Eta hona hemen formulak itzultzen duen emaitza:

Noski, aste-zenbaki bat data bihurtzeko formula ez da hutsala, eta baliteke denbora pixka bat behar izatea lortzeko. zure burua logikaren inguruan. Dena den, ahalegina egingo dut hondoraino iristeko jakin-mina dutenei azalpen esanguratsuak emateko.

Ikusten duzun bezala, gure formulak 2 zati ditu:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - aurreko urteko azken asteleheneko data kalkulatzen du.
• B2 * 7 - aste kopurua 7z biderkatu (asteko egun kopurua) gehitzen du astearen astelehena (hasiera-data) lortzeko. galdera.

ISO asteen zenbaketa-sisteman, 1. astea urteko lehen osteguna duen astea da. Ondorioz, lehen astelehena abenduaren 29tik urtarrilaren 4ra bitartean izaten da beti. Beraz, data hori aurkitzeko, urtarrilaren 5a baino lehen astelehena aurkitu behar dugu.

Microsoft Excel-en, asteko egun bat atera dezakezu. data bat ASTEEGUNA funtzioa erabiliz. Eta formula generiko hau erabil dezakezu astelehena edozein dataren aurretik berehala lortzeko:

GureAzken helburua urteko urtarrilaren 5a baino lehen astelehena aurkitzea zen A2n, DATE funtzio hauek erabil genitzake:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Baina benetan behar duguna ez da lehen astelehena. aurten, aurreko urteko azken astelehenean baizik. Beraz, urtarrilaren 5etik 7 egun kendu behar dituzu eta, ondorioz, -2 lortzen duzu lehen DATE funtzioan:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Ikasi berri duzun formula delikatuaren aldean, <7 kalkulatuz>Asteko amaiera-data oso erraza da :) Asteko igandea lortzeko, 6 egun gehitu besterik ez duzu Hasiera-data -ri, hau da, =D2+6

Bestela, 6 gehi ditzakezu zuzenean formulan:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Formulek beti data egokiak ematen dituztela ziurtatzeko, begiratu honako hau. pantaila-argazkia. Goian aztertutako hasiera-data eta amaiera-data formulak D eta E zutabetan kopiatzen dira, hurrenez hurren:

Aste zenbakia Excel-en data bihurtzeko beste modu batzuk

ISO asteko data-sisteman oinarritutako goiko formulak zure eskakizunak betetzen ez baditu, saiatu irtenbide hauetako bat.

1. formula. Urtarrila-1a duen astea 1. astea da, astelehena-igandea

Gogoratzen duzunez, aurreko formulak ISO data-sisteman oinarrituta funtzionatzen du, non urteko lehen osteguna 1. astea hartzen den. Urtarrilaren 1a duen astea 1. astea hartzen den data-sistema batean oinarrituta lan egiten baduzu, erabili honako hauformulak:

Hasierako data:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Amaiera data:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Formula 2. Urtarrila-1a duen astea 1. astea da, Eguzkia-Larunbat astea

Formula hauek aurrekoen antzekoak dira, idatzita daudelako desberdintasun bakarrarekin. Igandetik larunbaterako asterako.

Hasierako data:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Amaiera data:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

3. Formula. Hasi beti zenbatzen urtarrilaren 1ean, astelehenetik igandera astean

Aurreko formulak 1. asteko astelehenean (edo igandean) itzultzen diren bitartean, edozein dela ere Urte honetakoa edo aurreko urtekoa bada, hasiera-dataren formula honek urtarrilak 1 itzultzen du beti 1. astearen hasiera-data gisa asteko eguna edozein dela ere. Analogiaz, amaiera dataren formulak abenduaren 31 itzultzen du beti urteko azken asteko amaiera data gisa, asteko eguna edozein dela ere. Beste alde guztietan, formula hauek goiko 1 Formularen antzera funtzionatzen dute.

Hasierako data:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Amaiera data:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

4. Formula. Hasi beti zenbatzen urtarrilaren 1ean, igandea-larunbata astea

Hasierako eta amaiera datak kalkulatzeko Igande eta larunbateko aste baterako, goiko formuletan doikuntza txiki bat besterik ez da behar :)

Hasiera data:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Amaiera-data:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Nola lortu hilabetea aste zenbakitik

Asteari dagokion hilabetea lortzeko zenbakia, aste jakin bateko lehen eguna aurkituko duzu honetan azaltzen den moduanadibidea, eta ondoren bildu formula hori Excel HILABETEA funtzioan honela:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Oharra. Gogoratu goiko formulak ISO asteko data-sisteman oinarrituta funtzionatzen duela, non astea astelehenean hasten baita eta urteko 1. osteguna duen astea 1. astetzat hartzen den. Adibidez, 2016 urtean, lehenengo osteguna urtarrilaren 7an da, eta horregatik 1. astea 2016ko urtarrilaren 4an hasiko da.

Nola lortu aste-zenbaki bat hilabete batean (1etik 6ra)

Zure negozio-logikak dagokion hilabetean data zehatz bat asteko zenbakira bihurtzea eskatzen badu, WEEKNUM konbinazioa erabil dezakezu, DATE eta HILABETEA funtzioak:

A2 gelaxkak jatorrizko data duela suposatuz, erabili formula hau astelehena -n hasten den astean (oharra 21. WEEKNUM-en return_type argumentuan):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Igandea hasten den aste batez, baztertu return_type argumentua:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Nola balioak batu eta aurkitu batez bestekoa aste-zenbakiaren arabera

Orain data bat Excel-en aste-zenbaki bihurtzen dakizunez, ikus dezagun nola erabil ditzakezun aste-zenbakiak beste kalkulu batzuetan.

Demagun. , hileroko salmenten zifra batzuk dituzu eta aste bakoitzeko guztirakoak jakin nahi dituzu.

Hasteko, aurki dezagun salmenta bakoitzari dagokion aste-zenbaki bat. Zure datak A zutabean eta salmentak B zutabean badaude, kopiatu =WEEKNUM(A2) formula C zutabean gelaxkan hasita.C2.

Eta, ondoren, egin aste zenbakien zerrenda beste zutabe batean (esan, E zutabean) eta kalkulatu aste bakoitzeko salmentak, SUMIF formula hau erabiliz:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Non E2 asteko zenbakia den.

Adibide honetan, martxoko salmenten zerrenda batekin ari gara lanean, beraz, 10etik 14ra arteko aste zenbakiak ditugu. hurrengo pantaila-argazkian frogatua:

Antzeko modu batean, aste jakin bateko salmenten batez bestekoa kalkula dezakezu:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

WEEKNUM formula duen laguntzaile-zutabea zure datu-diseinuan ondo sartzen ez bada, damutzen naiz ez dagoela hura kentzeko modu errazik Excel WEEKNUM funtzio horietako bat delako. horrek ez ditu barruti argumentuak onartzen. Hori dela eta, ezin da erabili SUMPRODUCT edo MONTH funtzioa bezalako beste edozein matrize formulan antzeko eszenatoki batean.

Nola nabarmendu gelaxkak aste zenbakiaren arabera

Demagun zerrenda luzea duzula zutabe batzuetan datak eta aste jakin bati dagozkionak bakarrik nabarmendu nahi dituzu. Behar duzun guztia baldintzapeko formatu-arau bat da WEEKNUM formula honen antzekoa duena:

=WEEKNUM($A2)=10

Beheko pantaila-argazkian frogatzen den bezala, arauak 10. astean egindako salmentak nabarmentzen ditu, hau da. 2015eko martxoko lehen astea. Araua A2:B15-i aplikatzen denez, bi zutabeetan balioak nabarmentzen ditu. Baldintzapeko formatu-arauak sortzeari buruz gehiago ikas dezakezu honetantutoriala: Excel baldintzapeko formatua beste gelaxka-balio batean oinarrituta.

Horrela nola kalkula ditzakezu aste zenbakiak Excel-en, aste zenbakia data bihur dezakezu eta aste zenbakia datatik atera. Zorionez, gaur ikasi dituzun WEEKNUM formulak erabilgarriak izango dira zure lan-orrietan. Hurrengo tutorialean, Excel-en adina eta urteak kalkulatzeari buruz hitz egingo dugu. Eskerrak ematen dizkizut irakurtzeagatik eta datorren astean elkartzea espero dut!