جبکہ Microsoft Excel ہفتے کے دنوں، مہینوں اور سالوں کے ساتھ کام کرنے کے لیے فنکشنز کی ایک صف فراہم کرتا ہے، صرف ایک ہفتے کے لیے دستیاب ہے - WEEKNUM فنکشن۔ لہذا، اگر آپ کسی تاریخ سے ہفتہ نمبر حاصل کرنے کا طریقہ تلاش کر رہے ہیں، تو WEEKNUM وہ فنکشن ہے جو آپ چاہتے ہیں۔

اس مختصر ٹیوٹوریل میں، ہم ایکسل WEEKNUM کے نحو اور دلائل کے بارے میں مختصراً بات کریں گے، اور پھر چند فارمولہ مثالوں پر تبادلہ خیال کریں جس سے یہ ظاہر ہوتا ہے کہ آپ اپنی ایکسل ورک شیٹس میں ہفتہ کے نمبروں کا حساب لگانے کے لیے کس طرح WEEKNUM فنکشن استعمال کر سکتے ہیں۔

Excel WEEKNUM فنکشن - نحو

WEEKNUM فنکشن ہے ایکسل میں سال میں کسی مخصوص تاریخ کے ہفتہ نمبر کو واپس کرنے کے لیے استعمال کیا جاتا ہے (1 اور 54 کے درمیان نمبر)۔ اس کے دو دلائل ہیں، پہلا مطلوبہ ہے اور دوسرا اختیاری ہے:

• سیریل_نمبر - ہفتہ کے اندر کوئی بھی تاریخ جس کا نمبر آپ آزما رہے ہیں۔ تلاش کرنے کے لئے. یہ تاریخ پر مشتمل سیل کا حوالہ ہو سکتا ہے، DATE فنکشن کا استعمال کرتے ہوئے درج کی گئی تاریخ یا کسی اور فارمولے کے ذریعے واپس کی گئی ہے۔
• Return_type (اختیاری) - ایک عدد جو اس بات کا تعین کرتا ہے کہ ہفتے کا دن شروع ہوتا ہے. اگر چھوڑ دیا جائے تو پہلے سے طے شدہ قسم 1 استعمال کیا جاتا ہے (اتوار سے شروع ہونے والا ہفتہ)۔

یہاں return_type اقدار کی مکمل فہرست ہے جو WEEKNUM فارمولوں میں معاون ہے۔

WEEKNUM فنکشن میں، دو مختلف ہفتہ نمبرنگ سسٹمز استعمال کیے جاتے ہیں:

• سسٹم 1۔ 1 جنوری پر مشتمل ہفتہ سمجھا جاتا ہے۔ سال کا پہلا ہفتہ اور ہفتہ 1 کا شمار کیا جاتا ہے۔ اس نظام میں، ہفتہ روایتی طور پر اتوار کو شروع ہوتا ہے۔
• سسٹم 2۔ یہ ISO ہفتہ کی تاریخ کا نظام ہے جو ISO 8601 تاریخ اور وقت کا معیار۔ اس نظام میں، ہفتہ پیر کو شروع ہوتا ہے اور سال کی پہلی جمعرات پر مشتمل ہفتہ ہفتہ 1 سمجھا جاتا ہے۔ اسے عام طور پر یوروپی ہفتہ نمبری نظام کے نام سے جانا جاتا ہے اور یہ بنیادی طور پر حکومت اور کاروبار میں مالی سال اور ٹائم کیپنگ میں استعمال ہوتا ہے۔

اوپر دی گئی تمام واپسی کی اقسام سسٹم 1 پر لاگو ہوتی ہیں، سوائے واپسی کی قسم 21 کے جو سسٹم 2 میں استعمال ہوتی ہے۔

نوٹ۔ Excel 2007 اور اس سے پہلے کے ورژن میں، صرف 1 اور 2 کے اختیارات دستیاب ہیں۔ 11 سے 21 تک کی واپسی کی قسمیں صرف Excel 2010 اور Excel 2013 میں معاون ہیں۔ 4

اوپر میںفارمولہ، return_type دلیل کو چھوڑ دیا گیا ہے، جس کا مطلب ہے کہ پہلے سے طے شدہ قسم 1 استعمال کیا جاتا ہے - ہفتہ اتوار سے شروع ہوتا ہے۔

اگر آپ ہفتے کے کسی اور دن سے شروع کرنا چاہتے ہیں تو پیر کو کہیں، پھر 2 کا استعمال کریں۔ دوسری دلیل میں:

=WEEKNUM(A2, 2)

کسی سیل کا حوالہ دینے کے بجائے، آپ DATE(سال، مہینہ، دن) فنکشن کا استعمال کرکے براہ راست فارمولے میں تاریخ کی وضاحت کرسکتے ہیں، مثال کے طور پر:

=WEEKNUM(DATE(2015,4,15), 2)

مندرجہ بالا فارمولہ 16 لوٹاتا ہے، جو 15 اپریل 2015 پر مشتمل ہفتہ کا نمبر ہے، جس میں ایک ہفتہ پیر سے شروع ہوتا ہے۔

حقیقی زندگی کے حالات میں ، Excel WEEKNUM فنکشن شاذ و نادر ہی اپنے طور پر استعمال ہوتا ہے۔ اکثر آپ اسے دوسرے فنکشنز کے ساتھ مل کر ہفتے کے نمبر کی بنیاد پر مختلف حسابات کرنے کے لیے استعمال کریں گے، جیسا کہ مزید مثالوں میں دکھایا گیا ہے۔

ایکسل میں ہفتے کے نمبر کو تاریخ میں کیسے تبدیل کریں

جیسا کہ ابھی دیکھا ہے، ایکسل WEEKNUM فنکشن کا استعمال کرتے ہوئے تاریخ کو ہفتہ کے نمبر میں تبدیل کرنا کوئی بڑی بات نہیں ہے۔ لیکن کیا ہوگا اگر آپ اس کے برعکس تلاش کر رہے ہیں، یعنی ہفتے کے نمبر کو تاریخ میں تبدیل کرنا؟ افسوس، کوئی ایکسل فنکشن نہیں ہے جو اسے فوراً کر سکے۔ لہذا، ہمیں اپنے فارمولے خود بنانا ہوں گے۔

فرض کریں کہ آپ کے سیل A2 میں ایک سال ہے اور B2 میں ایک ہفتہ نمبر ہے، اور اب آپ اس ہفتے کے آغاز اور اختتامی تاریخوں کا حساب لگانا چاہتے ہیں۔

نوٹ۔ یہ فارمولہ مثال پیر سے شروع ہونے والے ہفتہ کے ساتھ ISO ہفتہ کے نمبروں پر مبنی ہے۔

شروع کو واپس کرنے کا فارمولاہفتہ کی تاریخ درج ذیل ہے:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

جہاں A2 سال ہے اور B2 ہفتہ کا نمبر ہے۔

براہ کرم نوٹ کریں کہ فارمولہ تاریخ لوٹاتا ہے۔ سیریل نمبر کے طور پر، اور اسے تاریخ کے طور پر ظاہر کرنے کے لیے، آپ کو سیل کو اس کے مطابق فارمیٹ کرنے کی ضرورت ہے۔ آپ ایکسل میں تاریخ کی شکل تبدیل کرنے میں تفصیلی ہدایات حاصل کر سکتے ہیں۔ اور یہاں فارمولے کے ذریعہ نتیجہ واپس کیا گیا ہے:

یقینا، ایک ہفتہ کے نمبر کو تاریخ میں تبدیل کرنے کا فارمولا معمولی نہیں ہے، اور اسے حاصل کرنے میں کچھ وقت لگ سکتا ہے۔ آپ کا سر منطق پر ہے۔ بہرحال، میں ان لوگوں کے لیے بامعنی وضاحت فراہم کرنے کی پوری کوشش کروں گا جو نیچے تک جانے کے خواہشمند ہیں۔

جیسا کہ آپ دیکھ رہے ہیں، ہمارا فارمولا 2 حصوں پر مشتمل ہے:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - پچھلے سال میں آخری پیر کی تاریخ کا حساب لگاتا ہے۔
• B2 * 7 - ہفتے کا پیر (تاریخ شروع) حاصل کرنے کے لیے ہفتوں کی تعداد کو 7 سے ضرب (ایک ہفتے میں دنوں کی تعداد) شامل کرتا ہے۔ سوال۔

آئی ایس او ہفتہ نمبری نظام میں، ہفتہ 1 وہ ہفتہ ہے جس میں سال کی پہلی جمعرات ہوتی ہے۔ نتیجتاً، پہلا پیر ہمیشہ 29 دسمبر اور 4 جنوری کے درمیان ہوتا ہے۔ لہٰذا، اس تاریخ کو تلاش کرنے کے لیے، ہمیں 5 جنوری سے پہلے کے پیر کو تلاش کرنا ہوگا۔

مائیکروسافٹ ایکسل میں، آپ ہفتے کا ایک دن نکال سکتے ہیں۔ WEEKDAY فنکشن استعمال کرکے تاریخ۔ اور آپ درج ذیل عام فارمولے کو کسی بھی دی گئی تاریخ سے فوراً پہلے پیر حاصل کرنے کے لیے استعمال کر سکتے ہیں:

اگر ہماریحتمی مقصد A2 میں سال کے 5 جنوری سے پہلے پیر کو تلاش کرنا تھا، ہم درج ذیل DATE فنکشنز استعمال کر سکتے ہیں:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

لیکن ہمیں درحقیقت جس کی ضرورت ہے وہ پہلا پیر نہیں ہے اس سال، بلکہ پچھلے سال کے آخری پیر کو۔ لہذا، آپ کو 5 جنوری سے 7 دن کم کرنے ہوں گے اور اس وجہ سے آپ کو پہلے DATE فنکشن میں -2 ملے گا:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

اس مشکل فارمولے کے مقابلے جو آپ نے ابھی سیکھا ہے، <7 کا حساب لگاتے ہوئے ہفتے کی>اختتام کی تاریخ کیک کا ایک ٹکڑا ہے :) ہفتے کے اتوار کو زیر بحث لانے کے لیے، آپ صرف تاریخ آغاز میں 6 دن کا اضافہ کریں، یعنی =D2+6

>>>> اسکرین شاٹ اوپر زیر بحث شروع کی تاریخ اور اختتامی تاریخ کے فارمولوں کو بالترتیب کالم D اور E میں کاپی کیا گیا ہے:

ایکسل میں ہفتہ کے نمبر کو تاریخ میں تبدیل کرنے کے دوسرے طریقے

اگر ISO ہفتہ تاریخ کے نظام پر مبنی مندرجہ بالا فارمولہ آپ کی ضروریات کو پورا نہیں کرتا ہے، تو درج ذیل میں سے ایک حل آزمائیں۔

فارمولہ 1۔ جنوری-1 پر مشتمل ایک ہفتہ ہفتہ 1، پیر- اتوار ہفتہ ہے

جیسا کہ آپ کو یاد ہے، پچھلا فارمولہ ISO تاریخ کے نظام کی بنیاد پر کام کرتا ہے جہاں سال کی پہلی جمعرات کو ہفتہ 1 سمجھا جاتا ہے۔ اگر آپ تاریخ کے نظام پر کام کرتے ہیں جہاں یکم جنوری والے ہفتہ کو ہفتہ 1 سمجھا جاتا ہے، مندرجہ ذیل کا استعمال کریںفارمولے:

تاریخ آغاز:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

اختتام کی تاریخ:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

فارمولہ 2. جنوری-1 پر مشتمل ہفتہ ہفتہ 1، اتوار-ہفتہ ہفتہ ہے

یہ فارمولے اوپر والے فارمولوں سے ملتے جلتے ہیں صرف فرق کے ساتھ اتوار - ہفتہ ہفتہ کے لیے۔

آغاز کی تاریخ:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

اختتام کی تاریخ:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

فارمولہ 3۔ ہمیشہ 1 جنوری، پیر تا اتوار ہفتہ کو گننا شروع کریں

جب کہ پچھلے فارمولے ہفتہ 1 کے پیر (یا اتوار) واپس آتے ہیں، قطع نظر اس کے چاہے اس سال کے اندر آتا ہے یا پچھلے سال، یہ تاریخ آغاز کا فارمولہ ہمیشہ جنوری 1 ہفتے کے دن سے قطع نظر ہفتہ 1 کی تاریخ آغاز کے طور پر واپس آتا ہے۔ تشبیہ کے مطابق، اختتامی تاریخ کا فارمولہ ہمیشہ 31 دسمبر سال کے آخری ہفتے کی آخری تاریخ کے طور پر واپس آتا ہے، چاہے ہفتے کا دن کچھ بھی ہو۔ دیگر تمام معاملات میں، یہ فارمولے اوپر والے فارمولہ 1 کی طرح کام کرتے ہیں۔

تاریخ آغاز:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

اختتام کی تاریخ:<8

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

فارمولہ 4. ہمیشہ 1 جنوری، اتوار-ہفتہ ہفتہ کو گننا شروع کریں

شروع اور اختتامی تاریخوں کا حساب لگانے کے لیے اتوار - ہفتہ کے ہفتے کے لیے، مندرجہ بالا فارمولوں میں صرف ایک چھوٹی سی ایڈجسٹمنٹ کی ضرورت ہے :)

تاریخ آغاز:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

اختتام کی تاریخ:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

ہفتہ نمبر سے مہینہ کیسے حاصل کیا جائے

ہفتے کے مطابق مہینہ حاصل کرنے کے لیے نمبر، آپ کو کسی ہفتے میں پہلا دن ملتا ہے جیسا کہ اس میں بیان کیا گیا ہے۔مثال کے طور پر، اور پھر اس فارمولے کو Excel MONTH فنکشن میں اس طرح لپیٹیں:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

نوٹ۔ براہ کرم یاد رکھیں کہ مندرجہ بالا فارمولہ ISO ہفتہ کی تاریخ کے نظام کی بنیاد پر کام کرتا ہے، جہاں ہفتہ پیر کو شروع ہوتا ہے اور سال کی پہلی جمعرات والے ہفتہ کو ہفتہ 1 سمجھا جاتا ہے۔ مثال کے طور پر، سال 2016 میں، پہلی جمعرات 7 جنوری ہے، اور اسی وجہ سے ہفتہ 1 کا آغاز 4-جنوری-2016 کو ہوتا ہے۔

ایک مہینے میں ہفتہ کا نمبر کیسے حاصل کیا جائے (1 سے 6 تک)

اگر آپ کی کاروباری منطق کے مطابق ایک مخصوص تاریخ کو متعلقہ مہینے کے اندر ہفتہ کے نمبر میں تبدیل کرنے کی ضرورت ہے، تو آپ WEEKNUM کا مجموعہ استعمال کر سکتے ہیں، DATE اور MONTH فنکشنز:

یہ فرض کرتے ہوئے کہ سیل A2 اصل تاریخ پر مشتمل ہے، پیر سے شروع ہونے والے ایک ہفتے کے لیے درج ذیل فارمولے کا استعمال کریں (WEEKNUM کی return_type argument میں نوٹس 21):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

اتوار سے شروع ہونے والے ایک ہفتے کے لیے، return_type دلیل کو چھوڑ دیں:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

کیسے کریں قدریں جمع کریں اور ہفتے کے نمبر کے حساب سے اوسط تلاش کریں

اب جب کہ آپ جانتے ہیں کہ ایکسل میں تاریخ کو ہفتے کے نمبر میں کیسے تبدیل کرنا ہے، آئیے دیکھتے ہیں کہ آپ دوسرے حسابات میں ہفتے کے نمبروں کو کیسے استعمال کرسکتے ہیں۔

فرض کریں ، آپ کے پاس ماہانہ فروخت کے کچھ اعداد و شمار ہیں اور آپ ہر ہفتے کی کل تعداد جاننا چاہتے ہیں۔

شروع کرنے کے لیے، آئیے ہر فروخت کے مطابق ایک ہفتے کا نمبر معلوم کریں۔ اگر آپ کی تاریخیں کالم A میں ہیں اور کالم B میں سیلز ہیں تو سیل میں شروع ہونے والے کالم C میں =WEEKNUM(A2) فارمولہ کاپی کریں۔C2.

اور پھر، کسی دوسرے کالم میں ہفتے کے نمبروں کی فہرست بنائیں (کہیں، کالم E میں) اور درج ذیل SUMIF فارمولے کا استعمال کرتے ہوئے ہر ہفتے کی فروخت کا حساب لگائیں:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

جہاں E2 ہفتہ نمبر ہے۔

اس مثال میں، ہم مارچ کی فروخت کی فہرست کے ساتھ کام کر رہے ہیں، اس لیے ہمارے پاس ہفتہ نمبر 10 سے 14 ہیں، جیسا کہ مندرجہ ذیل اسکرین شاٹ میں دکھایا گیا ہے:

اسی طرح، آپ کسی ہفتے کے لیے فروخت کی اوسط کا حساب لگا سکتے ہیں:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

اگر WEEKNUM فارمولے کے ساتھ مددگار کالم آپ کے ڈیٹا لے آؤٹ میں اچھی طرح سے فٹ نہیں بیٹھتا ہے، تو مجھے یہ بتاتے ہوئے افسوس ہے کہ اس سے چھٹکارا پانے کا کوئی آسان طریقہ نہیں ہے کیونکہ Excel WEEKNUM ان افعال میں سے ایک ہے۔ جو رینج کے دلائل کو قبول نہیں کرتا ہے۔ اس لیے، اسے SUMPRODUCT یا اسی طرح کے منظر نامے میں MONTH فنکشن جیسے کسی دوسرے ارے فارمولے میں استعمال نہیں کیا جا سکتا۔

ہفتہ نمبر کی بنیاد پر سیلز کو کیسے نمایاں کریں

آئیے کہتے ہیں کہ آپ کے پاس ایک لمبی فہرست ہے۔ کچھ کالم میں تاریخوں کی اور آپ صرف وہی نمایاں کرنا چاہتے ہیں جو کسی مخصوص ہفتے سے متعلق ہوں۔ آپ کو صرف اس سے ملتا جلتا WEEKNUM فارمولہ کے ساتھ مشروط فارمیٹنگ کے اصول کی ضرورت ہے:

=WEEKNUM($A2)=10

جیسا کہ ذیل کے اسکرین شاٹ میں دکھایا گیا ہے، یہ قاعدہ فروخت کو نمایاں کرتا ہے جو ہفتہ 10 کے اندر کی گئی تھیں، جو کہ مارچ 2015 میں پہلا ہفتہ۔ چونکہ اصول A2:B15 پر لاگو ہوتا ہے، اس لیے یہ دونوں کالموں میں اقدار کو نمایاں کرتا ہے۔ آپ اس میں مشروط فارمیٹنگ کے اصول بنانے کے بارے میں مزید جان سکتے ہیں۔ٹیوٹوریل: ایک دوسرے سیل ویلیو پر مبنی ایکسل مشروط فارمیٹنگ۔

اس طرح آپ ایکسل میں ہفتے کے نمبروں کا حساب لگا سکتے ہیں، ہفتے کے نمبر کو تاریخ میں تبدیل کر سکتے ہیں اور تاریخ سے ہفتہ کا نمبر نکال سکتے ہیں۔ امید ہے، آج آپ نے جو WEEKNUM فارمولے سیکھے ہیں وہ آپ کی ورک شیٹس میں کارآمد ثابت ہوں گے۔ اگلے ٹیوٹوریل میں، ہم ایکسل میں عمر اور سالوں کا حساب لگانے کے بارے میں بات کریں گے۔ میں پڑھنے کے لیے آپ کا شکریہ ادا کرتا ہوں اور امید کرتا ہوں کہ اگلے ہفتے آپ سے ملوں گا!