Ingawa Microsoft Excel hutoa safu ya vitendakazi vya kufanya kazi na siku za wiki, miezi na miaka, ni moja tu inayopatikana kwa wiki - chaguo la kukokotoa la WEEKNUM. Kwa hivyo, ikiwa unatafuta njia ya kupata nambari ya wiki kutoka tarehe, WEEKNUM ndiyo chaguo la kukokotoa unalotaka.

Katika mafunzo haya mafupi, tutazungumza kwa ufupi kuhusu sintaksia na hoja za Excel WEEKNUM, na kisha jadili mifano michache ya fomula inayoonyesha jinsi unavyoweza kutumia kitendakazi cha WEEKNUM kukokotoa nambari za wiki katika lahakazi zako za Excel.

Kitendakazi cha Excel WEEKNUM - sintaksia

Kitendaji cha WEEKNUM ni inayotumika katika Excel kurudisha nambari ya wiki ya tarehe maalum katika mwaka (nambari kati ya 1 na 54). Ina hoja mbili, ya 1 inahitajika na ya 2 ni ya hiari:

• Serial_number - tarehe yoyote ndani ya wiki ambayo nambari yake unajaribu. kutafuta. Hii inaweza kuwa rejeleo la kisanduku kilicho na tarehe, tarehe iliyoingizwa kwa kutumia chaguo la kukokotoa la DATE au kurejeshwa kwa fomula nyingine.
• Return_type (si lazima) - nambari inayobainisha tarehe gani siku ya wiki huanza. Ikiondolewa, aina chaguo-msingi ya 1 itatumika (wiki inayoanza Jumapili).

Hii hapa ni orodha kamili ya thamani return_type zinazotumika katika fomula za WEEKNUM.

Katika chaguo la kukokotoa la WEEKNUM, mifumo miwili ya nambari za wiki inatumika:

• Mfumo wa 1. Wiki iliyo na Januari 1 inazingatiwa. wiki ya 1 ya mwaka na imehesabiwa wiki 1. Katika mfumo huu, wiki kwa desturi huanza Jumapili.
• Mfumo wa 2. Huu ni mfumo wa tarehe wa wiki wa ISO ambao ni sehemu ya Kiwango cha tarehe na wakati cha ISO 8601. Katika mfumo huu, wiki huanza Jumatatu na wiki iliyo na Alhamisi ya kwanza ya mwaka inazingatiwa wiki ya 1. Inajulikana kama mfumo wa nambari za wiki za Ulaya na hutumiwa hasa katika serikali na biashara kwa miaka ya fedha na utunzaji wa wakati.

Aina zote za kurejesha zilizoorodheshwa hapo juu zinatumika kwa Mfumo wa 1, isipokuwa aina ya 21 ya kurejesha ambayo inatumika katika Mfumo wa 2.

Kumbuka. Katika Excel 2007 na matoleo ya awali, chaguo 1 na 2 pekee zinapatikana. Aina za kurejesha 11 hadi 21 zinatumika katika Excel 2010 na Excel 2013 pekee.

Fomula za WEEKNUM za Excel za kubadilisha tarehe hadi nambari ya wiki (kutoka 1 hadi 54)

Picha ya skrini ifuatayo inaonyesha jinsi unavyoweza kupata nambari za wiki kuanzia tarehe kwa kutumia fomula rahisi zaidi ya =WEEKNUM(A2) :

Katika hapo juuformula, hoja ya return_type imeachwa, ambayo ina maana kwamba aina chaguo-msingi ya 1 inatumiwa - wiki inayoanza Jumapili.

Ikiwa ungependa kuanza na siku nyingine ya juma, sema Jumatatu, basi tumia 2 katika hoja ya pili:

=WEEKNUM(A2, 2)

Badala ya kurejelea kisanduku, unaweza kubainisha tarehe moja kwa moja kwenye fomula kwa kutumia DATE(mwaka, mwezi, siku), kwa mfano:

=WEEKNUM(DATE(2015,4,15), 2)

Fomula iliyo hapo juu inarejesha 16, ambayo ni nambari ya wiki iliyo na Aprili 15, 2015, ikiwa na wiki inayoanza Jumatatu.

Katika hali halisi , kitendakazi cha Excel WEEKNUM hakitumiki chenyewe mara chache sana. Mara nyingi ungeitumia pamoja na vitendaji vingine kufanya hesabu mbalimbali kulingana na nambari ya wiki, kama inavyoonyeshwa katika mifano zaidi.

Jinsi ya kubadilisha nambari ya wiki hadi tarehe katika Excel

Kama wewe nimeona hivi punde, si jambo kubwa kugeuza tarehe kuwa nambari ya wiki kwa kutumia kitendakazi cha Excel WEEKNUM. Lakini vipi ikiwa unatafuta kinyume, yaani, kubadilisha nambari ya wiki hadi tarehe? Ole, hakuna kitendakazi cha Excel ambacho kinaweza kufanya hivi mara moja. Kwa hivyo, itatubidi tuunde fomula zetu wenyewe.

Tuseme una mwaka katika kisanduku A2 na nambari ya wiki katika B2, na sasa ungependa kukokotoa tarehe za Kuanza na Kumaliza katika wiki hii.

Kumbuka. Mfano huu wa fomula unatokana na nambari za wiki za ISO, na wiki inayoanza Jumatatu.

Mfumo wa kurejesha Mwanzotarehe ya wiki ni kama ifuatavyo:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Ambapo A2 ni mwaka na B2 ni nambari ya wiki.

Tafadhali kumbuka kuwa fomula hurejesha tarehe kama nambari ya mfululizo, na ili ionyeshwe kama tarehe, unahitaji kufomati kisanduku ipasavyo. Unaweza kupata maagizo ya kina katika Kubadilisha muundo wa tarehe katika Excel. Na haya ndiyo matokeo yaliyorejeshwa na fomula:

Bila shaka, fomula ya kubadilisha nambari ya wiki hadi tarehe si ndogo, na inaweza kuchukua muda kupata. kichwa chako kinazunguka mantiki. Hata hivyo, nitajitahidi niwezavyo kutoa maelezo ya maana kwa wale ambao wana hamu ya kutaka kujua zaidi.

Kama unavyoona, fomula yetu ina sehemu 2:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - hukokotoa tarehe ya Jumatatu ya mwisho katika mwaka uliotangulia.
• B2 * 7 - huongeza idadi ya wiki ikizidishwa na 7 (idadi ya siku katika wiki) ili kupata Jumatatu (tarehe ya kuanza) ya juma katika swali.

Katika mfumo wa nambari za wiki wa ISO, wiki ya 1 ni wiki iliyo na Alhamisi ya kwanza ya mwaka. Kwa hivyo, Jumatatu ya kwanza huwa kati ya Desemba 29 na Januari 4. Kwa hivyo, ili kupata tarehe hiyo, tunapaswa kutafuta Jumatatu mara moja kabla ya Januari 5.

Katika Microsoft Excel, unaweza kutoa siku ya wiki kutoka. tarehe kwa kutumia kitendakazi cha WEEKDAY. Na unaweza kutumia fomula ifuatayo ili kupata Jumatatu mara moja kabla ya tarehe yoyote:

Ikiwa yetulengo kuu lilikuwa kupata Jumatatu mara moja kabla ya tarehe 5 Januari ya mwaka katika A2, tunaweza kutumia vitendaji vifuatavyo vya DATE:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Lakini tunachohitaji hasa si Jumatatu ya kwanza ya mwaka huu, lakini Jumatatu ya mwisho ya mwaka uliopita. Kwa hivyo, lazima utoe siku 7 kutoka Januari 5 na kwa hivyo utapata -2 katika chaguo la kukokotoa la kwanza la DATE:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Ikilinganishwa na fomula ya hila ambayo umejifunza hivi punde, ukikokotoa Tarehe ya mwisho ya wiki ni kipande cha keki :) Ili kupata Jumapili ya wiki inayohusika, unaongeza tu siku 6 kwenye Tarehe ya kuanza , yaani =D2+6

Badala yake, unaweza kuongeza 6 moja kwa moja kwenye fomula:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Ili kuhakikisha kuwa fomula hutoa tarehe zinazofaa kila wakati, tafadhali angalia zifuatazo. picha ya skrini. Fomula za Tarehe ya Kuanza na Tarehe ya Mwisho zilizojadiliwa hapo juu zimenakiliwa kote kwenye safu wima D na E, mtawalia:

Njia zingine za kubadilisha nambari ya wiki hadi tarehe katika Excel

Iwapo fomula iliyo hapo juu kulingana na mfumo wa tarehe ya wiki ya ISO haikidhi mahitaji yako, jaribu mojawapo ya masuluhisho yafuatayo.

Mfumo wa 1. Wiki iliyo na Januari-1 ni wiki 1, wiki ya Jumatatu-Juma

Kama unavyokumbuka, fomula iliyotangulia inafanya kazi kulingana na mfumo wa tarehe wa ISO ambapo Alhamisi ya kwanza ya mwaka inachukuliwa kuwa wiki ya 1. Ikiwa unafanya kazi kulingana na mfumo wa tarehe ambapo wiki iliyo na tarehe 1 Januari inazingatiwa wiki ya 1, tumia zifuatazofomula:

Tarehe ya kuanza:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Tarehe ya mwisho:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Mfumo wa 2. Wiki iliyo na Jan-1 ni wiki 1, Sun-Sat week

Formula hizi ni sawa na zilizo hapo juu na tofauti pekee kwamba zimeandikwa. kwa Jumapili - Jumamosi wiki.

Tarehe ya kuanza:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Tarehe ya mwisho:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Mfumo wa 3. Anza kuhesabu kila siku Januari 1, Wiki ya Jumatatu-Jumapili

Huku fomula za awali zitakaporudi Jumatatu (au Jumapili) ya wiki ya 1, bila kujali ya iwapo itaangukia ndani ya mwaka huu au mwaka uliotangulia, fomula hii ya tarehe ya kuanza daima inarudi Januari 1 kama tarehe ya kuanza kwa wiki ya 1 bila kujali siku ya juma. Kwa mlinganisho, fomula ya tarehe ya mwisho daima inarudi Desemba 31 kama tarehe ya mwisho ya wiki ya mwisho katika mwaka, bila kujali siku ya wiki. Katika mambo mengine yote, fomula hizi hufanya kazi sawa na Formula 1 hapo juu.

Tarehe ya kuanza:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Tarehe ya mwisho:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Mfumo wa 4. Anza kuhesabu kila siku tarehe 1 Januari, Wiki ya Jua-Jumapili

Ili kukokotoa tarehe za kuanza na kumalizia kwa wiki ya Jumapili - Jumamosi, kinachohitajika ni marekebisho madogo tu katika fomula zilizo hapo juu :)

Tarehe ya kuanza:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Tarehe ya mwisho:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Jinsi ya kupata mwezi kutoka nambari ya wiki

Ili kupata mwezi unaolingana na wiki nambari, unapata siku ya kwanza katika wiki fulani kama ilivyoelezewa katika hilimfano, na kisha funga fomula hiyo katika kitendakazi cha Excel MONTH kama hii:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Kumbuka. Tafadhali kumbuka kuwa fomula iliyo hapo juu inafanya kazi kulingana na mfumo wa tarehe ya wiki ya ISO , ambapo wiki huanza Jumatatu na wiki iliyo na Alhamisi ya 1 ya mwaka inazingatiwa wiki ya 1. Kwa mfano, katika mwaka wa 2016, Alhamisi ya kwanza ni Januari 7, na ndiyo sababu wiki ya 1 huanza tarehe 4-Jan-2016.

Jinsi ya kupata nambari ya wiki katika mwezi (kutoka 1 hadi 6)

Ikiwa mantiki ya biashara yako inahitaji kubadilisha tarehe mahususi hadi nambari ya wiki ndani ya mwezi husika, unaweza kutumia mchanganyiko wa WEEKNUM, DATE na MONTH utendakazi:

Ikiwa kisanduku A2 kina tarehe asili, tumia fomula ifuatayo kwa wiki inayoanza Jumatatu (taarifa ya 21 katika hoja ya WEEKNUM ya return_type):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Kwa wiki moja inayoanza Jumapili , ondoa hoja_ya aina ya return:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Jinsi ya kufanya jumla ya thamani na kupata wastani kwa nambari ya wiki

Kwa kuwa sasa unajua jinsi ya kubadilisha tarehe kuwa nambari ya wiki katika Excel, hebu tuone jinsi unavyoweza kutumia nambari za wiki katika hesabu zingine.

Tuseme , una takwimu za mauzo ya kila mwezi na ungependa kujua jumla ya kila wiki.

Kwa kuanzia, hebu tujue nambari ya wiki inayolingana na kila ofa. Ikiwa tarehe zako ziko kwenye safu wima A na mauzo katika safu wima B, nakili fomula ya =WEEKNUM(A2) kwenye safu wima C inayoanzia kwenye kisanduku.C2.

Na kisha, tengeneza orodha ya nambari za wiki katika safu wima nyingine (sema, katika safu wima E) na ukokote mauzo ya kila wiki kwa kutumia fomula ifuatayo ya SUMIF:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

E2 ilipo nambari ya wiki.

Katika mfano huu, tunashughulikia orodha ya mauzo ya Machi, kwa hivyo tuna nambari za wiki 10 hadi 14, kama inavyoonyeshwa katika picha ya skrini ifuatayo:

Vivyo hivyo, unaweza kukokotoa wastani wa mauzo kwa wiki fulani:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Iwapo safu wima ya usaidizi iliyo na fomula ya WEEKNUM haitoshei vizuri katika mpangilio wako wa data, ninasikitika kukuambia kwamba hakuna njia rahisi ya kuiondoa kwa sababu Excel WEEKNUM ni mojawapo ya vipengele hivyo. hiyo haikubali hoja za masafa. Kwa hivyo, haiwezi kutumika ndani ya SUMPRODUCT au fomula nyingine yoyote kama vile chaguo la kukokotoa la MONTH katika hali sawa.

Jinsi ya kuangazia visanduku kulingana na nambari ya wiki

Tuseme una orodha ndefu. ya tarehe katika baadhi ya safu na unataka kuangazia zile tu zinazohusiana na wiki fulani. Unachohitaji ni sheria ya uumbizaji yenye masharti yenye fomula ya WEEKNUM sawa na hii:

=WEEKNUM($A2)=10

Kama inavyoonyeshwa kwenye picha ya skrini iliyo hapa chini, sheria hiyo inaangazia mauzo yaliyofanywa ndani ya wiki ya 10, ambayo ni wiki ya kwanza Machi 2015. Kwa kuwa sheria hiyo inatumika kwa A2:B15, inaangazia maadili katika safu zote mbili. Unaweza kujifunza zaidi kuhusu kuunda sheria za umbizo la masharti katika hilisomo: umbizo la masharti la Excel kulingana na thamani nyingine ya seli.

Hivi ndivyo unavyoweza kukokotoa nambari za wiki katika Excel, kubadilisha nambari ya wiki hadi tarehe na kutoa nambari ya wiki kutoka tarehe. Tunatumahi, fomula za WEEKNUM ambazo umejifunza leo zitakuwa muhimu katika laha zako za kazi. Katika somo linalofuata, tutazungumza juu ya kuhesabu umri na miaka katika Excel. Ninakushukuru kwa kusoma na natumai kukuona wiki ijayo!