Ενώ το Microsoft Excel παρέχει μια σειρά από συναρτήσεις για την εργασία με τις καθημερινές, τους μήνες και τα έτη, μόνο μία είναι διαθέσιμη για τις εβδομάδες - η συνάρτηση WEEKNUM. Έτσι, αν ψάχνετε έναν τρόπο να λάβετε έναν αριθμό εβδομάδας από μια ημερομηνία, η WEEKNUM είναι η συνάρτηση που θέλετε.

Σε αυτό το σύντομο σεμινάριο, θα μιλήσουμε εν συντομία για τη σύνταξη και τα ορίσματα της συνάρτησης WEEKNUM του Excel και στη συνέχεια θα συζητήσουμε μερικά παραδείγματα τύπων που δείχνουν πώς μπορείτε να χρησιμοποιήσετε τη συνάρτηση WEEKNUM για να υπολογίσετε τους αριθμούς εβδομάδων στα φύλλα εργασίας του Excel.

Συνάρτηση WEEKNUM του Excel - σύνταξη

Η συνάρτηση WEEKNUM χρησιμοποιείται στο Excel για την επιστροφή του αριθμού εβδομάδας μιας συγκεκριμένης ημερομηνίας του έτους (ένας αριθμός μεταξύ 1 και 54). Έχει δύο ορίσματα, το 1ο είναι υποχρεωτικό και το 2ο προαιρετικό:

• Serial_number - οποιαδήποτε ημερομηνία εντός της εβδομάδας της οποίας τον αριθμό προσπαθείτε να βρείτε. Αυτή μπορεί να είναι μια αναφορά σε ένα κελί που περιέχει την ημερομηνία, μια ημερομηνία που έχει εισαχθεί με τη χρήση της συνάρτησης DATE ή που επιστρέφεται από κάποιον άλλο τύπο.
• Return_type (προαιρετικό) - ένας αριθμός που καθορίζει την ημέρα έναρξης της εβδομάδας. Εάν παραλειφθεί, χρησιμοποιείται ο προεπιλεγμένος τύπος 1 (η εβδομάδα αρχίζει την Κυριακή).

Ακολουθεί πλήρης κατάλογος των return_type τιμές που υποστηρίζονται σε τύπους WEEKNUM.

Στη συνάρτηση WEEKNUM, δύο διαφορετικές συστήματα αρίθμησης εβδομάδων χρησιμοποιούνται:

• Σύστημα 1. Η εβδομάδα που περιέχει την 1η Ιανουαρίου θεωρείται η 1η εβδομάδα του έτους και αριθμείται ως εβδομάδα 1. Σε αυτό το σύστημα, η εβδομάδα παραδοσιακά αρχίζει την Κυριακή.
• Σύστημα 2. Πρόκειται για το σύστημα ημερομηνίας εβδομάδας ISO που αποτελεί μέρος του προτύπου ημερομηνίας και ώρας ISO 8601. Σε αυτό το σύστημα, η εβδομάδα αρχίζει τη Δευτέρα και η εβδομάδα που περιέχει την πρώτη Πέμπτη του έτους θεωρείται εβδομάδα 1. Είναι ευρέως γνωστό ως το ευρωπαϊκό σύστημα αρίθμησης εβδομάδων και χρησιμοποιείται κυρίως στην κυβέρνηση και τις επιχειρήσεις για τα φορολογικά έτη και την τήρηση του χρόνου.

Όλοι οι παραπάνω τύποι επιστροφής ισχύουν για το σύστημα 1, εκτός από τον τύπο επιστροφής 21 που χρησιμοποιείται στο σύστημα 2.

Σημείωση. Στο Excel 2007 και σε προηγούμενες εκδόσεις, είναι διαθέσιμες μόνο οι επιλογές 1 και 2. Οι τύποι επιστροφής 11 έως 21 υποστηρίζονται μόνο στο Excel 2010 και στο Excel 2013.

Τύποι του Excel WEEKNUM για τη μετατροπή ημερομηνίας σε αριθμό εβδομάδας (από 1 έως 54)

Το παρακάτω στιγμιότυπο οθόνης δείχνει πώς μπορείτε να λάβετε αριθμούς εβδομάδων από ημερομηνίες με το πιο απλό =WEEKNUM(A2) φόρμουλα:

Στον παραπάνω τύπο, το return_type παραλείπεται, πράγμα που σημαίνει ότι χρησιμοποιείται ο προεπιλεγμένος τύπος 1 - η εβδομάδα που αρχίζει την Κυριακή.

Αν προτιμάτε να ξεκινήσετε με κάποια άλλη ημέρα της εβδομάδας, π.χ. τη Δευτέρα, τότε χρησιμοποιήστε το 2 στο δεύτερο όρισμα:

=WEEKNUM(A2, 2)

Αντί να αναφέρεστε σε ένα κελί, μπορείτε να καθορίσετε την ημερομηνία απευθείας στον τύπο χρησιμοποιώντας τη συνάρτηση DATE(year, month, day), για παράδειγμα:

=WEEKNUM(DATE(2015,4,15), 2)

Ο παραπάνω τύπος επιστρέφει τον αριθμό 16, ο οποίος είναι ο αριθμός της εβδομάδας που περιέχει την 15η Απριλίου 2015, με μια εβδομάδα που αρχίζει τη Δευτέρα.

Σε πραγματικά σενάρια, η συνάρτηση WEEKNUM του Excel σπάνια χρησιμοποιείται μόνη της. Τις περισσότερες φορές τη χρησιμοποιείτε σε συνδυασμό με άλλες συναρτήσεις για να εκτελέσετε διάφορους υπολογισμούς με βάση τον αριθμό της εβδομάδας, όπως φαίνεται σε περαιτέρω παραδείγματα.

Πώς να μετατρέψετε τον αριθμό εβδομάδας σε ημερομηνία στο Excel

Όπως μόλις είδατε, δεν είναι μεγάλη υπόθεση να μετατρέψετε μια ημερομηνία σε αριθμό εβδομάδας χρησιμοποιώντας τη συνάρτηση WEEKNUM του Excel. Τι γίνεται όμως αν θέλετε το αντίθετο, δηλαδή να μετατρέψετε έναν αριθμό εβδομάδας σε ημερομηνία; Δυστυχώς, δεν υπάρχει καμία συνάρτηση του Excel που να μπορεί να το κάνει αυτό αμέσως. Έτσι, θα πρέπει να κατασκευάσουμε τους δικούς μας τύπους.

Ας υποθέσουμε ότι έχετε ένα έτος στο κελί Α2 και έναν αριθμό εβδομάδας στο Β2 και τώρα θέλετε να υπολογίσετε τις ημερομηνίες έναρξης και λήξης αυτής της εβδομάδας.

Σημείωση: Αυτό το παράδειγμα τύπου βασίζεται σε αριθμούς εβδομάδων ISO, με μια εβδομάδα που αρχίζει τη Δευτέρα.

Ο τύπος για την επιστροφή του Ημερομηνία έναρξης της εβδομάδας έχει ως εξής:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Όπου Α2 είναι το έτος και Β2 είναι ο αριθμός της εβδομάδας.

Λάβετε υπόψη ότι ο τύπος επιστρέφει την ημερομηνία ως αύξοντα αριθμό και για να εμφανίζεται ως ημερομηνία, πρέπει να μορφοποιήσετε το κελί ανάλογα. Μπορείτε να βρείτε τις λεπτομερείς οδηγίες στην ενότητα Αλλαγή μορφής ημερομηνίας στο Excel. Και εδώ είναι το αποτέλεσμα που επιστρέφει ο τύπος:

Φυσικά, ο τύπος για τη μετατροπή ενός αριθμού εβδομάδας σε ημερομηνία δεν είναι τετριμμένος, και μπορεί να χρειαστεί λίγος χρόνος για να καταλάβετε τη λογική. Εν πάση περιπτώσει, θα βάλω τα δυνατά μου για να δώσω μια ουσιαστική εξήγηση για όσους είναι περίεργοι να φτάσουν στο βάθος.

Όπως βλέπετε, η φόρμουλά μας αποτελείται από 2 μέρη:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - υπολογίζει την ημερομηνία της τελευταίας Δευτέρας του προηγούμενου έτους.
• B2 * 7 - προσθέτει τον αριθμό των εβδομάδων πολλαπλασιασμένο επί 7 (ο αριθμός των ημερών της εβδομάδας) για να προκύψει η Δευτέρα (ημερομηνία έναρξης) της εν λόγω εβδομάδας.

Στο σύστημα αρίθμησης εβδομάδων ISO, η εβδομάδα 1 είναι η εβδομάδα που περιέχει την πρώτη Πέμπτη του έτους. Κατά συνέπεια, η πρώτη Δευτέρα είναι πάντα μεταξύ 29 Δεκεμβρίου και 4 Ιανουαρίου. Έτσι, για να βρούμε αυτή την ημερομηνία, πρέπει να βρούμε τη Δευτέρα αμέσως πριν από τις 5 Ιανουαρίου.

Στο Microsoft Excel, μπορείτε να εξάγετε μια ημέρα της εβδομάδας από μια ημερομηνία χρησιμοποιώντας τη συνάρτηση WEEKDAY. Και μπορείτε να χρησιμοποιήσετε τον ακόλουθο γενικό τύπο για να λάβετε τη Δευτέρα αμέσως πριν από οποιαδήποτε δεδομένη ημερομηνία:

Αν ο απώτερος στόχος μας ήταν να βρούμε τη Δευτέρα αμέσως πριν από την 5η Ιανουαρίου του έτους Α2, θα μπορούσαμε να χρησιμοποιήσουμε τις ακόλουθες συναρτήσεις DATE:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Αλλά αυτό που χρειαζόμαστε στην πραγματικότητα δεν είναι η πρώτη Δευτέρα του τρέχοντος έτους, αλλά η τελευταία Δευτέρα του προηγούμενου έτους. Έτσι, πρέπει να αφαιρέσετε 7 ημέρες από την 5η Ιανουαρίου και ως εκ τούτου θα λάβετε -2 στην πρώτη συνάρτηση DATE:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Σε σύγκριση με τον δύσκολο τύπο που μόλις μάθατε, ο υπολογισμός του Ημερομηνία λήξης της εβδομάδας είναι πανεύκολο :) Για να πάρετε την Κυριακή της εν λόγω εβδομάδας, απλά προσθέτετε 6 ημέρες στο Ημερομηνία έναρξης , δηλ. =D2+6

Εναλλακτικά, μπορείτε να προσθέσετε 6 απευθείας στον τύπο:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Για να βεβαιωθείτε ότι οι τύποι παρέχουν πάντα τις σωστές ημερομηνίες, ρίξτε μια ματιά στο ακόλουθο στιγμιότυπο οθόνης. Οι τύποι Ημερομηνία έναρξης και Ημερομηνία λήξης που συζητήθηκαν παραπάνω αντιγράφονται στις στήλες D και E, αντίστοιχα:

Άλλοι τρόποι μετατροπής αριθμού εβδομάδας σε ημερομηνία στο Excel

Εάν ο παραπάνω τύπος που βασίζεται στο σύστημα ημερομηνίας εβδομάδας ISO δεν ανταποκρίνεται στις απαιτήσεις σας, δοκιμάστε μία από τις ακόλουθες λύσεις.

Τύπος 1. Μια εβδομάδα που περιέχει τον Ιαν-1 είναι εβδομάδα 1, Δευτέρα-Κυριακή εβδομάδα

Όπως θυμάστε, ο προηγούμενος τύπος λειτουργεί με βάση το σύστημα ημερομηνιών ISO, όπου η πρώτη Πέμπτη του έτους θεωρείται εβδομάδα 1. Εάν εργάζεστε με βάση ένα σύστημα ημερομηνιών όπου η εβδομάδα που περιέχει την 1η Ιανουαρίου θεωρείται εβδομάδα 1, χρησιμοποιήστε τους ακόλουθους τύπους:

Ημερομηνία έναρξης:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Ημερομηνία λήξης:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Τύπος 2. Μια εβδομάδα που περιέχει τον Ιαν-1 είναι η εβδομάδα 1, εβδομάδα Κυρ-Σαββάτου

Αυτοί οι τύποι είναι παρόμοιοι με τους παραπάνω με τη μόνη διαφορά ότι είναι γραμμένοι για την εβδομάδα Κυριακή - Σάββατο.

Ημερομηνία έναρξης:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Ημερομηνία λήξης:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Τύπος 3. Ξεκινάτε πάντα την καταμέτρηση την 1η Ιανουαρίου, Δευτέρα-Κυριακή εβδομάδα

Ενώ οι προηγούμενοι τύποι επιστρέφουν τη Δευτέρα (ή την Κυριακή) της εβδομάδας 1, ανεξάρτητα από το αν πέφτει μέσα στο τρέχον ή το προηγούμενο έτος, αυτός ο τύπος ημερομηνίας έναρξης επιστρέφει πάντα 1 Ιανουαρίου ως ημερομηνία έναρξης της εβδομάδας 1, ανεξάρτητα από την ημέρα της εβδομάδας. Κατ' αναλογία, ο τύπος της ημερομηνίας λήξης επιστρέφει πάντα 31 Δεκεμβρίου ως η ημερομηνία λήξης της τελευταίας εβδομάδας του έτους, ανεξάρτητα από την ημέρα της εβδομάδας. Κατά τα άλλα, οι τύποι αυτοί λειτουργούν παρόμοια με τον τύπο 1 ανωτέρω.

Ημερομηνία έναρξης:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Ημερομηνία λήξης:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Τύπος 4. Ξεκινάτε πάντα την καταμέτρηση την 1η Ιανουαρίου, εβδομάδα Κυρ-Σαββάτου

Για τον υπολογισμό των ημερομηνιών έναρξης και λήξης μιας εβδομάδας Κυριακή - Σάββατο, αρκεί μια μικρή προσαρμογή στους παραπάνω τύπους :)

Ημερομηνία έναρξης:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Ημερομηνία λήξης:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Πώς να πάρετε το μήνα από τον αριθμό της εβδομάδας

Για να λάβετε έναν μήνα που αντιστοιχεί στον αριθμό της εβδομάδας, βρίσκετε την πρώτη ημέρα μιας δεδομένης εβδομάδας, όπως εξηγείται σε αυτό το παράδειγμα, και στη συνέχεια τυλίγετε αυτόν τον τύπο στη συνάρτηση MONTH του Excel ως εξής:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Σημείωση. Να θυμάστε ότι ο παραπάνω τύπος λειτουργεί με βάση το Σύστημα ημερομηνίας εβδομάδας ISO , όπου η εβδομάδα αρχίζει τη Δευτέρα και η εβδομάδα που περιέχει την 1η Πέμπτη του έτους θεωρείται εβδομάδα 1. Για παράδειγμα, το έτος 2016, η πρώτη Πέμπτη είναι η 7η Ιανουαρίου και γι' αυτό η εβδομάδα 1 αρχίζει στις 4 Ιανουαρίου 2016.

Πώς να βρείτε τον αριθμό μιας εβδομάδας σε ένα μήνα (από το 1 έως το 6)

Εάν η επιχειρησιακή σας λογική απαιτεί τη μετατροπή μιας συγκεκριμένης ημερομηνίας σε αριθμό εβδομάδας εντός του αντίστοιχου μήνα, μπορείτε να χρησιμοποιήσετε το συνδυασμό των συναρτήσεων WEEKNUM, DATE και MONTH:

Υποθέτοντας ότι το κελί A2 περιέχει την αρχική ημερομηνία, χρησιμοποιήστε τον ακόλουθο τύπο για μια εβδομάδα που αρχίζει στις Δευτέρα (παρατηρήστε το 21 στο όρισμα return_type της WEEKNUM):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Για μια εβδομάδα που αρχίζει στις Κυριακή , παραλείψτε το όρισμα return_type:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Πώς να αθροίσετε τις τιμές και να βρείτε το μέσο όρο με τον αριθμό εβδομάδας

Τώρα που ξέρετε πώς να μετατρέπετε μια ημερομηνία σε αριθμό εβδομάδας στο Excel, ας δούμε πώς μπορείτε να χρησιμοποιήσετε τους αριθμούς εβδομάδας σε άλλους υπολογισμούς.

Ας υποθέσουμε ότι έχετε κάποια μηνιαία στοιχεία πωλήσεων και θέλετε να μάθετε το σύνολο για κάθε εβδομάδα.

Αρχικά, ας βρούμε έναν αριθμό εβδομάδας που αντιστοιχεί σε κάθε πώληση. Αν οι ημερομηνίες σας βρίσκονται στη στήλη Α και οι πωλήσεις στη στήλη Β, αντιγράψτε το =WEEKNUM(A2) σε όλη τη στήλη C ξεκινώντας από το κελί C2.

Και στη συνέχεια, φτιάξτε έναν κατάλογο με τους αριθμούς των εβδομάδων σε κάποια άλλη στήλη (π.χ. στη στήλη Ε) και υπολογίστε τις πωλήσεις για κάθε εβδομάδα χρησιμοποιώντας τον ακόλουθο τύπο SUMIF:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Όπου E2 είναι ο αριθμός της εβδομάδας.

Σε αυτό το παράδειγμα, δουλεύουμε με μια λίστα με τις πωλήσεις του Μαρτίου, οπότε έχουμε τους αριθμούς εβδομάδας 10 έως 14, όπως φαίνεται στο ακόλουθο στιγμιότυπο οθόνης:

Με παρόμοιο τρόπο, μπορείτε να υπολογίσετε τον μέσο όρο των πωλήσεων για μια δεδομένη εβδομάδα:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Εάν η βοηθητική στήλη με τον τύπο WEEKNUM δεν ταιριάζει καλά στη διάταξη των δεδομένων σας, λυπάμαι που σας λέω ότι δεν υπάρχει απλός τρόπος να απαλλαγείτε από αυτήν, επειδή η Excel WEEKNUM είναι μία από τις συναρτήσεις που δεν δέχεται ορίσματα εύρους. Ως εκ τούτου, δεν μπορεί να χρησιμοποιηθεί εντός της SUMPRODUCT ή οποιουδήποτε άλλου τύπου συστοιχίας όπως η συνάρτηση MONTH σε παρόμοιο σενάριο.

Πώς να επισημάνετε τα κελιά με βάση τον αριθμό της εβδομάδας

Ας υποθέσουμε ότι έχετε μια μεγάλη λίστα ημερομηνιών σε κάποια στήλη και θέλετε να επισημάνετε μόνο εκείνες που αφορούν μια συγκεκριμένη εβδομάδα. Το μόνο που χρειάζεστε είναι ένας κανόνας μορφοποίησης υπό όρους με τύπο WEEKNUM παρόμοιο με αυτόν:

=WEEKNUM($A2)=10

Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, ο κανόνας επισημαίνει τις πωλήσεις που πραγματοποιήθηκαν εντός της εβδομάδας 10, δηλαδή την πρώτη εβδομάδα του Μαρτίου 2015. Δεδομένου ότι ο κανόνας ισχύει για τις στήλες A2:B15, επισημαίνει τις τιμές και στις δύο στήλες. Μπορείτε να μάθετε περισσότερα σχετικά με τη δημιουργία κανόνων μορφοποίησης υπό όρους σε αυτό το σεμινάριο: Μορφοποίηση υπό όρους του Excel με βάση την τιμή ενός άλλου κελιού.

Με αυτόν τον τρόπο μπορείτε να υπολογίζετε αριθμούς εβδομάδων στο Excel, να μετατρέπετε τον αριθμό εβδομάδας σε ημερομηνία και να εξάγετε τον αριθμό εβδομάδας από την ημερομηνία. Ελπίζουμε ότι οι τύποι WEEKNUM που μάθατε σήμερα θα σας φανούν χρήσιμοι στα φύλλα εργασίας σας. Στο επόμενο σεμινάριο, θα μιλήσουμε για τον υπολογισμό της ηλικίας και των ετών στο Excel. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω την επόμενη εβδομάδα!