मायक्रोसॉफ्ट एक्सेल आठवड्याचे दिवस, महिने आणि वर्षांसह कार्य करण्यासाठी फंक्शन्सची अॅरे प्रदान करत असताना, फक्त एक आठवड्यासाठी उपलब्ध आहे - WEEKNUM फंक्शन. त्यामुळे, जर तुम्ही एखाद्या तारखेपासून आठवडा क्रमांक मिळवण्याचा मार्ग शोधत असाल तर, WEEKNUM हे तुम्हाला हवे असलेले कार्य आहे.

या छोट्या ट्युटोरियलमध्ये, आम्ही Excel WEEKNUM च्या वाक्यरचना आणि युक्तिवादांबद्दल थोडक्यात बोलू, आणि नंतर तुमच्या एक्सेल वर्कशीटमध्ये आठवड्याच्या संख्येची गणना करण्यासाठी तुम्ही WEEKNUM फंक्शन कसे वापरू शकता हे दाखवणाऱ्या काही सूत्र उदाहरणांवर चर्चा करा.

Excel WEEKNUM फंक्शन - सिंटॅक्स

WEEKNUM फंक्शन आहे वर्षातील विशिष्ट तारखेचा आठवडा क्रमांक परत करण्यासाठी Excel मध्ये वापरले जाते (1 आणि 54 मधील संख्या). यात दोन युक्तिवाद आहेत, 1ला आवश्यक आहे आणि दुसरा पर्यायी आहे:

• Serial_number - तुम्ही ज्या नंबरचा प्रयत्न करत आहात त्या आठवड्यातील कोणतीही तारीख शोधण्यासाठी. हा सेलचा संदर्भ असू शकतो ज्यामध्ये तारीख, DATE फंक्शन वापरून एंटर केलेली तारीख किंवा काही अन्य सूत्राद्वारे परत केली जाऊ शकते.
• Return_type (पर्यायी) - एक संख्या जी निर्धारित करते आठवड्याचा दिवस सुरू होतो. वगळल्यास, डीफॉल्ट प्रकार 1 वापरला जातो (रविवारपासून सुरू होणारा आठवडा).

WEEKNUM सूत्रांमध्ये समर्थित return_type मूल्यांची संपूर्ण यादी येथे आहे.

WEEKNUM फंक्शनमध्ये, दोन भिन्न आठवडा क्रमांकन प्रणाली वापरल्या जातात:

• सिस्टम 1. 1 जानेवारी असलेला आठवडा मानला जातो. वर्षाचा पहिला आठवडा आणि आठवडा 1 क्रमांकित आहे. या प्रणालीमध्ये, आठवडा पारंपारिकपणे रविवारी सुरू होतो.
• सिस्टम 2. ही ISO आठवड्याची तारीख प्रणाली आहे जी ISO 8601 तारीख आणि वेळ मानक. या प्रणालीमध्ये, आठवडा सोमवारपासून सुरू होतो आणि वर्षाचा पहिला गुरुवार असलेला आठवडा आठवडा 1 मानला जातो. याला सामान्यतः युरोपियन आठवडा क्रमांकन प्रणाली म्हणून ओळखले जाते आणि हे मुख्यत्वे सरकार आणि व्यवसायात आर्थिक वर्षांसाठी आणि वेळेचे पालन करण्यासाठी वापरले जाते.

वर सूचीबद्ध केलेले सर्व रिटर्न प्रकार सिस्टम 1 ला लागू होतात, रिटर्न प्रकार 21 वगळता जो सिस्टम 2 मध्ये वापरला जातो.

टीप. Excel 2007 आणि पूर्वीच्या आवृत्त्यांमध्ये, फक्त 1 आणि 2 पर्याय उपलब्ध आहेत. रिटर्न प्रकार 11 ते 21 फक्त Excel 2010 आणि Excel 2013 मध्ये समर्थित आहेत.

तारीख आठवड्याच्या क्रमांकामध्ये रूपांतरित करण्यासाठी एक्सेल WEEKNUM सूत्र (1 ते 54 पर्यंत)

खालील स्क्रीनशॉट तुम्हाला सर्वात सोप्या =WEEKNUM(A2) सूत्रासह तारखांमधून आठवड्याचे क्रमांक कसे मिळवू शकतात हे दर्शविते:

<18

वरील मध्येफॉर्म्युला, return_type युक्तिवाद वगळला आहे, याचा अर्थ डीफॉल्ट प्रकार 1 वापरला जातो - रविवारपासून सुरू होणारा आठवडा.

तुम्हाला आठवड्याच्या इतर कोणत्याही दिवसाने सुरुवात करायची असल्यास, सोमवार म्हणा, नंतर 2 वापरा दुसऱ्या युक्तिवादात:

=WEEKNUM(A2, 2)

सेलचा संदर्भ घेण्याऐवजी, तुम्ही DATE(वर्ष, महिना, दिवस) फंक्शन वापरून थेट सूत्रामध्ये तारीख निर्दिष्ट करू शकता, उदाहरणार्थ:

=WEEKNUM(DATE(2015,4,15), 2)

वरील सूत्र 16 मिळवते, जे 15 एप्रिल 2015 असलेल्या आठवड्याची संख्या आहे, ज्यामध्ये सोमवारपासून आठवडा सुरू होतो.

वास्तविक जीवनातील परिस्थितींमध्ये , Excel WEEKNUM फंक्शन स्वतःहून क्वचितच वापरले जाते. पुढील उदाहरणांमध्ये दर्शविल्याप्रमाणे, आठवड्याच्या संख्येवर आधारित विविध गणना करण्यासाठी आपण बहुतेकदा इतर फंक्शन्सच्या संयोजनात त्याचा वापर कराल.

एक्सेलमध्ये आठवड्याच्या क्रमांकाला तारखेत कसे रूपांतरित करावे

आपण जसे नुकतेच पाहिले आहे, Excel WEEKNUM फंक्शन वापरून तारखेला आठवड्याच्या संख्येत बदलणे ही काही मोठी गोष्ट नाही. पण जर तुम्ही उलट शोधत असाल, म्हणजे आठवड्याच्या क्रमांकाला तारखेत रूपांतरित करत असाल तर? अरेरे, असे कोणतेही एक्सेल फंक्शन नाही जे हे लगेच करू शकेल. त्यामुळे, आम्हाला आमची स्वतःची सूत्रे तयार करावी लागतील.

समजा तुमच्या सेल A2 मध्ये एक वर्ष आणि B2 मध्ये आठवडा क्रमांक आहे, आणि आता तुम्हाला या आठवड्यातील प्रारंभ आणि समाप्ती तारखांची गणना करायची आहे.

टीप. हे सूत्र उदाहरण ISO आठवडा क्रमांकांवर आधारित आहे, ज्याचा आठवडा सोमवारपासून सुरू होतो.

प्रारंभ परत करण्यासाठी सूत्रआठवड्याची तारीख खालीलप्रमाणे आहे:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

जेथे A2 वर्ष आहे आणि B2 हा आठवड्याचा क्रमांक आहे.

कृपया लक्षात ठेवा की सूत्र तारीख परत करतो. अनुक्रमांक म्‍हणून, आणि ती तारीख म्‍हणून प्रदर्शित करण्‍यासाठी, तुम्‍हाला त्यानुसार सेल फॉरमॅट करण्‍याची आवश्‍यकता आहे. तुम्हाला एक्सेलमध्ये बदलण्याची तारीख फॉरमॅटमध्ये तपशीलवार सूचना मिळू शकतात. आणि सूत्राने दिलेला निकाल येथे आहे:

अर्थात, आठवड्याच्या संख्येला तारखेत रूपांतरित करण्याचे सूत्र क्षुल्लक नाही आणि ते मिळण्यास थोडा वेळ लागू शकतो तुमचे डोके तर्काच्या भोवती आहे. तरीही, जे लोक तळाशी जाण्यास उत्सुक आहेत त्यांच्यासाठी मी अर्थपूर्ण स्पष्टीकरण देण्याचा सर्वतोपरी प्रयत्न करेन.

तुम्ही पाहिल्याप्रमाणे, आमच्या सूत्रामध्ये 2 भाग आहेत:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - मागील वर्षातील शेवटच्या सोमवारच्या तारखेची गणना करते.
• B2 * 7 - आठवड्याचा सोमवार (सुरुवात तारीख) मिळवण्यासाठी 7 ने गुणाकार केलेल्या आठवड्यांची संख्या (आठवड्यातील दिवसांची संख्या) जोडते प्रश्न.

ISO आठवडा क्रमांकन प्रणालीमध्ये, आठवडा 1 हा आठवडा आहे ज्यामध्ये वर्षाचा पहिला गुरुवार असतो. परिणामी, पहिला सोमवार हा नेहमी 29 डिसेंबर ते 4 जानेवारी दरम्यान असतो. त्यामुळे, ती तारीख शोधण्यासाठी, आम्हाला 5 जानेवारीपूर्वीचा सोमवार शोधावा लागेल.

मायक्रोसॉफ्ट एक्सेलमध्ये, तुम्ही आठवड्यातील एक दिवस काढू शकता. WEEKDAY फंक्शन वापरून तारीख. आणि कोणत्याही दिलेल्या तारखेपूर्वी सोमवार प्राप्त करण्यासाठी तुम्ही खालील सामान्य सूत्र वापरू शकता:

जर आमचेA2 मध्ये वर्षाच्या 5 जानेवारीच्या लगेच आधी सोमवार शोधणे हे अंतिम उद्दिष्ट होते, आम्ही खालील DATE फंक्शन्स वापरू शकतो:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

परंतु आपल्याला प्रत्यक्षात आवश्यक असलेला पहिला सोमवार नाही या वर्षी, परंतु मागील वर्षाचा शेवटचा सोमवार. त्यामुळे, तुम्हाला 5 जानेवारीपासून 7 दिवस वजा करावे लागतील आणि म्हणून तुम्हाला पहिल्या DATE फंक्शनमध्ये -2 मिळेल:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

तुम्ही नुकत्याच शिकलेल्या अवघड सूत्राच्या तुलनेत, <7 ची गणना करून आठवड्याची शेवटची तारीख हा केकचा तुकडा आहे :) आठवड्याचा रविवार विचारात घेण्यासाठी, तुम्ही फक्त 6 दिवस सुरुवात तारखेला जोडता, म्हणजे =D2+6

वैकल्पिकपणे, तुम्ही फॉर्म्युलामध्ये थेट 6 जोडू शकता:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

सूत्र नेहमी योग्य तारखा वितरीत करतात याची खात्री करण्यासाठी, कृपया खालील गोष्टी पहा स्क्रीनशॉट वर चर्चा केलेली प्रारंभ तारीख आणि समाप्ती तारीख सूत्रे अनुक्रमे स्तंभ D आणि E मध्ये कॉपी केली आहेत:

एक्सेलमध्ये आठवड्याची संख्या तारखेत रूपांतरित करण्याचे इतर मार्ग

जर ISO आठवड्याच्या तारीख प्रणालीवर आधारित वरील सूत्र तुमच्या गरजा पूर्ण करत नसेल, तर खालीलपैकी एक उपाय वापरून पहा.

सूत्र 1. जानेवारी-1 असलेला आठवडा म्हणजे आठवडा 1, सोम-रवि आठवडा

तुम्हाला आठवते त्याप्रमाणे, मागील सूत्र ISO तारीख प्रणालीवर आधारित कार्य करते जेथे वर्षाचा पहिला गुरुवार आठवडा 1 मानला जातो. जर तुम्ही तारीख प्रणालीवर आधारित काम करत असाल जिथे 1 जानेवारीचा आठवडा आठवडा 1 मानला जातो, खालील वापरासूत्र:

सुरुवात तारीख:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

शेवटची तारीख:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

सूत्र 2. जानेवारी-1 असलेला आठवडा म्हणजे आठवडा 1, रवि-शनि आठवडा

ही सूत्रे वरील सूत्रांसारखीच आहेत फक्त एवढाच फरक आहे की ते लिहिलेले आहेत. रविवार - शनिवार आठवड्यासाठी.

सुरुवात तारीख:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

शेवटची तारीख:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

सूत्र 3. नेहमी 1 जानेवारी, सोम-रवि आठवड्यात मोजणे सुरू करा

मागील सूत्रे आठवडा 1 च्या सोमवार (किंवा रविवार) परत येत असताना, पर्वा न करता या वर्षात किंवा मागील वर्षाच्या आत येत असल्यास, हे प्रारंभ तारीख सूत्र नेहमी आठवड्याच्या दिवसाची पर्वा न करता आठवडा 1 ची प्रारंभ तारीख म्हणून नेहमी जानेवारी 1 परत करते. सादृश्यतेनुसार, शेवटची तारीख सूत्र नेहमी डिसेंबर 31 वर्षातील शेवटच्या आठवड्याची शेवटची तारीख म्हणून परत येते, आठवड्याचा दिवस काहीही असो. इतर सर्व बाबतीत, ही सूत्रे वरील फॉर्म्युला 1 प्रमाणेच कार्य करतात.

सुरुवात तारीख:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

शेवटची तारीख:<8

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

सूत्र 4. नेहमी 1 जानेवारी, रवि-शनि आठवड्यात मोजणे सुरू करा

सुरुवात आणि समाप्ती तारखांची गणना करण्यासाठी रविवार - शनिवार आठवड्यासाठी, वरील सूत्रांमध्ये फक्त एक लहान समायोजन आवश्यक आहे :)

सुरुवात तारीख:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

अंतिम तारीख:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

आठवड्याच्या क्रमांकावरून महिना कसा मिळवायचा

आठवड्याशी संबंधित महिना मिळवण्यासाठी संख्या, यात स्पष्ट केल्याप्रमाणे तुम्हाला दिलेल्या आठवड्यातील पहिला दिवस सापडतोउदाहरणार्थ, आणि नंतर ते सूत्र Excel MONTH फंक्शनमध्ये याप्रमाणे गुंडाळा:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

टीप. कृपया लक्षात ठेवा की वरील सूत्र ISO आठवड्याची तारीख प्रणाली वर आधारित कार्य करते, जिथे आठवडा सोमवारपासून सुरू होतो आणि वर्षाचा पहिला गुरुवार असलेला आठवडा आठवडा 1 मानला जातो. उदाहरणार्थ, वर्ष 2016 मध्ये, पहिला गुरुवार 7 जानेवारी आहे आणि म्हणूनच 4-जानेवारी-2016 रोजी पहिला आठवडा सुरू होतो.

महिन्यात आठवडा क्रमांक कसा मिळवायचा (1 ते 6 पर्यंत)

तुमच्या व्यवसाय तर्कानुसार विशिष्ट तारखेला संबंधित महिन्यातील आठवड्याच्या क्रमांकामध्ये रूपांतरित करणे आवश्यक असल्यास, तुम्ही WEEKNUM चे संयोजन वापरू शकता, DATE आणि MONTH कार्ये:

सेल A2 मध्ये मूळ तारीख आहे असे गृहीत धरून, सोमवार पासून सुरू होणार्‍या आठवड्यासाठी खालील सूत्र वापरा (WEEKNUM च्या return_type वितर्कातील 21 सूचना):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

रविवार पासून सुरू होणाऱ्या एका आठवड्यासाठी, return_type वितर्क वगळा:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

कसे करावे मूल्यांची बेरीज करा आणि आठवड्याच्या संख्येनुसार सरासरी शोधा

आता तुम्हाला एक्सेलमध्ये तारखेला आठवड्याच्या संख्येमध्ये कसे रूपांतरित करायचे हे माहित आहे, चला पाहू या की तुम्ही इतर गणनांमध्ये आठवड्याचे क्रमांक कसे वापरू शकता.

समजा , तुमच्याकडे काही मासिक विक्रीचे आकडे आहेत आणि तुम्हाला प्रत्येक आठवड्याची एकूण संख्या जाणून घ्यायची आहे.

सुरुवातीसाठी, प्रत्येक विक्रीशी संबंधित आठवड्याची संख्या शोधूया. जर तुमच्या तारखा कॉलम A मध्ये असतील आणि कॉलम B मध्ये विक्री असेल, तर सेलमधील कॉलम C मध्ये =WEEKNUM(A2) फॉर्म्युला कॉपी कराC2.

आणि नंतर, काही इतर कॉलममध्ये (म्हणजे कॉलम E मध्ये) आठवड्याच्या क्रमांकांची सूची बनवा आणि खालील SUMIF सूत्र वापरून प्रत्येक आठवड्यासाठी विक्रीची गणना करा:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

जेथे E2 हा आठवडा क्रमांक आहे.

या उदाहरणात, आम्ही मार्चच्या विक्रीच्या सूचीसह काम करत आहोत, म्हणून आमच्याकडे आठवडा क्रमांक 10 ते 14 आहेत. खालील स्क्रीनशॉटमध्ये प्रात्यक्षिक:

तत्सम पद्धतीने, तुम्ही दिलेल्या आठवड्यासाठी विक्री सरासरी काढू शकता:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

जर WEEKNUM सूत्रासह हेल्पर कॉलम तुमच्या डेटा लेआउटमध्ये नीट बसत नसेल, तर मला तुम्हाला सांगायला खेद वाटतो की यापासून मुक्त होण्याचा कोणताही सोपा मार्ग नाही कारण Excel WEEKNUM हे त्यापैकी एक फंक्शन आहे. ते श्रेणी युक्तिवाद स्वीकारत नाही. त्यामुळे, ते SUMPRODUCT मध्ये किंवा MONTH फंक्शन सारख्या इतर कोणत्याही अॅरे फॉर्म्युलामध्ये वापरले जाऊ शकत नाही.

आठवडा क्रमांकावर आधारित सेल कसे हायलाइट करायचे

आपल्याकडे एक लांबलचक यादी आहे असे समजा काही कॉलममधील तारखांची संख्या आणि तुम्ही दिलेल्या आठवड्याशी संबंधित असलेल्यांनाच हायलाइट करू इच्छित आहात. तुम्हाला फक्त यासारख्याच WEEKNUM सूत्रासह सशर्त स्वरूपन नियमाची आवश्यकता आहे:

=WEEKNUM($A2)=10

खालील स्क्रीनशॉटमध्ये दर्शविल्याप्रमाणे, नियम 10 व्या आठवड्यात झालेल्या विक्रीवर प्रकाश टाकतो, जे मार्च 2015 मध्ये पहिला आठवडा. हा नियम A2:B15 ला लागू होत असल्याने, तो दोन्ही स्तंभांमधील मूल्ये हायलाइट करतो. तुम्ही यामध्ये सशर्त स्वरूपन नियम तयार करण्याबद्दल अधिक जाणून घेऊ शकताट्युटोरियल: एक्सेल कंडिशनल फॉरमॅटिंग दुसर्‍या सेल व्हॅल्यूवर आधारित.

अशा प्रकारे तुम्ही एक्सेलमध्ये आठवड्याच्या संख्येची गणना करू शकता, आठवड्याच्या क्रमांकाला तारखेत रूपांतरित करू शकता आणि तारखेपासून आठवड्याचा क्रमांक काढू शकता. आशा आहे की, आज तुम्ही शिकलेले WEEKNUM सूत्र तुमच्या वर्कशीटमध्ये उपयुक्त ठरतील. पुढील ट्युटोरियलमध्ये, आपण Excel मध्ये वय आणि वर्षे मोजण्याबद्दल बोलू. वाचल्याबद्दल मी तुमचा आभारी आहे आणि तुम्हाला पुढील आठवड्यात भेटण्याची आशा आहे!