Microsoft Excel ish kunlari, oylar va yillar bilan ishlash uchun bir qator funksiyalarni taqdim etsa-da, haftalar davomida faqat bittasi mavjud - WEEKNUM funksiyasi. Shunday qilib, agar siz sanadan hafta raqamini olish yo‘lini izlayotgan bo‘lsangiz, WEEKNUM siz xohlagan funksiyadir.

Ushbu qisqa qo‘llanmada biz Excel WEEKNUM ning sintaksisi va argumentlari haqida qisqacha gaplashamiz va keyin Excel ish varaqlarida hafta raqamlarini hisoblash uchun WEEKNUM funksiyasidan qanday foydalanishingiz mumkinligini ko'rsatadigan bir nechta formula misollarini muhokama qiling.

Excel WEEKNUM funktsiyasi - sintaksis

WEEKNUM funksiyasi Yildagi ma'lum bir sananing hafta raqamini qaytarish uchun Excelda foydalaniladi (1 va 54 orasidagi raqam). Uning ikkita argumenti bor, birinchisi talab qilinadi, ikkinchisi esa ixtiyoriy:

• Serial_raqam - raqamini sinab koʻrayotgan hafta ichidagi istalgan sana topmoq. Bu sanani o'z ichiga olgan katakchaga havola bo'lishi mumkin, sana DATE funksiyasidan foydalangan holda kiritilgan yoki boshqa formula bilan qaytarilgan sana.
• Qaytish_turi (ixtiyoriy) - qaysi raqamni aniqlaydigan raqam. hafta boshlanadigan kun. Agar oʻtkazib yuborilsa, standart turdagi 1 ishlatiladi (hafta yakshanba kuni boshlanadi).

Bu yerda WEEKNUM formulalarida qoʻllab-quvvatlanadigan return_type ta qiymatning toʻliq roʻyxati keltirilgan.

WEEKNUM funksiyasida ikki xil hafta raqamlash tizimi ishlatiladi:

• 1-tizim. 1-yanvarni o'z ichiga olgan hafta hisoblanadi. yilning 1-haftasi va 1-hafta bilan raqamlangan. Ushbu tizimda hafta anʼanaviy ravishda yakshanba kuni boshlanadi.
• 2-tizim. Bu ISO haftalik sanasi tizimi ISO 8601 sana va vaqt standarti. Bu tizimda hafta dushanba kuni boshlanadi va yilning birinchi payshanbasini o'z ichiga olgan hafta 1-hafta hisoblanadi. U odatda Yevropa haftalarini raqamlash tizimi sifatida tanilgan va u asosan hukumat va biznesda moliyaviy yillar va vaqt hisobi uchun qo'llaniladi.

Yuqorida sanab o'tilgan barcha qaytarish turlari 1-tizimga taalluqlidir, 2-tizimda qo'llaniladigan qaytarish turi 21 bundan mustasno.

Eslatma. Excel 2007 va oldingi versiyalarida faqat 1 va 2 variantlari mavjud. 11 dan 21 gacha bo'lgan qaytarish turlari faqat Excel 2010 va Excel 2013 da qo'llab-quvvatlanadi.

Sanani hafta raqamiga (1 dan 54 gacha) aylantirish uchun Excel WEEKNUM formulalari

Quyidagi skrinshotda eng oddiy =WEEKNUM(A2) formulali sanalardan hafta raqamlarini qanday olish mumkinligi ko'rsatilgan:

Yuqoridaformulada return_type argumenti olib tashlandi, ya'ni standart turdagi 1 ishlatiladi - hafta yakshanba kuni boshlanadi.

Agar siz haftaning boshqa kunidan boshlashni xohlasangiz, dushanba deylik, keyin 2 dan foydalaning. ikkinchi argumentda:

=WEEKNUM(A2, 2)

Yacheykaga murojaat qilish o'rniga, DATE(yil, oy, kun) funksiyasidan foydalanib, to'g'ridan-to'g'ri formulada sanani belgilashingiz mumkin, masalan:

=WEEKNUM(DATE(2015,4,15), 2)

Yuqoridagi formula 16 ni qaytaradi, bu 2015-yil 15-aprelni oʻz ichiga olgan hafta soni, dushanba kuni boshlanadigan hafta.

Haqiqiy hayot stsenariylarida. , Excel WEEKNUM funksiyasi o'z-o'zidan kamdan-kam qo'llaniladi. Ko'pincha siz uni boshqa funktsiyalar bilan birgalikda boshqa misollarda ko'rsatilganidek, hafta soniga qarab turli xil hisob-kitoblarni amalga oshirasiz.

Excel'da hafta sonini sanaga qanday o'zgartirish mumkin

Sizga o'xshab Hozirgina ko'rdim, Excel WEEKNUM funksiyasidan foydalanib sanani hafta raqamiga aylantirish unchalik katta ish emas. Ammo agar siz buning aksini qidirsangiz, ya'ni hafta raqamini sanaga aylantirsangiz nima bo'ladi? Afsuski, buni darhol amalga oshiradigan Excel funktsiyasi yo'q. Shunday qilib, biz o'z formulalarimizni yaratishimiz kerak.

Aytaylik, sizda A2 katakda yil va B2da hafta raqami bor va endi siz ushbu haftaning boshlanish va tugash sanalarini hisoblamoqchisiz.

Eslatma. Ushbu formula misoli ISO hafta raqamlariga asoslanadi, hafta dushanba kuni boshlanadi.

Startni qaytarish formulasisana hafta quyidagicha:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Bu erda A2 yil va B2 hafta raqami.

E'tibor bering, formula sanani qaytaradi. seriya raqami sifatida va uni sana sifatida ko'rsatish uchun hujayrani mos ravishda formatlashingiz kerak. Batafsil ko'rsatmalarni Excelda Sana formatini o'zgartirish bo'limida topishingiz mumkin. Va bu formula bilan qaytarilgan natija:

Albatta, hafta sonini sanaga aylantirish formulasi ahamiyatsiz emas va uni olish uchun biroz vaqt ketishi mumkin. boshingiz mantiq atrofida. Qanday bo'lmasin, men pastga tushmoqchi bo'lganlar uchun mazmunli tushuntirish berish uchun qo'limdan kelganini qilaman.

Ko'rib turganingizdek, bizning formulamiz 2 qismdan iborat:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - o'tgan yilning oxirgi dushanba kunini hisoblab chiqadi.
• B2 * 7 - haftaning dushanbasini (boshlanish sanasi) olish uchun haftalar sonini 7 ga (haftadagi kunlar soni) ko'paytiradi. savol.

ISO haftalik raqamlash tizimida 1-hafta yilning birinchi payshanbasini o'z ichiga olgan hafta hisoblanadi. Shunday qilib, birinchi dushanba har doim 29 dekabrdan 4 yanvargacha bo'ladi. Demak, bu sanani topish uchun biz 5 yanvardan oldingi dushanbani darhol topishimiz kerak.

Microsoft Excelda haftaning bir kunini quyidagidan ajratib olishingiz mumkin. WEEKDAY funksiyasidan foydalangan holda sana. Va siz dushanbani istalgan sanadan oldin darhol olish uchun quyidagi umumiy formuladan foydalanishingiz mumkin:

Agar bizningYakuniy maqsad A2 formatida yilning 5-yanvaridan oldin dushanbani topish edi, biz quyidagi DATE funksiyalaridan foydalanishimiz mumkin edi:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Ammo bizga kerak bo'lgan narsa bu yilning birinchi dushanbasi emas. bu yil, balki o'tgan yilning oxirgi dushanbasi. Shunday qilib, siz 5-yanvardan 7 kunni ayirishingiz kerak va shuning uchun siz birinchi DATE funksiyasida -2 ga ega bo'lasiz:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Yaqinda o'rgangan murakkab formula bilan solishtirganda, <7 Haftaning>tugash sanasi bir parcha tort :) Ko'rib chiqilayotgan haftaning yakshanbasini olish uchun Boshlanish sanasi ga 6 kun qo'shishingiz kifoya, ya'ni =D2+6

Muqobil ravishda 6 ni toʻgʻridan-toʻgʻri formulaga qoʻshishingiz mumkin:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Formullar har doim toʻgʻri sanalar berilganiga ishonch hosil qilish uchun quyidagini koʻrib chiqing. skrinshot. Yuqorida ko'rib chiqilgan Boshlanish sanasi va tugash sanasi formulalari mos ravishda D va E ustunlari bo'ylab ko'chiriladi:

Excelda hafta sonini sanaga aylantirishning boshqa usullari

Agar ISO hafta sanasi tizimiga asoslangan yuqoridagi formula talablaringizga javob bermasa, quyidagi yechimlardan birini sinab ko'ring.

Formula 1. Yanvar-1ni o'z ichiga olgan hafta 1-hafta, dushanba-yaks hafta

Esingizda bo'lsa, oldingi formula ISO sana tizimi asosida ishlaydi, bunda yilning birinchi payshanbasi 1-hafta hisoblanadi. Agar siz 1-yanvarni o'z ichiga olgan hafta 1-hafta hisoblangan sana tizimi asosida ishlasangiz, quyidagilardan foydalaningformulalar:

Boshlanish sanasi:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Yakunlash sanasi:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Formula 2. Yanvar-1ni o'z ichiga olgan hafta - 1-hafta, Yakshanba-Shanba haftasi

Bu formulalar yuqoridagilarga o'xshash, ular faqat yozilishidagi farq bilan. yakshanba - shanba haftasi uchun.

Boshlanish sanasi:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Yakuniy sana:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Formula 3. Har doim 1-yanvar, dushanba-yakshanba kunlaridan boshlab hisoblashni boshlang

Avvalgi formulalar 1-haftaning dushanbasi (yoki yakshanbasi) qaytsa, bundan qatʼi nazar Bu yil yoki oldingi yilga to'g'ri keladimi, bu boshlanish sanasi formulasi haftaning kunidan qat'iy nazar har doim 1-yanvar 1-haftaning boshlanish sanasi sifatida qaytariladi. O'xshashlik bo'yicha, tugash sanasi formulasi har doim haftaning kunidan qat'i nazar, yilning oxirgi haftasining tugash sanasi sifatida 31 dekabr ni qaytaradi. Boshqa barcha jihatlarda bu formulalar yuqoridagi Formula 1 ga o‘xshash ishlaydi.

Boshlanish sanasi:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Yakuniy sana:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Formula 4. Har doim 1-yanvar, yakshanba-shanba haftasida hisoblashni boshlang

Boshlanish va tugash sanalarini hisoblash uchun yakshanba - shanba kunlari uchun yuqoridagi formulalarda bitta kichik tuzatish kifoya qiladi :)

Boshlanish sanasi:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Yakunlash sanasi:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Hafta raqamidan oyni qanday olish mumkin

Haftaga mos keladigan oyni olish uchun raqam, siz ma'lum bir haftaning birinchi kunini bu erda tushuntirilganidek topasizMisol uchun, so'ngra formulani Excel MONTH funksiyasiga o'rang:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Eslatma. Esda tutingki, yuqoridagi formula ISO hafta sanasi tizimi asosida ishlaydi, bu erda hafta dushanba kuni boshlanadi va yilning 1-payshanbasini o'z ichiga olgan hafta 1-hafta hisoblanadi. Masalan, 2016 yilda, birinchi payshanba 7-yanvar va shuning uchun 1-hafta 2016-yil 4-yanvarda boshlanadi.

Bir oyda hafta raqamini qanday olish mumkin (1 dan 6 gacha)

Agar biznes mantiqingiz ma'lum bir sanani tegishli oy ichida hafta raqamiga aylantirishni talab qilsa, siz WEEKNUM kombinatsiyasidan foydalanishingiz mumkin, DATE va MONTH funksiyalari:

A2 katak asl sanani o‘z ichiga olgan deb faraz qilsak, Dushanba kuni boshlangan hafta uchun quyidagi formuladan foydalaning (WEEKNUM ning qaytish_turi argumentidagi 21-sonli eslatma):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Yakshanba kuni boshlangan bir hafta davomida return_type argumentini o'tkazib yuboring:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Qanday qilib yig'indisi qiymatlarini toping va hafta raqami bo'yicha o'rtachani toping

Endi Excelda sanani hafta raqamiga qanday o'zgartirishni bilganingizdan so'ng, keling, hafta raqamlarini boshqa hisob-kitoblarda qanday ishlatishni ko'rib chiqamiz.

Deylik. , sizda bir necha oylik savdo ko'rsatkichlari bor va siz har hafta uchun jami ma'lumotlarni bilishni xohlaysiz.

Boshlash uchun, har bir sotuvga mos keladigan hafta raqamini bilib olaylik. Agar sanalaringiz A ustunida va sotuvlar B ustunida bo'lsa, =WEEKNUM(A2) formulasini C ustuni bo'ylab hujayradan boshlab ko'chiring.C2.

Keyin, boshqa ustunda (masalan, E ustunida) hafta raqamlari roʻyxatini tuzing va quyidagi SUMIF formulasidan foydalanib har hafta uchun savdolarni hisoblang:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Bu erda E2 hafta raqami.

Ushbu misolda biz mart oyidagi sotuvlar ro'yxati bilan ishlayapmiz, shuning uchun bizda 10 dan 14 gacha bo'lgan hafta raqamlari mavjud, chunki quyidagi skrinshotda ko'rsatilgan:

Shunga o'xshash tarzda siz ma'lum bir hafta uchun o'rtacha savdoni hisoblashingiz mumkin:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Agar WEEKNUM formulali yordamchi ustun maʼlumotlar joylashuvingizga toʻgʻri kelmasa, afsusdamanki, undan xalos boʻlishning oddiy usuli yoʻq, chunki Excel WEEKNUM bu funksiyalardan biri. bu diapazon argumentlarini qabul qilmaydi. Shuning uchun uni SUMPRODUCT yoki MONTH funksiyasi kabi boshqa massiv formulasida shunga o‘xshash stsenariyda ishlatib bo‘lmaydi.

Hafta raqami asosida hujayralarni qanday ajratib ko‘rsatish mumkin

Aytaylik, sizda uzoq ro‘yxat bor. ba'zi bir ustundagi sanalar va siz faqat ma'lum bir haftaga tegishli bo'lganlarni ajratib ko'rsatishni xohlaysiz. Sizga kerak bo'lgan narsa - WEEKNUM formulasiga o'xshash shartli formatlash qoidasi:

=WEEKNUM($A2)=10

Quyidagi skrinshotda ko'rsatilganidek, qoida 10-hafta ichida amalga oshirilgan sotuvlarni ta'kidlaydi. 2015-yil mart oyining birinchi haftasi. Qoida A2:B15 uchun amal qilgani uchun u ikkala ustundagi qiymatlarni ajratib ko‘rsatadi. Bu erda shartli formatlash qoidalarini yaratish haqida ko'proq bilib olishingiz mumkino'quv qo'llanma: Boshqa hujayra qiymatiga asoslangan Excelni shartli formatlash.

Mana shu tarzda Excelda hafta raqamlarini hisoblashingiz, hafta sonini sanaga o'tkazishingiz va sanadan hafta raqamini chiqarishingiz mumkin. Umid qilamizki, siz bugun o'rgangan WEEKNUM formulalari ish varaqlaringiz uchun foydali bo'ladi. Keyingi qo'llanmada Excelda yosh va yillarni hisoblash haqida gapiramiz. O'qiganingiz uchun rahmat va keyingi haftada ko'rishga umid qilaman!