Dema ku Microsoft Excel komek fonksiyonan peyda dike ku bi rojên hefteyê, meh û salan re bixebite, tenê yek bi hefteyan peyda dibe - fonksiyona WEEKNUM. Ji ber vê yekê, heke hûn li rêyek digerin ku hûn hejmarek hefteyek ji rojekê bistînin, WEEKNUM fonksiyona ku hûn dixwazin e.

Di vê dersa kurt de, em ê bi kurtî li ser hevoksazî û argumanên Excel WEEKNUM biaxivin, û paşê çend nimûneyên formulê nîqaş bikin ku nîşan didin ka hûn çawa dikarin fonksiyona WEEKNUM bikar bînin da ku hejmarên hefteyê di pelên xebatê yên Excel de hesab bikin.

Fonksiyon WEEKNUM Excel - hevoksaziya

Fonksiyon WEEKNUM e di Excel de tê bikar anîn da ku hejmara hefteyê ya tarîxek taybetî ya salê vegerîne (hejmarek di navbera 1 û 54 de). Du argumanên wê hene, ya 1-ê hewce ye û ya 2-an vebijarkî ye:

• Hejmara_serî - her rojek di nava hefteyê de ku hejmara ku hûn hewl didin bibînin. Ev dikare bibe referansek ji şaneya ku tarîx tê de ye, tarîxek ku bi karanîna fonksiyona DATE hatî nivîsandin an jî bi formûlek din ve hatî vegerandin.
• Cîpa_vegerê (vebijarkî) - jimareyek ku diyar dike ku kîjan roja hefteyê dest pê dike. Heke ji holê rabe, tîpa xwerû 1 tê bikaranîn (hefteya ku roja Yekşemê dest pê dike).

Li vir navnîşek tevahî ya return_type nirxên ku di formula WEEKNUM de têne piştgirî kirin.

Di fonksiyona WEEKNUM de, du pergalên hejmarkirinê yên hefteyê yên cihêreng têne bikar anîn:

• Pergala 1. Hefteya ku 1-ê Çile tê de tê hesibandin. hefteya 1emîn a salê ye û hefteya 1 tê hejmartin. Di vê pergalê de, hefte bi kevneşopî roja Yekşemê dest pê dike.
• Pergala 2. Ev pergala roja hefteya ISO-yê ye ku beşek ji Standarda dîrok û demjimêr ISO 8601. Di vê pergalê de, hefte roja duşemê dest pê dike û hefteya ku pêncşema yekem a salê vedihewîne, hefteya 1 tê hesibandin. Ew bi gelemperî wekî pergala jimarekirina hefteyên Ewropî tê zanîn û bi giranî di hikûmetê û karsaziyê de ji bo salên darayî û jimartina demê tê bikar anîn. 9>

Hemû celebên vegerê yên ku li jor hatine rêz kirin ji bo Pergala 1-ê derbas dibin, ji bilî celebê vegerê 21 ku di Pergala 2-ê de tê bikar anîn.

Nîşe. Di Excel 2007 û guhertoyên berê de, tenê vebijarkên 1 û 2 hene. Cûreyên vegerê 11 heta 21 tenê di Excel 2010 û Excel 2013 de têne piştgirî kirin.

Formulên WEEKNUM Excel ji bo veguhertina dîrokê bo hejmara heftiyê (ji 1 heta 54)

Wêneya jêrîn nîşan dide ku hûn çawa dikarin hejmarên hefteyê ji tarîxên bi formula =WEEKNUM(A2) ya herî hêsan bistînin:

Li jorformula, argumana return_type dernakeve, ev tê vê wateyê ku tîpa 1-ê ya xwerû tê bikar anîn - hefteya ku roja Yekşemê dest pê dike.

Heke hûn tercîh dikin ku bi rojek din a hefteyê dest pê bikin, bibêjin Duşem, paşê 2 bikar bînin. di argumana duyemîn de:

=WEEKNUM(A2, 2)

Li şûna ku hûn behsa şaneyek bikin, hûn dikarin bi karanîna fonksiyona DATE(sal, meh, roj) rasterast di formula de tarîxê diyar bikin, mînak:

=WEEKNUM(DATE(2015,4,15), 2)

Formula li jor 16 vedigere, ku hejmara hefteya ku 15ê Avrêl, 2015 dihewîne, bi hefteyek roja Duşemê dest pê dike.

Di senaryoyên jiyanî de , fonksiyona Excel WEEKNUM pir kêm bi serê xwe tê bikar anîn. Pir caran hûn ê wê li gel fonksiyonên din bikar bînin da ku hesabên cihêreng ên li ser bingeha hejmara hefteyê pêk bînin, wekî ku di mînakên din de têne xuyang kirin.

Çawa di Excel-ê de jimareya hefteyê vediguhezînin dîrokê

Wek ku hûn nû dîtiye, ne tiştek mezin e ku meriv bi karanîna fonksiyona Excel WEEKNUM tarîxekê bike jimareyek hefteyekê. Lê heke hûn li berevajiyê digerin, ango jimareyek hefteyekê vediguherînin dîrokek? Mixabin, fonksiyonek Excel tune ku dikare vê yekê yekser bike. Ji ber vê yekê, em neçar in ku formulên xwe bi xwe ava bikin.

Bihesibînin ku we salek di hucreya A2 de û hejmarek hefteyek di B2 de heye, û naha hûn dixwazin di vê hefteyê de tarîxên Destpêk û Dawî bihesibînin.

Nîşe. Ev nimûne formula li ser hejmarên hefteya ISO-ê ye, bi hefteyek roja Duşemê dest pê dike.

Formula vegerandina Destpêkêdîroka ya hefteyê wiha ye:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Li ku derê A2 sal e û B2 hejmara hefteyê ye.

Ji kerema xwe bala xwe bidin ku formula tarîxê vedigerîne wekî jimareyek rêzik, û ji bo ku ew wekî tarîx were xuyang kirin, hûn hewce ne ku li gorî wê şaneyê format bikin. Hûn dikarin rêwerzên berfireh di Guhertina formata tarîxê de li Excel-ê bibînin. Û li vir encama ku ji hêla formulê ve hatî vegerandin ev e:

Bê guman, formula ku ji bo veguheztina jimareyek hefteyek ji mêj ve ne hindik e, û dibe ku demek bigire heya ku were girtin. serê te li dora mantiqê. Her çi be jî, ez ê çi ji destê min bê, ji bo kesên ku meraq dikin heta binî ve ravekirinek watedar pêşkêş bikim.

Wek hûn jî dibînin, formula me ji 2 beşan pêk tê:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - roja duşema dawî ya sala berê dihesibîne.
• B2 * 7 - hejmara hefteyên bi 7 (hejmara rojên hefteyê) zêde dike da ku roja duşemê (roja destpêkê) ya heftiyê bi dest bixe. pirs.

Di pergala jimarekirina hefteyê ya ISO de, hefteya 1 hefteya ku pêncşema pêşîn a salê vedihewîne ye. Ji ber vê yekê, Duşema yekem her dem di navbera 29ê Kanûna Pêşîn û 4ê Çile de ye. Ji ber vê yekê, ji bo dîtina wê tarîxê, divê em roja duşemê tavilê berî 5ê Rêbendanê bibînin.

Di Microsoft Excel de, hûn dikarin rojek hefteyê ji rojek bi karanîna fonksiyona WEEKDAY. Û hûn dikarin formula giştî ya jêrîn bikar bînin da ku duşemê yekser berî her tarîxek diyarkirî bistînin:

Eger meArmanca dawîn ev bû ku em duşemê tavilê beriya 5-ê Çile ya salê di A2-ê de bibînin, em dikarin fonksiyonên DATE-ê yên jêrîn bikar bînin:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Lê tiştê ku em bi rastî hewce ne duşema yekem e. îsal, lê belê duşema dawî ya sala borî. Ji ber vê yekê, divê hûn ji 5ê Rêbendanê 7 rojan kêm bikin û ji ber vê yekê hûn di yekem fonksiyona DATE-ê de -2-ê bistînin:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

Li gorî formula dijwar a ku we nû fêr bûye, hesabkirina Dîroka dawîyê ya heftê pîçek e :) Ji bo ku hûn roja Yekşemê ya hefteya navborî bistînin, hûn tenê 6 rojan li Dîroka Destpêkê , ango =D2+6

Alternatîf, hûn dikarin 6 rasterast di formulê de zêde bikin:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Ji bo ku formula her gav tarîxên rast radigihînin, ji kerema xwe li jêrîn binêrin screenshot. Formulên Dîroka Destpêkê û Dîroka Dawî ya ku li jor hatine nîqaş kirin bi rêzê li stûna D û E têne kopî kirin:

Rêyên din ên veguherîna hejmara hefteyê ji bo tarîxê di Excel de

Ger formula jorîn li ser bingeha pergala tarîxa hefteya ISO-yê hewcedariyên we pêk nayîne, yek ji çareseriyên jêrîn biceribîne.

Formula 1. Hefteyek ku Jan-1 tê de hefteyek 1 e, hefteya Duşemê ye

Wekî ku tê bîra we, formula berê li ser bingeha pergala tarîxa ISO-yê dixebite ku roja pêncşema pêşîn a salê wekî hefte 1 tê hesibandin. jêrîn bikar bîninformulas:

Dîroka destpêkê:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Dîroka dawîyê:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Formula 2. Hefteyek ku Jan-1 tê de hefteya 1 ye, heftiya roj-şemiyê ye

Ev formulan dişibin yên jorîn bi tenê cudahiya wan ku hatine nivîsandin. ji bo hefteya Yekşem - Şemî.

Dîroka Destpêkê:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Dîroka dawî:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Formula 3. Her dem di 1ê Rêbendanê de, hefteya duşemê, dest bi jimartinê bikin

Dema ku formûlên berê roja Duşemê (an Yekşemê) ji hefteya 1ê vedigerin. eger bikeve nava vê salê yan sala berê, ev formula tarîxa destpêkê her tim 1ê Çile wekî roja destpêka hefteya 1-ê bêyî roja hefteyê vedigere. Bi analogê, formula tarîxa dawîyê her gav 31ê Kanûna Pêşîn wekî roja dawiya hefteya dawî ya salê vedigere, bêyî ku roja hefteyê be. Di hemî aliyên din de, ev formulan mîna Formula 1-ê ya jorîn dixebitin.

Dîroka Destpêkê:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Dîroka dawî:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Formula 4. Hergav di 1ê Çile, hefteya Roj-Şemiyê de dest bi jimartinê bikin

Ji bo hejmartina tarîxên destpêk û dawîyê ji bo hefteyek Yekşem - Şemî, ya ku hewce dike di formûlên jorîn de verastkirinek piçûk e :)

Dîroka Destpêkê:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Dîroka dawîyê:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Meriv çawa mehekê ji jimareya heftê werdigire

Mehek li gorî heftê tê bidestxistin jimare, hûn roja yekem di hefteyek diyarkirî de wekî ku di vê yekê de hatî diyar kirin bibîninmînak, û dûv re wê formula di fonksiyona MEHA Excel de bi vî rengî bipêçin:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Nîşe. Ji kerema xwe ji bîr mekin ku formula li jor li ser bingeha Sîstema dîroka hefteya ISO-yê dixebite, ku hefteyek roja Duşemê dest pê dike û hefteya ku roja pêncşema 1-ê salê vedihewîne hefteya 1 tê hesibandin. Mînak, di sala 2016-an de, yekem pêncşem 7ê Çile ye, û ji ber vê yekê hefteya 1 di 4-Jan-2016 de dest pê dike.

Meriv çawa di mehekê de jimareyek hefteyekê werdigire (ji 1 heta 6)

Heke mantiqa karsaziya we hewce dike ku tarîxek taybetî bi jimareya hefteyê veguhezîne di nav meha têkildar de, hûn dikarin berhevoka WEEKNUM bikar bînin, Fonksiyonên DATE û MONTH:

Bihesibînin ku hucreya A2 dîroka orîjînal dihewîne, formula jêrîn ji bo hefteyek ku Duşem dest pê dike bikar bînin (di argumana WEEKNUM-ê vegerê_type de 21 bala xwe bidin):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Ji bo hefteyekê ku ji Yekşemê dest pê dike, argumana return_type berde:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Çawa nirxan berhev bikin û navînî li gorî jimareya heftiyê bibînin

Niha ku hûn dizanin ka meriv çawa di Excel de dîrokek vediguherîne jimareyek hefteyekê, em bibînin ka hûn çawa dikarin hejmarên hefteyê di hesabên din de bikar bînin.

Berxwedan , çend hejmarên firotina mehane yên we hene û hûn dixwazin bi giştî her hefte zanibin.

Ji bo destpêkê, werin em jimareyek hefteyek li gorî her firotanê peyda bikin. Ger tarîxên we di stûna A de û firotan di stûna B de ne, formula =WEEKNUM(A2) li ser stûna C-yê ku di hucreyê de dest pê dike kopî bikin.C2.

Û paşê, di stûnek din de navnîşek hejmarên hefteyê çêkin (dibêjin, di stûna E de) û firotanên her hefte bi karanîna formula SUMIF ya jêrîn hesab bikin:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Li ku derê E2 hejmara hefteyê ye.

Di vê nimûneyê de, em bi navnîşek firotanên Adarê re dixebitin, ji ber vê yekê me hejmarên hefteyê 10 heta 14 hene, wekî di dîmena jêrîn de tê xuyang kirin:

Bi vî rengî, hûn dikarin navgîniya firotanê ji bo hefteyek diyar hesab bikin:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Heke stûna arîkar a bi formula WEEKNUM baş di sêwirana daneya we de cîh nagire, ez poşman im ku ji we re bêjim ku rêyek hêsan tune ku meriv jê xilas bibe ji ber ku Excel WEEKNUM yek ji wan fonksiyonan e. ku argumanên rêzê qebûl nake. Ji ber vê yekê, ew nikare di nav SUMPRODUCT an formûlek rêzek din de mîna fonksiyona MEHA-yê di senaryoyek weha de were bikar anîn.

Çawa li ser bingeha hejmara hefteyê şaneyan ronî dikin

Em bibêjin navnîşek we ya dirêj heye. tarîxên di hin stûnan de û hûn dixwazin tenê yên ku bi hefteyek diyarkirî ve girêdayî ne ronî bikin. Tiştê ku hûn hewce ne qaîdeyek formatkirina şertî ye ku bi formula WEEKNUM-ê mîna vê ye:

=WEEKNUM($A2)=10

Wek ku di dîmena jêrîn de tê xuyang kirin, qaîdeyek firotanên ku di hefteya 10-an de hatine çêkirin ronî dike, ku ev e. Hefteya yekem a Adar 2015. Ji ber ku qayde ji bo A2:B15 derbas dibe, ew di her du stûnan de nirxan ronî dike. Hûn dikarin di vê yekê de di derbarê afirandina qaîdeyên formatkirina şertî de bêtir fêr bibintutorial: Formkirina şertî ya Excel li ser bingeha nirxek şaneyek din.

Bi vî rengî hûn dikarin hejmarên hefteyê li Excel hesab bikin, jimareya hefteyê veguherînin tarîx û jimareya hefteyê ji tarîxê derxin. Hêvîdarim, formulên WEEKNUM ku we îro fêr bûne dê di pelên xebata we de bikêr bibin. Di dersa paşîn de, em ê li ser hesabkirina temen û salan li Excel biaxivin. Ez ji bo xwendinê spas dikim û hêvî dikim ku hûn hefteya pêş me bibînin!